New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcice_lim.F90 in branches/2013/dev_LOCEAN_CMCC_INGV_MERC_UKMO_2013/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2013/dev_LOCEAN_CMCC_INGV_MERC_UKMO_2013/NEMOGCM/NEMO/OPA_SRC/SBC/sbcice_lim.F90 @ 4269

Last change on this file since 4269 was 4269, checked in by clem, 10 years ago

update lim3 for bdy purpose
  • Property svn:keywords set to Id
File size: 42.4 KB
Line 
1MODULE sbcice_lim
2   !!======================================================================
3   !!                       ***  MODULE  sbcice_lim  ***
4   !! Surface module :  update the ocean surface boundary condition over ice
5   !!       &           covered area using LIM sea-ice model
6   !! Sea-Ice model  :  LIM-3 Sea ice model time-stepping
7   !!=====================================================================
8   !! History :  2.0  ! 2006-12  (M. Vancoppenolle) Original code
9   !!            3.0  ! 2008-02  (C. Talandier)  Surface module from icestp.F90
10   !!             -   ! 2008-04  (G. Madec)  sltyle and lim_ctl routine
11   !!            3.3  ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!            3.4  ! 2011-01  (A Porter)  dynamical allocation
13   !!             -   ! 2012-10  (C. Rousset)  add lim_diahsb
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3' :                                  LIM 3.0 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   sbc_ice_lim  : sea-ice model time-stepping and update ocean sbc over ice-covered area
20   !!   lim_ctl       : alerts in case of ice model crash
21   !!   lim_prt_state : ice control print at a given grid point
22   !!----------------------------------------------------------------------
23   USE oce             ! ocean dynamics and tracers
24   USE dom_oce         ! ocean space and time domain
25   USE par_ice         ! sea-ice parameters
26   USE ice             ! LIM-3: ice variables
27   USE iceini          ! LIM-3: ice initialisation
28   USE dom_ice         ! LIM-3: ice domain
29
30   USE sbc_oce         ! Surface boundary condition: ocean fields
31   USE sbc_ice         ! Surface boundary condition: ice   fields
32   USE sbcblk_core     ! Surface boundary condition: CORE bulk
33   USE sbcblk_clio     ! Surface boundary condition: CLIO bulk
34   USE sbccpl          ! Surface boundary condition: coupled interface
35   USE albedo          ! ocean & ice albedo
36
37   USE phycst          ! Define parameters for the routines
38   USE eosbn2          ! equation of state
39   USE limdyn          ! Ice dynamics
40   USE limtrp          ! Ice transport
41   USE limthd          ! Ice thermodynamics
42   USE limitd_th       ! Thermodynamics on ice thickness distribution
43   USE limitd_me       ! Mechanics on ice thickness distribution
44   USE limsbc          ! sea surface boundary condition
45   USE limdiahsb       ! Ice budget diagnostics
46   USE limwri          ! Ice outputs
47   USE limrst          ! Ice restarts
48   USE limupdate1       ! update of global variables
49   USE limupdate2       ! update of global variables
50   USE limvar          ! Ice variables switch
51
52   USE c1d             ! 1D vertical configuration
53   USE lbclnk          ! lateral boundary condition - MPP link
54   USE lib_mpp         ! MPP library
55   USE wrk_nemo        ! work arrays
56   USE timing          ! Timing
57   USE iom             ! I/O manager library
58   USE in_out_manager  ! I/O manager
59   USE prtctl          ! Print control
60
61#if defined key_bdy 
62   USE bdyice_lim       ! unstructured open boundary data  (bdy_ice_lim routine)
63#endif
64
65   IMPLICIT NONE
66   PRIVATE
67
68   PUBLIC sbc_ice_lim  ! routine called by sbcmod.F90
69   
70   !! * Substitutions
71#  include "domzgr_substitute.h90"
72#  include "vectopt_loop_substitute.h90"
73   !!----------------------------------------------------------------------
74   !! NEMO/OPA 4.0 , UCL NEMO Consortium (2011)
75   !! $Id$
76   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
77   !!----------------------------------------------------------------------
78CONTAINS
79
80   FUNCTION fice_cell_ave ( ptab)
81      !!--------------------------------------------------------------------------
82      !! * Compute average over categories, for grid cell (ice covered and free ocean)
83      !!--------------------------------------------------------------------------
84      REAL (wp), DIMENSION (jpi,jpj) :: fice_cell_ave
85      REAL (wp), DIMENSION (jpi,jpj,jpl), INTENT (in) :: ptab
86      INTEGER :: jl ! Dummy loop index
87     
88      fice_cell_ave (:,:) = 0.0_wp
89     
90      DO jl = 1, jpl
91         fice_cell_ave (:,:) = fice_cell_ave (:,:) &
92            &                  + a_i (:,:,jl) * ptab (:,:,jl)
93      END DO
94     
95   END FUNCTION fice_cell_ave
96   
97   FUNCTION fice_ice_ave ( ptab)
98      !!--------------------------------------------------------------------------
99      !! * Compute average over categories, for ice covered part of grid cell
100      !!--------------------------------------------------------------------------
101      REAL (kind=wp), DIMENSION (jpi,jpj) :: fice_ice_ave
102      REAL (kind=wp), DIMENSION (jpi,jpj,jpl), INTENT(in) :: ptab
103
104      fice_ice_ave (:,:) = 0.0_wp
105      WHERE ( at_i (:,:) .GT. 0.0_wp ) fice_ice_ave (:,:) = fice_cell_ave ( ptab (:,:,:)) / at_i (:,:)
106
107   END FUNCTION fice_ice_ave
108
109   !!======================================================================
110
111   SUBROUTINE sbc_ice_lim( kt, kblk )
112      !!---------------------------------------------------------------------
113      !!                  ***  ROUTINE sbc_ice_lim  ***
114      !!                   
115      !! ** Purpose :   update the ocean surface boundary condition via the
116      !!                Louvain la Neuve Sea Ice Model time stepping
117      !!
118      !! ** Method  :   ice model time stepping
119      !!              - call the ice dynamics routine
120      !!              - call the ice advection/diffusion routine
121      !!              - call the ice thermodynamics routine
122      !!              - call the routine that computes mass and
123      !!                heat fluxes at the ice/ocean interface
124      !!              - save the outputs
125      !!              - save the outputs for restart when necessary
126      !!
127      !! ** Action  : - time evolution of the LIM sea-ice model
128      !!              - update all sbc variables below sea-ice:
129      !!                utau, vtau, taum, wndm, qns , qsr, emp , sfx
130      !!---------------------------------------------------------------------
131      INTEGER, INTENT(in) ::   kt      ! ocean time step
132      INTEGER, INTENT(in) ::   kblk    ! type of bulk (=3 CLIO, =4 CORE)
133      !!
134      INTEGER  ::   jl      ! dummy loop index
135      REAL(wp) ::   zcoef   ! local scalar
136      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   zalb_ice_os, zalb_ice_cs  ! albedo of the ice under overcast/clear sky
137      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   zalb_ice      ! mean albedo of ice (for coupled)
138
139      REAL(wp), POINTER, DIMENSION(:,:) :: zalb_ice_all    ! Mean albedo over all categories
140      REAL(wp), POINTER, DIMENSION(:,:) :: ztem_ice_all    ! Mean temperature over all categories
141     
142      REAL(wp), POINTER, DIMENSION(:,:) :: z_qsr_ice_all   ! Mean solar heat flux over all categories
143      REAL(wp), POINTER, DIMENSION(:,:) :: z_qns_ice_all   ! Mean non solar heat flux over all categories
144      REAL(wp), POINTER, DIMENSION(:,:) :: z_qla_ice_all   ! Mean latent heat flux over all categories
145      REAL(wp), POINTER, DIMENSION(:,:) :: z_dqns_ice_all  ! Mean d(qns)/dT over all categories
146      REAL(wp), POINTER, DIMENSION(:,:) :: z_dqla_ice_all  ! Mean d(qla)/dT over all categories
147      !!----------------------------------------------------------------------
148
149      !- O.M. : why do we allocate all these arrays even when MOD( kt-1, nn_fsbc ) /= 0 ?????
150
151      IF( nn_timing == 1 )  CALL timing_start('sbc_ice_lim')
152
153      CALL wrk_alloc( jpi,jpj,jpl, zalb_ice_os, zalb_ice_cs )
154
155#if defined key_coupled
156      IF ( ln_cpl .OR. ln_iceflx_ave .OR. ln_iceflx_linear ) CALL wrk_alloc( jpi,jpj,jpl, zalb_ice)
157      IF ( ln_iceflx_ave .OR. ln_iceflx_linear ) &
158         &   CALL wrk_alloc( jpi,jpj, ztem_ice_all, zalb_ice_all, z_qsr_ice_all, z_qns_ice_all, z_qla_ice_all, z_dqns_ice_all, z_dqla_ice_all)
159#endif
160
161      IF( kt == nit000 ) THEN
162         IF(lwp) WRITE(numout,*)
163         IF(lwp) WRITE(numout,*) 'sbc_ice_lim : update ocean surface boudary condition' 
164         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   via Louvain la Neuve Ice Model (LIM-3) time stepping'
165         !
166         CALL ice_init
167         !
168         IF( ln_nicep ) THEN      ! control print at a given point
169            jiindx = 6   ;   jjindx = 47
170            WRITE(numout,*) ' The debugging point is : jiindx : ',jiindx, ' jjindx : ',jjindx
171         ENDIF
172      ENDIF
173
174      !                                        !----------------------!
175      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN     !  Ice time-step only  !
176         !                                     !----------------------!
177         !                                           !  Bulk Formulea !
178         !                                           !----------------!
179         !
180         u_oce(:,:) = ssu_m(:,:)                     ! mean surface ocean current at ice velocity point
181         v_oce(:,:) = ssv_m(:,:)                     ! (C-grid dynamics :  U- & V-points as the ocean)
182         !
183         t_bo(:,:) = tfreez( sss_m ) +  rt0          ! masked sea surface freezing temperature [Kelvin]
184         !                                           ! (set to rt0 over land)
185         CALL albedo_ice( t_su, ht_i, ht_s, zalb_ice_cs, zalb_ice_os )  ! ... ice albedo
186
187         DO jl = 1, jpl
188            t_su(:,:,jl) = t_su(:,:,jl) +  rt0 * ( 1. - tmask(:,:,1) )
189         END DO
190
191         IF ( ln_cpl ) zalb_ice (:,:,:) = 0.5 * ( zalb_ice_cs (:,:,:) +  zalb_ice_os (:,:,:) )
192         
193#if defined key_coupled
194         IF ( ln_iceflx_ave .OR. ln_iceflx_linear ) THEN
195            !
196            ! Compute mean albedo and temperature
197            zalb_ice_all (:,:) = fice_ice_ave ( zalb_ice (:,:,:) ) 
198            ztem_ice_all (:,:) = fice_ice_ave ( tn_ice   (:,:,:) ) 
199            !
200         ENDIF
201#endif
202                                               ! Bulk formulea - provides the following fields:
203         ! utau_ice, vtau_ice : surface ice stress                     (U- & V-points)   [N/m2]
204         ! qsr_ice , qns_ice  : solar & non solar heat flux over ice   (T-point)         [W/m2]
205         ! qla_ice            : latent heat flux over ice              (T-point)         [W/m2]
206         ! dqns_ice, dqla_ice : non solar & latent heat sensistivity   (T-point)         [W/m2]
207         ! tprecip , sprecip  : total & solid precipitation            (T-point)         [Kg/m2/s]
208         ! fr1_i0  , fr2_i0   : 1sr & 2nd fraction of qsr penetration in ice             [%]
209         !
210         SELECT CASE( kblk )
211         CASE( 3 )                                       ! CLIO bulk formulation
212            CALL blk_ice_clio( t_su , zalb_ice_cs, zalb_ice_os,                           &
213               &                      utau_ice   , vtau_ice   , qns_ice   , qsr_ice   ,   &
214               &                      qla_ice    , dqns_ice   , dqla_ice  ,               &
215               &                      tprecip    , sprecip    ,                           &
216               &                      fr1_i0     , fr2_i0     , cp_ice_msh, jpl  )
217            !         
218         CASE( 4 )                                       ! CORE bulk formulation
219            CALL blk_ice_core( t_su , u_ice     , v_ice     , zalb_ice_cs,               &
220               &                      utau_ice  , vtau_ice  , qns_ice    , qsr_ice   ,   &
221               &                      qla_ice   , dqns_ice  , dqla_ice   ,               &
222               &                      tprecip   , sprecip   ,                            &
223               &                      fr1_i0    , fr2_i0    , cp_ice_msh, jpl  )
224            !
225         CASE ( 5 )
226            zalb_ice (:,:,:) = 0.5 * ( zalb_ice_cs (:,:,:) +  zalb_ice_os (:,:,:) )
227           
228            CALL sbc_cpl_ice_tau( utau_ice , vtau_ice )
229
230            CALL sbc_cpl_ice_flx( p_frld=ato_i, palbi=zalb_ice, psst=sst_m, pist=tn_ice    )
231
232            ! Latent heat flux is forced to 0 in coupled :
233            !  it is included in qns (non-solar heat flux)
234            qla_ice  (:,:,:) = 0.0e0_wp
235            dqla_ice (:,:,:) = 0.0e0_wp
236            !
237         END SELECT
238
239         ! Average over all categories
240#if defined key_coupled
241         IF ( ln_iceflx_ave .OR. ln_iceflx_linear ) THEN
242
243            z_qns_ice_all  (:,:) = fice_ice_ave ( qns_ice  (:,:,:) )
244            z_qsr_ice_all  (:,:) = fice_ice_ave ( qsr_ice  (:,:,:) )
245            z_dqns_ice_all (:,:) = fice_ice_ave ( dqns_ice (:,:,:) )
246            z_qla_ice_all  (:,:) = fice_ice_ave ( qla_ice  (:,:,:) )
247            z_dqla_ice_all (:,:) = fice_ice_ave ( dqla_ice (:,:,:) )
248
249            DO jl = 1, jpl
250               dqns_ice (:,:,jl) = z_dqns_ice_all (:,:)
251               dqla_ice (:,:,jl) = z_dqla_ice_all (:,:)
252            END DO
253            !
254            IF ( ln_iceflx_ave ) THEN
255               DO jl = 1, jpl
256                  qns_ice  (:,:,jl) = z_qns_ice_all  (:,:)
257                  qsr_ice  (:,:,jl) = z_qsr_ice_all  (:,:)
258                  qla_ice  (:,:,jl) = z_qla_ice_all  (:,:)
259               END DO
260            END IF
261            !
262            IF ( ln_iceflx_linear ) THEN
263               DO jl = 1, jpl
264                  qns_ice  (:,:,jl) = z_qns_ice_all(:,:) + z_dqns_ice_all(:,:) * (tn_ice(:,:,jl) - ztem_ice_all(:,:))
265                  qla_ice  (:,:,jl) = z_qla_ice_all(:,:) + z_dqla_ice_all(:,:) * (tn_ice(:,:,jl) - ztem_ice_all(:,:))
266                  qsr_ice  (:,:,jl) = (1.0e0_wp-zalb_ice(:,:,jl)) / (1.0e0_wp-zalb_ice_all(:,:)) * z_qsr_ice_all(:,:)
267               END DO
268            END IF
269         END IF
270#endif
271         !                                           !----------------------!
272         !                                           ! LIM-3  time-stepping !
273         !                                           !----------------------!
274         !
275         numit = numit + nn_fsbc                     ! Ice model time step
276         !
277         !                                           ! Store previous ice values
278!!gm : remark   old_...   should becomes ...b  as tn versus tb 
279         old_a_i  (:,:,:)   = a_i  (:,:,:)     ! ice area
280         old_e_i  (:,:,:,:) = e_i  (:,:,:,:)   ! ice thermal energy
281         old_v_i  (:,:,:)   = v_i  (:,:,:)     ! ice volume
282         old_v_s  (:,:,:)   = v_s  (:,:,:)     ! snow volume
283         old_e_s  (:,:,:,:) = e_s  (:,:,:,:)   ! snow thermal energy
284         old_smv_i(:,:,:)   = smv_i(:,:,:)     ! salt content
285         old_oa_i (:,:,:)   = oa_i (:,:,:)     ! areal age content
286         !
287         old_u_ice(:,:) = u_ice(:,:)
288         old_v_ice(:,:) = v_ice(:,:)
289         !                                           ! intialisation to zero    !!gm is it truly necessary ???
290         d_a_i_thd  (:,:,:)   = 0._wp   ;   d_a_i_trp  (:,:,:)   = 0._wp
291         d_v_i_thd  (:,:,:)   = 0._wp   ;   d_v_i_trp  (:,:,:)   = 0._wp
292         d_e_i_thd  (:,:,:,:) = 0._wp   ;   d_e_i_trp  (:,:,:,:) = 0._wp
293         d_v_s_thd  (:,:,:)   = 0._wp   ;   d_v_s_trp  (:,:,:)   = 0._wp
294         d_e_s_thd  (:,:,:,:) = 0._wp   ;   d_e_s_trp  (:,:,:,:) = 0._wp
295         d_smv_i_thd(:,:,:)   = 0._wp   ;   d_smv_i_trp(:,:,:)   = 0._wp
296         d_oa_i_thd (:,:,:)   = 0._wp   ;   d_oa_i_trp (:,:,:)   = 0._wp
297         !
298         d_u_ice_dyn(:,:) = 0._wp
299         d_v_ice_dyn(:,:) = 0._wp
300         !
301         sfx    (:,:) = 0._wp   ;   sfx_thd  (:,:) = 0._wp
302         sfx_bri(:,:) = 0._wp   ;   sfx_mec  (:,:) = 0._wp   ;   sfx_res  (:,:) = 0._wp
303         fhbri  (:,:) = 0._wp   ;   fheat_mec(:,:) = 0._wp   ;   fheat_res(:,:) = 0._wp
304         fhmec  (:,:) = 0._wp   ;   
305         fmmec  (:,:) = 0._wp     
306         focea2D(:,:) = 0._wp
307         fsup2D (:,:) = 0._wp
308
309         ! used in limthd.F90
310         rdvosif(:,:) = 0._wp   ! variation of ice volume at surface
311         rdvobif(:,:) = 0._wp   ! variation of ice volume at bottom
312         fdvolif(:,:) = 0._wp   ! total variation of ice volume
313         rdvonif(:,:) = 0._wp   ! lateral variation of ice volume
314         fstric (:,:) = 0._wp   ! part of solar radiation transmitted through the ice
315         ffltbif(:,:) = 0._wp   ! linked with fstric
316         qfvbq  (:,:) = 0._wp   ! linked with fstric
317         rdm_snw(:,:) = 0._wp   ! variation of snow mass per unit area
318         rdm_ice(:,:) = 0._wp   ! variation of ice mass per unit area
319         hicifp (:,:) = 0._wp   ! daily thermodynamic ice production.
320         !
321         diag_sni_gr(:,:) = 0._wp   ;   diag_lat_gr(:,:) = 0._wp
322         diag_bot_gr(:,:) = 0._wp   ;   diag_dyn_gr(:,:) = 0._wp
323         diag_bot_me(:,:) = 0._wp   ;   diag_sur_me(:,:) = 0._wp
324         diag_res_pr(:,:) = 0._wp   ;   diag_trp_vi(:,:) = 0._wp
325         ! dynamical invariants
326         delta_i(:,:) = 0._wp       ;   divu_i(:,:) = 0._wp       ;   shear_i(:,:) = 0._wp
327
328                          CALL lim_rst_opn( kt )     ! Open Ice restart file
329         !
330         IF( ln_nicep )   CALL lim_prt_state( jiindx, jjindx, 1, ' - Beginning the time step - ' )   ! control print
331         !
332         IF( .NOT. lk_c1d ) THEN                     ! Ice dynamics & transport (except in 1D case)
333                          CALL lim_dyn( kt )              ! Ice dynamics    ( rheology/dynamics )
334                          CALL lim_trp( kt )              ! Ice transport   ( Advection/diffusion )
335                          CALL lim_var_glo2eqv            ! equivalent variables, requested for rafting
336         IF( ln_nicep )   CALL lim_prt_state( jiindx, jjindx,-1, ' - ice dyn & trp - ' )   ! control print
337                          CALL lim_itd_me                 ! Mechanical redistribution ! (ridging/rafting)
338                          CALL lim_var_agg( 1 ) 
339                          CALL lim_update1
340         ENDIF
341!                         !- Change old values for new values
342                          old_u_ice(:,:)   = u_ice (:,:)
343                          old_v_ice(:,:)   = v_ice (:,:)
344                          old_a_i(:,:,:)   = a_i (:,:,:)
345                          old_v_s(:,:,:)   = v_s (:,:,:)
346                          old_v_i(:,:,:)   = v_i (:,:,:)
347                          old_e_s(:,:,:,:) = e_s (:,:,:,:)
348                          old_e_i(:,:,:,:) = e_i (:,:,:,:)
349                          old_oa_i(:,:,:)  = oa_i(:,:,:)
350                          old_smv_i(:,:,:) = smv_i (:,:,:)
351         !                                           ! Ice thermodynamics
352                          CALL lim_var_glo2eqv            ! equivalent variables
353                          CALL lim_var_agg(1)             ! aggregate ice categories
354                          CALL lim_var_bv                 ! bulk brine volume (diag)
355                          CALL lim_thd( kt )              ! Ice thermodynamics
356                          zcoef = rdt_ice /rday           !  Ice natural aging
357                          oa_i(:,:,:) = oa_i(:,:,:) + a_i(:,:,:) * zcoef
358                          CALL lim_var_glo2eqv            ! this CALL is maybe not necessary (Martin)
359         IF( ln_nicep )   CALL lim_prt_state( jiindx, jjindx, 1, ' - ice thermodyn. - ' )   ! control print
360                          CALL lim_itd_th( kt )           !  Remap ice categories, lateral accretion  !
361         !
362         !                                           ! Global variables update
363                          CALL lim_var_agg( 1 )           ! requested by limupdate
364                          CALL lim_update2                 ! Global variables update
365#if defined key_bdy
366                          CALL lim_var_glo2eqv            !
367                          CALL bdy_ice_lim( kt )          ! clem modif: bdy ice
368                          CALL bdy_ice_lim_dyn( 1 )       !?? repeated from limrhg.F90
369#endif
370                          CALL lim_var_glo2eqv            ! equivalent variables (outputs)
371                          CALL lim_var_agg(2)             ! aggregate ice thickness categories
372         IF( ln_nicep )   CALL lim_prt_state( jiindx, jjindx, 2, ' - Final state - ' )   ! control print
373         !
374                          CALL lim_sbc_flx( kt )     ! Update surface ocean mass, heat and salt fluxes
375         !
376         IF( ln_nicep )   CALL lim_prt_state( jiindx, jjindx, 3, ' - Final state lim_sbc - ' )   ! control print
377         !
378         !                                           ! Diagnostics and outputs
379         IF (ln_limdiaout) CALL lim_diahsb
380!clem # if ! defined key_iomput
381                          CALL lim_wri( 1  )              ! Ice outputs
382!clem # endif
383         IF( kt == nit000 .AND. ln_rstart )   &
384            &             CALL iom_close( numrir )        ! clem: close input ice restart file
385         !
386         IF( lrst_ice )   CALL lim_rst_write( kt )        ! Ice restart file
387                          CALL lim_var_glo2eqv            ! ???
388         !
389         IF( ln_nicep )   CALL lim_ctl               ! alerts in case of model crash
390         !
391      ENDIF                                    ! End sea-ice time step only
392
393      !                                        !--------------------------!
394      !                                        !  at all ocean time step  !
395      !                                        !--------------------------!
396      !                                               
397      !                                              ! Update surface ocean stresses (only in ice-dynamic case)
398      !                                                   ! otherwise the atm.-ocean stresses are used everywhere
399      IF( ln_limdyn )     CALL lim_sbc_tau( kt, ub(:,:,1), vb(:,:,1) )  ! using before instantaneous surf. currents
400     
401!!gm   remark, the ocean-ice stress is not saved in ice diag call above .....  find a solution!!!
402      !
403      CALL wrk_dealloc( jpi,jpj,jpl, zalb_ice_os, zalb_ice_cs )
404
405#if defined key_coupled
406      IF ( ln_cpl .OR. ln_iceflx_ave .OR. ln_iceflx_linear ) CALL wrk_dealloc( jpi,jpj,jpl, zalb_ice)
407      IF ( ln_iceflx_ave .OR. ln_iceflx_linear ) &
408         &    CALL wrk_dealloc( jpi,jpj, ztem_ice_all, zalb_ice_all, z_qsr_ice_all, z_qns_ice_all, z_qla_ice_all, z_dqns_ice_all, z_dqla_ice_all)
409#endif
410      !
411      IF( nn_timing == 1 )  CALL timing_stop('sbc_ice_lim')
412      !
413   END SUBROUTINE sbc_ice_lim
414
415
416   SUBROUTINE lim_ctl
417      !!-----------------------------------------------------------------------
418      !!                   ***  ROUTINE lim_ctl ***
419      !!                 
420      !! ** Purpose :   Alerts in case of model crash
421      !!-------------------------------------------------------------------
422      INTEGER  ::   ji, jj, jk,  jl   ! dummy loop indices
423      INTEGER  ::   inb_altests       ! number of alert tests (max 20)
424      INTEGER  ::   ialert_id         ! number of the current alert
425      REAL(wp) ::   ztmelts           ! ice layer melting point
426      CHARACTER (len=30), DIMENSION(20)      ::   cl_alname   ! name of alert
427      INTEGER           , DIMENSION(20)      ::   inb_alp     ! number of alerts positive
428      !!-------------------------------------------------------------------
429
430      inb_altests = 10
431      inb_alp(:)  =  0
432
433      ! Alert if incompatible volume and concentration
434      ialert_id = 2 ! reference number of this alert
435      cl_alname(ialert_id) = ' Incompat vol and con         '    ! name of the alert
436
437      DO jl = 1, jpl
438         DO jj = 1, jpj
439            DO ji = 1, jpi
440               IF(  v_i(ji,jj,jl) /= 0._wp   .AND.   a_i(ji,jj,jl) == 0._wp   ) THEN
441                  WRITE(numout,*) ' ALERTE 2 :   Incompatible volume and concentration '
442                  WRITE(numout,*) ' at_i     ', at_i(ji,jj)
443                  WRITE(numout,*) ' Point - category', ji, jj, jl
444                  WRITE(numout,*) ' a_i *** a_i_old ', a_i      (ji,jj,jl), old_a_i  (ji,jj,jl)
445                  WRITE(numout,*) ' v_i *** v_i_old ', v_i      (ji,jj,jl), old_v_i  (ji,jj,jl)
446                  WRITE(numout,*) ' d_a_i_thd/trp   ', d_a_i_thd(ji,jj,jl), d_a_i_trp(ji,jj,jl)
447                  WRITE(numout,*) ' d_v_i_thd/trp   ', d_v_i_thd(ji,jj,jl), d_v_i_trp(ji,jj,jl)
448                  inb_alp(ialert_id) = inb_alp(ialert_id) + 1
449               ENDIF
450            END DO
451         END DO
452      END DO
453
454      ! Alerte if very thick ice
455      ialert_id = 3 ! reference number of this alert
456      cl_alname(ialert_id) = ' Very thick ice               ' ! name of the alert
457      jl = jpl 
458      DO jj = 1, jpj
459         DO ji = 1, jpi
460            IF(   ht_i(ji,jj,jl)  >  50._wp   ) THEN
461               CALL lim_prt_state( ji, jj, 2, ' ALERTE 3 :   Very thick ice ' )
462               inb_alp(ialert_id) = inb_alp(ialert_id) + 1
463            ENDIF
464         END DO
465      END DO
466
467      ! Alert if very fast ice
468      ialert_id = 4 ! reference number of this alert
469      cl_alname(ialert_id) = ' Very fast ice               ' ! name of the alert
470      DO jj = 1, jpj
471         DO ji = 1, jpi
472            IF(   MAX( ABS( u_ice(ji,jj) ), ABS( v_ice(ji,jj) ) ) > 0.5  .AND.  &
473               &  at_i(ji,jj) > 0._wp   ) THEN
474               CALL lim_prt_state( ji, jj, 1, ' ALERTE 4 :   Very fast ice ' )
475               WRITE(numout,*) ' ice strength             : ', strength(ji,jj)
476               WRITE(numout,*) ' oceanic stress utau      : ', utau(ji,jj) 
477               WRITE(numout,*) ' oceanic stress vtau      : ', vtau(ji,jj)
478               WRITE(numout,*) ' sea-ice stress utau_ice  : ', utau_ice(ji,jj) 
479               WRITE(numout,*) ' sea-ice stress vtau_ice  : ', vtau_ice(ji,jj)
480               WRITE(numout,*) ' oceanic speed u          : ', u_oce(ji,jj)
481               WRITE(numout,*) ' oceanic speed v          : ', v_oce(ji,jj)
482               WRITE(numout,*) ' sst                      : ', sst_m(ji,jj)
483               WRITE(numout,*) ' sss                      : ', sss_m(ji,jj)
484               WRITE(numout,*) 
485               inb_alp(ialert_id) = inb_alp(ialert_id) + 1
486            ENDIF
487         END DO
488      END DO
489
490      ! Alert if there is ice on continents
491      ialert_id = 6 ! reference number of this alert
492      cl_alname(ialert_id) = ' Ice on continents           ' ! name of the alert
493      DO jj = 1, jpj
494         DO ji = 1, jpi
495            IF(   tms(ji,jj) <= 0._wp   .AND.   at_i(ji,jj) > 0._wp   ) THEN
496               CALL lim_prt_state( ji, jj, 1, ' ALERTE 6 :   Ice on continents ' )
497               WRITE(numout,*) ' masks s, u, v        : ', tms(ji,jj), tmu(ji,jj), tmv(ji,jj) 
498               WRITE(numout,*) ' sst                  : ', sst_m(ji,jj)
499               WRITE(numout,*) ' sss                  : ', sss_m(ji,jj)
500               WRITE(numout,*) ' at_i(ji,jj)          : ', at_i(ji,jj)
501               WRITE(numout,*) ' v_ice(ji,jj)         : ', v_ice(ji,jj)
502               WRITE(numout,*) ' v_ice(ji,jj-1)       : ', v_ice(ji,jj-1)
503               WRITE(numout,*) ' u_ice(ji-1,jj)       : ', u_ice(ji-1,jj)
504               WRITE(numout,*) ' u_ice(ji,jj)         : ', v_ice(ji,jj)
505               !
506               inb_alp(ialert_id) = inb_alp(ialert_id) + 1
507            ENDIF
508         END DO
509      END DO
510
511!
512!     ! Alert if very fresh ice
513      ialert_id = 7 ! reference number of this alert
514      cl_alname(ialert_id) = ' Very fresh ice               ' ! name of the alert
515      DO jl = 1, jpl
516         DO jj = 1, jpj
517            DO ji = 1, jpi
518!!gm  test twice sm_i ...  ????  bug?
519               IF( ( ( ABS( sm_i(ji,jj,jl) ) < 0.5 )   .OR.  &
520                     ( ABS( sm_i(ji,jj,jl) ) < 0.5 ) ) .AND. &
521                             ( a_i(ji,jj,jl) > 0._wp ) ) THEN
522!                 CALL lim_prt_state(ji,jj,1, ' ALERTE 7 :   Very fresh ice ' )
523!                 WRITE(numout,*) ' sst                  : ', sst_m(ji,jj)
524!                 WRITE(numout,*) ' sss                  : ', sss_m(ji,jj)
525!                 WRITE(numout,*) ' s_i_newice           : ', s_i_newice(ji,jj,1:jpl)
526!                 WRITE(numout,*)
527                  inb_alp(ialert_id) = inb_alp(ialert_id) + 1
528               ENDIF
529            END DO
530         END DO
531      END DO
532!
533
534!     ! Alert if too old ice
535      ialert_id = 9 ! reference number of this alert
536      cl_alname(ialert_id) = ' Very old   ice               ' ! name of the alert
537      DO jl = 1, jpl
538         DO jj = 1, jpj
539            DO ji = 1, jpi
540               IF ( ( ( ABS( o_i(ji,jj,jl) ) > rdt_ice ) .OR. &
541                      ( ABS( o_i(ji,jj,jl) ) < 0._wp) ) .AND. &
542                             ( a_i(ji,jj,jl) > 0._wp ) ) THEN
543                  CALL lim_prt_state( ji, jj, 1, ' ALERTE 9 :   Wrong ice age ')
544                  inb_alp(ialert_id) = inb_alp(ialert_id) + 1
545               ENDIF
546            END DO
547         END DO
548      END DO
549 
550      ! Alert on salt flux
551      ialert_id = 5 ! reference number of this alert
552      cl_alname(ialert_id) = ' High salt flux               ' ! name of the alert
553      DO jj = 1, jpj
554         DO ji = 1, jpi
555            IF( ABS( sfx (ji,jj) ) .GT. 1.0e-2 ) THEN
556               CALL lim_prt_state( ji, jj, 3, ' ALERTE 5 :   High salt flux ' )
557               DO jl = 1, jpl
558                  WRITE(numout,*) ' Category no: ', jl
559                  WRITE(numout,*) ' a_i        : ', a_i      (ji,jj,jl) , ' old_a_i    : ', old_a_i  (ji,jj,jl)   
560                  WRITE(numout,*) ' d_a_i_trp  : ', d_a_i_trp(ji,jj,jl) , ' d_a_i_thd  : ', d_a_i_thd(ji,jj,jl) 
561                  WRITE(numout,*) ' v_i        : ', v_i      (ji,jj,jl) , ' old_v_i    : ', old_v_i  (ji,jj,jl)   
562                  WRITE(numout,*) ' d_v_i_trp  : ', d_v_i_trp(ji,jj,jl) , ' d_v_i_thd  : ', d_v_i_thd(ji,jj,jl) 
563                  WRITE(numout,*) ' '
564               END DO
565               inb_alp(ialert_id) = inb_alp(ialert_id) + 1
566            ENDIF
567         END DO
568      END DO
569
570      ! Alert if qns very big
571      ialert_id = 8 ! reference number of this alert
572      cl_alname(ialert_id) = ' fnsolar very big             ' ! name of the alert
573      DO jj = 1, jpj
574         DO ji = 1, jpi
575            IF(   ABS( qns(ji,jj) ) > 1500._wp  .AND.  at_i(ji,jj) > 0._wp  )  THEN
576               !
577               WRITE(numout,*) ' ALERTE 8 :   Very high non-solar heat flux'
578               WRITE(numout,*) ' ji, jj    : ', ji, jj
579               WRITE(numout,*) ' qns       : ', qns(ji,jj)
580               WRITE(numout,*) ' sst       : ', sst_m(ji,jj)
581               WRITE(numout,*) ' sss       : ', sss_m(ji,jj)
582               WRITE(numout,*) ' qcmif     : ', qcmif(ji,jj)
583               WRITE(numout,*) ' qldif     : ', qldif(ji,jj)
584               WRITE(numout,*) ' qcmif     : ', qcmif(ji,jj) / rdt_ice
585               WRITE(numout,*) ' qldif     : ', qldif(ji,jj) / rdt_ice
586               WRITE(numout,*) ' qfvbq     : ', qfvbq(ji,jj)
587               WRITE(numout,*) ' qdtcn     : ', qdtcn(ji,jj)
588               WRITE(numout,*) ' qfvbq / dt: ', qfvbq(ji,jj) / rdt_ice
589               WRITE(numout,*) ' qdtcn / dt: ', qdtcn(ji,jj) / rdt_ice
590               WRITE(numout,*) ' fdtcn     : ', fdtcn(ji,jj) 
591               WRITE(numout,*) ' fhmec     : ', fhmec(ji,jj) 
592               WRITE(numout,*) ' fheat_mec : ', fheat_mec(ji,jj) 
593               WRITE(numout,*) ' fheat_res : ', fheat_res(ji,jj) 
594               WRITE(numout,*) ' fhbri     : ', fhbri(ji,jj) 
595               !
596               CALL lim_prt_state( ji, jj, 2, '   ')
597               inb_alp(ialert_id) = inb_alp(ialert_id) + 1
598               !
599            ENDIF
600         END DO
601      END DO
602      !+++++
603 
604      ! Alert if very warm ice
605      ialert_id = 10 ! reference number of this alert
606      cl_alname(ialert_id) = ' Very warm ice                ' ! name of the alert
607      inb_alp(ialert_id) = 0
608      DO jl = 1, jpl
609         DO jk = 1, nlay_i
610            DO jj = 1, jpj
611               DO ji = 1, jpi
612                  ztmelts    =  -tmut * s_i(ji,jj,jk,jl) + rtt
613                  IF( t_i(ji,jj,jk,jl) >= ztmelts  .AND.  v_i(ji,jj,jl) > 1.e-6   &
614                     &                             .AND.  a_i(ji,jj,jl) > 0._wp   ) THEN
615                     WRITE(numout,*) ' ALERTE 10 :   Very warm ice'
616                     WRITE(numout,*) ' ji, jj, jk, jl : ', ji, jj, jk, jl
617                     WRITE(numout,*) ' t_i : ', t_i(ji,jj,jk,jl)
618                     WRITE(numout,*) ' e_i : ', e_i(ji,jj,jk,jl)
619                     WRITE(numout,*) ' s_i : ', s_i(ji,jj,jk,jl)
620                     WRITE(numout,*) ' ztmelts : ', ztmelts
621                     inb_alp(ialert_id) = inb_alp(ialert_id) + 1
622                  ENDIF
623               END DO
624            END DO
625         END DO
626      END DO
627
628      ialert_id = 1                                 ! reference number of this alert
629      cl_alname(ialert_id) = ' NO alerte 1      '   ! name of the alert
630      WRITE(numout,*)
631      WRITE(numout,*) ' All alerts at the end of ice model '
632      DO ialert_id = 1, inb_altests
633         WRITE(numout,*) ialert_id, cl_alname(ialert_id)//' : ', inb_alp(ialert_id), ' times ! '
634      END DO
635      !
636   END SUBROUTINE lim_ctl
637 
638   
639   SUBROUTINE lim_prt_state( ki, kj, kn, cd1 )
640      !!-----------------------------------------------------------------------
641      !!                   ***  ROUTINE lim_prt_state ***
642      !!                 
643      !! ** Purpose :   Writes global ice state on the (i,j) point
644      !!                in ocean.ouput
645      !!                3 possibilities exist
646      !!                n = 1/-1 -> simple ice state (plus Mechanical Check if -1)
647      !!                n = 2    -> exhaustive state
648      !!                n = 3    -> ice/ocean salt fluxes
649      !!
650      !! ** input   :   point coordinates (i,j)
651      !!                n : number of the option
652      !!-------------------------------------------------------------------
653      INTEGER         , INTENT(in) ::   ki, kj, kn    ! ocean gridpoint indices
654      CHARACTER(len=*), INTENT(in) ::   cd1           !
655      !!
656      INTEGER :: jl
657      !!-------------------------------------------------------------------
658
659      WRITE(numout,*) cd1             ! print title
660
661      !----------------
662      !  Simple state
663      !----------------
664
665      IF ( kn == 1 .OR. kn == -1 ) THEN
666         WRITE(numout,*) ' lim_prt_state - Point : ',ki,kj
667         WRITE(numout,*) ' ~~~~~~~~~~~~~~ '
668         WRITE(numout,*) ' Simple state '
669         WRITE(numout,*) ' masks s,u,v   : ', tms(ki,kj), tmu(ki,kj), tmv(ki,kj)
670         WRITE(numout,*) ' lat - long    : ', gphit(ki,kj), glamt(ki,kj)
671         WRITE(numout,*) ' Time step     : ', numit
672         WRITE(numout,*) ' - Ice drift   '
673         WRITE(numout,*) '   ~~~~~~~~~~~ '
674         WRITE(numout,*) ' u_ice(i-1,j)  : ', u_ice(ki-1,kj)
675         WRITE(numout,*) ' u_ice(i  ,j)  : ', u_ice(ki,kj)
676         WRITE(numout,*) ' v_ice(i  ,j-1): ', v_ice(ki,kj-1)
677         WRITE(numout,*) ' v_ice(i  ,j)  : ', v_ice(ki,kj)
678         WRITE(numout,*) ' strength      : ', strength(ki,kj)
679         WRITE(numout,*)
680         WRITE(numout,*) ' - Cell values '
681         WRITE(numout,*) '   ~~~~~~~~~~~ '
682         WRITE(numout,*) ' cell area     : ', area(ki,kj)
683         WRITE(numout,*) ' at_i          : ', at_i(ki,kj)       
684         WRITE(numout,*) ' vt_i          : ', vt_i(ki,kj)       
685         WRITE(numout,*) ' vt_s          : ', vt_s(ki,kj)       
686         DO jl = 1, jpl
687            WRITE(numout,*) ' - Category (', jl,')'
688            WRITE(numout,*) ' a_i           : ', a_i(ki,kj,jl)
689            WRITE(numout,*) ' ht_i          : ', ht_i(ki,kj,jl)
690            WRITE(numout,*) ' ht_s          : ', ht_s(ki,kj,jl)
691            WRITE(numout,*) ' v_i           : ', v_i(ki,kj,jl)
692            WRITE(numout,*) ' v_s           : ', v_s(ki,kj,jl)
693            WRITE(numout,*) ' e_s           : ', e_s(ki,kj,1,jl)/1.0e9
694            WRITE(numout,*) ' e_i           : ', e_i(ki,kj,1:nlay_i,jl)/1.0e9
695            WRITE(numout,*) ' t_su          : ', t_su(ki,kj,jl)
696            WRITE(numout,*) ' t_snow        : ', t_s(ki,kj,1,jl)
697            WRITE(numout,*) ' t_i           : ', t_i(ki,kj,1:nlay_i,jl)
698            WRITE(numout,*) ' sm_i          : ', sm_i(ki,kj,jl)
699            WRITE(numout,*) ' smv_i         : ', smv_i(ki,kj,jl)
700            WRITE(numout,*)
701            WRITE(numout,*) ' Pathological case : ', patho_case(ki,kj,jl)
702         END DO
703      ENDIF
704      IF( kn == -1 ) THEN
705         WRITE(numout,*) ' Mechanical Check ************** '
706         WRITE(numout,*) ' Check what means ice divergence '
707         WRITE(numout,*) ' Total ice concentration ', at_i (ki,kj)
708         WRITE(numout,*) ' Total lead fraction     ', ato_i(ki,kj)
709         WRITE(numout,*) ' Sum of both             ', ato_i(ki,kj) + at_i(ki,kj)
710         WRITE(numout,*) ' Sum of both minus 1     ', ato_i(ki,kj) + at_i(ki,kj) - 1.00
711      ENDIF
712
713
714      !--------------------
715      !  Exhaustive state
716      !--------------------
717
718      IF ( kn .EQ. 2 ) THEN
719         WRITE(numout,*) ' lim_prt_state - Point : ',ki,kj
720         WRITE(numout,*) ' ~~~~~~~~~~~~~~ '
721         WRITE(numout,*) ' Exhaustive state '
722         WRITE(numout,*) ' lat - long ', gphit(ki,kj), glamt(ki,kj)
723         WRITE(numout,*) ' Time step ', numit
724         WRITE(numout,*) 
725         WRITE(numout,*) ' - Cell values '
726         WRITE(numout,*) '   ~~~~~~~~~~~ '
727         WRITE(numout,*) ' cell area     : ', area(ki,kj)
728         WRITE(numout,*) ' at_i          : ', at_i(ki,kj)       
729         WRITE(numout,*) ' vt_i          : ', vt_i(ki,kj)       
730         WRITE(numout,*) ' vt_s          : ', vt_s(ki,kj)       
731         WRITE(numout,*) ' u_ice(i-1,j)  : ', u_ice(ki-1,kj)
732         WRITE(numout,*) ' u_ice(i  ,j)  : ', u_ice(ki,kj)
733         WRITE(numout,*) ' v_ice(i  ,j-1): ', v_ice(ki,kj-1)
734         WRITE(numout,*) ' v_ice(i  ,j)  : ', v_ice(ki,kj)
735         WRITE(numout,*) ' strength      : ', strength(ki,kj)
736         WRITE(numout,*) ' d_u_ice_dyn   : ', d_u_ice_dyn(ki,kj), ' d_v_ice_dyn   : ', d_v_ice_dyn(ki,kj)
737         WRITE(numout,*) ' old_u_ice     : ', old_u_ice(ki,kj)  , ' old_v_ice     : ', old_v_ice(ki,kj) 
738         WRITE(numout,*)
739
740         DO jl = 1, jpl
741              WRITE(numout,*) ' - Category (',jl,')'
742              WRITE(numout,*) '   ~~~~~~~~         ' 
743              WRITE(numout,*) ' ht_i       : ', ht_i(ki,kj,jl)             , ' ht_s       : ', ht_s(ki,kj,jl)
744              WRITE(numout,*) ' t_i        : ', t_i(ki,kj,1:nlay_i,jl)
745              WRITE(numout,*) ' t_su       : ', t_su(ki,kj,jl)             , ' t_s        : ', t_s(ki,kj,1,jl)
746              WRITE(numout,*) ' sm_i       : ', sm_i(ki,kj,jl)             , ' o_i        : ', o_i(ki,kj,jl)
747              WRITE(numout,*) ' a_i        : ', a_i(ki,kj,jl)              , ' old_a_i    : ', old_a_i(ki,kj,jl)   
748              WRITE(numout,*) ' d_a_i_trp  : ', d_a_i_trp(ki,kj,jl)        , ' d_a_i_thd  : ', d_a_i_thd(ki,kj,jl) 
749              WRITE(numout,*) ' v_i        : ', v_i(ki,kj,jl)              , ' old_v_i    : ', old_v_i(ki,kj,jl)   
750              WRITE(numout,*) ' d_v_i_trp  : ', d_v_i_trp(ki,kj,jl)        , ' d_v_i_thd  : ', d_v_i_thd(ki,kj,jl) 
751              WRITE(numout,*) ' v_s        : ', v_s(ki,kj,jl)              , ' old_v_s    : ', old_v_s(ki,kj,jl) 
752              WRITE(numout,*) ' d_v_s_trp  : ', d_v_s_trp(ki,kj,jl)        , ' d_v_s_thd  : ', d_v_s_thd(ki,kj,jl)
753              WRITE(numout,*) ' e_i1       : ', e_i(ki,kj,1,jl)/1.0e9      , ' old_ei1    : ', old_e_i(ki,kj,1,jl)/1.0e9 
754              WRITE(numout,*) ' de_i1_trp  : ', d_e_i_trp(ki,kj,1,jl)/1.0e9, ' de_i1_thd  : ', d_e_i_thd(ki,kj,1,jl)/1.0e9
755              WRITE(numout,*) ' e_i2       : ', e_i(ki,kj,2,jl)/1.0e9      , ' old_ei2    : ', old_e_i(ki,kj,2,jl)/1.0e9 
756              WRITE(numout,*) ' de_i2_trp  : ', d_e_i_trp(ki,kj,2,jl)/1.0e9, ' de_i2_thd  : ', d_e_i_thd(ki,kj,2,jl)/1.0e9
757              WRITE(numout,*) ' e_snow     : ', e_s(ki,kj,1,jl)            , ' old_e_snow : ', old_e_s(ki,kj,1,jl) 
758              WRITE(numout,*) ' d_e_s_trp  : ', d_e_s_trp(ki,kj,1,jl)      , ' d_e_s_thd  : ', d_e_s_thd(ki,kj,1,jl)
759              WRITE(numout,*) ' smv_i      : ', smv_i(ki,kj,jl)            , ' old_smv_i  : ', old_smv_i(ki,kj,jl)   
760              WRITE(numout,*) ' d_smv_i_trp: ', d_smv_i_trp(ki,kj,jl)      , ' d_smv_i_thd: ', d_smv_i_thd(ki,kj,jl) 
761              WRITE(numout,*) ' oa_i       : ', oa_i(ki,kj,jl)             , ' old_oa_i   : ', old_oa_i(ki,kj,jl)
762              WRITE(numout,*) ' d_oa_i_trp : ', d_oa_i_trp(ki,kj,jl)       , ' d_oa_i_thd : ', d_oa_i_thd(ki,kj,jl)
763              WRITE(numout,*) ' Path. case : ', patho_case(ki,kj,jl)
764        END DO !jl
765
766        WRITE(numout,*)
767        WRITE(numout,*) ' - Heat / FW fluxes '
768        WRITE(numout,*) '   ~~~~~~~~~~~~~~~~ '
769!       WRITE(numout,*) ' sfx_bri    : ', sfx_bri  (ki,kj)
770!       WRITE(numout,*) ' sfx        : ', sfx      (ki,kj)
771!       WRITE(numout,*) ' sfx_res  : ', sfx_res(ki,kj)
772        WRITE(numout,*) ' fmmec      : ', fmmec    (ki,kj)
773        WRITE(numout,*) ' fhmec      : ', fhmec    (ki,kj)
774        WRITE(numout,*) ' fhbri      : ', fhbri    (ki,kj)
775        WRITE(numout,*) ' fheat_mec  : ', fheat_mec(ki,kj)
776        WRITE(numout,*) 
777        WRITE(numout,*) ' sst        : ', sst_m(ki,kj) 
778        WRITE(numout,*) ' sss        : ', sss_m(ki,kj) 
779        WRITE(numout,*) 
780        WRITE(numout,*) ' - Stresses '
781        WRITE(numout,*) '   ~~~~~~~~ '
782        WRITE(numout,*) ' utau_ice   : ', utau_ice(ki,kj) 
783        WRITE(numout,*) ' vtau_ice   : ', vtau_ice(ki,kj)
784        WRITE(numout,*) ' utau       : ', utau    (ki,kj) 
785        WRITE(numout,*) ' vtau       : ', vtau    (ki,kj)
786        WRITE(numout,*) ' oc. vel. u : ', u_oce   (ki,kj)
787        WRITE(numout,*) ' oc. vel. v : ', v_oce   (ki,kj)
788     ENDIF
789
790     !---------------------
791     ! Salt / heat fluxes
792     !---------------------
793
794     IF ( kn .EQ. 3 ) THEN
795        WRITE(numout,*) ' lim_prt_state - Point : ',ki,kj
796        WRITE(numout,*) ' ~~~~~~~~~~~~~~ '
797        WRITE(numout,*) ' - Salt / Heat Fluxes '
798        WRITE(numout,*) '   ~~~~~~~~~~~~~~~~ '
799        WRITE(numout,*) ' lat - long ', gphit(ki,kj), glamt(ki,kj)
800        WRITE(numout,*) ' Time step ', numit
801        WRITE(numout,*)
802        WRITE(numout,*) ' - Heat fluxes at bottom interface ***'
803        WRITE(numout,*) ' qsr       : ', qsr(ki,kj)
804        WRITE(numout,*) ' qns       : ', qns(ki,kj)
805        WRITE(numout,*)
806        WRITE(numout,*) ' - Salt fluxes at bottom interface ***'
807        WRITE(numout,*) ' emp       : ', emp    (ki,kj)
808        WRITE(numout,*) ' sfx_bri   : ', sfx_bri(ki,kj)
809        WRITE(numout,*) ' sfx       : ', sfx    (ki,kj)
810        WRITE(numout,*) ' sfx_res   : ', sfx_res(ki,kj)
811        WRITE(numout,*) ' sfx_mec   : ', sfx_mec(ki,kj)
812        WRITE(numout,*) ' - Heat fluxes at bottom interface ***'
813        WRITE(numout,*) ' fheat_res : ', fheat_res(ki,kj)
814        WRITE(numout,*)
815        WRITE(numout,*) ' - Momentum fluxes '
816        WRITE(numout,*) ' utau      : ', utau(ki,kj) 
817        WRITE(numout,*) ' vtau      : ', vtau(ki,kj)
818      ENDIF
819      WRITE(numout,*) ' '
820      !
821   END SUBROUTINE lim_prt_state
822
823#else
824   !!----------------------------------------------------------------------
825   !!   Default option           Dummy module      NO LIM 3.0 sea-ice model
826   !!----------------------------------------------------------------------
827CONTAINS
828   SUBROUTINE sbc_ice_lim ( kt, kblk )     ! Dummy routine
829      WRITE(*,*) 'sbc_ice_lim: You should not have seen this print! error?', kt, kblk
830   END SUBROUTINE sbc_ice_lim
831#endif
832
833   !!======================================================================
834END MODULE sbcice_lim
Note: See TracBrowser for help on using the repository browser.