New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd_ent.F90 in branches/2013/dev_LOCEAN_2013/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2013/dev_LOCEAN_2013/NEMOGCM/NEMO/LIM_SRC_3/limthd_ent.F90 @ 4161

Last change on this file since 4161 was 4161, checked in by cetlod, 10 years ago

dev_LOCEAN_2013 : merge in the 3rd dev branch dev_r4028_CNRS_LIM3, see ticket #1169
  • Property svn:keywords set to Id
File size: 27.2 KB
Line 
1MODULE limthd_ent
2   !!======================================================================
3   !!                       ***  MODULE limthd_ent   ***
4   !!                  Redistribution of Enthalpy in the ice
5   !!                        on the new vertical grid
6   !!                       after vertical growth/decay
7   !!======================================================================
8   !! History :  LIM  ! 2003-05 (M. Vancoppenolle) Original code in 1D
9   !!                 ! 2005-07 (M. Vancoppenolle) 3D version
10   !!                 ! 2006-11 (X. Fettweis) Vectorized
11   !!            3.0  ! 2008-03 (M. Vancoppenolle) Energy conservation and clean code
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!----------------------------------------------------------------------
14#if defined key_lim3
15   !!----------------------------------------------------------------------
16   !!   'key_lim3'                                      LIM3 sea-ice model
17   !!----------------------------------------------------------------------
18   !!   lim_thd_ent   : ice redistribution of enthalpy
19   !!----------------------------------------------------------------------
20   USE par_oce        ! ocean parameters
21   USE dom_oce        ! domain variables
22   USE domain         !
23   USE phycst         ! physical constants
24   USE ice            ! LIM variables
25   USE par_ice        ! LIM parameters
26   USE thd_ice        ! LIM thermodynamics
27   USE limvar         ! LIM variables
28   USE in_out_manager ! I/O manager
29   USE lib_mpp        ! MPP library
30   USE wrk_nemo       ! work arrays
31   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   lim_thd_ent         ! called by lim_thd
37
38   REAL(wp) ::   epsi20 = 1e-20_wp   ! constant values
39   REAL(wp) ::   epsi13 = 1e-13_wp   !
40   REAL(wp) ::   epsi10 = 1e-10_wp   !
41   REAL(wp) ::   epsi06 = 1e-06_wp   !
42   REAL(wp) ::   zzero  = 0._wp      !
43   REAL(wp) ::   zone   = 1._wp      !
44
45   !!----------------------------------------------------------------------
46   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
47   !! $Id$
48   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50CONTAINS
51 
52   SUBROUTINE lim_thd_ent( kideb, kiut, jl )
53      !!-------------------------------------------------------------------
54      !!               ***   ROUTINE lim_thd_ent  ***
55      !!
56      !! ** Purpose :
57      !!           This routine computes new vertical grids
58      !!           in the ice and in the snow, and consistently redistributes
59      !!           temperatures in the snow / ice.
60      !!           Redistribution is made so as to ensure to energy conservation
61      !!
62      !!
63      !! ** Method  : linear conservative remapping
64      !!           
65      !! ** Steps : 1) Grid
66      !!            2) Switches
67      !!            3) Snow redistribution
68      !!            4) Ice enthalpy redistribution
69      !!            5) Ice salinity, recover temperature
70      !!
71      !! References : Bitz & Lipscomb, JGR 99; Vancoppenolle et al., GRL, 2005
72      !!-------------------------------------------------------------------
73      INTEGER , INTENT(in) ::   kideb, kiut   ! Start/End point on which the  the computation is applied
74      INTEGER , INTENT(in) ::   jl            ! Thickness cateogry number
75
76      INTEGER ::   ji,jk   !  dummy loop indices
77      INTEGER ::   ii, ij       ,   &  !  dummy indices
78         ntop0          ,   &  !  old layer top index
79         nbot1          ,   &  !  new layer bottom index
80         ntop1          ,   &  !  new layer top index
81         limsum         ,   &  !  temporary loop index
82         nlayi0,nlays0  ,   &  !  old number of layers
83         maxnbot0       ,   &  !  old layer bottom index
84         layer0, layer1        !  old/new layer indexes
85
86
87      REAL(wp) :: &
88         ztmelts        ,   &  ! ice melting point
89         zqsnic         ,   &  ! enthalpy of snow ice layer
90         zhsnow         ,   &  ! temporary snow thickness variable
91         zswitch        ,   &  ! dummy switch argument
92         zfac1          ,   &  ! dummy factor
93         zfac2          ,   &  ! dummy factor
94         ztform         ,   &  !: bottom formation temperature
95         zaaa           ,   &  !: dummy factor
96         zbbb           ,   &  !: dummy factor
97         zccc           ,   &  !: dummy factor
98         zdiscrim              !: dummy factor
99
100      INTEGER, POINTER, DIMENSION(:) ::   snswi     !  snow switch
101      INTEGER, POINTER, DIMENSION(:) ::   nbot0     !  old layer bottom index
102      INTEGER, POINTER, DIMENSION(:) ::   icsuind   !  ice surface index
103      INTEGER, POINTER, DIMENSION(:) ::   icsuswi   !  ice surface switch
104      INTEGER, POINTER, DIMENSION(:) ::   icboind   !  ice bottom index
105      INTEGER, POINTER, DIMENSION(:) ::   icboswi   !  ice bottom switch
106      INTEGER, POINTER, DIMENSION(:) ::   snicind   !  snow ice index
107      INTEGER, POINTER, DIMENSION(:) ::   snicswi   !  snow ice switch
108      INTEGER, POINTER, DIMENSION(:) ::   snind     !  snow index
109      !
110      REAL(wp), POINTER, DIMENSION(:) ::   zh_i   ! thickness of an ice layer
111      REAL(wp), POINTER, DIMENSION(:) ::   zh_s          ! thickness of a snow layer
112      REAL(wp), POINTER, DIMENSION(:) ::   zqsnow        ! enthalpy of the snow put in snow ice   
113      REAL(wp), POINTER, DIMENSION(:) ::   zdeltah       ! temporary variable
114      REAL(wp), POINTER, DIMENSION(:) ::   zqti_in, zqts_in
115      REAL(wp), POINTER, DIMENSION(:) ::   zqti_fin, zqts_fin
116
117      REAL(wp), POINTER, DIMENSION(:,:) ::   zm0       !  old layer-system vertical cotes
118      REAL(wp), POINTER, DIMENSION(:,:) ::   qm0       !  old layer-system heat content
119      REAL(wp), POINTER, DIMENSION(:,:) ::   z_s       !  new snow system vertical cotes
120      REAL(wp), POINTER, DIMENSION(:,:) ::   z_i       !  new ice system vertical cotes
121      REAL(wp), POINTER, DIMENSION(:,:) ::   zthick0   !  old ice thickness
122      REAL(wp), POINTER, DIMENSION(:,:) ::   zhl0      ! old and new layer thicknesses
123      REAL(wp), POINTER, DIMENSION(:,:) ::   zrl01
124      !!-------------------------------------------------------------------
125
126      CALL wrk_alloc( jpij, snswi, nbot0, icsuind, icsuswi, icboind, icboswi, snicind, snicswi, snind )   ! integer
127      CALL wrk_alloc( jpij, zh_i, zh_s, zqsnow, zdeltah, zqti_in, zqts_in, zqti_fin, zqts_fin )           ! real
128      CALL wrk_alloc( jpij,jkmax+4, zm0, qm0, z_s, z_i, zthick0, zhl0, kjstart = 0 )
129      CALL wrk_alloc( jkmax+4,jkmax+4, zrl01, kistart = 0, kjstart = 0 )
130
131      zthick0(:,:) = 0._wp
132      zm0    (:,:) = 0._wp
133      qm0    (:,:) = 0._wp
134      zrl01  (:,:) = 0._wp
135      zhl0   (:,:) = 0._wp
136      z_i    (:,:) = 0._wp
137      z_s    (:,:) = 0._wp
138
139      !
140      !------------------------------------------------------------------------------|
141      !  1) Grid                                                                     |
142      !------------------------------------------------------------------------------|
143      nlays0 = nlay_s
144      nlayi0 = nlay_i
145
146      DO ji = kideb, kiut
147         zh_i(ji) = old_ht_i_b(ji) / REAL( nlay_i ) 
148         zh_s(ji) = old_ht_s_b(ji) / REAL( nlay_s )
149      END DO
150
151      !
152      !------------------------------------------------------------------------------|
153      !  2) Switches                                                                 |
154      !------------------------------------------------------------------------------|
155      ! 2.1 snind(ji), snswi(ji)
156      ! snow surface behaviour : computation of snind(ji)-snswi(ji)
157      ! snind(ji) : index which equals
158      !   0 if snow is accumulating
159      !   1 if 1st layer is melting
160      !   2 if 2nd layer is melting ...
161      DO ji = kideb, kiut
162         snind  (ji) = 0
163         zdeltah(ji) = 0._wp
164      ENDDO !ji
165
166      DO jk = 1, nlays0
167         DO ji = kideb, kiut
168            snind(ji)  = jk        *      NINT(MAX(0.0,SIGN(1.0,-dh_s_tot(ji)-zdeltah(ji)))) &
169               + snind(ji) * (1 - NINT(MAX(0.0,SIGN(1.0,-dh_s_tot(ji)-zdeltah(ji)))))
170            zdeltah(ji)= zdeltah(ji) + zh_s(ji)
171         END DO ! ji
172      END DO ! jk
173
174      ! snswi(ji) : switch which value equals 1 if snow melts
175      !              0 if not
176      DO ji = kideb, kiut
177         snswi(ji)     = MAX(0,NINT(-dh_s_tot(ji)/MAX(epsi20,ABS(dh_s_tot(ji)))))
178      END DO ! ji
179
180      ! 2.2 icsuind(ji), icsuswi(ji)
181      ! ice surface behaviour : computation of icsuind(ji)-icsuswi(ji)
182      ! icsuind(ji) : index which equals
183      !     0 if nothing happens at the surface
184      !     1 if first layer is melting
185      !     2 if 2nd layer is reached by melt ...
186      DO ji = kideb, kiut
187         icsuind(ji) = 0
188         zdeltah(ji) = 0._wp
189      END DO !ji
190      DO jk = 1, nlayi0
191         DO ji = kideb, kiut
192            icsuind(ji) = jk          *      NINT(MAX(0.0,SIGN(1.0,-dh_i_surf(ji)-zdeltah(ji)))) &
193               + icsuind(ji) * (1 - NINT(MAX(0.0,SIGN(1.0,-dh_i_surf(ji)-zdeltah(ji)))))
194            zdeltah(ji) = zdeltah(ji) + zh_i(ji)
195         END DO ! ji
196      ENDDO !jk
197
198      ! icsuswi(ji) : switch which equals
199      !     1 if ice melts at the surface
200      !     0 if not
201      DO ji = kideb, kiut
202         icsuswi(ji)  = MAX(0,NINT(-dh_i_surf(ji)/MAX(epsi20 , ABS(dh_i_surf(ji)) ) ) )
203      ENDDO
204
205      ! 2.3 icboind(ji), icboswi(ji)
206      ! ice bottom behaviour : computation of icboind(ji)-icboswi(ji)
207      ! icboind(ji) : index which equals
208      !     0 if accretion is on the way
209      !     1 if last layer has started to melt
210      !     2 if penultiem layer is melting ... and so on
211      !            N+1 if all layers melt and that snow transforms into ice
212      DO ji = kideb, kiut 
213         icboind(ji) = 0
214         zdeltah(ji) = 0._wp
215      END DO
216      DO jk = nlayi0, 1, -1
217         DO ji = kideb, kiut
218            icboind(ji) = (nlayi0+1-jk) *      NINT(MAX(0.0,SIGN(1.0,-dh_i_bott(ji)-zdeltah(ji)))) &
219               &          + icboind(ji) * (1 - NINT(MAX(0.0,SIGN(1.0,-dh_i_bott(ji)-zdeltah(ji))))) 
220            zdeltah(ji) = zdeltah(ji) + zh_i(ji)
221         END DO
222      END DO
223
224      DO ji = kideb, kiut
225         ! case of total ablation with remaining snow
226         IF ( ( ht_i_b(ji) .GT. epsi20 ) .AND. &
227            ( ht_i_b(ji) - dh_snowice(ji) .LT. epsi20 ) ) icboind(ji) = nlay_i + 1
228      END DO
229
230      ! icboswi(ji) : switch which equals
231      !     1 if ice accretion is on the way
232      !     0 if ablation is on the way
233      DO ji = kideb, kiut 
234         icboswi(ji) = MAX(0,NINT(dh_i_bott(ji) / MAX(epsi20,ABS(dh_i_bott(ji)))))
235      END DO
236
237      ! 2.4 snicind(ji), snicswi(ji)
238      ! snow ice formation : calcul de snicind(ji)-snicswi(ji)
239      ! snicind(ji) : index which equals
240      !     0 if no snow-ice forms
241      !     1 if last layer of snow has started to melt
242      !     2 if penultiem layer ...
243      DO ji = kideb, kiut
244         snicind(ji) = 0
245         zdeltah(ji) = 0._wp
246      END DO
247      DO jk = nlays0, 1, -1
248         DO ji = kideb, kiut
249            snicind(ji) = (nlays0+1-jk) &
250               *      NINT(MAX(0.0,SIGN(1.0,dh_snowice(ji)-zdeltah(ji)))) + snicind(ji)   &
251               * (1 - NINT(MAX(0.0,SIGN(1.0,dh_snowice(ji)-zdeltah(ji)))))
252            zdeltah(ji) = zdeltah(ji) + zh_s(ji)
253         END DO
254      END DO
255
256      ! snicswi(ji) : switch which equals
257      !     1 if snow-ice forms
258      !     0 if not
259      DO ji = kideb, kiut
260         snicswi(ji)   = MAX(0,NINT(dh_snowice(ji)/MAX(epsi20,ABS(dh_snowice(ji)))))
261      ENDDO
262
263      !
264      !------------------------------------------------------------------------------|
265      !  3) Snow redistribution                                                      |
266      !------------------------------------------------------------------------------|
267      !
268      !-------------
269      ! Old profile
270      !-------------
271
272      ! by 'old', it is meant that layers coming from accretion are included,
273      ! and that interfacial layers which were partly melted are reduced
274
275      ! indexes of the vectors
276      !------------------------
277      ntop0    =  1
278      maxnbot0 =  0
279
280      DO ji = kideb, kiut
281         nbot0(ji) =  nlays0  + 1 - snind(ji) + ( 1 - snicind(ji) ) * snicswi(ji)
282         ! cotes of the top of the layers
283         zm0(ji,0) =  0._wp
284         maxnbot0 =  MAX ( maxnbot0 , nbot0(ji) )
285      END DO
286      IF( lk_mpp )   CALL mpp_max( maxnbot0, kcom=ncomm_ice )
287
288      DO jk = 1, maxnbot0
289         DO ji = kideb, kiut
290            !change
291            limsum = ( 1 - snswi(ji) ) * ( jk - 1 ) + snswi(ji) * ( jk + snind(ji) - 1 )
292            limsum = MIN( limsum , nlay_s )
293            zm0(ji,jk) =  dh_s_tot(ji) + zh_s(ji) * REAL( limsum )
294         END DO
295      END DO
296
297      DO ji = kideb, kiut
298         zm0(ji,nbot0(ji)) =  dh_s_tot(ji) - REAL( snicswi(ji) ) * dh_snowice(ji) + zh_s(ji) * REAL( nlays0 )
299         zm0(ji,1)         =  dh_s_tot(ji) * REAL( 1 - snswi(ji) ) + REAL( snswi(ji) ) * zm0(ji,1)
300      END DO
301
302      DO jk = ntop0, maxnbot0
303         DO ji = kideb, kiut
304            zthick0(ji,jk)  =  zm0(ji,jk) - zm0(ji,jk-1)            ! layer thickness
305         END DO
306      END DO
307
308      zqts_in(:) = 0._wp
309
310      DO ji = kideb, kiut         ! layer heat content
311         qm0    (ji,1) =  rhosn * (  cpic * ( rtt - REAL( 1 - snswi(ji) ) * tatm_ice_1d(ji)        &
312            &                                         - REAL( snswi(ji) ) * t_s_b      (ji,1)  )   &
313            &                      + lfus  ) * zthick0(ji,1)
314         zqts_in(ji)   =  zqts_in(ji) + qm0(ji,1) 
315      END DO
316
317      DO jk = 2, maxnbot0
318         DO ji = kideb, kiut
319            limsum      = ( 1 - snswi(ji) ) * ( jk - 1 ) + snswi(ji) * ( jk + snind(ji) - 1 )
320            limsum      = MIN( limsum , nlay_s )
321            qm0(ji,jk)  = rhosn * ( cpic * ( rtt - t_s_b(ji,limsum) ) + lfus ) * zthick0(ji,jk)
322            zswitch = 1.0 - MAX (0.0, SIGN ( 1.0, - ht_s_b(ji) ) )
323            zqts_in(ji) = zqts_in(ji) + REAL( 1 - snswi(ji) ) * qm0(ji,jk) * zswitch
324         END DO ! jk
325      END DO ! ji
326
327      !------------------------------------------------
328      ! Energy given by the snow in snow-ice formation
329      !------------------------------------------------
330      ! zqsnow, enthalpy of the flooded snow
331      DO ji = kideb, kiut
332         zqsnow (ji) =  rhosn * lfus
333         zdeltah(ji) =  0._wp
334      END DO
335
336      DO jk =  nlays0, 1, -1
337         DO ji = kideb, kiut
338            zhsnow =  MAX( 0._wp , dh_snowice(ji)-zdeltah(ji) )
339            zqsnow (ji) =  zqsnow (ji) + rhosn*cpic*(rtt-t_s_b(ji,jk))
340            zdeltah(ji) =  zdeltah(ji) + zh_s(ji)
341         END DO
342      END DO
343
344      DO ji = kideb, kiut
345         zqsnow(ji) = zqsnow(ji) * dh_snowice(ji)
346      END DO
347
348      !------------------
349      ! new snow profile
350      !------------------
351
352      !--------------
353      ! Vector index   
354      !--------------
355      ntop1 =  1
356      nbot1 =  nlay_s
357
358      !-------------------
359      ! Layer coordinates
360      !-------------------
361      DO ji = kideb, kiut
362         zh_s(ji)  = ht_s_b(ji) / REAL( nlay_s )
363         z_s(ji,0) =  0._wp
364      ENDDO
365
366      DO jk = 1, nlay_s
367         DO ji = kideb, kiut
368            z_s(ji,jk) =  zh_s(ji) * REAL( jk )
369         END DO
370      END DO
371
372      !-----------------
373      ! Layer thickness
374      !-----------------
375      DO layer0 = ntop0, maxnbot0
376         DO ji = kideb, kiut
377            zhl0(ji,layer0) = zm0(ji,layer0) - zm0(ji,layer0-1)
378         END DO
379      END DO
380
381      DO layer1 = ntop1, nbot1
382         DO ji = kideb, kiut
383            q_s_b(ji,layer1) = 0._wp
384         END DO
385      END DO
386
387      !----------------
388      ! Weight factors
389      !----------------
390      DO layer0 = ntop0, maxnbot0
391         DO layer1 = ntop1, nbot1
392            DO ji = kideb, kiut
393               zrl01(layer1,layer0) = MAX(0.0,( MIN(zm0(ji,layer0),z_s(ji,layer1))   &
394                  &                 - MAX(zm0(ji,layer0-1), z_s(ji,layer1-1))) / MAX(zhl0(ji,layer0),epsi10)) 
395               q_s_b(ji,layer1) = q_s_b(ji,layer1) + zrl01(layer1,layer0)*qm0(ji,layer0)   &
396                  &                                * MAX(0.0,SIGN(1.0,REAL(nbot0(ji)-layer0)))
397            END DO
398         END DO
399      END DO
400
401      ! Heat conservation
402      zqts_fin(:) = 0._wp
403      DO jk = 1, nlay_s
404         DO ji = kideb, kiut
405            zqts_fin(ji) = zqts_fin(ji) + q_s_b(ji,jk)
406         END DO
407      END DO
408
409      IF ( con_i ) THEN
410         DO ji = kideb, kiut
411            IF ( ABS ( zqts_in(ji) - zqts_fin(ji) ) * r1_rdtice  >  1.0e-6 ) THEN
412               ii                 = MOD( npb(ji) - 1, jpi ) + 1
413               ij                 = ( npb(ji) - 1 ) / jpi + 1
414               WRITE(numout,*) ' violation of heat conservation : ', ABS ( zqts_in(ji) - zqts_fin(ji) ) * r1_rdtice
415               WRITE(numout,*) ' ji, jj   : ', ii, ij
416               WRITE(numout,*) ' ht_s_b   : ', ht_s_b(ji)
417               WRITE(numout,*) ' zqts_in  : ', zqts_in (ji) * r1_rdtice
418               WRITE(numout,*) ' zqts_fin : ', zqts_fin(ji) * r1_rdtice
419               WRITE(numout,*) ' dh_snowice : ', dh_snowice(ji)
420               WRITE(numout,*) ' dh_s_tot : ', dh_s_tot(ji)
421               WRITE(numout,*) ' snswi    : ', snswi(ji)
422            ENDIF
423         END DO
424      ENDIF
425
426      !---------------------
427      ! Recover heat content
428      !---------------------
429      DO jk = 1, nlay_s
430         DO ji = kideb, kiut
431            q_s_b(ji,jk) = q_s_b(ji,jk) / MAX( zh_s(ji) , epsi20 )
432         END DO !ji
433      END DO !jk 
434
435      !---------------------
436      ! Recover temperature
437      !---------------------
438      zfac1 = 1. / ( rhosn * cpic )
439      zfac2 = lfus / cpic 
440      DO jk = 1, nlay_s
441         DO ji = kideb, kiut
442            zswitch = MAX ( 0.0 , SIGN ( 1.0, - ht_s_b(ji) ) )
443            t_s_b(ji,jk) = rtt + ( 1.0 - zswitch ) * ( - zfac1 * q_s_b(ji,jk) + zfac2 )
444         END DO
445      END DO
446      !
447      !------------------------------------------------------------------------------|
448      !  4) Ice redistribution                                                       |
449      !------------------------------------------------------------------------------|
450      !
451      !-------------
452      ! OLD PROFILE
453      !-------------
454
455      !----------------
456      ! Vector indexes
457      !----------------
458      ntop0    =  1
459      maxnbot0 =  0
460
461      DO ji = kideb, kiut
462         ! reference number of the bottommost layer
463         nbot0(ji) =  MAX( 1 ,  MIN( nlayi0 + ( 1 - icboind(ji) ) +        &
464            &                           ( 1 - icsuind(ji) ) * icsuswi(ji) + snicswi(ji) , nlay_i + 2 ) )
465         ! maximum reference number of the bottommost layer over all domain
466         maxnbot0 =  MAX( maxnbot0 , nbot0(ji) )
467      END DO
468
469      !-------------------------
470      ! Cotes of old ice layers
471      !-------------------------
472      zm0(:,0) =  0._wp
473
474      DO jk = 1, maxnbot0
475         DO ji = kideb, kiut
476            ! jk goes from 1 to nbot0
477            ! the ice layer number goes from 1 to nlay_i
478            ! limsum is the real ice layer number corresponding to present jk
479            limsum    =  ( (icsuswi(ji)*(icsuind(ji)+jk-1) + & 
480               (1-icsuswi(ji))*jk))*(1-snicswi(ji)) + (jk-1)*snicswi(ji)
481            zm0(ji,jk)=  REAL(icsuswi(ji))*dh_i_surf(ji) + REAL(snicswi(ji))*dh_snowice(ji) &
482               +  REAL(limsum) * zh_i(ji)
483         END DO
484      END DO
485
486      DO ji = kideb, kiut
487         zm0(ji,nbot0(ji)) =  REAL(icsuswi(ji))*dh_i_surf(ji) + REAL(snicswi(ji))*dh_snowice(ji) + dh_i_bott(ji) &
488            +  zh_i(ji) * REAL(nlayi0)
489         zm0(ji,1)         =  REAL(snicswi(ji))*dh_snowice(ji) + REAL(1-snicswi(ji))*zm0(ji,1)
490      END DO
491
492      !-----------------------------
493      ! Thickness of old ice layers
494      !-----------------------------
495      DO jk = ntop0, maxnbot0
496         DO ji = kideb, kiut
497            zthick0(ji,jk) =  zm0(ji,jk) - zm0(ji,jk-1)
498         END DO
499      END DO
500
501      !---------------------------
502      ! Inner layers heat content
503      !---------------------------
504      qm0(:,:) =  0.0
505      zqti_in(:) = 0.0
506
507      DO jk = ntop0, maxnbot0
508         DO ji = kideb, kiut
509            limsum =  MAX(1,MIN(snicswi(ji)*(jk-1) + icsuswi(ji)*(jk-1+icsuind(ji)) + &
510               (1-icsuswi(ji))*(1-snicswi(ji))*jk,nlay_i))
511            ztmelts = -tmut * s_i_b(ji,limsum) + rtt
512            qm0(ji,jk) = rhoic * ( cpic * (ztmelts-t_i_b(ji,limsum)) + lfus * ( 1.0-(ztmelts-rtt)/ &
513               MIN((t_i_b(ji,limsum)-rtt),-epsi20) ) - rcp*(ztmelts-rtt) ) &
514               * zthick0(ji,jk)
515         END DO
516      END DO
517
518      !----------------------------
519      ! Bottom layers heat content
520      !----------------------------
521      DO ji = kideb, kiut       
522         ztmelts    = REAL( 1 - icboswi(ji) ) * (-tmut * s_i_b  (ji,nlayi0) )   &   ! case of melting ice
523            &       +     REAL( icboswi(ji) ) * (-tmut * s_i_new(ji)        )   &   ! case of forming ice
524            &       + rtt                                                         ! in Kelvin
525
526         ! bottom formation temperature
527         ztform = t_i_b(ji,nlay_i)
528         IF(  num_sal == 2  )   ztform = t_bo_b(ji)
529         qm0(ji,nbot0(ji)) = REAL( 1 - icboswi(ji) )*qm0(ji,nbot0(ji))             &   ! case of melting ice
530            &              + REAL( icboswi(ji) ) * rhoic * ( cpic*(ztmelts-ztform)       &   ! case of forming ice
531            + lfus *( 1.0-(ztmelts-rtt) / MIN ( (ztform-rtt) , - epsi10 ) )      & 
532            - rcp*(ztmelts-rtt) ) * zthick0(ji,nbot0(ji)  )
533      END DO
534
535      !-----------------------------
536      ! Snow ice layer heat content
537      !-----------------------------
538      DO ji = kideb, kiut
539         ! energy of the flooding seawater
540         zqsnic = rau0 * rcp * ( rtt - t_bo_b(ji) ) * dh_snowice(ji) * &
541            (rhoic - rhosn) / rhoic * REAL(snicswi(ji)) ! generally positive
542         ! Heat conservation diagnostic
543         qt_i_in(ji,jl) = qt_i_in(ji,jl) + zqsnic 
544
545         qldif_1d(ji)   = qldif_1d(ji) + zqsnic * a_i_b(ji)
546
547         ! enthalpy of the newly formed snow-ice layer
548         ! = enthalpy of snow + enthalpy of frozen water
549         zqsnic         =  zqsnow(ji) + zqsnic
550         qm0(ji,1)      =  REAL(snicswi(ji)) * zqsnic + REAL( 1 - snicswi(ji) ) * qm0(ji,1)
551
552      END DO ! ji
553
554      DO jk = ntop0, maxnbot0
555         DO ji = kideb, kiut
556            ! Heat conservation
557            zqti_in(ji) = zqti_in(ji) + qm0(ji,jk) * MAX( 0.0 , SIGN(1.0,ht_i_b(ji)-epsi06) ) &
558               &                                   * MAX( 0.0 , SIGN( 1. , REAL(nbot0(ji) - jk) ) )
559         END DO
560      END DO
561
562      !-------------
563      ! NEW PROFILE
564      !-------------
565
566      !---------------
567      ! Vectors index
568      !---------------
569      ntop1 =  1 
570      nbot1 =  nlay_i
571
572      !------------------
573      ! Layers thickness
574      !------------------
575      DO ji = kideb, kiut
576         zh_i(ji) = ht_i_b(ji) / REAL( nlay_i )
577      ENDDO
578
579      !-------------
580      ! Layer cotes     
581      !-------------
582      z_i(:,0) =  0._wp
583      DO jk = 1, nlay_i
584         DO ji = kideb, kiut
585            z_i(ji,jk) =  zh_i(ji) * jk
586         END DO
587      END DO
588
589      !--thicknesses of the layers
590      DO layer0 = ntop0, maxnbot0
591         DO ji = kideb, kiut
592            zhl0(ji,layer0) = zm0(ji,layer0) - zm0(ji,layer0-1)   ! thicknesses of the layers
593         END DO
594      END DO
595
596      !------------------------
597      ! Weights for relayering
598      !------------------------
599      q_i_b(:,:) = 0._wp
600      DO layer0 = ntop0, maxnbot0
601         DO layer1 = ntop1, nbot1
602            DO ji = kideb, kiut
603               zrl01(layer1,layer0) = MAX(0.0,( MIN(zm0(ji,layer0),z_i(ji,layer1)) &
604                  - MAX(zm0(ji,layer0-1), z_i(ji,layer1-1)))/MAX(zhl0(ji,layer0),epsi10))
605               q_i_b(ji,layer1) = q_i_b(ji,layer1) & 
606                  + zrl01(layer1,layer0)*qm0(ji,layer0) &
607                  * MAX(0.0,SIGN(1.0,ht_i_b(ji)-epsi06)) &
608                  * MAX(0.0,SIGN(1.0,REAL(nbot0(ji)-layer0)))
609            END DO
610         END DO
611      END DO
612
613      !-------------------------
614      ! Heat conservation check
615      !-------------------------
616      zqti_fin(:) = 0._wp
617      DO jk = 1, nlay_i
618         DO ji = kideb, kiut
619            zqti_fin(ji) = zqti_fin(ji) + q_i_b(ji,jk)
620         END DO
621      END DO
622      !
623      IF ( con_i ) THEN
624         DO ji = kideb, kiut
625            IF ( ABS ( zqti_in(ji) - zqti_fin(ji) ) * r1_rdtice  >  1.0e-6 ) THEN
626               ii                 = MOD( npb(ji) - 1, jpi ) + 1
627               ij                 = ( npb(ji) - 1 ) / jpi + 1
628               WRITE(numout,*) ' violation of heat conservation : ', ABS ( zqti_in(ji) - zqti_fin(ji) ) * r1_rdtice
629               WRITE(numout,*) ' ji, jj   : ', ii, ij
630               WRITE(numout,*) ' ht_i_b   : ', ht_i_b(ji)
631               WRITE(numout,*) ' zqti_in  : ', zqti_in (ji) * r1_rdtice
632               WRITE(numout,*) ' zqti_fin : ', zqti_fin(ji) * r1_rdtice
633               WRITE(numout,*) ' dh_i_bott: ', dh_i_bott(ji)
634               WRITE(numout,*) ' dh_i_surf: ', dh_i_surf(ji)
635               WRITE(numout,*) ' dh_snowice:', dh_snowice(ji)
636               WRITE(numout,*) ' icsuswi  : ', icsuswi(ji)
637               WRITE(numout,*) ' icboswi  : ', icboswi(ji)
638               WRITE(numout,*) ' snicswi  : ', snicswi(ji)
639            ENDIF
640         END DO
641      ENDIF
642
643      !----------------------
644      ! Recover heat content
645      !----------------------
646      DO jk = 1, nlay_i
647         DO ji = kideb, kiut
648            q_i_b(ji,jk) = q_i_b(ji,jk) / MAX( zh_i(ji) , epsi20 )
649         END DO !ji
650      END DO !jk 
651
652      ! Heat conservation
653      zqti_fin(:) = 0.0
654      DO jk = 1, nlay_i
655         DO ji = kideb, kiut
656            zqti_fin(ji) = zqti_fin(ji) + q_i_b(ji,jk) * zh_i(ji)
657         END DO
658      END DO
659
660      !
661      !------------------------------------------------------------------------------|
662      !  5) Update salinity and recover temperature                                  |
663      !------------------------------------------------------------------------------|
664      !
665      ! Update salinity (basal entrapment, snow ice formation)
666      DO ji = kideb, kiut
667         sm_i_b(ji) = sm_i_b(ji) + dsm_i_se_1d(ji) + dsm_i_si_1d(ji)
668      END DO !ji
669
670      ! Recover temperature
671      DO jk = 1, nlay_i
672         DO ji = kideb, kiut
673            ztmelts    =  -tmut*s_i_b(ji,jk) + rtt
674            !Conversion q(S,T) -> T (second order equation)
675            zaaa         =  cpic
676            zbbb         =  ( rcp - cpic ) * ( ztmelts - rtt ) + q_i_b(ji,jk) / rhoic - lfus
677            zccc         =  lfus * ( ztmelts - rtt )
678            zdiscrim     =  SQRT( MAX(zbbb*zbbb - 4.0*zaaa*zccc,0.0) )
679            t_i_b(ji,jk) =  rtt - ( zbbb + zdiscrim ) / ( 2.0 *zaaa )
680         END DO !ji
681
682      END DO !jk
683      !
684      CALL wrk_dealloc( jpij, snswi, nbot0, icsuind, icsuswi, icboind, icboswi, snicind, snicswi, snind )   ! integer
685      CALL wrk_dealloc( jpij, zh_i, zh_s, zqsnow, zdeltah, zqti_in, zqts_in, zqti_fin, zqts_fin )           ! real
686      CALL wrk_dealloc( jpij,jkmax+4, zm0, qm0, z_s, z_i, zthick0, zhl0, kjstart = 0 )
687      CALL wrk_dealloc( jkmax+4,jkmax+4, zrl01, kistart = 0, kjstart = 0 )
688      !
689   END SUBROUTINE lim_thd_ent
690
691#else
692   !!----------------------------------------------------------------------
693   !!   Default option                               NO  LIM3 sea-ice model
694   !!----------------------------------------------------------------------
695CONTAINS
696   SUBROUTINE lim_thd_ent          ! Empty routine
697   END SUBROUTINE lim_thd_ent
698#endif
699
700   !!======================================================================
701END MODULE limthd_ent
Note: See TracBrowser for help on using the repository browser.