New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

limitd_th.F90 in branches/2013/dev_LOCEAN_2013/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

Context Navigation

source: branches/2013/dev_LOCEAN_2013/NEMOGCM/NEMO/LIM_SRC_3/limitd_th.F90 @ 4161

Last change on this file since 4161 was 4161, checked in by cetlod, 10 years ago
dev_LOCEAN_2013 : merge in the 3rd dev branch dev_r4028_CNRS_LIM3, see ticket #1169
Property svn:keywords set to `Id`
File size: 48.7 KB

Line
1	MODULE limitd_th
2	!!======================================================================
3	!! * MODULE limitd_th *
4	!! LIM3 ice model : ice thickness distribution: Thermodynamics
5	!!======================================================================
6	!! History : - ! (W. H. Lipscomb and E.C. Hunke) CICE (c) original code
7	!! 3.0 ! 2005-12 (M. Vancoppenolle) adaptation to LIM-3
8	!! - ! 2006-06 (M. Vancoppenolle) adaptation to include salt, age and types
9	!! - ! 2007-04 (M. Vancoppenolle) Mass conservation checked
10	!!----------------------------------------------------------------------
11	#if defined key_lim3
12	!!----------------------------------------------------------------------
13	!! 'key_lim3' : LIM3 sea-ice model
14	!!----------------------------------------------------------------------
15	!! lim_itd_th : thermodynamics of ice thickness distribution
16	!! lim_itd_th_rem :
17	!! lim_itd_th_reb :
18	!! lim_itd_fitline :
19	!! lim_itd_shiftice :
20	!!----------------------------------------------------------------------
21	USE dom_ice ! LIM-3 domain
22	USE par_oce ! ocean parameters
23	USE dom_oce ! ocean domain
24	USE phycst ! physical constants (ocean directory)
25	USE thd_ice ! LIM-3 thermodynamic variables
26	USE ice ! LIM-3 variables
27	USE par_ice ! LIM-3 parameters
28	USE limthd_lac ! LIM-3 lateral accretion
29	USE limvar ! LIM-3 variables
30	USE limcons ! LIM-3 conservation
31	USE prtctl ! Print control
32	USE in_out_manager ! I/O manager
33	USE lib_mpp ! MPP library
34	USE wrk_nemo ! work arrays
35	USE lib_fortran ! to use key_nosignedzero
36	USE timing ! Timing
37
38	IMPLICIT NONE
39	PRIVATE
40
41	PUBLIC lim_itd_th ! called by ice_stp
42	PUBLIC lim_itd_th_rem
43	PUBLIC lim_itd_th_reb
44	PUBLIC lim_itd_fitline
45	PUBLIC lim_itd_shiftice
46
47	REAL(wp) :: epsi20 = 1.e-20_wp ! constant values
48	REAL(wp) :: epsi13 = 1.e-13_wp !
49	REAL(wp) :: epsi10 = 1.e-10_wp !
50
51	!!----------------------------------------------------------------------
52	!! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2010)
53	!! $Id$
54	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
55	!!----------------------------------------------------------------------
56	CONTAINS
57
58	SUBROUTINE lim_itd_th( kt )
59	!!------------------------------------------------------------------
60	!! * ROUTINE lim_itd_th *
61	!!
62	!! ** Purpose : computes the thermodynamics of ice thickness distribution
63	!!
64	!! ** Method :
65	!!------------------------------------------------------------------
66	INTEGER, INTENT(in) :: kt ! time step index
67	!
68	INTEGER :: jl, ja, jm, jbnd1, jbnd2 ! ice types dummy loop index
69	REAL(wp) :: zchk_v_i, zchk_smv, zchk_fs, zchk_fw, zchk_v_i_b, zchk_smv_b, zchk_fs_b, zchk_fw_b ! Check conservation (C Rousset)
70	REAL(wp) :: zchk_vmin, zchk_amin, zchk_amax ! Check errors (C Rousset)
71	!!------------------------------------------------------------------
72	IF( nn_timing == 1 ) CALL timing_start('limitd_th')
73
74	! -------------------------------
75	!- check conservation (C Rousset)
76	IF (ln_limdiahsb) THEN
77	zchk_v_i_b = glob_sum( SUM( v_i(:,:,:), dim=3 ) * area(:,:) * tms(:,:) )
78	zchk_smv_b = glob_sum( SUM( smv_i(:,:,:), dim=3 ) * area(:,:) * tms(:,:) )
79	zchk_fw_b = glob_sum( rdm_ice(:,:) * area(:,:) * tms(:,:) )
80	zchk_fs_b = glob_sum( ( sfx_bri(:,:) + sfx_thd(:,:) + sfx_res(:,:) + sfx_mec(:,:) ) * area(:,:) * tms(:,:) )
81	ENDIF
82	!- check conservation (C Rousset)
83	! -------------------------------
84
85	IF( kt == nit000 .AND. lwp ) THEN
86	WRITE(numout,*)
87	WRITE(numout,*) 'lim_itd_th : Thermodynamics of the ice thickness distribution'
88	WRITE(numout,*) '~~~~~~~~~~~'
89	ENDIF
90
91	!------------------------------------------------------------------------------\|
92	! 1) Transport of ice between thickness categories. \|
93	!------------------------------------------------------------------------------\|
94	! Given thermodynamic growth rates, transport ice between
95	! thickness categories.
96	DO jm = 1, jpm
97	jbnd1 = ice_cat_bounds(jm,1)
98	jbnd2 = ice_cat_bounds(jm,2)
99	IF( ice_ncat_types(jm) > 1 ) CALL lim_itd_th_rem( jbnd1, jbnd2, jm, kt )
100	END DO
101	!
102	CALL lim_var_glo2eqv ! only for info
103	CALL lim_var_agg(1)
104
105	!------------------------------------------------------------------------------\|
106	! 3) Add frazil ice growing in leads.
107	!------------------------------------------------------------------------------\|
108
109	CALL lim_thd_lac
110	CALL lim_var_glo2eqv ! only for info
111
112	!----------------------------------------------------------------------------------------
113	! 4) Computation of trend terms and get back to old values
114	!----------------------------------------------------------------------------------------
115
116	!- Trend terms
117	d_a_i_thd(:,:,:) = a_i(:,:,:) - old_a_i(:,:,:)
118	d_v_s_thd(:,:,:) = v_s(:,:,:) - old_v_s(:,:,:)
119	d_v_i_thd(:,:,:) = v_i(:,:,:) - old_v_i(:,:,:)
120	d_e_s_thd(:,:,:,:) = e_s(:,:,:,:) - old_e_s(:,:,:,:)
121	d_e_i_thd(:,:,:,:) = e_i(:,:,:,:) - old_e_i(:,:,:,:)
122	!?? d_oa_i_thd(:,:,:) = oa_i (:,:,:) - old_oa_i (:,:,:)
123	d_smv_i_thd(:,:,:) = 0._wp
124	IF( num_sal == 2 ) d_smv_i_thd(:,:,:) = smv_i(:,:,:) - old_smv_i(:,:,:)
125
126	! diag only (clem)
127	dv_dt_thd(:,:,:) = d_v_i_thd(:,:,:) * r1_rdtice * rday
128
129	IF(ln_ctl) THEN ! Control print
130	CALL prt_ctl_info(' ')
131	CALL prt_ctl_info(' - Cell values : ')
132	CALL prt_ctl_info(' ~~~~~~~~~~~~~ ')
133	CALL prt_ctl(tab2d_1=area , clinfo1=' lim_itd_th : cell area :')
134	CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_itd_th : at_i :')
135	CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_itd_th : vt_i :')
136	CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_itd_th : vt_s :')
137	DO jl = 1, jpl
138	CALL prt_ctl_info(' ')
139	CALL prt_ctl_info(' - Category : ', ivar1=jl)
140	CALL prt_ctl_info(' ~~~~~~~~~~')
141	CALL prt_ctl(tab2d_1=a_i (:,:,jl) , clinfo1= ' lim_itd_th : a_i : ')
142	CALL prt_ctl(tab2d_1=ht_i (:,:,jl) , clinfo1= ' lim_itd_th : ht_i : ')
143	CALL prt_ctl(tab2d_1=ht_s (:,:,jl) , clinfo1= ' lim_itd_th : ht_s : ')
144	CALL prt_ctl(tab2d_1=v_i (:,:,jl) , clinfo1= ' lim_itd_th : v_i : ')
145	CALL prt_ctl(tab2d_1=v_s (:,:,jl) , clinfo1= ' lim_itd_th : v_s : ')
146	CALL prt_ctl(tab2d_1=e_s (:,:,1,jl) , clinfo1= ' lim_itd_th : e_s : ')
147	CALL prt_ctl(tab2d_1=t_su (:,:,jl) , clinfo1= ' lim_itd_th : t_su : ')
148	CALL prt_ctl(tab2d_1=t_s (:,:,1,jl) , clinfo1= ' lim_itd_th : t_snow : ')
149	CALL prt_ctl(tab2d_1=sm_i (:,:,jl) , clinfo1= ' lim_itd_th : sm_i : ')
150	CALL prt_ctl(tab2d_1=smv_i (:,:,jl) , clinfo1= ' lim_itd_th : smv_i : ')
151	DO ja = 1, nlay_i
152	CALL prt_ctl_info(' ')
153	CALL prt_ctl_info(' - Layer : ', ivar1=ja)
154	CALL prt_ctl_info(' ~~~~~~~')
155	CALL prt_ctl(tab2d_1=t_i(:,:,ja,jl) , clinfo1= ' lim_itd_th : t_i : ')
156	CALL prt_ctl(tab2d_1=e_i(:,:,ja,jl) , clinfo1= ' lim_itd_th : e_i : ')
157	END DO
158	END DO
159	ENDIF
160	!
161	! -------------------------------
162	!- check conservation (C Rousset)
163	IF( ln_limdiahsb ) THEN
164	zchk_fs = glob_sum( ( sfx_bri(:,:) + sfx_thd(:,:) + sfx_res(:,:) + sfx_mec(:,:) ) * area(:,:) * tms(:,:) ) - zchk_fs_b
165	zchk_fw = glob_sum( rdm_ice(:,:) * area(:,:) * tms(:,:) ) - zchk_fw_b
166
167	zchk_v_i = ( glob_sum( SUM( v_i(:,:,:), dim=3 ) * area(:,:) * tms(:,:) ) - zchk_v_i_b - ( zchk_fw / rhoic ) ) * r1_rdtice
168	zchk_smv = ( glob_sum( SUM( smv_i(:,:,:), dim=3 ) * area(:,:) * tms(:,:) ) - zchk_smv_b ) * r1_rdtice + ( zchk_fs / rhoic )
169
170	zchk_vmin = glob_min(v_i)
171	zchk_amax = glob_max(SUM(a_i,dim=3))
172	zchk_amin = glob_min(a_i)
173
174	IF(lwp) THEN
175	IF ( ABS( zchk_v_i ) > 1.e-5 ) WRITE(numout,) 'violation volume [m3/day] (limitd_th) = ',(zchk_v_i rday)
176	IF ( ABS( zchk_smv ) > 1.e-4 ) WRITE(numout,) 'violation saline [psum3/day] (limitd_th) = ',(zchk_smv * rday)
177	IF ( zchk_vmin < 0. ) WRITE(numout,) 'violation v_i<0 [mm] (limitd_th) = ',(zchk_vmin 1.e-3)
178	IF ( zchk_amax > amax+epsi10 ) WRITE(numout,*) 'violation a_i>amax (limitd_th) = ',zchk_amax
179	IF ( zchk_amin < 0. ) WRITE(numout,*) 'violation a_i<0 (limitd_th) = ',zchk_amin
180	ENDIF
181	ENDIF
182	!- check conservation (C Rousset)
183	! -------------------------------
184	!
185	!- Recover Old values
186	a_i(:,:,:) = old_a_i (:,:,:)
187	v_s(:,:,:) = old_v_s (:,:,:)
188	v_i(:,:,:) = old_v_i (:,:,:)
189	e_s(:,:,:,:) = old_e_s (:,:,:,:)
190	e_i(:,:,:,:) = old_e_i (:,:,:,:)
191	!?? oa_i(:,:,:) = old_oa_i(:,:,:)
192	IF( num_sal == 2 ) smv_i(:,:,:) = old_smv_i(:,:,:)
193	!
194	IF( nn_timing == 1 ) CALL timing_stop('limitd_th')
195	END SUBROUTINE lim_itd_th
196	!
197
198	SUBROUTINE lim_itd_th_rem( klbnd, kubnd, ntyp, kt )
199	!!------------------------------------------------------------------
200	!! * ROUTINE lim_itd_th_rem *
201	!!
202	!! ** Purpose : computes the redistribution of ice thickness
203	!! after thermodynamic growth of ice thickness
204	!!
205	!! ** Method : Linear remapping
206	!!
207	!! References : W.H. Lipscomb, JGR 2001
208	!!------------------------------------------------------------------
209	INTEGER , INTENT (in) :: klbnd ! Start thickness category index point
210	INTEGER , INTENT (in) :: kubnd ! End point on which the the computation is applied
211	INTEGER , INTENT (in) :: ntyp ! Number of the type used
212	INTEGER , INTENT (in) :: kt ! Ocean time step
213	!
214	INTEGER :: ji, jj, jl ! dummy loop index
215	INTEGER :: ii, ij ! 2D corresponding indices to ji
216	INTEGER :: nd ! local integer
217	REAL(wp) :: zx1, zwk1, zdh0, zetamin, zdamax ! local scalars
218	REAL(wp) :: zx2, zwk2, zda0, zetamax ! - -
219	REAL(wp) :: zx3, zareamin, zindb ! - -
220	CHARACTER (len = 15) :: fieldid
221
222	INTEGER , POINTER, DIMENSION(:,:,:) :: zdonor ! donor category index
223
224	REAL(wp), POINTER, DIMENSION(:,:,:) :: zdhice ! ice thickness increment
225	REAL(wp), POINTER, DIMENSION(:,:,:) :: g0 ! coefficients for fitting the line of the ITD
226	REAL(wp), POINTER, DIMENSION(:,:,:) :: g1 ! coefficients for fitting the line of the ITD
227	REAL(wp), POINTER, DIMENSION(:,:,:) :: hL ! left boundary for the ITD for each thickness
228	REAL(wp), POINTER, DIMENSION(:,:,:) :: hR ! left boundary for the ITD for each thickness
229	REAL(wp), POINTER, DIMENSION(:,:,:) :: zht_i_o ! old ice thickness
230	REAL(wp), POINTER, DIMENSION(:,:,:) :: dummy_es
231	REAL(wp), POINTER, DIMENSION(:,:,:) :: zdaice, zdvice ! local increment of ice area and volume
232	REAL(wp), POINTER, DIMENSION(:) :: zvetamin, zvetamax ! maximum values for etas
233	INTEGER , POINTER, DIMENSION(:) :: nind_i, nind_j ! compressed indices for i/j directions
234	INTEGER :: nbrem ! number of cells with ice to transfer
235	REAL(wp) :: zslope ! used to compute local thermodynamic "speeds"
236	REAL(wp), POINTER, DIMENSION(:,:) :: zhb0, zhb1 ! category boundaries for thinnes categories
237	REAL(wp), POINTER, DIMENSION(:,:) :: vt_i_init, vt_i_final ! ice volume summed over categories
238	REAL(wp), POINTER, DIMENSION(:,:) :: vt_s_init, vt_s_final ! snow volume summed over categories
239	REAL(wp), POINTER, DIMENSION(:,:) :: et_i_init, et_i_final ! ice energy summed over categories
240	REAL(wp), POINTER, DIMENSION(:,:) :: et_s_init, et_s_final ! snow energy summed over categories
241	INTEGER , POINTER, DIMENSION(:,:) :: zremap_flag ! compute remapping or not ????
242	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhbnew ! new boundaries of ice categories
243	!!------------------------------------------------------------------
244
245	CALL wrk_alloc( jpi,jpj, zremap_flag ) ! integer
246	CALL wrk_alloc( jpi,jpj,jpl-1, zdonor ) ! integer
247	CALL wrk_alloc( jpi,jpj,jpl, zdhice, g0, g1, hL, hR, zht_i_o, dummy_es )
248	CALL wrk_alloc( jpi,jpj,jpl-1, zdaice, zdvice )
249	CALL wrk_alloc( jpi,jpj,jpl+1, zhbnew, kkstart = 0 )
250	CALL wrk_alloc( (jpi+1)*(jpj+1), zvetamin, zvetamax )
251	CALL wrk_alloc( (jpi+1)*(jpj+1), nind_i, nind_j ) ! integer
252	CALL wrk_alloc( jpi,jpj, zhb0,zhb1,vt_i_init,vt_i_final,vt_s_init,vt_s_final,et_i_init,et_i_final,et_s_init,et_s_final )
253
254	zareamin = epsi10 !minimum area in thickness categories tolerated by the conceptors of the model
255
256	!!----------------------------------------------------------------------------------------------
257	!! 0) Conservation checkand changes in each ice category
258	!!----------------------------------------------------------------------------------------------
259	IF( con_i ) THEN
260	CALL lim_column_sum (jpl, v_i, vt_i_init)
261	CALL lim_column_sum (jpl, v_s, vt_s_init)
262	CALL lim_column_sum_energy (jpl, nlay_i, e_i, et_i_init)
263	dummy_es(:,:,:) = e_s(:,:,1,:)
264	CALL lim_column_sum (jpl, dummy_es(:,:,:) , et_s_init)
265	ENDIF
266
267	!!----------------------------------------------------------------------------------------------
268	!! 1) Compute thickness and changes in each ice category
269	!!----------------------------------------------------------------------------------------------
270	IF( kt == nit000 .AND. lwp) THEN
271	WRITE(numout,*)
272	WRITE(numout,*) 'lim_itd_th_rem : Remapping the ice thickness distribution'
273	WRITE(numout,*) '~~~~~~~~~~~~~~~'
274	WRITE(numout,*) ' klbnd : ', klbnd
275	WRITE(numout,*) ' kubnd : ', kubnd
276	WRITE(numout,*) ' ntyp : ', ntyp
277	ENDIF
278
279	zdhice(:,:,:) = 0._wp
280	DO jl = klbnd, kubnd
281	DO jj = 1, jpj
282	DO ji = 1, jpi
283	zindb = 1.0-MAX(0.0,SIGN(1.0,-a_i(ji,jj,jl)+epsi10)) !0 if no ice and 1 if yes
284	ht_i(ji,jj,jl) = v_i(ji,jj,jl) / MAX(a_i(ji,jj,jl),epsi10) * zindb
285	zindb = 1.0-MAX(0.0,SIGN(1.0,-old_a_i(ji,jj,jl)+epsi10)) !0 if no ice and 1 if yes
286	zht_i_o(ji,jj,jl) = old_v_i(ji,jj,jl) / MAX(old_a_i(ji,jj,jl),epsi10) * zindb
287	IF( a_i(ji,jj,jl) > 1e-6 ) zdhice(ji,jj,jl) = ht_i(ji,jj,jl) - zht_i_o(ji,jj,jl)
288	END DO
289	END DO
290	END DO
291
292	!-----------------------------------------------------------------------------------------------
293	! 2) Compute fractional ice area in each grid cell
294	!-----------------------------------------------------------------------------------------------
295	at_i(:,:) = 0._wp
296	DO jl = klbnd, kubnd
297	at_i(:,:) = at_i(:,:) + a_i(:,:,jl)
298	END DO
299
300	!-----------------------------------------------------------------------------------------------
301	! 3) Identify grid cells with ice
302	!-----------------------------------------------------------------------------------------------
303	nbrem = 0
304	DO jj = 1, jpj
305	DO ji = 1, jpi
306	IF ( at_i(ji,jj) .gt. zareamin ) THEN
307	nbrem = nbrem + 1
308	nind_i(nbrem) = ji
309	nind_j(nbrem) = jj
310	zremap_flag(ji,jj) = 1
311	ELSE
312	zremap_flag(ji,jj) = 0
313	ENDIF
314	END DO !ji
315	END DO !jj
316
317	!-----------------------------------------------------------------------------------------------
318	! 4) Compute new category boundaries
319	!-----------------------------------------------------------------------------------------------
320	!- 4.1 Compute category boundaries
321	! Tricky trick see limitd_me.F90
322	! will be soon removed, CT
323	! hi_max(kubnd) = 999.99
324	zhbnew(:,:,:) = 0._wp
325
326	DO jl = klbnd, kubnd - 1
327	DO ji = 1, nbrem
328	ii = nind_i(ji)
329	ij = nind_j(ji)
330	!
331	IF ( ( zht_i_o(ii,ij,jl) .GT.epsi10 ) .AND. &
332	( zht_i_o(ii,ij,jl+1).GT.epsi10 ) ) THEN
333	!interpolate between adjacent category growth rates
334	zslope = ( zdhice(ii,ij,jl+1) - zdhice(ii,ij,jl) ) / &
335	( zht_i_o (ii,ij,jl+1) - zht_i_o (ii,ij,jl) )
336	zhbnew(ii,ij,jl) = hi_max(jl) + zdhice(ii,ij,jl) + &
337	zslope * ( hi_max(jl) - zht_i_o(ii,ij,jl) )
338	ELSEIF (zht_i_o(ii,ij,jl).gt.epsi10) THEN
339	zhbnew(ii,ij,jl) = hi_max(jl) + zdhice(ii,ij,jl)
340	ELSEIF (zht_i_o(ii,ij,jl+1).gt.epsi10) THEN
341	zhbnew(ii,ij,jl) = hi_max(jl) + zdhice(ii,ij,jl+1)
342	ELSE
343	zhbnew(ii,ij,jl) = hi_max(jl)
344	ENDIF
345	END DO
346
347	!- 4.2 Check that each zhbnew lies between adjacent values of ice thickness
348	DO ji = 1, nbrem
349	! jl, ji
350	ii = nind_i(ji)
351	ij = nind_j(ji)
352	! jl, ji
353	IF ( ( a_i(ii,ij,jl) .GT.epsi10) .AND. &
354	( ht_i(ii,ij,jl).GE. zhbnew(ii,ij,jl) ) &
355	) THEN
356	zremap_flag(ii,ij) = 0
357	ELSEIF ( ( a_i(ii,ij,jl+1) .GT. epsi10 ) .AND. &
358	( ht_i(ii,ij,jl+1).LE. zhbnew(ii,ij,jl) ) &
359	) THEN
360	zremap_flag(ii,ij) = 0
361	ENDIF
362
363	!- 4.3 Check that each zhbnew does not exceed maximal values hi_max
364	! jl, ji
365	IF (zhbnew(ii,ij,jl).gt.hi_max(jl+1)) THEN
366	zremap_flag(ii,ij) = 0
367	ENDIF
368	! jl, ji
369	IF (zhbnew(ii,ij,jl).lt.hi_max(jl-1)) THEN
370	zremap_flag(ii,ij) = 0
371	ENDIF
372	! jl, ji
373	END DO !ji
374	! ji
375	END DO !jl
376
377	!-----------------------------------------------------------------------------------------------
378	! 5) Identify cells where ITD is to be remapped
379	!-----------------------------------------------------------------------------------------------
380	nbrem = 0
381	DO jj = 1, jpj
382	DO ji = 1, jpi
383	IF ( zremap_flag(ji,jj) == 1 ) THEN
384	nbrem = nbrem + 1
385	nind_i(nbrem) = ji
386	nind_j(nbrem) = jj
387	ENDIF
388	END DO !ji
389	END DO !jj
390
391	!-----------------------------------------------------------------------------------------------
392	! 6) Fill arrays with lowermost / uppermost boundaries of 'new' categories
393	!-----------------------------------------------------------------------------------------------
394	DO jj = 1, jpj
395	DO ji = 1, jpi
396	zhb0(ji,jj) = hi_max_typ(0,ntyp) ! 0eme
397	zhb1(ji,jj) = hi_max_typ(1,ntyp) ! 1er
398
399	zhbnew(ji,jj,klbnd-1) = 0._wp
400
401	IF( a_i(ji,jj,kubnd) > epsi10 ) THEN
402	zhbnew(ji,jj,kubnd) = 3._wp * ht_i(ji,jj,kubnd) - 2._wp * zhbnew(ji,jj,kubnd-1)
403	ELSE
404	zhbnew(ji,jj,kubnd) = hi_max(kubnd)
405	ENDIF
406
407	IF( zhbnew(ji,jj,kubnd) < hi_max(kubnd-1) ) zhbnew(ji,jj,kubnd) = hi_max(kubnd-1)
408
409	END DO !jj
410	END DO !jj
411
412	!-----------------------------------------------------------------------------------------------
413	! 7) Compute g(h)
414	!-----------------------------------------------------------------------------------------------
415	!- 7.1 g(h) for category 1 at start of time step
416	CALL lim_itd_fitline( klbnd, zhb0, zhb1, zht_i_o(:,:,klbnd), &
417	& g0(:,:,klbnd), g1(:,:,klbnd), hL(:,:,klbnd), &
418	& hR(:,:,klbnd), zremap_flag )
419
420	!- 7.2 Area lost due to melting of thin ice (first category, klbnd)
421	DO ji = 1, nbrem
422	ii = nind_i(ji)
423	ij = nind_j(ji)
424
425	!ji
426	IF (a_i(ii,ij,klbnd) .gt. epsi10) THEN
427	zdh0 = zdhice(ii,ij,klbnd) !decrease of ice thickness in the lower category
428	! ji, a_i > epsi10
429	IF (zdh0 .lt. 0.0) THEN !remove area from category 1
430	! ji, a_i > epsi10; zdh0 < 0
431	zdh0 = MIN(-zdh0,hi_max(klbnd))
432
433	!Integrate g(1) from 0 to dh0 to estimate area melted
434	zetamax = MIN(zdh0,hR(ii,ij,klbnd)) - hL(ii,ij,klbnd)
435	IF (zetamax.gt.0.0) THEN
436	zx1 = zetamax
437	zx2 = 0.5 * zetamax*zetamax
438	zda0 = g1(ii,ij,klbnd) * zx2 + g0(ii,ij,klbnd) * zx1 !ice area removed
439	! Constrain new thickness <= ht_i
440	zdamax = a_i(ii,ij,klbnd) * &
441	(1.0 - ht_i(ii,ij,klbnd)/zht_i_o(ii,ij,klbnd)) ! zdamax > 0
442	!ice area lost due to melting of thin ice
443	zda0 = MIN(zda0, zdamax)
444
445	! Remove area, conserving volume
446	ht_i(ii,ij,klbnd) = ht_i(ii,ij,klbnd) &
447	* a_i(ii,ij,klbnd) / ( a_i(ii,ij,klbnd) - zda0 )
448	a_i(ii,ij,klbnd) = a_i(ii,ij,klbnd) - zda0
449	v_i(ii,ij,klbnd) = a_i(ii,ij,klbnd)*ht_i(ii,ij,klbnd) ! clem@useless ?
450	ENDIF ! zetamax > 0
451	! ji, a_i > epsi10
452
453	ELSE ! if ice accretion
454	! ji, a_i > epsi10; zdh0 > 0
455	IF ( ntyp .EQ. 1 ) zhbnew(ii,ij,klbnd-1) = MIN(zdh0,hi_max(klbnd))
456	! zhbnew was 0, and is shifted to the right to account for thin ice
457	! growth in openwater (F0 = f1)
458	IF ( ntyp .NE. 1 ) zhbnew(ii,ij,0) = 0
459	! in other types there is
460	! no open water growth (F0 = 0)
461	ENDIF ! zdh0
462
463	! a_i > epsi10
464	ENDIF ! a_i > epsi10
465
466	END DO ! ji
467
468	!- 7.3 g(h) for each thickness category
469	DO jl = klbnd, kubnd
470	CALL lim_itd_fitline(jl, zhbnew(:,:,jl-1), zhbnew(:,:,jl), ht_i(:,:,jl), &
471	g0(:,:,jl), g1(:,:,jl), hL(:,:,jl), hR(:,:,jl), &
472	zremap_flag)
473	END DO
474
475	!-----------------------------------------------------------------------------------------------
476	! 8) Compute area and volume to be shifted across each boundary
477	!-----------------------------------------------------------------------------------------------
478
479	DO jl = klbnd, kubnd - 1
480	DO jj = 1, jpj
481	DO ji = 1, jpi
482	zdonor(ji,jj,jl) = 0
483	zdaice(ji,jj,jl) = 0.0
484	zdvice(ji,jj,jl) = 0.0
485	END DO
486	END DO
487
488	DO ji = 1, nbrem
489	ii = nind_i(ji)
490	ij = nind_j(ji)
491
492	IF (zhbnew(ii,ij,jl) .gt. hi_max(jl)) THEN ! transfer from jl to jl+1
493
494	! left and right integration limits in eta space
495	zvetamin(ji) = MAX(hi_max(jl), hL(ii,ij,jl)) - hL(ii,ij,jl)
496	zvetamax(ji) = MIN(zhbnew(ii,ij,jl), hR(ii,ij,jl)) - hL(ii,ij,jl)
497	zdonor(ii,ij,jl) = jl
498
499	ELSE ! zhbnew(jl) <= hi_max(jl) ; transfer from jl+1 to jl
500
501	! left and right integration limits in eta space
502	zvetamin(ji) = 0.0
503	zvetamax(ji) = MIN(hi_max(jl), hR(ii,ij,jl+1)) - hL(ii,ij,jl+1)
504	zdonor(ii,ij,jl) = jl + 1
505
506	ENDIF ! zhbnew(jl) > hi_max(jl)
507
508	zetamax = MAX(zvetamax(ji), zvetamin(ji)) ! no transfer if etamax < etamin
509	zetamin = zvetamin(ji)
510
511	zx1 = zetamax - zetamin
512	zwk1 = zetamin*zetamin
513	zwk2 = zetamax*zetamax
514	zx2 = 0.5 * (zwk2 - zwk1)
515	zwk1 = zwk1 * zetamin
516	zwk2 = zwk2 * zetamax
517	zx3 = 1.0/3.0 * (zwk2 - zwk1)
518	nd = zdonor(ii,ij,jl)
519	zdaice(ii,ij,jl) = g1(ii,ij,nd)zx2 + g0(ii,ij,nd)zx1
520	zdvice(ii,ij,jl) = g1(ii,ij,nd)zx3 + g0(ii,ij,nd)zx2 + &
521	zdaice(ii,ij,jl)*hL(ii,ij,nd)
522
523	END DO ! ji
524	END DO ! jl klbnd -> kubnd - 1
525
526	!!----------------------------------------------------------------------------------------------
527	!! 9) Shift ice between categories
528	!!----------------------------------------------------------------------------------------------
529	CALL lim_itd_shiftice ( klbnd, kubnd, zdonor, zdaice, zdvice )
530
531	!!----------------------------------------------------------------------------------------------
532	!! 10) Make sure ht_i >= minimum ice thickness hi_min
533	!!----------------------------------------------------------------------------------------------
534
535	DO ji = 1, nbrem
536	ii = nind_i(ji)
537	ij = nind_j(ji)
538	IF ( ( a_i(ii,ij,1) > epsi10 ) .AND. ( ht_i(ii,ij,1) < hiclim ) ) THEN
539	a_i(ii,ij,1) = a_i(ii,ij,1) * ht_i(ii,ij,1) / hiclim
540	ht_i(ii,ij,1) = hiclim
541	v_i(ii,ij,1) = a_i(ii,ij,1) * ht_i(ii,ij,1) !clem@useless
542	ENDIF
543	END DO !ji
544
545	!!----------------------------------------------------------------------------------------------
546	!! 11) Conservation check
547	!!----------------------------------------------------------------------------------------------
548	IF ( con_i ) THEN
549	CALL lim_column_sum (jpl, v_i, vt_i_final)
550	fieldid = ' v_i : limitd_th '
551	CALL lim_cons_check (vt_i_init, vt_i_final, 1.0e-6, fieldid)
552
553	CALL lim_column_sum_energy (jpl, nlay_i, e_i, et_i_final)
554	fieldid = ' e_i : limitd_th '
555	CALL lim_cons_check (et_i_init, et_i_final, 1.0e-3, fieldid)
556
557	CALL lim_column_sum (jpl, v_s, vt_s_final)
558	fieldid = ' v_s : limitd_th '
559	CALL lim_cons_check (vt_s_init, vt_s_final, 1.0e-6, fieldid)
560
561	dummy_es(:,:,:) = e_s(:,:,1,:)
562	CALL lim_column_sum (jpl, dummy_es(:,:,:) , et_s_final)
563	fieldid = ' e_s : limitd_th '
564	CALL lim_cons_check (et_s_init, et_s_final, 1.0e-3, fieldid)
565	ENDIF
566
567	CALL wrk_dealloc( jpi,jpj, zremap_flag ) ! integer
568	CALL wrk_dealloc( jpi,jpj,jpl-1, zdonor ) ! integer
569	CALL wrk_dealloc( jpi,jpj,jpl, zdhice, g0, g1, hL, hR, zht_i_o, dummy_es )
570	CALL wrk_dealloc( jpi,jpj,jpl-1, zdaice, zdvice )
571	CALL wrk_dealloc( jpi,jpj,jpl+1, zhbnew, kkstart = 0 )
572	CALL wrk_dealloc( (jpi+1)*(jpj+1), zvetamin, zvetamax )
573	CALL wrk_dealloc( (jpi+1)*(jpj+1), nind_i, nind_j ) ! integer
574	CALL wrk_dealloc( jpi,jpj, zhb0,zhb1,vt_i_init,vt_i_final,vt_s_init,vt_s_final,et_i_init,et_i_final,et_s_init,et_s_final )
575
576	END SUBROUTINE lim_itd_th_rem
577
578
579	SUBROUTINE lim_itd_fitline( num_cat, HbL, Hbr, hice, &
580	& g0, g1, hL, hR, zremap_flag )
581	!!------------------------------------------------------------------
582	!! * ROUTINE lim_itd_fitline *
583	!!
584	!! ** Purpose : fit g(h) with a line using area, volume constraints
585	!!
586	!! ** Method : Fit g(h) with a line, satisfying area and volume constraints.
587	!! To reduce roundoff errors caused by large values of g0 and g1,
588	!! we actually compute g(eta), where eta = h - hL, and hL is the
589	!! left boundary.
590	!!------------------------------------------------------------------
591	INTEGER , INTENT(in ) :: num_cat ! category index
592	REAL(wp), DIMENSION(jpi,jpj), INTENT(in ) :: HbL, HbR ! left and right category boundaries
593	REAL(wp), DIMENSION(jpi,jpj), INTENT(in ) :: hice ! ice thickness
594	REAL(wp), DIMENSION(jpi,jpj), INTENT( out) :: g0, g1 ! coefficients in linear equation for g(eta)
595	REAL(wp), DIMENSION(jpi,jpj), INTENT( out) :: hL ! min value of range over which g(h) > 0
596	REAL(wp), DIMENSION(jpi,jpj), INTENT( out) :: hR ! max value of range over which g(h) > 0
597	INTEGER , DIMENSION(jpi,jpj), INTENT(in ) :: zremap_flag !
598	!
599	INTEGER :: ji,jj ! horizontal indices
600	REAL(wp) :: zh13 ! HbL + 1/3 * (HbR - HbL)
601	REAL(wp) :: zh23 ! HbL + 2/3 * (HbR - HbL)
602	REAL(wp) :: zdhr ! 1 / (hR - hL)
603	REAL(wp) :: zwk1, zwk2 ! temporary variables
604	REAL(wp) :: zacrith ! critical minimum concentration in an ice category
605	!!------------------------------------------------------------------
606	!
607	zacrith = 1.0e-6
608	!
609	DO jj = 1, jpj
610	DO ji = 1, jpi
611	!
612	IF( zremap_flag(ji,jj) == 1 .AND. a_i(ji,jj,num_cat) > zacrith &
613	& .AND. hice(ji,jj) > 0._wp ) THEN
614
615	! Initialize hL and hR
616
617	hL(ji,jj) = HbL(ji,jj)
618	hR(ji,jj) = HbR(ji,jj)
619
620	! Change hL or hR if hice falls outside central third of range
621
622	zh13 = 1.0/3.0 * (2.0*hL(ji,jj) + hR(ji,jj))
623	zh23 = 1.0/3.0 * (hL(ji,jj) + 2.0*hR(ji,jj))
624
625	IF ( hice(ji,jj) < zh13 ) THEN ; hR(ji,jj) = 3._wp * hice(ji,jj) - 2._wp * hL(ji,jj)
626	ELSEIF( hice(ji,jj) > zh23 ) THEN ; hL(ji,jj) = 3._wp * hice(ji,jj) - 2._wp * hR(ji,jj)
627	ENDIF
628
629	! Compute coefficients of g(eta) = g0 + g1*eta
630
631	zdhr = 1._wp / (hR(ji,jj) - hL(ji,jj))
632	zwk1 = 6._wp * a_i(ji,jj,num_cat) * zdhr
633	zwk2 = ( hice(ji,jj) - hL(ji,jj) ) * zdhr
634	g0(ji,jj) = zwk1 * ( 2._wp/3._wp - zwk2 )
635	g1(ji,jj) = 2._wp * zdhr * zwk1 * (zwk2 - 0.5)
636	!
637	ELSE ! remap_flag = .false. or a_i < epsi10
638	hL(ji,jj) = 0._wp
639	hR(ji,jj) = 0._wp
640	g0(ji,jj) = 0._wp
641	g1(ji,jj) = 0._wp
642	ENDIF ! a_i > epsi10
643	!
644	END DO
645	END DO
646	!
647	END SUBROUTINE lim_itd_fitline
648
649
650	SUBROUTINE lim_itd_shiftice( klbnd, kubnd, zdonor, zdaice, zdvice )
651	!!------------------------------------------------------------------
652	!! * ROUTINE lim_itd_shiftice *
653	!!
654	!! ** Purpose : shift ice across category boundaries, conserving everything
655	!! ( area, volume, energy, age*vol, and mass of salt )
656	!!
657	!! ** Method :
658	!!------------------------------------------------------------------
659	INTEGER , INTENT(in ) :: klbnd ! Start thickness category index point
660	INTEGER , INTENT(in ) :: kubnd ! End point on which the the computation is applied
661	INTEGER , DIMENSION(jpi,jpj,jpl-1), INTENT(in ) :: zdonor ! donor category index
662	REAL(wp), DIMENSION(jpi,jpj,jpl-1), INTENT(inout) :: zdaice ! ice area transferred across boundary
663	REAL(wp), DIMENSION(jpi,jpj,jpl-1), INTENT(inout) :: zdvice ! ice volume transferred across boundary
664
665	INTEGER :: ji, jj, jl, jl2, jl1, jk ! dummy loop indices
666	INTEGER :: ii, ij ! indices when changing from 2D-1D is done
667
668	REAL(wp), POINTER, DIMENSION(:,:,:) :: zaTsfn
669	REAL(wp), POINTER, DIMENSION(:,:) :: zworka ! temporary array used here
670
671	REAL(wp) :: zdvsnow, zdesnow ! snow volume and energy transferred
672	REAL(wp) :: zdeice ! ice energy transferred
673	REAL(wp) :: zdsm_vice ! ice salinity times volume transferred
674	REAL(wp) :: zdo_aice ! ice age times volume transferred
675	REAL(wp) :: zdaTsf ! aicen*Tsfcn transferred
676	REAL(wp) :: zindsn ! snow or not
677	REAL(wp) :: zindb ! ice or not
678
679	INTEGER, POINTER, DIMENSION(:) :: nind_i, nind_j ! compressed indices for i/j directions
680
681	INTEGER :: nbrem ! number of cells with ice to transfer
682
683	LOGICAL :: zdaice_negative ! true if daice < -puny
684	LOGICAL :: zdvice_negative ! true if dvice < -puny
685	LOGICAL :: zdaice_greater_aicen ! true if daice > aicen
686	LOGICAL :: zdvice_greater_vicen ! true if dvice > vicen
687	!!------------------------------------------------------------------
688
689	CALL wrk_alloc( jpi,jpj,jpl, zaTsfn )
690	CALL wrk_alloc( jpi,jpj, zworka )
691	CALL wrk_alloc( (jpi+1)*(jpj+1), nind_i, nind_j ) ! integer
692
693	!----------------------------------------------------------------------------------------------
694	! 1) Define a variable equal to a_i*T_su
695	!----------------------------------------------------------------------------------------------
696
697	DO jl = klbnd, kubnd
698	zaTsfn(:,:,jl) = a_i(:,:,jl)*t_su(:,:,jl)
699	END DO
700
701	!----------------------------------------------------------------------------------------------
702	! 2) Check for daice or dvice out of range, allowing for roundoff error
703	!----------------------------------------------------------------------------------------------
704	! Note: zdaice < 0 or zdvice < 0 usually happens when category jl
705	! has a small area, with h(n) very close to a boundary. Then
706	! the coefficients of g(h) are large, and the computed daice and
707	! dvice can be in error. If this happens, it is best to transfer
708	! either the entire category or nothing at all, depending on which
709	! side of the boundary hice(n) lies.
710	!-----------------------------------------------------------------
711	DO jl = klbnd, kubnd-1
712
713	zdaice_negative = .false.
714	zdvice_negative = .false.
715	zdaice_greater_aicen = .false.
716	zdvice_greater_vicen = .false.
717
718	DO jj = 1, jpj
719	DO ji = 1, jpi
720
721	IF (zdonor(ji,jj,jl) .GT. 0) THEN
722	jl1 = zdonor(ji,jj,jl)
723
724	IF (zdaice(ji,jj,jl) .LT. 0.0) THEN
725	IF (zdaice(ji,jj,jl) .GT. -epsi10) THEN
726	IF ( ( jl1.EQ.jl .AND. ht_i(ji,jj,jl1) .GT. hi_max(jl) ) &
727	.OR. &
728	( jl1.EQ.jl+1 .AND. ht_i(ji,jj,jl1) .LE. hi_max(jl) ) &
729	) THEN
730	zdaice(ji,jj,jl) = a_i(ji,jj,jl1) ! shift entire category
731	zdvice(ji,jj,jl) = v_i(ji,jj,jl1)
732	ELSE
733	zdaice(ji,jj,jl) = 0.0 ! shift no ice
734	zdvice(ji,jj,jl) = 0.0
735	ENDIF
736	ELSE
737	zdaice_negative = .true.
738	ENDIF
739	ENDIF
740
741	IF (zdvice(ji,jj,jl) .LT. 0.0) THEN
742	IF (zdvice(ji,jj,jl) .GT. -epsi10 ) THEN
743	IF ( ( jl1.EQ.jl .AND. ht_i(ji,jj,jl1).GT.hi_max(jl) ) &
744	.OR. &
745	( jl1.EQ.jl+1 .AND. ht_i(ji,jj,jl1) .LE. hi_max(jl) ) &
746	) THEN
747	zdaice(ji,jj,jl) = a_i(ji,jj,jl1) ! shift entire category
748	zdvice(ji,jj,jl) = v_i(ji,jj,jl1)
749	ELSE
750	zdaice(ji,jj,jl) = 0.0 ! shift no ice
751	zdvice(ji,jj,jl) = 0.0
752	ENDIF
753	ELSE
754	zdvice_negative = .true.
755	ENDIF
756	ENDIF
757
758	! If daice is close to aicen, set daice = aicen.
759	IF (zdaice(ji,jj,jl) .GT. a_i(ji,jj,jl1) - epsi10 ) THEN
760	IF (zdaice(ji,jj,jl) .LT. a_i(ji,jj,jl1)+epsi10) THEN
761	zdaice(ji,jj,jl) = a_i(ji,jj,jl1)
762	zdvice(ji,jj,jl) = v_i(ji,jj,jl1)
763	ELSE
764	zdaice_greater_aicen = .true.
765	ENDIF
766	ENDIF
767
768	IF (zdvice(ji,jj,jl) .GT. v_i(ji,jj,jl1)-epsi10) THEN
769	IF (zdvice(ji,jj,jl) .LT. v_i(ji,jj,jl1)+epsi10) THEN
770	zdaice(ji,jj,jl) = a_i(ji,jj,jl1)
771	zdvice(ji,jj,jl) = v_i(ji,jj,jl1)
772	ELSE
773	zdvice_greater_vicen = .true.
774	ENDIF
775	ENDIF
776
777	ENDIF ! donor > 0
778	END DO ! i
779	END DO ! j
780
781	END DO !jl
782
783	!-------------------------------------------------------------------------------
784	! 3) Transfer volume and energy between categories
785	!-------------------------------------------------------------------------------
786
787	DO jl = klbnd, kubnd - 1
788	nbrem = 0
789	DO jj = 1, jpj
790	DO ji = 1, jpi
791	IF (zdaice(ji,jj,jl) .GT. 0.0 ) THEN ! daice(n) can be < puny
792	nbrem = nbrem + 1
793	nind_i(nbrem) = ji
794	nind_j(nbrem) = jj
795	ENDIF ! tmask
796	END DO
797	END DO
798
799	DO ji = 1, nbrem
800	ii = nind_i(ji)
801	ij = nind_j(ji)
802
803	jl1 = zdonor(ii,ij,jl)
804	zindb = MAX( 0.0 , SIGN( 1.0 , v_i(ii,ij,jl1) - epsi10 ) )
805	zworka(ii,ij) = zdvice(ii,ij,jl) / MAX(v_i(ii,ij,jl1),epsi10) * zindb
806	IF( jl1 == jl) THEN ; jl2 = jl1+1
807	ELSE ; jl2 = jl
808	ENDIF
809
810	!--------------
811	! Ice areas
812	!--------------
813
814	a_i(ii,ij,jl1) = a_i(ii,ij,jl1) - zdaice(ii,ij,jl)
815	a_i(ii,ij,jl2) = a_i(ii,ij,jl2) + zdaice(ii,ij,jl)
816
817	!--------------
818	! Ice volumes
819	!--------------
820
821	v_i(ii,ij,jl1) = v_i(ii,ij,jl1) - zdvice(ii,ij,jl)
822	v_i(ii,ij,jl2) = v_i(ii,ij,jl2) + zdvice(ii,ij,jl)
823
824	!--------------
825	! Snow volumes
826	!--------------
827
828	zdvsnow = v_s(ii,ij,jl1) * zworka(ii,ij)
829	v_s(ii,ij,jl1) = v_s(ii,ij,jl1) - zdvsnow
830	v_s(ii,ij,jl2) = v_s(ii,ij,jl2) + zdvsnow
831
832	!--------------------
833	! Snow heat content
834	!--------------------
835
836	zdesnow = e_s(ii,ij,1,jl1) * zworka(ii,ij)
837	e_s(ii,ij,1,jl1) = e_s(ii,ij,1,jl1) - zdesnow
838	e_s(ii,ij,1,jl2) = e_s(ii,ij,1,jl2) + zdesnow
839
840	!--------------
841	! Ice age
842	!--------------
843
844	zdo_aice = oa_i(ii,ij,jl1) * zdaice(ii,ij,jl)
845	oa_i(ii,ij,jl1) = oa_i(ii,ij,jl1) - zdo_aice
846	oa_i(ii,ij,jl2) = oa_i(ii,ij,jl2) + zdo_aice
847
848	!--------------
849	! Ice salinity
850	!--------------
851
852	zdsm_vice = smv_i(ii,ij,jl1) * zworka(ii,ij)
853	smv_i(ii,ij,jl1) = smv_i(ii,ij,jl1) - zdsm_vice
854	smv_i(ii,ij,jl2) = smv_i(ii,ij,jl2) + zdsm_vice
855
856	!---------------------
857	! Surface temperature
858	!---------------------
859
860	zdaTsf = t_su(ii,ij,jl1) * zdaice(ii,ij,jl)
861	zaTsfn(ii,ij,jl1) = zaTsfn(ii,ij,jl1) - zdaTsf
862	zaTsfn(ii,ij,jl2) = zaTsfn(ii,ij,jl2) + zdaTsf
863
864	END DO ! ji
865
866	!------------------
867	! Ice heat content
868	!------------------
869
870	DO jk = 1, nlay_i
871	!CDIR NODEP
872	DO ji = 1, nbrem
873	ii = nind_i(ji)
874	ij = nind_j(ji)
875
876	jl1 = zdonor(ii,ij,jl)
877	IF (jl1 .EQ. jl) THEN
878	jl2 = jl+1
879	ELSE ! n1 = n+1
880	jl2 = jl
881	ENDIF
882
883	zdeice = e_i(ii,ij,jk,jl1) * zworka(ii,ij)
884	e_i(ii,ij,jk,jl1) = e_i(ii,ij,jk,jl1) - zdeice
885	e_i(ii,ij,jk,jl2) = e_i(ii,ij,jk,jl2) + zdeice
886	END DO ! ji
887	END DO ! jk
888
889	END DO ! boundaries, 1 to ncat-1
890
891	!-----------------------------------------------------------------
892	! Update ice thickness and temperature
893	!-----------------------------------------------------------------
894
895	DO jl = klbnd, kubnd
896	DO jj = 1, jpj
897	DO ji = 1, jpi
898	IF ( a_i(ji,jj,jl) > epsi10 ) THEN
899	ht_i(ji,jj,jl) = v_i (ji,jj,jl) / a_i(ji,jj,jl)
900	t_su(ji,jj,jl) = zaTsfn(ji,jj,jl) / a_i(ji,jj,jl)
901	zindsn = 1.0 - MAX(0.0,SIGN(1.0,-v_s(ji,jj,jl)+epsi10)) !0 if no ice and 1 if yes
902	ELSE
903	ht_i(ji,jj,jl) = 0._wp
904	t_su(ji,jj,jl) = rtt
905	ENDIF
906	END DO ! ji
907	END DO ! jj
908	END DO ! jl
909	!
910	CALL wrk_dealloc( jpi,jpj,jpl, zaTsfn )
911	CALL wrk_dealloc( jpi,jpj, zworka )
912	CALL wrk_dealloc( (jpi+1)*(jpj+1), nind_i, nind_j ) ! integer
913	!
914	END SUBROUTINE lim_itd_shiftice
915
916
917	SUBROUTINE lim_itd_th_reb( klbnd, kubnd, ntyp )
918	!!------------------------------------------------------------------
919	!! * ROUTINE lim_itd_th_reb *
920	!!
921	!! ** Purpose : rebin - rebins thicknesses into defined categories
922	!!
923	!! ** Method :
924	!!------------------------------------------------------------------
925	INTEGER , INTENT (in) :: klbnd ! Start thickness category index point
926	INTEGER , INTENT (in) :: kubnd ! End point on which the the computation is applied
927	INTEGER , INTENT (in) :: ntyp ! number of the ice type involved in the rebinning process
928	!
929	INTEGER :: ji,jj, jl ! dummy loop indices
930	INTEGER :: zshiftflag ! = .true. if ice must be shifted
931	CHARACTER (len = 15) :: fieldid
932
933	INTEGER , POINTER, DIMENSION(:,:,:) :: zdonor ! donor category index
934	REAL(wp), POINTER, DIMENSION(:,:,:) :: zdaice, zdvice ! ice area and volume transferred
935
936	REAL(wp), POINTER, DIMENSION(:,:) :: vt_i_init, vt_i_final ! ice volume summed over categories
937	REAL(wp), POINTER, DIMENSION(:,:) :: vt_s_init, vt_s_final ! snow volume summed over categories
938	!!------------------------------------------------------------------
939
940	CALL wrk_alloc( jpi,jpj,jpl, zdonor ) ! interger
941	CALL wrk_alloc( jpi,jpj,jpl, zdaice, zdvice )
942	CALL wrk_alloc( jpi,jpj, vt_i_init, vt_i_final, vt_s_init, vt_s_final )
943	!
944	IF( con_i ) THEN ! conservation check
945	CALL lim_column_sum (jpl, v_i, vt_i_init)
946	CALL lim_column_sum (jpl, v_s, vt_s_init)
947	ENDIF
948
949	!
950	!------------------------------------------------------------------------------
951	! 1) Compute ice thickness.
952	!------------------------------------------------------------------------------
953	DO jl = klbnd, kubnd
954	DO jj = 1, jpj
955	DO ji = 1, jpi
956	IF( a_i(ji,jj,jl) > epsi10 ) THEN
957	ht_i(ji,jj,jl) = v_i(ji,jj,jl) / a_i(ji,jj,jl)
958	ELSE
959	ht_i(ji,jj,jl) = 0._wp
960	ENDIF
961	END DO
962	END DO
963	END DO
964
965	!------------------------------------------------------------------------------
966	! 2) Make sure thickness of cat klbnd is at least hi_max_typ(klbnd)
967	!------------------------------------------------------------------------------
968	DO jj = 1, jpj
969	DO ji = 1, jpi
970	IF( a_i(ji,jj,klbnd) > epsi10 ) THEN
971	IF( ht_i(ji,jj,klbnd) <= hi_max_typ(0,ntyp) .AND. hi_max_typ(0,ntyp) > 0._wp ) THEN
972	a_i(ji,jj,klbnd) = v_i(ji,jj,klbnd) / hi_max_typ(0,ntyp)
973	ht_i(ji,jj,klbnd) = hi_max_typ(0,ntyp)
974	ENDIF
975	ENDIF
976	END DO
977	END DO
978
979	!------------------------------------------------------------------------------
980	! 3) If a category thickness is not in bounds, shift the
981	! entire area, volume, and energy to the neighboring category
982	!------------------------------------------------------------------------------
983	!-------------------------
984	! Initialize shift arrays
985	!-------------------------
986	DO jl = klbnd, kubnd
987	zdonor(:,:,jl) = 0
988	zdaice(:,:,jl) = 0._wp
989	zdvice(:,:,jl) = 0._wp
990	END DO
991
992	!-------------------------
993	! Move thin categories up
994	!-------------------------
995
996	DO jl = klbnd, kubnd - 1 ! loop over category boundaries
997
998	!---------------------------------------
999	! identify thicknesses that are too big
1000	!---------------------------------------
1001	zshiftflag = 0
1002
1003	DO jj = 1, jpj
1004	DO ji = 1, jpi
1005	IF( a_i(ji,jj,jl) > epsi10 .AND. ht_i(ji,jj,jl) > hi_max(jl) ) THEN
1006	zshiftflag = 1
1007	zdonor(ji,jj,jl) = jl
1008	! begin TECLIM change
1009	!zdaice(ji,jj,jl) = a_i(ji,jj,jl)
1010	!zdvice(ji,jj,jl) = v_i(ji,jj,jl)
1011	zdaice(ji,jj,jl) = a_i(ji,jj,jl)/2
1012	zdvice(ji,jj,jl) = v_i(ji,jj,jl)-zdaice(ji,jj,jl)*(hi_max(jl)+hi_max(jl-1))/2
1013	! end TECLIM change
1014	ENDIF
1015	END DO ! ji
1016	END DO ! jj
1017	IF(lk_mpp) CALL mpp_max( zshiftflag )
1018
1019	IF( zshiftflag == 1 ) THEN ! Shift ice between categories
1020	CALL lim_itd_shiftice( klbnd, kubnd, zdonor, zdaice, zdvice )
1021	! Reset shift parameters
1022	zdonor(:,:,jl) = 0
1023	zdaice(:,:,jl) = 0._wp
1024	zdvice(:,:,jl) = 0._wp
1025	ENDIF
1026	!
1027	END DO ! jl
1028
1029	!----------------------------
1030	! Move thick categories down
1031	!----------------------------
1032
1033	DO jl = kubnd - 1, 1, -1 ! loop over category boundaries
1034
1035	!-----------------------------------------
1036	! Identify thicknesses that are too small
1037	!-----------------------------------------
1038	zshiftflag = 0
1039
1040	DO jj = 1, jpj
1041	DO ji = 1, jpi
1042	IF( a_i(ji,jj,jl+1) > epsi10 .AND. &
1043	ht_i(ji,jj,jl+1) <= hi_max(jl) ) THEN
1044	!
1045	zshiftflag = 1
1046	zdonor(ji,jj,jl) = jl + 1
1047	zdaice(ji,jj,jl) = a_i(ji,jj,jl+1)
1048	zdvice(ji,jj,jl) = v_i(ji,jj,jl+1)
1049	ENDIF
1050	END DO ! ji
1051	END DO ! jj
1052
1053	IF(lk_mpp) CALL mpp_max( zshiftflag )
1054
1055	IF( zshiftflag == 1 ) THEN ! Shift ice between categories
1056	CALL lim_itd_shiftice( klbnd, kubnd, zdonor, zdaice, zdvice )
1057	! Reset shift parameters
1058	zdonor(:,:,jl) = 0
1059	zdaice(:,:,jl) = 0._wp
1060	zdvice(:,:,jl) = 0._wp
1061	ENDIF
1062
1063	END DO ! jl
1064
1065	!------------------------------------------------------------------------------
1066	! 4) Conservation check
1067	!------------------------------------------------------------------------------
1068
1069	IF( con_i ) THEN
1070	CALL lim_column_sum (jpl, v_i, vt_i_final)
1071	fieldid = ' v_i : limitd_reb '
1072	CALL lim_cons_check (vt_i_init, vt_i_final, 1.0e-6, fieldid)
1073
1074	CALL lim_column_sum (jpl, v_s, vt_s_final)
1075	fieldid = ' v_s : limitd_reb '
1076	CALL lim_cons_check (vt_s_init, vt_s_final, 1.0e-6, fieldid)
1077	ENDIF
1078	!
1079	CALL wrk_dealloc( jpi,jpj,jpl, zdonor ) ! interger
1080	CALL wrk_dealloc( jpi,jpj,jpl, zdaice, zdvice )
1081	CALL wrk_dealloc( jpi,jpj, vt_i_init, vt_i_final, vt_s_init, vt_s_final )
1082
1083	END SUBROUTINE lim_itd_th_reb
1084
1085	#else
1086	!!----------------------------------------------------------------------
1087	!! Default option Dummy module NO LIM sea-ice model
1088	!!----------------------------------------------------------------------
1089	CONTAINS
1090	SUBROUTINE lim_itd_th ! Empty routines
1091	END SUBROUTINE lim_itd_th
1092	SUBROUTINE lim_itd_th_ini
1093	END SUBROUTINE lim_itd_th_ini
1094	SUBROUTINE lim_itd_th_rem
1095	END SUBROUTINE lim_itd_th_rem
1096	SUBROUTINE lim_itd_fitline
1097	END SUBROUTINE lim_itd_fitline
1098	SUBROUTINE lim_itd_shiftice
1099	END SUBROUTINE lim_itd_shiftice
1100	SUBROUTINE lim_itd_th_reb
1101	END SUBROUTINE lim_itd_th_reb
1102	#endif
1103	!!======================================================================
1104	END MODULE limitd_th

Note: See TracBrowser for help on using the repository browser.

Download in other formats: