New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso.F90 in branches/2012/dev_v3_4_STABLE_2012/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2012/dev_v3_4_STABLE_2012/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_iso.F90 @ 3783

Last change on this file since 3783 was 3783, checked in by acc, 11 years ago

Branch dev_v3_4_STABLE_2012. #1043 correct sign of diagnostic diffusive transport
  • Property svn:keywords set to Id
File size: 16.0 KB
Line 
1MODULE traldf_iso
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :  OPA  !  1994-08  (G. Madec, M. Imbard)
7   !!            8.0  !  1997-05  (G. Madec)  split into traldf and trazdf
8   !!            NEMO !  2002-08  (G. Madec)  Free form, F90
9   !!            1.0  !  2005-11  (G. Madec)  merge traldf and trazdf :-)
10   !!            3.3  !  2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!----------------------------------------------------------------------
12#if   defined key_ldfslp   ||   defined key_esopa
13   !!----------------------------------------------------------------------
14   !!   'key_ldfslp'               slope of the lateral diffusive direction
15   !!----------------------------------------------------------------------
16   !!   tra_ldf_iso  : update the tracer trend with the horizontal
17   !!                  component of a iso-neutral laplacian operator
18   !!                  and with the vertical part of
19   !!                  the isopycnal or geopotential s-coord. operator
20   !!----------------------------------------------------------------------
21   USE oce             ! ocean dynamics and active tracers
22   USE dom_oce         ! ocean space and time domain
23   USE trc_oce         ! share passive tracers/Ocean variables
24   USE zdf_oce         ! ocean vertical physics
25   USE ldftra_oce      ! ocean active tracers: lateral physics
26   USE ldfslp          ! iso-neutral slopes
27   USE diaptr          ! poleward transport diagnostics
28   USE in_out_manager  ! I/O manager
29   USE iom             ! I/O library
30#if defined key_diaar5
31   USE phycst          ! physical constants
32   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
33#endif
34   USE wrk_nemo        ! Memory Allocation
35   USE timing          ! Timing
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   tra_ldf_iso   ! routine called by step.F90
41
42   !! * Substitutions
43#  include "domzgr_substitute.h90"
44#  include "ldftra_substitute.h90"
45#  include "vectopt_loop_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
48   !! $Id$
49   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE tra_ldf_iso( kt, kit000, cdtype, pgu, pgv,              &
54      &                                ptb, pta, kjpt, pahtb0 )
55      !!----------------------------------------------------------------------
56      !!                  ***  ROUTINE tra_ldf_iso  ***
57      !!
58      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
59      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
60      !!      add it to the general trend of tracer equation.
61      !!
62      !! ** Method  :   The horizontal component of the lateral diffusive trends
63      !!      is provided by a 2nd order operator rotated along neural or geopo-
64      !!      tential surfaces to which an eddy induced advection can be added
65      !!      It is computed using before fields (forward in time) and isopyc-
66      !!      nal or geopotential slopes computed in routine ldfslp.
67      !!
68      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
69      !!      ========    with partial cell update if ln_zps=T.
70      !!
71      !!      2nd part :  horizontal fluxes of the lateral mixing operator
72      !!      ========   
73      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
74      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
75      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
76      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
77      !!      take the horizontal divergence of the fluxes:
78      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
79      !!      Add this trend to the general trend (ta,sa):
80      !!         ta = ta + difft
81      !!
82      !!      3rd part: vertical trends of the lateral mixing operator
83      !!      ========  (excluding the vertical flux proportional to dk[t] )
84      !!      vertical fluxes associated with the rotated lateral mixing:
85      !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
86      !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
87      !!      take the horizontal divergence of the fluxes:
88      !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
89      !!      Add this trend to the general trend (ta,sa):
90      !!         pta = pta + difft
91      !!
92      !! ** Action :   Update pta arrays with the before rotated diffusion
93      !!----------------------------------------------------------------------
94      USE oce     , ONLY:   zftu => ua       , zftv  => va         ! (ua,va) used as workspace
95      !
96      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
97      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
98      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
99      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
100      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
101      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
102      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
103      REAL(wp)                             , INTENT(in   ) ::   pahtb0     ! background diffusion coef
104      !
105      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
106      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3   ! local scalars
107      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4   !   -      -
108      REAL(wp) ::  zcoef0, zbtr, ztra            !   -      -
109#if defined key_diaar5
110      REAL(wp)                         ::   zztmp               ! local scalar
111#endif
112      REAL(wp), POINTER, DIMENSION(:,:  ) ::  zdkt, zdk1t, z2d
113      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zdit, zdjt, ztfw 
114      !!----------------------------------------------------------------------
115      !
116      IF( nn_timing == 1 )  CALL timing_start('tra_ldf_iso')
117      !
118      CALL wrk_alloc( jpi, jpj,      zdkt, zdk1t, z2d ) 
119      CALL wrk_alloc( jpi, jpj, jpk, zdit, zdjt, ztfw  ) 
120      !
121
122      IF( kt == kit000 )  THEN
123         IF(lwp) WRITE(numout,*)
124         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator on ', cdtype
125         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
126      ENDIF
127      !
128      !                                                          ! ===========
129      DO jn = 1, kjpt                                            ! tracer loop
130         !                                                       ! ===========
131         !                                               
132         !!----------------------------------------------------------------------
133         !!   I - masked horizontal derivative
134         !!----------------------------------------------------------------------
135         !!bug ajout.... why?   ( 1,jpj,:) and (jpi,1,:) should be sufficient....
136         zdit (1,:,:) = 0.e0     ;     zdit (jpi,:,:) = 0.e0
137         zdjt (1,:,:) = 0.e0     ;     zdjt (jpi,:,:) = 0.e0
138         !!end
139
140         ! Horizontal tracer gradient
141         DO jk = 1, jpkm1
142            DO jj = 1, jpjm1
143               DO ji = 1, fs_jpim1   ! vector opt.
144                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
145                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
146               END DO
147            END DO
148         END DO
149         IF( ln_zps ) THEN      ! partial steps correction at the last ocean level
150            DO jj = 1, jpjm1
151               DO ji = 1, fs_jpim1   ! vector opt.
152                  zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)         
153                  zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)     
154               END DO
155            END DO
156         ENDIF
157
158         !!----------------------------------------------------------------------
159         !!   II - horizontal trend  (full)
160         !!----------------------------------------------------------------------
161!CDIR PARALLEL DO PRIVATE( zdk1t )
162         !                                                ! ===============
163         DO jk = 1, jpkm1                                 ! Horizontal slab
164            !                                             ! ===============
165            ! 1. Vertical tracer gradient at level jk and jk+1
166            ! ------------------------------------------------
167            ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
168            zdk1t(:,:) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
169            !
170            IF( jk == 1 ) THEN   ;   zdkt(:,:) = zdk1t(:,:)
171            ELSE                 ;   zdkt(:,:) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask(:,:,jk)
172            ENDIF
173
174            ! 2. Horizontal fluxes
175            ! --------------------   
176            DO jj = 1 , jpjm1
177               DO ji = 1, fs_jpim1   ! vector opt.
178                  zabe1 = ( fsahtu(ji,jj,jk) + pahtb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
179                  zabe2 = ( fsahtv(ji,jj,jk) + pahtb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
180                  !
181                  zmsku = 1. / MAX(  tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
182                     &             + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
183                  !
184                  zmskv = 1. / MAX(  tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
185                     &             + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
186                  !
187                  zcof1 = - fsahtu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
188                  zcof2 = - fsahtv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
189                  !
190                  zftu(ji,jj,jk ) = (  zabe1 * zdit(ji,jj,jk)   &
191                     &              + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
192                     &                         + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  ) * umask(ji,jj,jk)
193                  zftv(ji,jj,jk) = (  zabe2 * zdjt(ji,jj,jk)   &
194                     &              + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
195                     &                         + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  ) * vmask(ji,jj,jk)                 
196               END DO
197            END DO
198
199            ! II.4 Second derivative (divergence) and add to the general trend
200            ! ----------------------------------------------------------------
201            DO jj = 2 , jpjm1
202               DO ji = fs_2, fs_jpim1   ! vector opt.
203                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
204                  ztra = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )
205                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
206               END DO
207            END DO
208            !                                          ! ===============
209         END DO                                        !   End of slab 
210         !                                             ! ===============
211         !
212         ! "Poleward" diffusive heat or salt transports (T-S case only)
213         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN
214            IF( jn == jp_tem)   htr_ldf(:) = ptr_vj( zftv(:,:,:) )
215            IF( jn == jp_sal)   str_ldf(:) = ptr_vj( zftv(:,:,:) )
216         ENDIF
217 
218#if defined key_diaar5
219         IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
220            z2d(:,:) = 0._wp 
221            ! note sign is reversed to give down-gradient diffusive transports (#1043)
222            zztmp = -1.0_wp * rau0 * rcp 
223            DO jk = 1, jpkm1
224               DO jj = 2, jpjm1
225                  DO ji = fs_2, fs_jpim1   ! vector opt.
226                     z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) 
227                  END DO
228               END DO
229            END DO
230            z2d(:,:) = zztmp * z2d(:,:)
231            CALL lbc_lnk( z2d, 'U', -1. )
232            CALL iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
233            z2d(:,:) = 0._wp 
234            DO jk = 1, jpkm1
235               DO jj = 2, jpjm1
236                  DO ji = fs_2, fs_jpim1   ! vector opt.
237                     z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) 
238                  END DO
239               END DO
240            END DO
241            z2d(:,:) = zztmp * z2d(:,:)
242            CALL lbc_lnk( z2d, 'V', -1. )
243            CALL iom_put( "vdiff_heattr", z2d )                  !  heat transport in i-direction
244         END IF
245#endif
246
247         !!----------------------------------------------------------------------
248         !!   III - vertical trend of T & S (extra diagonal terms only)
249         !!----------------------------------------------------------------------
250         
251         ! Local constant initialization
252         ! -----------------------------
253         ztfw(1,:,:) = 0.e0     ;     ztfw(jpi,:,:) = 0.e0
254         
255         ! Vertical fluxes
256         ! ---------------
257         
258         ! Surface and bottom vertical fluxes set to zero
259         ztfw(:,:, 1 ) = 0.e0      ;      ztfw(:,:,jpk) = 0.e0
260         
261         ! interior (2=<jk=<jpk-1)
262         DO jk = 2, jpkm1
263            DO jj = 2, jpjm1
264               DO ji = fs_2, fs_jpim1   ! vector opt.
265                  zcoef0 = - fsahtw(ji,jj,jk) * tmask(ji,jj,jk)
266                  !
267                  zmsku = 1./MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)      &
268                     &            + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk), 1.  )
269                  zmskv = 1./MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)      &
270                     &            + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk), 1.  )
271                  !
272                  zcoef3 = zcoef0 * e2t(ji,jj) * zmsku * wslpi (ji,jj,jk)
273                  zcoef4 = zcoef0 * e1t(ji,jj) * zmskv * wslpj (ji,jj,jk)
274                  !
275                  ztfw(ji,jj,jk) = zcoef3 * (   zdit(ji  ,jj  ,jk-1) + zdit(ji-1,jj  ,jk)      &
276                     &                        + zdit(ji-1,jj  ,jk-1) + zdit(ji  ,jj  ,jk)  )   &
277                     &           + zcoef4 * (   zdjt(ji  ,jj  ,jk-1) + zdjt(ji  ,jj-1,jk)      &
278                     &                        + zdjt(ji  ,jj-1,jk-1) + zdjt(ji  ,jj  ,jk)  )
279               END DO
280            END DO
281         END DO
282         
283         
284         ! I.5 Divergence of vertical fluxes added to the general tracer trend
285         ! -------------------------------------------------------------------
286         DO jk = 1, jpkm1
287            DO jj = 2, jpjm1
288               DO ji = fs_2, fs_jpim1   ! vector opt.
289                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
290                  ztra = (  ztfw(ji,jj,jk) - ztfw(ji,jj,jk+1)  ) * zbtr
291                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
292               END DO
293            END DO
294         END DO
295         !
296      END DO
297      !
298      CALL wrk_dealloc( jpi, jpj,      zdkt, zdk1t, z2d ) 
299      CALL wrk_dealloc( jpi, jpj, jpk, zdit, zdjt, ztfw  ) 
300      !
301      IF( nn_timing == 1 )  CALL timing_stop('tra_ldf_iso')
302      !
303   END SUBROUTINE tra_ldf_iso
304
305#else
306   !!----------------------------------------------------------------------
307   !!   default option :   Dummy code   NO rotation of the diffusive tensor
308   !!----------------------------------------------------------------------
309CONTAINS
310   SUBROUTINE tra_ldf_iso( kt, kit000,cdtype, pgu, pgv, ptb, pta, kjpt, pahtb0 )      ! Empty routine
311      INTEGER:: kt, kit000
312      CHARACTER(len=3) ::   cdtype
313      REAL, DIMENSION(:,:,:) ::   pgu, pgv   ! tracer gradient at pstep levels
314      REAL, DIMENSION(:,:,:,:) ::   ptb, pta
315      WRITE(*,*) 'tra_ldf_iso: You should not have seen this print! error?', kt, kit000, cdtype,   &
316         &                       pgu(1,1,1), pgv(1,1,1), ptb(1,1,1,1), pta(1,1,1,1), kjpt, pahtb0
317   END SUBROUTINE tra_ldf_iso
318#endif
319
320   !!==============================================================================
321END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.