source: branches/2013/dev_LOCEAN_2013/NEMOGCM/NEMO/LIM_SRC_3/limvar.F90 @ 4205

Last change on this file since 4205 was 4205, checked in by clem, 7 years ago
  • Property svn:keywords set to Id
File size: 22.9 KB
Line 
1MODULE limvar
2   !!======================================================================
3   !!                       ***  MODULE limvar ***
4   !!                 Different sets of ice model variables
5   !!                   how to switch from one to another
6   !!
7   !!                 There are three sets of variables
8   !!                 VGLO : global variables of the model
9   !!                        - v_i (jpi,jpj,jpl)
10   !!                        - v_s (jpi,jpj,jpl)
11   !!                        - a_i (jpi,jpj,jpl)
12   !!                        - t_s (jpi,jpj,jpl)
13   !!                        - e_i (jpi,jpj,nlay_i,jpl)
14   !!                        - smv_i(jpi,jpj,jpl)
15   !!                        - oa_i (jpi,jpj,jpl)
16   !!                 VEQV : equivalent variables sometimes used in the model
17   !!                        - ht_i(jpi,jpj,jpl)
18   !!                        - ht_s(jpi,jpj,jpl)
19   !!                        - t_i (jpi,jpj,nlay_i,jpl)
20   !!                        ...
21   !!                 VAGG : aggregate variables, averaged/summed over all
22   !!                        thickness categories
23   !!                        - vt_i(jpi,jpj)
24   !!                        - vt_s(jpi,jpj)
25   !!                        - at_i(jpi,jpj)
26   !!                        - et_s(jpi,jpj)  !total snow heat content
27   !!                        - et_i(jpi,jpj)  !total ice thermal content
28   !!                        - smt_i(jpi,jpj) !mean ice salinity
29   !!                        - ot_i(jpi,jpj)  !average ice age
30   !!======================================================================
31   !! History :   -   ! 2006-01 (M. Vancoppenolle) Original code
32   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
33   !!----------------------------------------------------------------------
34#if defined key_lim3
35   !!----------------------------------------------------------------------
36   !!   'key_lim3'                                      LIM3 sea-ice model
37   !!----------------------------------------------------------------------
38   !!   lim_var_agg       :
39   !!   lim_var_glo2eqv   :
40   !!   lim_var_eqv2glo   :
41   !!   lim_var_salprof   :
42   !!   lim_var_salprof1d :
43   !!   lim_var_bv        :
44   !!----------------------------------------------------------------------
45   USE par_oce        ! ocean parameters
46   USE phycst         ! physical constants (ocean directory)
47   USE sbc_oce        ! Surface boundary condition: ocean fields
48   USE ice            ! ice variables
49   USE par_ice        ! ice parameters
50   USE thd_ice        ! ice variables (thermodynamics)
51   USE dom_ice        ! ice domain
52   USE in_out_manager ! I/O manager
53   USE lib_mpp        ! MPP library
54   USE wrk_nemo       ! work arrays
55   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
56
57   IMPLICIT NONE
58   PRIVATE
59
60   PUBLIC   lim_var_agg          !
61   PUBLIC   lim_var_glo2eqv      !
62   PUBLIC   lim_var_eqv2glo      !
63   PUBLIC   lim_var_salprof      !
64   PUBLIC   lim_var_icetm        !
65   PUBLIC   lim_var_bv           !
66   PUBLIC   lim_var_salprof1d    !
67
68   REAL(wp) ::   epsi20 = 1.e-20_wp   ! module constants
69   REAL(wp) ::   epsi16 = 1.e-16_wp   !    -       -
70   REAL(wp) ::   epsi13 = 1.e-13_wp   !    -       -
71   REAL(wp) ::   epsi10 = 1.e-10_wp   !    -       -
72   REAL(wp) ::   epsi06 = 1.e-06_wp   !    -       -
73   REAL(wp) ::   zzero = 0.e0        !    -       -
74   REAL(wp) ::   zone  = 1.e0        !    -       -
75
76   !!----------------------------------------------------------------------
77   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
78   !! $Id$
79   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
80   !!----------------------------------------------------------------------
81CONTAINS
82
83   SUBROUTINE lim_var_agg( kn )
84      !!------------------------------------------------------------------
85      !!                ***  ROUTINE lim_var_agg  ***
86      !!
87      !! ** Purpose :   aggregates ice-thickness-category variables to all-ice variables
88      !!              i.e. it turns VGLO into VAGG
89      !! ** Method  :
90      !!
91      !! ** Arguments : n = 1, at_i vt_i only
92      !!                n = 2 everything
93      !!
94      !! note : you could add an argument when you need only at_i, vt_i
95      !!        and when you need everything
96      !!------------------------------------------------------------------
97      INTEGER, INTENT( in ) ::   kn     ! =1 at_i & vt only ; = what is needed
98      !
99      INTEGER  ::   ji, jj, jk, jl   ! dummy loop indices
100      REAL(wp) ::   zinda, zindb
101      !!------------------------------------------------------------------
102
103      !--------------------
104      ! Compute variables
105      !--------------------
106      vt_i (:,:) = 0._wp
107      vt_s (:,:) = 0._wp
108      at_i (:,:) = 0._wp
109      ato_i(:,:) = 1._wp
110      !
111      DO jl = 1, jpl
112         DO jj = 1, jpj
113            DO ji = 1, jpi
114               !
115               vt_i(ji,jj) = vt_i(ji,jj) + v_i(ji,jj,jl) ! ice volume
116               vt_s(ji,jj) = vt_s(ji,jj) + v_s(ji,jj,jl) ! snow volume
117               at_i(ji,jj) = at_i(ji,jj) + a_i(ji,jj,jl) ! ice concentration
118               !
119               zinda = MAX( zzero , SIGN( zone , at_i(ji,jj) - epsi16 ) ) 
120               icethi(ji,jj) = vt_i(ji,jj) / MAX( at_i(ji,jj) , epsi16 ) * zinda  ! ice thickness
121            END DO
122         END DO
123      END DO
124
125      DO jj = 1, jpj
126         DO ji = 1, jpi
127            ato_i(ji,jj) = MAX( 1._wp - at_i(ji,jj), 0._wp )   ! open water fraction
128         END DO
129      END DO
130
131      IF( kn > 1 ) THEN
132         et_s (:,:) = 0._wp
133         ot_i (:,:) = 0._wp
134         smt_i(:,:) = 0._wp
135         et_i (:,:) = 0._wp
136         !
137         DO jl = 1, jpl
138            DO jj = 1, jpj
139               DO ji = 1, jpi
140                  zinda = MAX( zzero , SIGN( zone , vt_i(ji,jj) - epsi16 ) ) 
141                  zindb = MAX( zzero , SIGN( zone , at_i(ji,jj) - epsi16 ) ) 
142                  et_s(ji,jj)  = et_s(ji,jj)  + e_s(ji,jj,1,jl)                                       ! snow heat content
143                  smt_i(ji,jj) = smt_i(ji,jj) + smv_i(ji,jj,jl) / MAX( vt_i(ji,jj) , epsi16 ) * zinda   ! ice salinity
144                  ot_i(ji,jj)  = ot_i(ji,jj)  + oa_i(ji,jj,jl)  / MAX( at_i(ji,jj) , epsi16 ) * zindb   ! ice age
145               END DO
146            END DO
147         END DO
148         !
149         DO jl = 1, jpl
150            DO jk = 1, nlay_i
151               et_i(:,:) = et_i(:,:) + e_i(:,:,jk,jl)       ! ice heat content
152            END DO
153         END DO
154         !
155      ENDIF
156      !
157   END SUBROUTINE lim_var_agg
158
159
160   SUBROUTINE lim_var_glo2eqv
161      !!------------------------------------------------------------------
162      !!                ***  ROUTINE lim_var_glo2eqv ***
163      !!
164      !! ** Purpose :   computes equivalent variables as function of global variables
165      !!              i.e. it turns VGLO into VEQV
166      !!------------------------------------------------------------------
167      INTEGER  ::   ji, jj, jk, jl   ! dummy loop indices
168      REAL(wp) ::   zq_i, zaaa, zbbb, zccc, zdiscrim     ! local scalars
169      REAL(wp) ::   ztmelts, zindb, zq_s, zfac1, zfac2   !   -      -
170      !!------------------------------------------------------------------
171
172      !-------------------------------------------------------
173      ! Ice thickness, snow thickness, ice salinity, ice age
174      !-------------------------------------------------------
175      DO jl = 1, jpl
176         DO jj = 1, jpj
177            DO ji = 1, jpi
178               zindb = 1._wp - MAX( 0._wp , SIGN( 1._wp,- a_i(ji,jj,jl) + epsi10 ) )   !0 if no ice and 1 if yes
179               ht_i(ji,jj,jl) = v_i (ji,jj,jl) / MAX( a_i(ji,jj,jl) , epsi10 ) * zindb
180               ht_s(ji,jj,jl) = v_s (ji,jj,jl) / MAX( a_i(ji,jj,jl) , epsi10 ) * zindb
181               o_i(ji,jj,jl)  = oa_i(ji,jj,jl) / MAX( a_i(ji,jj,jl) , epsi10 ) * zindb
182            END DO
183         END DO
184      END DO
185
186      IF(  num_sal == 2  )THEN
187         DO jl = 1, jpl
188            DO jj = 1, jpj
189               DO ji = 1, jpi
190                  zindb = 1._wp - MAX( 0._wp , SIGN( 1._wp,- a_i(ji,jj,jl) + epsi10 ) )   !0 if no ice and 1 if yes
191                  sm_i(ji,jj,jl) = smv_i(ji,jj,jl) / MAX( v_i(ji,jj,jl) , epsi10 ) * zindb
192               END DO
193            END DO
194         END DO
195      ENDIF
196
197      CALL lim_var_salprof      ! salinity profile
198
199      !-------------------
200      ! Ice temperatures
201      !-------------------
202!CDIR NOVERRCHK
203      DO jl = 1, jpl
204!CDIR NOVERRCHK
205         DO jk = 1, nlay_i
206!CDIR NOVERRCHK
207            DO jj = 1, jpj
208!CDIR NOVERRCHK
209               DO ji = 1, jpi
210                  !                                                              ! Energy of melting q(S,T) [J.m-3]
211                  zq_i    = e_i(ji,jj,jk,jl) / area(ji,jj) / MAX( v_i(ji,jj,jl) , epsi06 ) * REAL(nlay_i,wp) 
212                  zindb   = 1.0 - MAX( 0.0 , SIGN( 1.0 , - v_i(ji,jj,jl) ) )     ! zindb = 0 if no ice and 1 if yes
213                  zq_i    = zq_i * unit_fac * zindb                              !convert units
214                  ztmelts = -tmut * s_i(ji,jj,jk,jl) + rtt                       ! Ice layer melt temperature
215                  !
216                  zaaa       =  cpic                  ! Conversion q(S,T) -> T (second order equation)
217                  zbbb       =  ( rcp - cpic ) * ( ztmelts - rtt ) + zq_i / rhoic - lfus
218                  zccc       =  lfus * (ztmelts-rtt)
219                  zdiscrim   =  SQRT( MAX(zbbb*zbbb - 4._wp*zaaa*zccc , 0._wp) )
220                  t_i(ji,jj,jk,jl) = rtt + zindb *( - zbbb - zdiscrim ) / ( 2.0 *zaaa )
221                  t_i(ji,jj,jk,jl) = MIN( rtt, MAX( 173.15_wp, t_i(ji,jj,jk,jl) ) )       ! 100-rtt < t_i < rtt
222               END DO
223            END DO
224         END DO
225      END DO
226
227      !--------------------
228      ! Snow temperatures
229      !--------------------
230      zfac1 = 1._wp / ( rhosn * cpic )
231      zfac2 = lfus / cpic 
232      DO jl = 1, jpl
233         DO jk = 1, nlay_s
234            DO jj = 1, jpj
235               DO ji = 1, jpi
236                  !Energy of melting q(S,T) [J.m-3]
237                  zq_s  = e_s(ji,jj,jk,jl) / ( area(ji,jj) * MAX( v_s(ji,jj,jl) , epsi06 ) ) * REAL(nlay_s,wp)
238                  zindb = 1._wp - MAX( 0._wp , SIGN( 1._wp , - v_s(ji,jj,jl) ) )     ! zindb = 0 if no ice and 1 if yes
239                  zq_s  = zq_s * unit_fac * zindb                                    ! convert units
240                  !
241                  t_s(ji,jj,jk,jl) = rtt + zindb * ( - zfac1 * zq_s + zfac2 )
242                  t_s(ji,jj,jk,jl) = MIN( rtt, MAX( 173.15, t_s(ji,jj,jk,jl) ) )     ! 100-rtt < t_i < rtt
243               END DO
244            END DO
245         END DO
246      END DO
247
248      !-------------------
249      ! Mean temperature
250      !-------------------
251      tm_i(:,:) = 0._wp
252      DO jl = 1, jpl
253         DO jk = 1, nlay_i
254            DO jj = 1, jpj
255               DO ji = 1, jpi
256                  zindb = (  1._wp - MAX( 0._wp , SIGN( 1._wp , - vt_i(ji,jj) + epsi10 ) )  )
257                  tm_i(ji,jj) = tm_i(ji,jj) + zindb * t_i(ji,jj,jk,jl) * v_i(ji,jj,jl)   &
258                     &                      / (  REAL(nlay_i,wp) * MAX( vt_i(ji,jj) , epsi10 )  )
259               END DO
260            END DO
261         END DO
262      END DO
263      !
264   END SUBROUTINE lim_var_glo2eqv
265
266
267   SUBROUTINE lim_var_eqv2glo
268      !!------------------------------------------------------------------
269      !!                ***  ROUTINE lim_var_eqv2glo ***
270      !!
271      !! ** Purpose :   computes global variables as function of equivalent variables
272      !!                i.e. it turns VEQV into VGLO
273      !! ** Method  :
274      !!
275      !! ** History :  (01-2006) Martin Vancoppenolle, UCL-ASTR
276      !!------------------------------------------------------------------
277      !
278      v_i(:,:,:)   = ht_i(:,:,:) * a_i(:,:,:)
279      v_s(:,:,:)   = ht_s(:,:,:) * a_i(:,:,:)
280      smv_i(:,:,:) = sm_i(:,:,:) * v_i(:,:,:)
281      oa_i (:,:,:) = o_i (:,:,:) * a_i(:,:,:)
282      !
283   END SUBROUTINE lim_var_eqv2glo
284
285
286   SUBROUTINE lim_var_salprof
287      !!------------------------------------------------------------------
288      !!                ***  ROUTINE lim_var_salprof ***
289      !!
290      !! ** Purpose :   computes salinity profile in function of bulk salinity     
291      !!
292      !! ** Method  : If bulk salinity greater than s_i_1,
293      !!              the profile is assumed to be constant (S_inf)
294      !!              If bulk salinity lower than s_i_0,
295      !!              the profile is linear with 0 at the surface (S_zero)
296      !!              If it is between s_i_0 and s_i_1, it is a
297      !!              alpha-weighted linear combination of s_inf and s_zero
298      !!
299      !! ** References : Vancoppenolle et al., 2007 (in preparation)
300      !!------------------------------------------------------------------
301      INTEGER  ::   ji, jj, jk, jl   ! dummy loop index
302      REAL(wp) ::   dummy_fac0, dummy_fac1, dummy_fac, zsal      ! local scalar
303      REAL(wp) ::   zind0, zind01, zindbal, zargtemp , zs_zero   !   -      -
304      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_slope_s, zalpha   ! 3D pointer
305      !!------------------------------------------------------------------
306
307      CALL wrk_alloc( jpi, jpj, jpl, z_slope_s, zalpha )
308
309      !---------------------------------------
310      ! Vertically constant, constant in time
311      !---------------------------------------
312      IF(  num_sal == 1  )   s_i(:,:,:,:) = bulk_sal
313
314      !-----------------------------------
315      ! Salinity profile, varying in time
316      !-----------------------------------
317      IF(  num_sal == 2  ) THEN
318         !
319         DO jk = 1, nlay_i
320            s_i(:,:,jk,:)  = sm_i(:,:,:)
321         END DO
322         !
323         DO jl = 1, jpl                               ! Slope of the linear profile
324            DO jj = 1, jpj
325               DO ji = 1, jpi
326                  z_slope_s(ji,jj,jl) = 2._wp * sm_i(ji,jj,jl) / MAX( 0.01 , ht_i(ji,jj,jl) )
327               END DO
328            END DO
329         END DO
330         !
331         dummy_fac0 = 1._wp / ( s_i_0 - s_i_1 )       ! Weighting factor between zs_zero and zs_inf
332         dummy_fac1 = s_i_1 / ( s_i_1 - s_i_0 )
333         !
334         zalpha(:,:,:) = 0._wp
335         DO jl = 1, jpl
336            DO jj = 1, jpj
337               DO ji = 1, jpi
338                  ! zind0 = 1 if sm_i le s_i_0 and 0 otherwise
339                  zind0  = MAX( 0._wp   , SIGN( 1._wp  , s_i_0 - sm_i(ji,jj,jl) ) ) 
340                  ! zind01 = 1 if sm_i is between s_i_0 and s_i_1 and 0 othws
341                  zind01 = ( 1._wp - zind0 ) * MAX( 0._wp   , SIGN( 1._wp  , s_i_1 - sm_i(ji,jj,jl) ) ) 
342                  ! If 2.sm_i GE sss_m then zindbal = 1
343                  zindbal = MAX( 0._wp , SIGN( 1._wp , 2._wp * sm_i(ji,jj,jl) - sss_m(ji,jj) ) )
344                  zalpha(ji,jj,jl) = zind0  + zind01 * ( sm_i(ji,jj,jl) * dummy_fac0 + dummy_fac1 )
345                  zalpha(ji,jj,jl) = zalpha(ji,jj,jl) * ( 1._wp - zindbal )
346               END DO
347            END DO
348         END DO
349
350         dummy_fac = 1._wp / REAL( nlay_i )                   ! Computation of the profile
351         DO jl = 1, jpl
352            DO jk = 1, nlay_i
353               DO jj = 1, jpj
354                  DO ji = 1, jpi
355                     !                                      ! linear profile with 0 at the surface
356                     zs_zero = z_slope_s(ji,jj,jl) * ( REAL(jk,wp) - 0.5_wp ) * ht_i(ji,jj,jl) * dummy_fac
357                     !                                      ! weighting the profile
358                     s_i(ji,jj,jk,jl) = zalpha(ji,jj,jl) * zs_zero + ( 1._wp - zalpha(ji,jj,jl) ) * sm_i(ji,jj,jl)
359                  END DO ! ji
360               END DO ! jj
361            END DO ! jk
362         END DO ! jl
363         !
364      ENDIF ! num_sal
365
366      !-------------------------------------------------------
367      ! Vertically varying salinity profile, constant in time
368      !-------------------------------------------------------
369
370      IF(  num_sal == 3  ) THEN      ! Schwarzacher (1959) multiyear salinity profile (mean = 2.30)
371         !
372         sm_i(:,:,:) = 2.30_wp
373         !
374         DO jl = 1, jpl
375!CDIR NOVERRCHK
376            DO jk = 1, nlay_i
377               zargtemp  = ( REAL(jk,wp) - 0.5_wp ) / REAL(nlay_i,wp)
378               zsal =  1.6_wp * (  1._wp - COS( rpi * zargtemp**(0.407_wp/(0.573_wp+zargtemp)) )  )
379               s_i(:,:,jk,jl) =  zsal
380            END DO
381         END DO
382         !
383      ENDIF ! num_sal
384      !
385      CALL wrk_dealloc( jpi, jpj, jpl, z_slope_s, zalpha )
386      !
387   END SUBROUTINE lim_var_salprof
388
389
390   SUBROUTINE lim_var_icetm
391      !!------------------------------------------------------------------
392      !!                ***  ROUTINE lim_var_icetm ***
393      !!
394      !! ** Purpose :   computes mean sea ice temperature
395      !!------------------------------------------------------------------
396      INTEGER  ::   ji, jj, jk, jl   ! dummy loop indices
397      REAL(wp) ::   zindb   !   -      -
398      !!------------------------------------------------------------------
399
400      ! Mean sea ice temperature
401      tm_i(:,:) = 0._wp
402      DO jl = 1, jpl
403         DO jk = 1, nlay_i
404            DO jj = 1, jpj
405               DO ji = 1, jpi
406                  zindb = (  1._wp - MAX( 0._wp , SIGN( 1._wp , - vt_i(ji,jj) + epsi10 ) )  )
407                  tm_i(ji,jj) = tm_i(ji,jj) + zindb * t_i(ji,jj,jk,jl) * v_i(ji,jj,jl)   &
408                     &                      / (  REAL(nlay_i,wp) * MAX( vt_i(ji,jj) , epsi10 )  )
409               END DO
410            END DO
411         END DO
412      END DO
413
414   END SUBROUTINE lim_var_icetm
415
416
417   SUBROUTINE lim_var_bv
418      !!------------------------------------------------------------------
419      !!                ***  ROUTINE lim_var_bv ***
420      !!
421      !! ** Purpose :   computes mean brine volume (%) in sea ice
422      !!
423      !! ** Method  : e = - 0.054 * S (ppt) / T (C)
424      !!
425      !! References : Vancoppenolle et al., JGR, 2007
426      !!------------------------------------------------------------------
427      INTEGER  ::   ji, jj, jk, jl   ! dummy loop indices
428      REAL(wp) ::   zbvi, zinda, zindb      ! local scalars
429      !!------------------------------------------------------------------
430      !
431      bv_i(:,:) = 0._wp
432      DO jl = 1, jpl
433         DO jk = 1, nlay_i
434            DO jj = 1, jpj
435               DO ji = 1, jpi
436                  zinda = (  1._wp - MAX( 0._wp , SIGN( 1._wp , (t_i(ji,jj,jk,jl) - rtt) + epsi16 ) )  )
437                  zindb = (  1._wp - MAX( 0._wp , SIGN( 1._wp , - vt_i(ji,jj) + epsi16 ) )  )
438                  zbvi  = - zinda * tmut * s_i(ji,jj,jk,jl) / MIN( t_i(ji,jj,jk,jl) - rtt, - epsi16 )   &
439                     &                   * v_i(ji,jj,jl)    / REAL(nlay_i,wp)
440                  bv_i(ji,jj) = bv_i(ji,jj) + zindb * zbvi  / MAX( vt_i(ji,jj) , epsi16 )
441               END DO
442            END DO
443         END DO
444      END DO
445      !
446   END SUBROUTINE lim_var_bv
447
448
449   SUBROUTINE lim_var_salprof1d( kideb, kiut )
450      !!-------------------------------------------------------------------
451      !!                  ***  ROUTINE lim_thd_salprof1d  ***
452      !!
453      !! ** Purpose :   1d computation of the sea ice salinity profile
454      !!                Works with 1d vectors and is used by thermodynamic modules
455      !!-------------------------------------------------------------------
456      INTEGER, INTENT(in) ::   kideb, kiut   ! thickness category index
457      !
458      INTEGER  ::   ji, jk    ! dummy loop indices
459      INTEGER  ::   ii, ij  ! local integers
460      REAL(wp) ::   dummy_fac0, dummy_fac1, dummy_fac2, zargtemp, zsal   ! local scalars
461      REAL(wp) ::   zalpha, zind0, zind01, zindbal, zs_zero              !   -      -
462      !
463      REAL(wp), POINTER, DIMENSION(:) ::   z_slope_s
464      !!---------------------------------------------------------------------
465
466      CALL wrk_alloc( jpij, z_slope_s )
467
468      !---------------------------------------
469      ! Vertically constant, constant in time
470      !---------------------------------------
471      IF( num_sal == 1 )   s_i_b(:,:) = bulk_sal
472
473      !------------------------------------------------------
474      ! Vertically varying salinity profile, varying in time
475      !------------------------------------------------------
476
477      IF(  num_sal == 2  ) THEN
478         !
479         DO ji = kideb, kiut          ! Slope of the linear profile zs_zero
480            z_slope_s(ji) = 2._wp * sm_i_b(ji) / MAX( 0.01 , ht_i_b(ji) )
481         END DO
482
483         ! Weighting factor between zs_zero and zs_inf
484         !---------------------------------------------
485         dummy_fac0 = 1._wp / ( s_i_0 - s_i_1 )
486         dummy_fac1 = s_i_1 / ( s_i_1 - s_i_0 )
487         dummy_fac2 = 1._wp / REAL(nlay_i,wp)
488
489!CDIR NOVERRCHK
490         DO jk = 1, nlay_i
491!CDIR NOVERRCHK
492            DO ji = kideb, kiut
493               ii =  MOD( npb(ji) - 1 , jpi ) + 1
494               ij =     ( npb(ji) - 1 ) / jpi + 1
495               ! zind0 = 1 if sm_i le s_i_0 and 0 otherwise
496               zind0  = MAX( 0._wp , SIGN( 1._wp  , s_i_0 - sm_i_b(ji) ) ) 
497               ! zind01 = 1 if sm_i is between s_i_0 and s_i_1 and 0 othws
498               zind01 = ( 1._wp - zind0 ) * MAX( 0._wp , SIGN( 1._wp , s_i_1 - sm_i_b(ji) ) ) 
499               ! if 2.sm_i GE sss_m then zindbal = 1
500               zindbal = MAX( 0._wp , SIGN( 1._wp , 2._wp * sm_i_b(ji) - sss_m(ii,ij) ) )
501               !
502               zalpha = (  zind0 + zind01 * ( sm_i_b(ji) * dummy_fac0 + dummy_fac1 )  ) * ( 1.0 - zindbal )
503               !
504               zs_zero = z_slope_s(ji) * ( REAL(jk,wp) - 0.5_wp ) * ht_i_b(ji) * dummy_fac2
505               ! weighting the profile
506               s_i_b(ji,jk) = zalpha * zs_zero + ( 1._wp - zalpha ) * sm_i_b(ji)
507            END DO ! ji
508         END DO ! jk
509
510      ENDIF ! num_sal
511
512      !-------------------------------------------------------
513      ! Vertically varying salinity profile, constant in time
514      !-------------------------------------------------------
515
516      IF( num_sal == 3 ) THEN      ! Schwarzacher (1959) multiyear salinity profile (mean = 2.30)
517         !
518         sm_i_b(:) = 2.30_wp
519         !
520!CDIR NOVERRCHK
521         DO jk = 1, nlay_i
522            zargtemp  = ( REAL(jk,wp) - 0.5_wp ) / REAL(nlay_i,wp)
523            zsal =  1.6_wp * (  1._wp - COS( rpi * zargtemp**(0.407_wp/(0.573_wp+zargtemp)) )  )
524            DO ji = kideb, kiut
525               s_i_b(ji,jk) = zsal
526            END DO
527         END DO
528         !
529      ENDIF
530      !
531      CALL wrk_dealloc( jpij, z_slope_s )
532      !
533   END SUBROUTINE lim_var_salprof1d
534
535#else
536   !!----------------------------------------------------------------------
537   !!   Default option         Dummy module          NO  LIM3 sea-ice model
538   !!----------------------------------------------------------------------
539CONTAINS
540   SUBROUTINE lim_var_agg          ! Empty routines
541   END SUBROUTINE lim_var_agg
542   SUBROUTINE lim_var_glo2eqv      ! Empty routines
543   END SUBROUTINE lim_var_glo2eqv
544   SUBROUTINE lim_var_eqv2glo      ! Empty routines
545   END SUBROUTINE lim_var_eqv2glo
546   SUBROUTINE lim_var_salprof      ! Empty routines
547   END SUBROUTINE lim_var_salprof
548   SUBROUTINE lim_var_bv           ! Emtpy routines
549   END SUBROUTINE lim_var_bv
550   SUBROUTINE lim_var_salprof1d    ! Emtpy routines
551   END SUBROUTINE lim_var_salprof1d
552#endif
553
554   !!======================================================================
555END MODULE limvar
Note: See TracBrowser for help on using the repository browser.