source: branches/2013/dev_LOCEAN_CMCC_INGV_MERC_UKMO_2013/NEMOGCM/NEMO/LIM_SRC_3/limtrp.F90 @ 4259

Last change on this file since 4259 was 4259, checked in by cetlod, 7 years ago

minor updates

  • Property svn:keywords set to Id
File size: 32.1 KB
Line 
1MODULE limtrp
2   !!======================================================================
3   !!                       ***  MODULE limtrp   ***
4   !! LIM transport ice model : sea-ice advection/diffusion
5   !!======================================================================
6   !! History : LIM-2 ! 2000-01 (M.A. Morales Maqueda, H. Goosse, and T. Fichefet)  Original code
7   !!            3.0  ! 2005-11 (M. Vancoppenolle)   Multi-layer sea ice, salinity variations
8   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
9   !!----------------------------------------------------------------------
10#if defined key_lim3
11   !!----------------------------------------------------------------------
12   !!   'key_lim3'                                      LIM3 sea-ice model
13   !!----------------------------------------------------------------------
14   !!   lim_trp      : advection/diffusion process of sea ice
15   !!----------------------------------------------------------------------
16   USE phycst         ! physical constant
17   USE dom_oce        ! ocean domain
18   USE sbc_oce        ! ocean surface boundary condition
19   USE par_ice        ! ice parameter
20   USE dom_ice        ! ice domain
21   USE ice            ! ice variables
22   USE limadv         ! ice advection
23   USE limhdf         ! ice horizontal diffusion
24   USE in_out_manager ! I/O manager
25   USE lbclnk         ! lateral boundary conditions -- MPP exchanges
26   USE lib_mpp        ! MPP library
27   USE wrk_nemo       ! work arrays
28   USE prtctl         ! Print control
29   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
30   USE limvar          ! clem for ice thickness correction
31   USE timing          ! Timing
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   lim_trp    ! called by ice_step
37
38   REAL(wp)  ::   epsi06 = 1.e-06_wp   ! constant values
39   REAL(wp)  ::   epsi03 = 1.e-03_wp 
40   REAL(wp)  ::   epsi10 = 1.e-10_wp 
41   REAL(wp)  ::   epsi16 = 1.e-16_wp
42   REAL(wp)  ::   epsi20 = 1.e-20_wp
43   REAL(wp)  ::   rzero  = 0._wp   
44   REAL(wp)  ::   rone   = 1._wp
45
46   !! * Substitution
47#  include "vectopt_loop_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
50   !! $Id$
51   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   SUBROUTINE lim_trp( kt ) 
56      !!-------------------------------------------------------------------
57      !!                   ***  ROUTINE lim_trp ***
58      !!                   
59      !! ** purpose : advection/diffusion process of sea ice
60      !!
61      !! ** method  : variables included in the process are scalar,   
62      !!     other values are considered as second order.
63      !!     For advection, a second order Prather scheme is used. 
64      !!
65      !! ** action :
66      !!---------------------------------------------------------------------
67      INTEGER, INTENT(in) ::   kt   ! number of iteration
68      !
69      INTEGER  ::   ji, jj, jk, jl, layer   ! dummy loop indices
70      INTEGER  ::   initad                  ! number of sub-timestep for the advection
71      INTEGER  ::   ierr                    ! error status
72      REAL(wp) ::   zindb  , zindsn , zindic, zindh, zinda      ! local scalar
73      REAL(wp) ::   zusvosn, zusvoic, zbigval     !   -      -
74      REAL(wp) ::   zcfl , zusnit                 !   -      -
75      REAL(wp) ::   ze   , zsal   , zage          !   -      -
76      !
77      REAL(wp), POINTER, DIMENSION(:,:)      ::   zui_u, zvi_v, zsm, zs0at, zs0ow
78      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   zs0ice, zs0sn, zs0a, zs0c0 , zs0sm , zs0oi
79      REAL(wp), POINTER, DIMENSION(:,:,:,:)  ::   zs0e
80      REAL(wp) :: zchk_v_i, zchk_smv, zchk_fs, zchk_fw, zchk_v_i_b, zchk_smv_b, zchk_fs_b, zchk_fw_b ! Check conservation (C Rousset)
81      REAL(wp) :: zchk_vmin, zchk_amin, zchk_amax, zchk_umax ! Check errors (C Rousset)
82      ! mass and salt flux (clem)
83      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zviold   ! old ice volume...
84      ! correct ice thickness (clem)
85      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zaiold, zhimax   ! old ice concentration and thickness
86      REAL(wp) :: zdv, zda, zvi, zvs, zsmv
87      !!---------------------------------------------------------------------
88      IF( nn_timing == 1 )  CALL timing_start('limtrp')
89
90      CALL wrk_alloc( jpi, jpj, zui_u, zvi_v, zsm, zs0at, zs0ow )
91      CALL wrk_alloc( jpi, jpj, jpl, zs0ice, zs0sn, zs0a, zs0c0 , zs0sm , zs0oi )
92      CALL wrk_alloc( jpi, jpj, jkmax, jpl, zs0e )
93
94      CALL wrk_alloc( jpi,jpj,jpl,zviold )   ! clem
95      CALL wrk_alloc( jpi,jpj,jpl,zaiold, zhimax )   ! clem
96
97      ! -------------------------------
98      !- check conservation (C Rousset)
99      IF( ln_limdiahsb ) THEN
100         zchk_v_i_b = glob_sum( SUM(   v_i(:,:,:), dim=3 ) * area(:,:) * tms(:,:) )
101         zchk_smv_b = glob_sum( SUM( smv_i(:,:,:), dim=3 ) * area(:,:) * tms(:,:) )
102         zchk_fw_b  = glob_sum( rdm_ice(:,:) * area(:,:) * tms(:,:) )
103         zchk_fs_b  = glob_sum( ( sfx_bri(:,:) + sfx_thd(:,:) + sfx_res(:,:) + sfx_mec(:,:) ) * area(:,:) * tms(:,:) )
104      ENDIF
105      !- check conservation (C Rousset)
106      ! -------------------------------
107
108      IF( numit == nstart .AND. lwp ) THEN
109         WRITE(numout,*)
110         IF( ln_limdyn ) THEN   ;   WRITE(numout,*) 'lim_trp : Ice transport '
111         ELSE                   ;   WRITE(numout,*) 'lim_trp : No ice advection as ln_limdyn = ', ln_limdyn
112         ENDIF
113         WRITE(numout,*) '~~~~~~~~~~~~'
114      ENDIF
115     
116      zsm(:,:) = area(:,:)
117
118      !                             !-------------------------------------!
119      IF( ln_limdyn ) THEN          !   Advection of sea ice properties   !
120         !                          !-------------------------------------!
121         ! mass and salt flux init (clem)
122         zviold(:,:,:)  = v_i(:,:,:)
123
124         !--- Thickness correction init. (clem) -------------------------------
125         CALL lim_var_glo2eqv
126         zaiold(:,:,:) = a_i(:,:,:)
127         !---------------------------------------------------------------------
128         ! Record max of the surrounding ice thicknesses for correction in limupdate
129         ! in case advection creates ice too thick.
130         !---------------------------------------------------------------------
131         zhimax(:,:,:) = ht_i(:,:,:)
132         DO jl = 1, jpl
133            DO jj = 2, jpjm1
134               DO ji = 2, jpim1
135                  zhimax(ji,jj,jl) = MAXVAL( ht_i(ji-1:ji+1,jj-1:jj+1,jl) )
136                  !zhimax(ji,jj,jl) = ( ht_i(ji  ,jj  ,jl) * tmask(ji,  jj  ,1) + ht_i(ji-1,jj-1,jl) * tmask(ji-1,jj-1,1) + ht_i(ji+1,jj+1,jl) * tmask(ji+1,jj+1,1) &
137                  !     &             + ht_i(ji-1,jj  ,jl) * tmask(ji-1,jj  ,1) + ht_i(ji  ,jj-1,jl) * tmask(ji  ,jj-1,1) &
138                  !     &             + ht_i(ji+1,jj  ,jl) * tmask(ji+1,jj  ,1) + ht_i(ji  ,jj+1,jl) * tmask(ji  ,jj+1,1) &
139                  !     &             + ht_i(ji-1,jj+1,jl) * tmask(ji-1,jj+1,1) + ht_i(ji+1,jj-1,jl) * tmask(ji+1,jj-1,1) )
140               END DO
141            END DO
142            CALL lbc_lnk(zhimax(:,:,jl),'T',1.)
143         END DO
144         
145         !-------------------------
146         ! transported fields                                       
147         !-------------------------
148         ! Snow vol, ice vol, salt and age contents, area
149         zs0ow(:,:) = ato_i(:,:) * area(:,:)               ! Open water area
150         DO jl = 1, jpl
151            zs0sn (:,:,jl)   = v_s  (:,:,jl) * area(:,:)    ! Snow volume
152            zs0ice(:,:,jl)   = v_i  (:,:,jl) * area(:,:)    ! Ice  volume
153            zs0a  (:,:,jl)   = a_i  (:,:,jl) * area(:,:)    ! Ice area
154            zs0sm (:,:,jl)   = smv_i(:,:,jl) * area(:,:)    ! Salt content
155            zs0oi (:,:,jl)   = oa_i (:,:,jl) * area(:,:)    ! Age content
156            zs0c0 (:,:,jl)   = e_s  (:,:,1,jl)              ! Snow heat content
157            zs0e  (:,:,:,jl) = e_i  (:,:,:,jl)              ! Ice  heat content
158         END DO
159
160         !--------------------------
161         ! Advection of Ice fields  (Prather scheme)                                           
162         !--------------------------
163         ! If ice drift field is too fast, use an appropriate time step for advection.         
164         ! CFL test for stability
165         zcfl  =            MAXVAL( ABS( u_ice(:,:) ) * rdt_ice / e1u(:,:) )
166         zcfl  = MAX( zcfl, MAXVAL( ABS( v_ice(:,:) ) * rdt_ice / e2v(:,:) ) )
167         IF(lk_mpp )   CALL mpp_max( zcfl )
168!!gm more readability:
169!         IF( zcfl > 0.5 ) THEN   ;   initad = 2   ;   zusnit = 0.5_wp
170!         ELSE                    ;   initad = 1   ;   zusnit = 1.0_wp
171!         ENDIF
172!!gm end
173         initad = 1 + NINT( MAX( rzero, SIGN( rone, zcfl-0.5 ) ) )
174         zusnit = 1.0 / REAL( initad ) 
175         IF( zcfl > 0.5 .AND. lwp )   &
176            WRITE(numout,*) 'lim_trp   : CFL violation at day ', nday, ', cfl = ', zcfl,   &
177               &                        ': the ice time stepping is split in two'
178
179         IF( MOD( ( kt - 1) / nn_fsbc , 2 ) == 0 ) THEN       !==  odd ice time step:  adv_x then adv_y  ==!
180            DO jk = 1,initad
181               CALL lim_adv_x( zusnit, u_ice, rone , zsm, zs0ow (:,:), sxopw(:,:),   &             !--- ice open water area
182                  &                                       sxxopw(:,:), syopw(:,:), syyopw(:,:), sxyopw(:,:)  )
183               CALL lim_adv_y( zusnit, v_ice, rzero, zsm, zs0ow (:,:), sxopw(:,:),   &
184                  &                                       sxxopw(:,:), syopw(:,:), syyopw(:,:), sxyopw(:,:)  )
185               DO jl = 1, jpl
186                  CALL lim_adv_x( zusnit, u_ice, rone , zsm, zs0ice(:,:,jl), sxice(:,:,jl),   &    !--- ice volume  ---
187                     &                                       sxxice(:,:,jl), syice(:,:,jl), syyice(:,:,jl), sxyice(:,:,jl)  )
188                  CALL lim_adv_y( zusnit, v_ice, rzero, zsm, zs0ice(:,:,jl), sxice(:,:,jl),   &
189                     &                                       sxxice(:,:,jl), syice(:,:,jl), syyice(:,:,jl), sxyice(:,:,jl)  )
190                  CALL lim_adv_x( zusnit, u_ice, rone , zsm, zs0sn (:,:,jl), sxsn (:,:,jl),   &    !--- snow volume  ---
191                     &                                       sxxsn (:,:,jl), sysn (:,:,jl), syysn (:,:,jl), sxysn (:,:,jl)  )
192                  CALL lim_adv_y( zusnit, v_ice, rzero, zsm, zs0sn (:,:,jl), sxsn (:,:,jl),   &
193                     &                                       sxxsn (:,:,jl), sysn (:,:,jl), syysn (:,:,jl), sxysn (:,:,jl)  )
194                  CALL lim_adv_x( zusnit, u_ice, rone , zsm, zs0sm (:,:,jl), sxsal(:,:,jl),   &    !--- ice salinity ---
195                     &                                       sxxsal(:,:,jl), sysal(:,:,jl), syysal(:,:,jl), sxysal(:,:,jl)  )
196                  CALL lim_adv_y( zusnit, v_ice, rzero, zsm, zs0sm (:,:,jl), sxsal(:,:,jl),   &
197                     &                                       sxxsal(:,:,jl), sysal(:,:,jl), syysal(:,:,jl), sxysal(:,:,jl)  )
198                  CALL lim_adv_x( zusnit, u_ice, rone , zsm, zs0oi (:,:,jl), sxage(:,:,jl),   &   !--- ice age      ---     
199                     &                                       sxxage(:,:,jl), syage(:,:,jl), syyage(:,:,jl), sxyage(:,:,jl)  )
200                  CALL lim_adv_y( zusnit, v_ice, rzero, zsm, zs0oi (:,:,jl), sxage(:,:,jl),   &
201                     &                                       sxxage(:,:,jl), syage(:,:,jl), syyage(:,:,jl), sxyage(:,:,jl)  )
202                  CALL lim_adv_x( zusnit, u_ice, rone , zsm, zs0a  (:,:,jl), sxa  (:,:,jl),   &   !--- ice concentrations ---
203                     &                                       sxxa  (:,:,jl), sya  (:,:,jl), syya  (:,:,jl), sxya  (:,:,jl)  )
204                  CALL lim_adv_y( zusnit, v_ice, rzero, zsm, zs0a  (:,:,jl), sxa  (:,:,jl),   & 
205                     &                                       sxxa  (:,:,jl), sya  (:,:,jl), syya  (:,:,jl), sxya  (:,:,jl)  )
206                  CALL lim_adv_x( zusnit, u_ice, rone , zsm, zs0c0 (:,:,jl), sxc0 (:,:,jl),   &  !--- snow heat contents ---
207                     &                                       sxxc0 (:,:,jl), syc0 (:,:,jl), syyc0 (:,:,jl), sxyc0 (:,:,jl)  )
208                  CALL lim_adv_y( zusnit, v_ice, rzero, zsm, zs0c0 (:,:,jl), sxc0 (:,:,jl),   &
209                     &                                       sxxc0 (:,:,jl), syc0 (:,:,jl), syyc0 (:,:,jl), sxyc0 (:,:,jl)  )
210                  DO layer = 1, nlay_i                                                           !--- ice heat contents ---
211                     CALL lim_adv_x( zusnit, u_ice, rone , zsm, zs0e(:,:,layer,jl), sxe (:,:,layer,jl),   & 
212                        &                                       sxxe(:,:,layer,jl), sye (:,:,layer,jl),   &
213                        &                                       syye(:,:,layer,jl), sxye(:,:,layer,jl) )
214                     CALL lim_adv_y( zusnit, v_ice, rzero, zsm, zs0e(:,:,layer,jl), sxe (:,:,layer,jl),   & 
215                        &                                       sxxe(:,:,layer,jl), sye (:,:,layer,jl),   &
216                        &                                       syye(:,:,layer,jl), sxye(:,:,layer,jl) )
217                  END DO
218               END DO
219            END DO
220         ELSE
221            DO jk = 1, initad
222               CALL lim_adv_y( zusnit, v_ice, rone , zsm, zs0ow (:,:), sxopw(:,:),   &             !--- ice open water area
223                  &                                       sxxopw(:,:), syopw(:,:), syyopw(:,:), sxyopw(:,:)  )
224               CALL lim_adv_x( zusnit, u_ice, rzero, zsm, zs0ow (:,:), sxopw(:,:),   &
225                  &                                       sxxopw(:,:), syopw(:,:), syyopw(:,:), sxyopw(:,:)  )
226               DO jl = 1, jpl
227                  CALL lim_adv_y( zusnit, v_ice, rone , zsm, zs0ice(:,:,jl), sxice(:,:,jl),   &    !--- ice volume  ---
228                     &                                       sxxice(:,:,jl), syice(:,:,jl), syyice(:,:,jl), sxyice(:,:,jl)  )
229                  CALL lim_adv_x( zusnit, u_ice, rzero, zsm, zs0ice(:,:,jl), sxice(:,:,jl),   &
230                     &                                       sxxice(:,:,jl), syice(:,:,jl), syyice(:,:,jl), sxyice(:,:,jl)  )
231                  CALL lim_adv_y( zusnit, v_ice, rone , zsm, zs0sn (:,:,jl), sxsn (:,:,jl),   &    !--- snow volume  ---
232                     &                                       sxxsn (:,:,jl), sysn (:,:,jl), syysn (:,:,jl), sxysn (:,:,jl)  )
233                  CALL lim_adv_x( zusnit, u_ice, rzero, zsm, zs0sn (:,:,jl), sxsn (:,:,jl),   &
234                     &                                       sxxsn (:,:,jl), sysn (:,:,jl), syysn (:,:,jl), sxysn (:,:,jl)  )
235                  CALL lim_adv_y( zusnit, v_ice, rone , zsm, zs0sm (:,:,jl), sxsal(:,:,jl),   &    !--- ice salinity ---
236                     &                                       sxxsal(:,:,jl), sysal(:,:,jl), syysal(:,:,jl), sxysal(:,:,jl)  )
237                  CALL lim_adv_x( zusnit, u_ice, rzero, zsm, zs0sm (:,:,jl), sxsal(:,:,jl),   &
238                     &                                       sxxsal(:,:,jl), sysal(:,:,jl), syysal(:,:,jl), sxysal(:,:,jl)  )
239
240                  CALL lim_adv_y( zusnit, v_ice, rone , zsm, zs0oi (:,:,jl), sxage(:,:,jl),   &   !--- ice age      ---
241                     &                                       sxxage(:,:,jl), syage(:,:,jl), syyage(:,:,jl), sxyage(:,:,jl)  )
242                  CALL lim_adv_x( zusnit, u_ice, rzero, zsm, zs0oi (:,:,jl), sxage(:,:,jl),   &
243                     &                                       sxxage(:,:,jl), syage(:,:,jl), syyage(:,:,jl), sxyage(:,:,jl)  )
244                  CALL lim_adv_y( zusnit, v_ice, rone , zsm, zs0a  (:,:,jl), sxa  (:,:,jl),   &   !--- ice concentrations ---
245                     &                                       sxxa  (:,:,jl), sya  (:,:,jl), syya  (:,:,jl), sxya  (:,:,jl)  )
246                  CALL lim_adv_x( zusnit, u_ice, rzero, zsm, zs0a  (:,:,jl), sxa  (:,:,jl),   &
247                     &                                       sxxa  (:,:,jl), sya  (:,:,jl), syya  (:,:,jl), sxya  (:,:,jl)  )
248                  CALL lim_adv_y( zusnit, v_ice, rone , zsm, zs0c0 (:,:,jl), sxc0 (:,:,jl),   &  !--- snow heat contents ---
249                     &                                       sxxc0 (:,:,jl), syc0 (:,:,jl), syyc0 (:,:,jl), sxyc0 (:,:,jl)  )
250                  CALL lim_adv_x( zusnit, u_ice, rzero, zsm, zs0c0 (:,:,jl), sxc0 (:,:,jl),   &
251                     &                                       sxxc0 (:,:,jl), syc0 (:,:,jl), syyc0 (:,:,jl), sxyc0 (:,:,jl)  )
252                  DO layer = 1, nlay_i                                                           !--- ice heat contents ---
253                     CALL lim_adv_y( zusnit, v_ice, rone , zsm, zs0e(:,:,layer,jl), sxe (:,:,layer,jl),   & 
254                        &                                       sxxe(:,:,layer,jl), sye (:,:,layer,jl),   &
255                        &                                       syye(:,:,layer,jl), sxye(:,:,layer,jl) )
256                     CALL lim_adv_x( zusnit, u_ice, rzero, zsm, zs0e(:,:,layer,jl), sxe (:,:,layer,jl),   & 
257                        &                                       sxxe(:,:,layer,jl), sye (:,:,layer,jl),   &
258                        &                                       syye(:,:,layer,jl), sxye(:,:,layer,jl) )
259                  END DO
260               END DO
261            END DO
262         ENDIF
263
264         !-------------------------------------------
265         ! Recover the properties from their contents
266         !-------------------------------------------
267         zs0ow(:,:) = zs0ow(:,:) / area(:,:)
268         DO jl = 1, jpl
269            zs0ice(:,:,jl) = zs0ice(:,:,jl) / area(:,:)
270            zs0sn (:,:,jl) = zs0sn (:,:,jl) / area(:,:)
271            zs0sm (:,:,jl) = zs0sm (:,:,jl) / area(:,:)
272            zs0oi (:,:,jl) = zs0oi (:,:,jl) / area(:,:)
273            zs0a  (:,:,jl) = zs0a  (:,:,jl) / area(:,:)
274            zs0c0 (:,:,jl) = zs0c0 (:,:,jl) / area(:,:)
275            DO jk = 1, nlay_i
276               zs0e(:,:,jk,jl) = zs0e(:,:,jk,jl) / area(:,:)
277            END DO
278         END DO
279
280         !------------------------------------------------------------------------------!
281         ! 4) Diffusion of Ice fields                 
282         !------------------------------------------------------------------------------!
283
284         !--------------------------------
285         !  diffusion of open water area
286         !--------------------------------
287         zs0at(:,:) = zs0a(:,:,1)      ! total ice fraction
288         DO jl = 2, jpl
289            zs0at(:,:) = zs0at(:,:) + zs0a(:,:,jl)
290         END DO
291         !
292         !                             ! Masked eddy diffusivity coefficient at ocean U- and V-points
293         DO jj = 1, jpjm1                    ! NB: has not to be defined on jpj line and jpi row
294            DO ji = 1 , fs_jpim1   ! vector opt.
295               pahu(ji,jj) = ( 1._wp - MAX( rzero, SIGN( rone, -zs0at(ji  ,jj) ) ) )   &
296                  &        * ( 1._wp - MAX( rzero, SIGN( rone, -zs0at(ji+1,jj) ) ) ) * ahiu(ji,jj)
297               pahv(ji,jj) = ( 1._wp - MAX( rzero, SIGN( rone, -zs0at(ji,jj  ) ) ) )   &
298                  &        * ( 1._wp - MAX( rzero, SIGN( rone,- zs0at(ji,jj+1) ) ) ) * ahiv(ji,jj)
299            END DO
300         END DO
301         !
302         CALL lim_hdf( zs0ow (:,:) )   ! Diffusion
303
304         !------------------------------------
305         !  Diffusion of other ice variables
306         !------------------------------------
307         DO jl = 1, jpl
308         !                             ! Masked eddy diffusivity coefficient at ocean U- and V-points
309            DO jj = 1, jpjm1                 ! NB: has not to be defined on jpj line and jpi row
310               DO ji = 1 , fs_jpim1   ! vector opt.
311                  pahu(ji,jj) = ( 1._wp - MAX( rzero, SIGN( rone, -zs0a(ji  ,jj,jl) ) ) )   &
312                     &        * ( 1._wp - MAX( rzero, SIGN( rone, -zs0a(ji+1,jj,jl) ) ) ) * ahiu(ji,jj)
313                  pahv(ji,jj) = ( 1._wp - MAX( rzero, SIGN( rone, -zs0a(ji,jj  ,jl) ) ) )   &
314                     &        * ( 1._wp - MAX( rzero, SIGN( rone,- zs0a(ji,jj+1,jl) ) ) ) * ahiv(ji,jj)
315               END DO
316            END DO
317
318            CALL lim_hdf( zs0ice (:,:,jl) )
319            CALL lim_hdf( zs0sn  (:,:,jl) )
320            CALL lim_hdf( zs0sm  (:,:,jl) )
321            CALL lim_hdf( zs0oi  (:,:,jl) )
322            CALL lim_hdf( zs0a   (:,:,jl) )
323            CALL lim_hdf( zs0c0  (:,:,jl) )
324            DO jk = 1, nlay_i
325               CALL lim_hdf( zs0e (:,:,jk,jl) )
326            END DO
327         END DO
328
329         !------------------------------------------------------------------------------!
330         ! 5) Update and limit ice properties after transport                           
331         !------------------------------------------------------------------------------!
332
333         !--------------------------------------------------
334         ! 5.1) Recover mean values over the grid squares.
335         !--------------------------------------------------
336         zs0at(:,:) = 0._wp
337         DO jl = 1, jpl
338            DO jj = 1, jpj
339               DO ji = 1, jpi
340                  zs0sn (ji,jj,jl) = MAX( rzero, zs0sn (ji,jj,jl) )
341                  zs0ice(ji,jj,jl) = MAX( rzero, zs0ice(ji,jj,jl) )
342                  zs0sm (ji,jj,jl) = MAX( rzero, zs0sm (ji,jj,jl) )
343                  zs0oi (ji,jj,jl) = MAX( rzero, zs0oi (ji,jj,jl) )
344                  zs0a  (ji,jj,jl) = MAX( rzero, zs0a  (ji,jj,jl) )
345                  zs0c0 (ji,jj,jl) = MAX( rzero, zs0c0 (ji,jj,jl) )
346                  zs0at (ji,jj)    = zs0at(ji,jj) + zs0a(ji,jj,jl)
347               END DO
348            END DO
349         END DO
350
351         !---------------------------------------------------------
352         ! 5.2) Snow thickness, Ice thickness, Ice concentrations
353         !---------------------------------------------------------
354         DO jj = 1, jpj
355            DO ji = 1, jpi
356               zindb        = MAX( 0._wp , SIGN( 1.0, zs0at(ji,jj) - epsi10) )
357               zs0ow(ji,jj) = ( 1._wp - zindb ) + zindb * MAX( zs0ow(ji,jj), 0._wp )
358               ato_i(ji,jj) = zs0ow(ji,jj)
359            END DO
360         END DO
361
362         DO jl = 1, jpl         ! Remove very small areas
363            DO jj = 1, jpj
364               DO ji = 1, jpi
365                  zvi = zs0ice(ji,jj,jl)
366                  zvs = zs0sn(ji,jj,jl)
367                  !
368                  zindb         = MAX( 0.0 , SIGN( 1.0, zs0a(ji,jj,jl) - epsi10) )
369                  !
370                  v_s(ji,jj,jl)  = zindb * zs0sn (ji,jj,jl) 
371                  v_i(ji,jj,jl)  = zindb * zs0ice(ji,jj,jl)
372                  !
373                  zindsn         = MAX( rzero, SIGN( rone, v_s(ji,jj,jl) - epsi10 ) )
374                  zindic         = MAX( rzero, SIGN( rone, v_i(ji,jj,jl) - epsi10 ) )
375                  zindb          = MAX( zindsn, zindic )
376                  !
377                  zs0a(ji,jj,jl) = zindb  * zs0a(ji,jj,jl) !ice concentration
378                  a_i (ji,jj,jl) = zs0a(ji,jj,jl)
379                  v_s (ji,jj,jl) = zindsn * v_s(ji,jj,jl)
380                  v_i (ji,jj,jl) = zindic * v_i(ji,jj,jl)
381                  !
382                  ! Update mass fluxes (clem)
383                  rdm_ice(ji,jj) = rdm_ice(ji,jj) + ( v_i(ji,jj,jl) - zvi ) * rhoic 
384                  rdm_snw(ji,jj) = rdm_snw(ji,jj) + ( v_s(ji,jj,jl) - zvs ) * rhosn 
385              END DO
386            END DO
387         END DO
388
389         !--- Thickness correction in case too high (clem) --------------------------------------------------------
390         CALL lim_var_glo2eqv
391         DO jl = 1, jpl
392            DO jj = 1, jpj
393               DO ji = 1, jpi
394
395                  IF ( v_i(ji,jj,jl) > 0._wp ) THEN
396                     zvi = v_i(ji,jj,jl)
397                     zvs = v_s(ji,jj,jl)
398                     zdv = v_i(ji,jj,jl) - zviold(ji,jj,jl)   
399                     !zda = a_i(ji,jj,jl) - zaiold(ji,jj,jl)   
400                     
401                     zindh = 1._wp
402                     IF ( ( zdv > 0.0 .AND. ht_i(ji,jj,jl) > zhimax(ji,jj,jl) .AND. SUM( zaiold(ji,jj,1:jpl) ) < 0.80 ) .OR. &
403                        & ( zdv < 0.0 .AND. ht_i(ji,jj,jl) > zhimax(ji,jj,jl) ) ) THEN                                         
404                        ht_i(ji,jj,jl) = MIN( zhimax(ji,jj,jl), hi_max(jl) )
405                        zindh   =  MAX( rzero, SIGN( rone, ht_i(ji,jj,jl) - epsi10 ) )
406                        a_i(ji,jj,jl)  = zindh * v_i(ji,jj,jl) / MAX( ht_i(ji,jj,jl), epsi10 )
407                     ELSE
408                        ht_i(ji,jj,jl) = MAX( MIN( ht_i(ji,jj,jl), hi_max(jl) ), hi_max(jl-1) )
409                        zindh   =  MAX( rzero, SIGN( rone, ht_i(ji,jj,jl) - epsi10 ) )
410                        a_i(ji,jj,jl)  = zindh * v_i(ji,jj,jl) / MAX( ht_i(ji,jj,jl), epsi10 )
411                     ENDIF
412
413                     ! small correction due to *zindh for a_i
414                     v_i(ji,jj,jl) = zindh * v_i(ji,jj,jl)
415                     v_s(ji,jj,jl) = zindh * v_s(ji,jj,jl)
416
417                     ! Update mass fluxes
418                     rdm_ice(ji,jj) = rdm_ice(ji,jj) + ( v_i(ji,jj,jl) - zvi ) * rhoic
419                     rdm_snw(ji,jj) = rdm_snw(ji,jj) + ( v_s(ji,jj,jl) - zvs ) * rhosn
420
421                  ENDIF
422
423                  diag_trp_vi(ji,jj) = diag_trp_vi(ji,jj) + ( v_i(ji,jj,jl) - zviold(ji,jj,jl) ) * r1_rdtice
424
425               END DO
426            END DO
427         END DO
428
429         ! ---
430         DO jj = 1, jpj
431            DO ji = 1, jpi
432               zs0at(ji,jj) = SUM( zs0a(ji,jj,1:jpl) ) ! clem@useless??
433            END DO
434         END DO
435
436         !----------------------
437         ! 5.3) Ice properties
438         !----------------------
439
440         zbigval = 1.e+13
441
442         DO jl = 1, jpl
443            DO jj = 1, jpj
444               DO ji = 1, jpi
445                  zsmv = zs0sm(ji,jj,jl)
446
447                  ! Switches and dummy variables
448                  zusvosn         = 1.0/MAX( v_s(ji,jj,jl) , epsi16 )
449                  zusvoic         = 1.0/MAX( v_i(ji,jj,jl) , epsi16 )
450                  zindsn          = MAX( rzero, SIGN( rone, v_s(ji,jj,jl) - epsi10 ) )
451                  zindic          = MAX( rzero, SIGN( rone, v_i(ji,jj,jl) - epsi10 ) )
452                  zindb           = MAX( zindsn, zindic )
453
454                  ! Ice salinity and age
455                  !clem zsal = MAX( MIN( (rhoic-rhosn)/rhoic*sss_m(ji,jj), zusvoic * zs0sm(ji,jj,jl) ), s_i_min ) * v_i(ji,jj,jl)
456                  IF(  num_sal == 2  ) THEN
457                     smv_i(ji,jj,jl) = MAX( MIN( s_i_max * v_i(ji,jj,jl), zsmv ), s_i_min * v_i(ji,jj,jl) )
458                  ENDIF
459
460                  zage = MAX( MIN( zbigval, zs0oi(ji,jj,jl) / MAX( a_i(ji,jj,jl), epsi16 ) ), 0._wp  ) * a_i(ji,jj,jl)
461                  oa_i (ji,jj,jl)  = zindic * zage 
462
463                  ! Snow heat content
464                  ze              =  MIN( MAX( 0.0, zs0c0(ji,jj,jl)*area(ji,jj) ), zbigval )
465                  e_s(ji,jj,1,jl) = zindsn * ze     
466
467                  ! Update salt fluxes (clem)
468                  sfx_res(ji,jj) = sfx_res(ji,jj) - ( smv_i(ji,jj,jl) - zsmv ) * rhoic * r1_rdtice 
469               END DO !ji
470            END DO !jj
471         END DO ! jl
472
473         DO jl = 1, jpl
474            DO jk = 1, nlay_i
475               DO jj = 1, jpj
476                  DO ji = 1, jpi
477                     ! Ice heat content
478                     zindic          =  MAX( rzero, SIGN( rone, v_i(ji,jj,jl) - epsi10 ) )
479                     ze              =  MIN( MAX( 0.0, zs0e(ji,jj,jk,jl)*area(ji,jj) ), zbigval )
480                     e_i(ji,jj,jk,jl) = zindic * ze
481                  END DO !ji
482               END DO ! jj
483            END DO ! jk
484         END DO ! jl
485
486
487      ! --- agglomerate variables (clem) -----------------
488      vt_i (:,:) = 0._wp
489      vt_s (:,:) = 0._wp
490      at_i (:,:) = 0._wp
491      !
492      DO jl = 1, jpl
493         DO jj = 1, jpj
494            DO ji = 1, jpi
495               !
496               vt_i(ji,jj) = vt_i(ji,jj) + v_i(ji,jj,jl) ! ice volume
497               vt_s(ji,jj) = vt_s(ji,jj) + v_s(ji,jj,jl) ! snow volume
498               at_i(ji,jj) = at_i(ji,jj) + a_i(ji,jj,jl) ! ice concentration
499               !
500               zinda = MAX( rzero , SIGN( rone , at_i(ji,jj) - epsi16 ) )
501               icethi(ji,jj) = vt_i(ji,jj) / MAX( at_i(ji,jj) , epsi16 ) * zinda  ! ice thickness
502            END DO
503         END DO
504      END DO
505      ! -------------------------------------------------
506
507
508
509      ENDIF
510
511      IF(ln_ctl) THEN   ! Control print
512         CALL prt_ctl_info(' ')
513         CALL prt_ctl_info(' - Cell values : ')
514         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
515         CALL prt_ctl(tab2d_1=area , clinfo1=' lim_trp  : cell area :')
516         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_trp  : at_i      :')
517         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_trp  : vt_i      :')
518         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_trp  : vt_s      :')
519         DO jl = 1, jpl
520            CALL prt_ctl_info(' ')
521            CALL prt_ctl_info(' - Category : ', ivar1=jl)
522            CALL prt_ctl_info('   ~~~~~~~~~~')
523            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_trp  : a_i      : ')
524            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_trp  : ht_i     : ')
525            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_trp  : ht_s     : ')
526            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_trp  : v_i      : ')
527            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_trp  : v_s      : ')
528            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_trp  : e_s      : ')
529            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_trp  : t_su     : ')
530            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_trp  : t_snow   : ')
531            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_trp  : sm_i     : ')
532            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_trp  : smv_i    : ')
533            DO jk = 1, nlay_i
534               CALL prt_ctl_info(' ')
535               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
536               CALL prt_ctl_info('   ~~~~~~~')
537               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_trp  : t_i      : ')
538               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_trp  : e_i      : ')
539            END DO
540         END DO
541      ENDIF
542      ! -------------------------------
543      !- check conservation (C Rousset)
544      IF( ln_limdiahsb ) THEN
545         zchk_fs  = glob_sum( ( sfx_bri(:,:) + sfx_thd(:,:) + sfx_res(:,:) + sfx_mec(:,:) ) * area(:,:) * tms(:,:) ) - zchk_fs_b
546         zchk_fw  = glob_sum( rdm_ice(:,:) * area(:,:) * tms(:,:) ) - zchk_fw_b
547 
548         zchk_v_i = ( glob_sum( SUM(   v_i(:,:,:), dim=3 ) * area(:,:) * tms(:,:) ) - zchk_v_i_b - ( zchk_fw / rhoic ) ) / rdt_ice
549         zchk_smv = ( glob_sum( SUM( smv_i(:,:,:), dim=3 ) * area(:,:) * tms(:,:) ) - zchk_smv_b ) / rdt_ice + ( zchk_fs / rhoic )
550
551         zchk_vmin = glob_min(v_i)
552         zchk_amax = glob_max(SUM(a_i,dim=3))
553         zchk_amin = glob_min(a_i)
554         zchk_umax = glob_max(SQRT(u_ice**2 + v_ice**2))
555
556         IF(lwp) THEN
557            IF ( ABS( zchk_v_i   ) >  1.e-5 ) THEN
558               WRITE(numout,*) 'violation volume [m3/day]     (limtrp) = ',(zchk_v_i * rday)
559               WRITE(numout,*) 'u_ice max [m/s]               (limtrp) = ',zchk_umax
560               WRITE(numout,*) 'number of time steps          (limtrp) =',kt
561            ENDIF
562            IF ( ABS( zchk_smv   ) >  1.e-4 ) WRITE(numout,*) 'violation saline [psu*m3/day] (limtrp) = ',(zchk_smv * rday)
563            IF ( zchk_vmin <  0.            ) WRITE(numout,*) 'violation v_i<0  [mm]         (limtrp) = ',(zchk_vmin * 1.e-3)
564            IF ( zchk_amin <  0.            ) WRITE(numout,*) 'violation a_i<0               (limtrp) = ',zchk_amin
565         ENDIF
566      ENDIF
567      !- check conservation (C Rousset)
568      ! -------------------------------
569      !
570      CALL wrk_dealloc( jpi, jpj, zui_u, zvi_v, zsm, zs0at, zs0ow )
571      CALL wrk_dealloc( jpi, jpj, jpl, zs0ice, zs0sn, zs0a, zs0c0 , zs0sm , zs0oi )
572      CALL wrk_dealloc( jpi, jpj, jkmax, jpl, zs0e )
573
574      CALL wrk_dealloc( jpi,jpj,jpl,zaiold, zhimax )   ! clem
575      !
576      IF( nn_timing == 1 )  CALL timing_stop('limtrp')
577   END SUBROUTINE lim_trp
578
579#else
580   !!----------------------------------------------------------------------
581   !!   Default option         Empty Module                No sea-ice model
582   !!----------------------------------------------------------------------
583CONTAINS
584   SUBROUTINE lim_trp        ! Empty routine
585   END SUBROUTINE lim_trp
586#endif
587
588   !!======================================================================
589END MODULE limtrp
Note: See TracBrowser for help on using the repository browser.