New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcmod.F90 in branches/2013/dev_ECMWF_waves/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2013/dev_ECMWF_waves/NEMOGCM/NEMO/OPA_SRC/SBC/sbcmod.F90 @ 4352

Last change on this file since 4352 was 4352, checked in by acc, 10 years ago

Branch 2013/dev_ECMWF_waves ticket #1216. Corrections to first set of code imports to solve compilation issues

  • Property svn:keywords set to Id
File size: 27.1 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!            3.4  ! 2011-11  (C. Harris) CICE added as an option
14   !!            3.5  ! 2012-11  (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!   sbc_init       : read namsbc namelist
19   !!   sbc            : surface ocean momentum, heat and freshwater boundary conditions
20   !!----------------------------------------------------------------------
21   USE oce              ! ocean dynamics and tracers
22   USE dom_oce          ! ocean space and time domain
23   USE phycst           ! physical constants
24   USE sbc_oce          ! Surface boundary condition: ocean fields
25   USE sbc_ice          ! Surface boundary condition: ice fields
26   USE sbcdcy           ! surface boundary condition: diurnal cycle
27   USE sbcssm           ! surface boundary condition: sea-surface mean variables
28   USE sbcapr           ! surface boundary condition: atmospheric pressure
29   USE sbcana           ! surface boundary condition: analytical formulation
30   USE sbcflx           ! surface boundary condition: flux formulation
31   USE sbcblk_clio      ! surface boundary condition: bulk formulation : CLIO
32   USE sbcblk_core      ! surface boundary condition: bulk formulation : CORE
33   USE sbcblk_mfs       ! surface boundary condition: bulk formulation : MFS
34   USE sbcice_if        ! surface boundary condition: ice-if sea-ice model
35   USE sbcice_lim       ! surface boundary condition: LIM 3.0 sea-ice model
36   USE sbcice_lim_2     ! surface boundary condition: LIM 2.0 sea-ice model
37   USE sbcice_cice      ! surface boundary condition: CICE    sea-ice model
38   USE sbccpl           ! surface boundary condition: coupled florulation
39   USE cpl_oasis3, ONLY:lk_cpl      ! are we in coupled mode?
40   USE sbcssr           ! surface boundary condition: sea surface restoring
41   USE sbcrnf           ! surface boundary condition: runoffs
42   USE sbcfwb           ! surface boundary condition: freshwater budget
43   USE closea           ! closed sea
44   USE icbstp           ! Icebergs!
45
46   USE prtctl           ! Print control                    (prt_ctl routine)
47   USE iom              ! IOM library
48   USE in_out_manager   ! I/O manager
49   USE lib_mpp          ! MPP library
50   USE timing           ! Timing
51   USE sbcwave          ! Wave module
52   USE sbcwave_ecmwf    ! ECMWF wave module
53
54   IMPLICIT NONE
55   PRIVATE
56
57   PUBLIC   sbc        ! routine called by step.F90
58   PUBLIC   sbc_init   ! routine called by opa.F90
59   
60   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
61     
62   !! * Substitutions
63#  include "domzgr_substitute.h90"
64   !!----------------------------------------------------------------------
65   !! NEMO/OPA 4.0 , NEMO-consortium (2011)
66   !! $Id$
67   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
68   !!----------------------------------------------------------------------
69CONTAINS
70
71   SUBROUTINE sbc_init
72      !!---------------------------------------------------------------------
73      !!                    ***  ROUTINE sbc_init ***
74      !!
75      !! ** Purpose :   Initialisation of the ocean surface boundary computation
76      !!
77      !! ** Method  :   Read the namsbc namelist and set derived parameters
78      !!                Call init routines for all other SBC modules that have one
79      !!
80      !! ** Action  : - read namsbc parameters
81      !!              - nsbc: type of sbc
82      !!----------------------------------------------------------------------
83      INTEGER ::   icpt   ! local integer
84      !!
85      NAMELIST/namsbc/ nn_fsbc   , ln_ana    , ln_flx ,  ln_blk_clio, ln_blk_core, ln_cpl,   &
86         &             ln_blk_mfs, ln_apr_dyn, nn_ice ,  nn_ice_embd, ln_dm2dc   , ln_rnf,   &
87         &             ln_ssr    , nn_fwb    , ln_cdgw , ln_wave    , ln_sdw     , nn_lsm,   &
88         &             cn_iceflx , ln_stcor  , ln_tauoc, ln_wavetke 
89      INTEGER  ::   ios
90      !!----------------------------------------------------------------------
91
92      IF(lwp) THEN
93         WRITE(numout,*)
94         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
95         WRITE(numout,*) '~~~~~~~~ '
96      ENDIF
97
98      REWIND( numnam_ref )              ! Namelist namsbc in reference namelist : Surface boundary
99      READ  ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901)
100901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in reference namelist', lwp )
101
102      REWIND( numnam_cfg )              ! Namelist namsbc in configuration namelist : Parameters of the run
103      READ  ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 )
104902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in configuration namelist', lwp )
105      WRITE ( numond, namsbc )
106
107      !                          ! overwrite namelist parameter using CPP key information
108      IF( Agrif_Root() ) THEN                ! AGRIF zoom
109        IF( lk_lim2 )   nn_ice      = 2
110        IF( lk_lim3 )   nn_ice      = 3
111        IF( lk_cice )   nn_ice      = 4
112      ENDIF
113      IF( cp_cfg == 'gyre' ) THEN            ! GYRE configuration
114          ln_ana      = .TRUE.   
115          nn_ice      =   0
116      ENDIF
117     
118      IF(lwp) THEN               ! Control print
119         WRITE(numout,*) '        Namelist namsbc (partly overwritten with CPP key setting)'
120         WRITE(numout,*) '           frequency update of sbc (and ice)             nn_fsbc     = ', nn_fsbc
121         WRITE(numout,*) '           Type of sbc : '
122         WRITE(numout,*) '              analytical formulation                     ln_ana      = ', ln_ana
123         WRITE(numout,*) '              flux       formulation                     ln_flx      = ', ln_flx
124         WRITE(numout,*) '              CLIO bulk  formulation                     ln_blk_clio = ', ln_blk_clio
125         WRITE(numout,*) '              CORE bulk  formulation                     ln_blk_core = ', ln_blk_core
126         WRITE(numout,*) '              MFS  bulk  formulation                     ln_blk_mfs  = ', ln_blk_mfs
127         WRITE(numout,*) '              coupled    formulation (T if key_sbc_cpl)  ln_cpl      = ', ln_cpl
128         WRITE(numout,*) '              Flux handling over ice categories          cn_iceflx   = ', TRIM (cn_iceflx)
129         WRITE(numout,*) '           Misc. options of sbc : '
130         WRITE(numout,*) '              Patm gradient added in ocean & ice Eqs.    ln_apr_dyn  = ', ln_apr_dyn
131         WRITE(numout,*) '              ice management in the sbc (=0/1/2/3)       nn_ice      = ', nn_ice 
132         WRITE(numout,*) '              ice-ocean embedded/levitating (=0/1/2)     nn_ice_embd = ', nn_ice_embd
133         WRITE(numout,*) '              daily mean to diurnal cycle qsr            ln_dm2dc    = ', ln_dm2dc 
134         WRITE(numout,*) '              runoff / runoff mouths                     ln_rnf      = ', ln_rnf
135         WRITE(numout,*) '              Sea Surface Restoring on SST and/or SSS    ln_ssr      = ', ln_ssr
136         WRITE(numout,*) '              FreshWater Budget control  (=0/1/2)        nn_fwb      = ', nn_fwb
137         WRITE(numout,*) '              closed sea (=0/1) (set in namdom)          nn_closea   = ', nn_closea
138         WRITE(numout,*) '              n. of iterations if land-sea-mask applied  nn_lsm      = ', nn_lsm
139         WRITE(numout,*) '              Drag coefficient from wave model           ln_cdgw     = ', ln_cdgw 
140         WRITE(numout,*) '              Stokes-Coriolis forcing from wave model    ln_stcor    = ', ln_stcor 
141         WRITE(numout,*) '              TKE wave breaking BC from wave model       ln_wavetke  = ', ln_wavetke
142         WRITE(numout,*) '              Wave-modified stress from wave model       ln_tauoc    = ', ln_tauoc
143      ENDIF
144
145      !   Flux handling over ice categories
146#if defined key_coupled 
147      SELECT CASE ( TRIM (cn_iceflx))
148      CASE ('ave')
149         ln_iceflx_ave    = .TRUE.
150         ln_iceflx_linear = .FALSE.
151      CASE ('linear')
152         ln_iceflx_ave    = .FALSE.
153         ln_iceflx_linear = .TRUE.
154      CASE default
155         ln_iceflx_ave    = .FALSE.
156         ln_iceflx_linear = .FALSE.
157      END SELECT
158      IF(lwp) WRITE(numout,*) '              Fluxes averaged over all ice categories         ln_iceflx_ave    = ', ln_iceflx_ave
159      IF(lwp) WRITE(numout,*) '              Fluxes distributed linearly over ice categories ln_iceflx_linear = ', ln_iceflx_linear
160#endif
161      !
162      !                              ! allocate sbc arrays
163      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_oce arrays' )
164
165      !                          ! Checks:
166      IF( .NOT. ln_rnf ) THEN                      ! no specific treatment in vicinity of river mouths
167         ln_rnf_mouth  = .false.                     
168         IF( sbc_rnf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_rnf arrays' )
169         nkrnf         = 0
170         rnf     (:,:) = 0.0_wp
171         rnfmsk  (:,:) = 0.0_wp
172         rnfmsk_z(:)   = 0.0_wp
173      ENDIF
174      IF( nn_ice == 0  )   fr_i(:,:) = 0.e0        ! no ice in the domain, ice fraction is always zero
175
176      sfx(:,:) = 0.0_wp                            ! the salt flux due to freezing/melting will be computed (i.e. will be non-zero)
177                                                   ! only if sea-ice is present
178 
179      fmmflx(:,:) = 0.0_wp                        ! freezing-melting array initialisation
180
181      !                                            ! restartability   
182      IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR.   &
183          MOD( nstock             , nn_fsbc) /= 0 ) THEN
184         WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock,   &
185            &           ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
186         CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
187      ENDIF
188      !
189      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
190         &  CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' )
191      !
192      IF( ( nn_ice == 2 .OR. nn_ice ==3 ) .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. lk_cpl ) )   &
193         &   CALL ctl_stop( 'LIM sea-ice model requires a bulk formulation or coupled configuration' )
194      IF( nn_ice == 4 .AND. .NOT.( ln_blk_core .OR. lk_cpl ) )   &
195         &   CALL ctl_stop( 'CICE sea-ice model requires ln_blk_core or lk_cpl' )
196      IF( nn_ice == 4 .AND. lk_agrif )   &
197         &   CALL ctl_stop( 'CICE sea-ice model not currently available with AGRIF' )
198      IF( ( nn_ice == 3 .OR. nn_ice == 4 ) .AND. nn_ice_embd == 0 )   &
199         &   CALL ctl_stop( 'LIM3 and CICE sea-ice models require nn_ice_embd = 1 or 2' )
200#if defined key_coupled
201      IF( ln_iceflx_ave .AND. ln_iceflx_linear ) &
202         &   CALL ctl_stop( ' ln_iceflx_ave and ln_iceflx_linear options are not compatible' )
203      IF( ( nn_ice ==3 .AND. lk_cpl) .AND. .NOT. ( ln_iceflx_ave .OR. ln_iceflx_linear ) ) &
204         &   CALL ctl_stop( ' With lim3 coupled, either ln_iceflx_ave or ln_iceflx_linear must be set to .TRUE.' )
205#endif     
206      IF( ln_dm2dc )   nday_qsr = -1   ! initialisation flag
207
208      IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk_core ) )   &
209         &   CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or core-bulk formulation' )
210     
211      IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) )  < 8 ) )   &
212         &   CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
213
214      IF ( ln_wave ) THEN
215      !Activated wave module but neither drag nor stokes drift activated
216         IF ( .NOT.(ln_cdgw .OR. ln_sdw) )   THEN
217            CALL ctl_warn( 'Ask for wave coupling but nor drag coefficient (ln_cdgw=F) neither stokes drift activated (ln_sdw=F)' )
218      !drag coefficient read from wave model definable only with mfs bulk formulae and core
219         ELSEIF (ln_cdgw .AND. .NOT.(ln_blk_mfs .OR. ln_blk_core) )       THEN       
220             CALL ctl_stop( 'drag coefficient read from wave model definable only with mfs bulk formulae and core')
221         ENDIF
222      ELSE
223      IF ( ln_cdgw .OR. ln_sdw  )                                         & 
224         &   CALL ctl_warn('Not Activated Wave Module (ln_wave=F) but     &
225         & asked coupling with drag coefficient (ln_cdgw =T) or Stokes drift (ln_sdw=T) ')
226      ENDIF 
227     
228      !                          ! Choice of the Surface Boudary Condition (set nsbc)
229      icpt = 0
230      IF( ln_ana          ) THEN   ;   nsbc =  1   ; icpt = icpt + 1   ;   ENDIF       ! analytical      formulation
231      IF( ln_flx          ) THEN   ;   nsbc =  2   ; icpt = icpt + 1   ;   ENDIF       ! flux            formulation
232      IF( ln_blk_clio     ) THEN   ;   nsbc =  3   ; icpt = icpt + 1   ;   ENDIF       ! CLIO bulk       formulation
233      IF( ln_blk_core     ) THEN   ;   nsbc =  4   ; icpt = icpt + 1   ;   ENDIF       ! CORE bulk       formulation
234      IF( ln_blk_mfs      ) THEN   ;   nsbc =  6   ; icpt = icpt + 1   ;   ENDIF       ! MFS  bulk       formulation
235      IF( ln_cpl          ) THEN   ;   nsbc =  5   ; icpt = icpt + 1   ;   ENDIF       ! Coupled         formulation
236      IF( cp_cfg == 'gyre') THEN   ;   nsbc =  0                       ;   ENDIF       ! GYRE analytical formulation
237      IF( lk_esopa        )            nsbc = -1                                       ! esopa test, ALL formulations
238      !
239      IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN
240         WRITE(numout,*)
241         WRITE(numout,*) '           E R R O R in setting the sbc, one and only one namelist/CPP key option '
242         WRITE(numout,*) '                     must be choosen. You choose ', icpt, ' option(s)'
243         WRITE(numout,*) '                     We stop'
244         nstop = nstop + 1
245      ENDIF
246      IF(lwp) THEN
247         WRITE(numout,*)
248         IF( nsbc == -1 )   WRITE(numout,*) '              ESOPA test All surface boundary conditions'
249         IF( nsbc ==  0 )   WRITE(numout,*) '              GYRE analytical formulation'
250         IF( nsbc ==  1 )   WRITE(numout,*) '              analytical formulation'
251         IF( nsbc ==  2 )   WRITE(numout,*) '              flux formulation'
252         IF( nsbc ==  3 )   WRITE(numout,*) '              CLIO bulk formulation'
253         IF( nsbc ==  4 )   WRITE(numout,*) '              CORE bulk formulation'
254         IF( nsbc ==  5 )   WRITE(numout,*) '              coupled formulation'
255         IF( nsbc ==  6 )   WRITE(numout,*) '              MFS Bulk formulation'
256      ENDIF
257      !
258                          CALL sbc_ssm_init               ! Sea-surface mean fields initialisation
259      !
260      IF( ln_ssr      )   CALL sbc_ssr_init               ! Sea-Surface Restoring initialisation
261      !
262      IF( nn_ice == 4 )   CALL cice_sbc_init( nsbc )      ! CICE initialisation
263      !
264   END SUBROUTINE sbc_init
265
266
267   SUBROUTINE sbc( kt )
268      !!---------------------------------------------------------------------
269      !!                    ***  ROUTINE sbc  ***
270      !!             
271      !! ** Purpose :   provide at each time-step the ocean surface boundary
272      !!                condition (momentum, heat and freshwater fluxes)
273      !!
274      !! ** Method  :   blah blah  to be written ?????????
275      !!                CAUTION : never mask the surface stress field (tke sbc)
276      !!
277      !! ** Action  : - set the ocean surface boundary condition at before and now
278      !!                time step, i.e. 
279      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b
280      !!                utau  , vtau  , qns  , qsr  , emp  , sfx  , qrp  , erp
281      !!              - updte the ice fraction : fr_i
282      !!----------------------------------------------------------------------
283      INTEGER, INTENT(in) ::   kt       ! ocean time step
284      !!---------------------------------------------------------------------
285      !
286      IF( nn_timing == 1 )  CALL timing_start('sbc')
287      !
288      !                                            ! ---------------------------------------- !
289      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
290         !                                         ! ---------------------------------------- !
291         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
292         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
293         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
294         ! The 3D heat content due to qsr forcing is treated in traqsr
295         ! qsr_b (:,:) = qsr (:,:)
296         emp_b(:,:) = emp(:,:)
297         sfx_b(:,:) = sfx(:,:)
298      ENDIF
299      !                                            ! ---------------------------------------- !
300      !                                            !        forcing field computation         !
301      !                                            ! ---------------------------------------- !
302      !
303      IF( ln_apr_dyn ) CALL sbc_apr( kt )                ! atmospheric pressure provided at kt+0.5*nn_fsbc
304                                                         ! (caution called before sbc_ssm)
305      !
306      CALL sbc_ssm( kt )                                 ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
307      !                                                  ! averaged over nf_sbc time-step
308
309      IF (ln_cdgw) CALL sbc_wave_ecmwf( kt )
310      ! Read wave parameters if Stokes-Coriolis forcing OR wave parameters for TKE are needed
311      ! Also read it if drag coefficient to ensure that we use the neutral 10m from WAM.
312      IF (ln_stcor .OR. ln_wavetke .OR. ln_tauoc .OR. ln_cdgw) THEN
313         CALL sbc_wavepar( kt )
314      ENDIF
315
316      IF (ln_wave) CALL sbc_wave( kt )
317                                                   !==  sbc formulation  ==!
318                                                           
319      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
320      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, sfx)
321      CASE(  0 )   ;   CALL sbc_gyre    ( kt )                    ! analytical formulation : GYRE configuration
322      CASE(  1 )   ;   CALL sbc_ana     ( kt )                    ! analytical formulation : uniform sbc
323      CASE(  2 )   ;   CALL sbc_flx     ( kt )                    ! flux formulation
324      CASE(  3 )   ;   CALL sbc_blk_clio( kt )                    ! bulk formulation : CLIO for the ocean
325      CASE(  4 )   ;   CALL sbc_blk_core( kt )                    ! bulk formulation : CORE for the ocean
326      CASE(  5 )   ;   CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! coupled formulation
327      CASE(  6 )   ;   CALL sbc_blk_mfs ( kt )                    ! bulk formulation : MFS for the ocean
328      CASE( -1 )                               
329                       CALL sbc_ana     ( kt )                    ! ESOPA, test ALL the formulations
330                       CALL sbc_gyre    ( kt )                    !
331                       CALL sbc_flx     ( kt )                    !
332                       CALL sbc_blk_clio( kt )                    !
333                       CALL sbc_blk_core( kt )                    !
334                       CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   !
335      END SELECT
336
337      !                                            !==  Misc. Options  ==!
338     
339      SELECT CASE( nn_ice )                                       ! Update heat and freshwater fluxes over sea-ice areas
340      CASE(  1 )   ;         CALL sbc_ice_if   ( kt )                ! Ice-cover climatology ("Ice-if" model)
341      CASE(  2 )   ;         CALL sbc_ice_lim_2( kt, nsbc )          ! LIM-2 ice model
342      CASE(  3 )   ;         CALL sbc_ice_lim  ( kt, nsbc )          ! LIM-3 ice model
343      !is it useful?
344      CASE(  4 )   ;         CALL sbc_ice_cice ( kt, nsbc )          ! CICE ice model
345      END SELECT                                             
346
347      IF( ln_icebergs    )   CALL icb_stp( kt )                   ! compute icebergs
348
349      IF( ln_rnf         )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
350 
351      IF( ln_ssr         )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
352
353      IF( nn_fwb    /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
354
355      IF( nn_closea == 1 )   CALL sbc_clo( kt )                   ! treatment of closed sea in the model domain
356      !                                                           ! (update freshwater fluxes)
357!RBbug do not understand why see ticket 667
358      !clem-bugsal CALL lbc_lnk( emp, 'T', 1. )
359      !
360      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
361         !                                             ! ---------------------------------------- !
362         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
363            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
364            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
365            CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b )   ! before i-stress  (U-point)
366            CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b )   ! before j-stress  (V-point)
367            CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b  )   ! before non solar heat flux (T-point)
368            ! The 3D heat content due to qsr forcing is treated in traqsr
369            ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b  ) ! before     solar heat flux (T-point)
370            CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b  )    ! before     freshwater flux (T-point)
371            ! To ensure restart capability with 3.3x/3.4 restart files    !! to be removed in v3.6
372            IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN
373               CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b )  ! before salt flux (T-point)
374            ELSE
375               sfx_b (:,:) = sfx(:,:)
376            ENDIF
377         ELSE                                                   !* no restart: set from nit000 values
378            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
379            utau_b(:,:) = utau(:,:) 
380            vtau_b(:,:) = vtau(:,:)
381            qns_b (:,:) = qns (:,:)
382            emp_b (:,:) = emp(:,:)
383            sfx_b (:,:) = sfx(:,:)
384         ENDIF
385      ENDIF
386      !                                                ! ---------------------------------------- !
387      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
388         !                                             ! ---------------------------------------- !
389         IF(lwp) WRITE(numout,*)
390         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
391            &                    'at it= ', kt,' date= ', ndastp
392         IF(lwp) WRITE(numout,*) '~~~~'
393         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau )
394         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau )
395         CALL iom_rstput( kt, nitrst, numrow, 'qns_b'  , qns  )
396         ! The 3D heat content due to qsr forcing is treated in traqsr
397         ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr  )
398         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp  )
399         CALL iom_rstput( kt, nitrst, numrow, 'sfx_b' , sfx )
400      ENDIF
401
402      !                                                ! ---------------------------------------- !
403      !                                                !        Outputs and control print         !
404      !                                                ! ---------------------------------------- !
405      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
406         CALL iom_put( "empmr" , emp  - rnf )                   ! upward water flux
407         CALL iom_put( "saltflx", sfx  )                        ! downward salt flux 
408                                                                ! (includes virtual salt flux beneath ice
409                                                                ! in linear free surface case)
410         CALL iom_put( "fmmflx", fmmflx  )                      ! Freezing-melting water flux
411         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
412         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
413         CALL iom_put( "qsr"   ,       qsr  )                   ! solar heat flux
414         IF( nn_ice > 0 )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
415      ENDIF
416      !
417      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at
418      CALL iom_put( "vtau", vtau )   ! j-wind stress    each time step in sea-ice)
419      CALL iom_put( "taum", taum )   ! wind stress module
420      CALL iom_put( "wspd", wndm )   ! wind speed  module
421      !
422      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
423         CALL prt_ctl(tab2d_1=fr_i             , clinfo1=' fr_i     - : ', mask1=tmask, ovlap=1 )
424         CALL prt_ctl(tab2d_1=(emp-rnf)        , clinfo1=' emp-rnf  - : ', mask1=tmask, ovlap=1 )
425         CALL prt_ctl(tab2d_1=(sfx-rnf)        , clinfo1=' sfx-rnf  - : ', mask1=tmask, ovlap=1 )
426         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask, ovlap=1 )
427         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask, ovlap=1 )
428         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, ovlap=1, kdim=jpk )
429         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst      - : ', mask1=tmask, ovlap=1, kdim=1   )
430         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss      - : ', mask1=tmask, ovlap=1, kdim=1   )
431         CALL prt_ctl(tab2d_1=utau             , clinfo1=' utau     - : ', mask1=umask,                      &
432            &         tab2d_2=vtau             , clinfo2=' vtau     - : ', mask2=vmask, ovlap=1 )
433      ENDIF
434
435      IF( kt == nitend )   CALL sbc_final         ! Close down surface module if necessary
436      !
437      IF( nn_timing == 1 )  CALL timing_stop('sbc')
438      !
439   END SUBROUTINE sbc
440
441
442   SUBROUTINE sbc_final
443      !!---------------------------------------------------------------------
444      !!                    ***  ROUTINE sbc_final  ***
445      !!
446      !! ** Purpose :   Finalize CICE (if used)
447      !!---------------------------------------------------------------------
448      !
449      IF( nn_ice == 4 )   CALL cice_sbc_final
450      !
451   END SUBROUTINE sbc_final
452
453   !!======================================================================
454END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.