New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in branches/2013/dev_MERGE_2013/NEMOGCM/NEMO/OFF_SRC – NEMO

source: branches/2013/dev_MERGE_2013/NEMOGCM/NEMO/OFF_SRC/nemogcm.F90 @ 4317

Last change on this file since 4317 was 4290, checked in by cetlod, 10 years ago

fix to lwp use for namelist reads

File size: 28.8 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Off-line Ocean   : passive tracer evolution, dynamics read in files
5   !!======================================================================
6   !! History :  3.3  ! 2010-05  (C. Ethe)  Full reorganization of the off-line: phasing with the on-line
7   !!            4.0  ! 2011-01  (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   nemo_gcm        : off-line: solve ocean tracer only
12   !!   nemo_init       : initialization of the nemo model
13   !!   nemo_ctl        : initialisation of algorithm flag
14   !!   nemo_closefile  : close remaining files
15   !!----------------------------------------------------------------------
16   USE dom_oce         ! ocean space domain variables
17   USE oce             ! dynamics and tracers variables
18   USE c1d             ! 1D configuration
19   USE domcfg          ! domain configuration               (dom_cfg routine)
20   USE domain          ! domain initialization             (dom_init routine)
21   USE istate          ! initial state setting          (istate_init routine)
22   USE eosbn2          ! equation of state            (eos bn2 routine)
23   !              ! ocean physics
24   USE ldftra          ! lateral diffusivity setting    (ldf_tra_init routine)
25   USE ldfslp          ! slopes of neutral surfaces     (ldf_slp_init routine)
26   USE traqsr          ! solar radiation penetration    (tra_qsr_init routine)
27   USE trabbl          ! bottom boundary layer          (tra_bbl_init routine)
28   USE zdfini          ! vertical physics: initialization
29   USE sbcmod          ! surface boundary condition       (sbc_init     routine)
30   USE phycst          ! physical constant                  (par_cst routine)
31   USE dtadyn          ! Lecture and Interpolation of the dynamical fields
32   USE trcini          ! Initilization of the passive tracers
33   USE daymod          ! calendar                         (day     routine)
34   USE trcstp          ! passive tracer time-stepping      (trc_stp routine)
35   USE dtadyn          ! Lecture and interpolation of the dynamical fields
36   USE stpctl          ! time stepping control            (stp_ctl routine)
37   !              ! I/O & MPP
38   USE iom             ! I/O library
39   USE in_out_manager  ! I/O manager
40   USE mppini          ! shared/distributed memory setting (mpp_init routine)
41   USE lib_mpp         ! distributed memory computing
42#if defined key_iomput
43   USE xios
44#endif
45   USE prtctl          ! Print control                    (prt_ctl_init routine)
46   USE timing          ! Timing
47   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
48   USE lbcnfd, ONLY: isendto, nsndto
49
50   USE trc
51   USE trcnam
52   USE trcrst
53
54   IMPLICIT NONE
55   PRIVATE
56   
57   PUBLIC   nemo_gcm   ! called by nemo.F90
58
59   CHARACTER (len=64) ::   cform_aaa="( /, 'AAAAAAAA', / ) "   ! flag for output listing
60
61   !!----------------------------------------------------------------------
62   !! NEMO/OFF 3.3 , NEMO Consortium (2010)
63   !! $Id: nemogcm.F90 2528 2010-12-27 17:33:53Z rblod $
64   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE nemo_gcm
69      !!----------------------------------------------------------------------
70      !!                     ***  ROUTINE nemo_gcm  ***
71      !!
72      !! ** Purpose :   nemo solves the primitive equations on an orthogonal
73      !!      curvilinear mesh on the sphere.
74      !!
75      !! ** Method  : - model general initialization
76      !!              - launch the time-stepping (dta_dyn and trc_stp)
77      !!              - finalize the run by closing files and communications
78      !!
79      !! References : Madec, Delecluse,Imbard, and Levy, 1997:  internal report, IPSL.
80      !!              Madec, 2008, internal report, IPSL.
81      !!----------------------------------------------------------------------
82      INTEGER :: istp, indic       ! time step index
83      !!----------------------------------------------------------------------
84
85      CALL nemo_init  ! Initializations
86
87      ! check that all process are still there... If some process have an error,
88      ! they will never enter in step and other processes will wait until the end of the cpu time!
89      IF( lk_mpp )   CALL mpp_max( nstop )
90
91      !                            !-----------------------!
92      !                            !==   time stepping   ==!
93      !                            !-----------------------!
94      istp = nit000
95      !
96      CALL iom_init( "nemo" )            ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
97      !
98      DO WHILE ( istp <= nitend .AND. nstop == 0 )    ! time stepping
99         !
100         IF( istp /= nit000 )   CALL day      ( istp )         ! Calendar (day was already called at nit000 in day_init)
101                                CALL iom_setkt( istp - nit000 + 1, "nemo" )   ! say to iom that we are at time step kstp
102                                CALL dta_dyn  ( istp )         ! Interpolation of the dynamical fields
103                                CALL trc_stp  ( istp )         ! time-stepping
104                                CALL stp_ctl  ( istp, indic )  ! Time loop: control and print
105         istp = istp + 1
106         IF( lk_mpp )   CALL mpp_max( nstop )
107      END DO
108#if defined key_iomput
109      CALL iom_context_finalize( "nemo" ) ! needed for XIOS+AGRIF
110#endif
111
112      !                            !------------------------!
113      !                            !==  finalize the run  ==!
114      !                            !------------------------!
115      IF(lwp) WRITE(numout,cform_aaa)                 ! Flag AAAAAAA
116
117      IF( nstop /= 0 .AND. lwp ) THEN                 ! error print
118         WRITE(numout,cform_err)
119         WRITE(numout,*) nstop, ' error have been found'
120      ENDIF
121      !
122      IF( nn_timing == 1 )   CALL timing_finalize
123      !
124      CALL nemo_closefile
125      !
126# if defined key_iomput
127      CALL xios_finalize             ! end mpp communications
128# else
129      IF( lk_mpp )   CALL mppstop       ! end mpp communications
130# endif
131      !
132   END SUBROUTINE nemo_gcm
133
134
135   SUBROUTINE nemo_init
136      !!----------------------------------------------------------------------
137      !!                     ***  ROUTINE nemo_init ***
138      !!
139      !! ** Purpose :   initialization of the nemo model in off-line mode
140      !!----------------------------------------------------------------------
141      INTEGER ::   ji            ! dummy loop indices
142      INTEGER ::   ilocal_comm   ! local integer
143      INTEGER ::   ios
144      CHARACTER(len=80), DIMENSION(16) ::   cltxt
145      !!
146      NAMELIST/namctl/ ln_ctl  , nn_print, nn_ictls, nn_ictle,   &
147         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
148         &             nn_bench, nn_timing
149      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
150         &             jpizoom, jpjzoom, jperio
151      !!----------------------------------------------------------------------
152      cltxt = ''
153      !
154      !                             ! Open reference namelist and configuration namelist files
155      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
156      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
157      CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. , 1 )
158      !
159      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
160      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
161901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
162
163      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
164      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
165902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
166      WRITE( numond, namctl )
167
168      !
169      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
170      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
171903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
172
173      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
174      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
175904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
176      WRITE( numond, namcfg )
177
178      !
179      !                             !--------------------------------------------!
180      !                             !  set communicator & select the local node  !
181      !                             !--------------------------------------------!
182#if defined key_iomput
183         CALL  xios_initialize( "nemo",return_comm=ilocal_comm )
184      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection
185#else
186      ilocal_comm = 0
187      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop )                ! Nodes selection (control print return in cltxt)
188#endif
189
190      narea = narea + 1                       ! mynode return the rank of proc (0 --> jpnij -1 )
191
192      lwp = (narea == 1) .OR. ln_ctl          ! control of all listing output print
193
194      ! If dimensions of processor grid weren't specified in the namelist file
195      ! then we calculate them here now that we have our communicator size
196      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
197#if   defined key_mpp_mpi
198         CALL nemo_partition(mppsize)
199#else
200         jpni = 1
201         jpnj = 1
202         jpnij = jpni*jpnj
203#endif
204      END IF
205
206      ! Calculate domain dimensions given calculated jpni and jpnj
207      ! This used to be done in par_oce.F90 when they were parameters rather
208      ! than variables
209      jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
210      jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
211      jpk = jpkdta                                             ! third dim
212      jpim1 = jpi-1                                            ! inner domain indices
213      jpjm1 = jpj-1                                            !   "           "
214      jpkm1 = jpk-1                                            !   "           "
215      jpij  = jpi*jpj                                          !  jpi x j
216
217
218      IF(lwp) THEN                            ! open listing units
219         !
220         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
221         !
222         WRITE(numout,*)
223         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
224         WRITE(numout,*) '                       NEMO team'
225         WRITE(numout,*) '            Ocean General Circulation Model'
226         WRITE(numout,*) '                  version 3.5  (2012) '
227         WRITE(numout,*)
228         WRITE(numout,*)
229         DO ji = 1, SIZE(cltxt) 
230            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
231         END DO
232         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
233         !
234      ENDIF
235
236      ! Now we know the dimensions of the grid and numout has been set we can
237      ! allocate arrays
238      CALL nemo_alloc()
239
240      !                             !--------------------------------!
241      !                             !  Model general initialization  !
242      !                             !--------------------------------!
243
244      CALL nemo_ctl                           ! Control prints & Benchmark
245
246      !                                      ! Domain decomposition
247      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
248      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
249      ENDIF
250      !
251      IF( nn_timing == 1 )  CALL timing_init
252      !
253
254      !                                      ! General initialization
255      IF( nn_timing == 1 )  CALL timing_start( 'nemo_init')
256      !
257                            CALL     phy_cst    ! Physical constants
258                            CALL     eos_init   ! Equation of state
259                            CALL     dom_cfg    ! Domain configuration
260                            CALL     dom_init   ! Domain
261                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
262
263      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
264
265      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
266
267      !                                     ! Ocean physics
268                            CALL     sbc_init   ! Forcings : surface module
269#if ! defined key_degrad
270                            CALL ldf_tra_init   ! Lateral ocean tracer physics
271#endif
272      IF( lk_ldfslp )       CALL ldf_slp_init   ! slope of lateral mixing
273
274      !                                     ! Active tracers
275                            CALL tra_qsr_init   ! penetrative solar radiation qsr
276      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
277
278                            CALL trc_nam_run  ! Needed to get restart parameters for passive tracers
279      IF( ln_rsttr ) THEN
280        neuler = 1   ! Set time-step indicator at nit000 (leap-frog)
281        CALL trc_rst_cal( nit000, 'READ' )   ! calendar
282      ELSE
283        neuler = 0                  ! Set time-step indicator at nit000 (euler)
284        CALL day_init               ! set calendar
285      ENDIF
286      !                                     ! Dynamics
287                            CALL dta_dyn_init   ! Initialization for the dynamics
288
289      !                                     ! Passive tracers
290                            CALL     trc_init   ! Passive tracers initialization
291
292      IF(lwp) WRITE(numout,cform_aaa)       ! Flag AAAAAAA
293      !
294      IF( nn_timing == 1 )  CALL timing_stop( 'nemo_init')
295      !
296   END SUBROUTINE nemo_init
297
298
299   SUBROUTINE nemo_ctl
300      !!----------------------------------------------------------------------
301      !!                     ***  ROUTINE nemo_ctl  ***
302      !!
303      !! ** Purpose :   control print setting
304      !!
305      !! ** Method  : - print namctl information and check some consistencies
306      !!----------------------------------------------------------------------
307      !
308      IF(lwp) THEN                  ! Parameter print
309         WRITE(numout,*)
310         WRITE(numout,*) 'nemo_flg: Control prints & Benchmark'
311         WRITE(numout,*) '~~~~~~~ '
312         WRITE(numout,*) '   Namelist namctl'
313         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
314         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
315         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
316         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
317         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
318         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
319         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
320         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
321         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
322      ENDIF
323      !
324      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
325      nictls    = nn_ictls
326      nictle    = nn_ictle
327      njctls    = nn_jctls
328      njctle    = nn_jctle
329      isplt     = nn_isplt
330      jsplt     = nn_jsplt
331      nbench    = nn_bench
332     IF(lwp) THEN                  ! control print
333         WRITE(numout,*)
334         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
335         WRITE(numout,*) '~~~~~~~ '
336         WRITE(numout,*) '   Namelist namcfg'
337         WRITE(numout,*) '      configuration name              cp_cfg      = ', TRIM(cp_cfg)
338         WRITE(numout,*) '      configuration resolution        jp_cfg      = ', jp_cfg
339         WRITE(numout,*) '      1st lateral dimension ( >= jpi ) jpidta     = ', jpidta
340         WRITE(numout,*) '      2nd    "         "    ( >= jpj ) jpjdta     = ', jpjdta
341         WRITE(numout,*) '      3nd    "         "               jpkdta     = ', jpkdta
342         WRITE(numout,*) '      1st dimension of global domain in i jpiglo  = ', jpiglo
343         WRITE(numout,*) '      2nd    -                  -    in j jpjglo  = ', jpjglo
344         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
345         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
346         WRITE(numout,*) '      lateral cond. type (between 0 and 6) jperio = ', jperio   
347      ENDIF
348      !                             ! Parameter control
349      !
350      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
351         IF( lk_mpp ) THEN
352            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real splitted domain
353         ELSE
354            IF( isplt == 1 .AND. jsplt == 1  ) THEN
355               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
356                  &           ' - the print control will be done over the whole domain' )
357            ENDIF
358            ijsplt = isplt * jsplt            ! total number of processors ijsplt
359         ENDIF
360         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
361         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
362         !
363         !                              ! indices used for the SUM control
364         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
365            lsp_area = .FALSE.
366         ELSE                                             ! print control done over a specific  area
367            lsp_area = .TRUE.
368            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
369               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
370               nictls = 1
371            ENDIF
372            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
373               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
374               nictle = jpiglo
375            ENDIF
376            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
377               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
378               njctls = 1
379            ENDIF
380            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
381               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
382               njctle = jpjglo
383            ENDIF
384         ENDIF
385      ENDIF
386      !
387      IF( nbench == 1 )   THEN            ! Benchmark
388         SELECT CASE ( cp_cfg )
389         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
390         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
391            &                                 ' cp_cfg="gyre" in namelsit &namcfg or set nbench = 0' )
392         END SELECT
393      ENDIF
394      !
395      IF( lk_c1d .AND. .NOT.lk_iomput )   CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ',   &
396         &                                               'with the IOM Input/Output manager. '        ,   &
397         &                                               'Compile with key_iomput enabled' )
398      !
399      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
400         &                                               'f2003 standard. '                              ,  &
401         &                                               'Compile with key_nosignedzero enabled' )
402      !
403   END SUBROUTINE nemo_ctl
404
405
406   SUBROUTINE nemo_closefile
407      !!----------------------------------------------------------------------
408      !!                     ***  ROUTINE nemo_closefile  ***
409      !!
410      !! ** Purpose :   Close the files
411      !!----------------------------------------------------------------------
412      !
413      IF ( lk_mpp ) CALL mppsync
414      !
415      CALL iom_close                                 ! close all input/output files managed by iom_*
416      !
417      IF( numstp     /= -1 )   CLOSE( numstp     )   ! time-step file
418      IF( numnam_ref /= -1 )   CLOSE( numnam_ref )   ! oce reference namelist
419      IF( numnam_cfg /= -1 )   CLOSE( numnam_cfg )   ! oce configuration namelist
420      IF( numout     /=  6 )   CLOSE( numout     )   ! standard model output file
421      numout = 6                                     ! redefine numout in case it is used after this point...
422      !
423   END SUBROUTINE nemo_closefile
424
425
426   SUBROUTINE nemo_alloc
427      !!----------------------------------------------------------------------
428      !!                     ***  ROUTINE nemo_alloc  ***
429      !!
430      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
431      !!
432      !! ** Method  :
433      !!----------------------------------------------------------------------
434      USE diawri,       ONLY: dia_wri_alloc
435      USE dom_oce,      ONLY: dom_oce_alloc
436      USE zdf_oce,      ONLY: zdf_oce_alloc
437      USE ldftra_oce,   ONLY: ldftra_oce_alloc
438      USE trc_oce,      ONLY: trc_oce_alloc
439      !
440      INTEGER :: ierr
441      !!----------------------------------------------------------------------
442      !
443      ierr =        oce_alloc       ()          ! ocean
444      ierr = ierr + dia_wri_alloc   ()
445      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
446      ierr = ierr + ldftra_oce_alloc()          ! ocean lateral  physics : tracers
447      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
448      !
449      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
450      !
451      IF( lk_mpp    )   CALL mpp_sum( ierr )
452      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
453      !
454   END SUBROUTINE nemo_alloc
455
456
457   SUBROUTINE nemo_partition( num_pes )
458      !!----------------------------------------------------------------------
459      !!                 ***  ROUTINE nemo_partition  ***
460      !!
461      !! ** Purpose :   
462      !!
463      !! ** Method  :
464      !!----------------------------------------------------------------------
465      INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
466      !
467      INTEGER, PARAMETER :: nfactmax = 20
468      INTEGER :: nfact ! The no. of factors returned
469      INTEGER :: ierr  ! Error flag
470      INTEGER :: ji
471      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
472      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
473      !!----------------------------------------------------------------------
474
475      ierr = 0
476
477      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
478
479      IF( nfact <= 1 ) THEN
480         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
481         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
482         jpnj = 1
483         jpni = num_pes
484      ELSE
485         ! Search through factors for the pair that are closest in value
486         mindiff = 1000000
487         imin    = 1
488         DO ji = 1, nfact-1, 2
489            idiff = ABS( ifact(ji) - ifact(ji+1) )
490            IF( idiff < mindiff ) THEN
491               mindiff = idiff
492               imin = ji
493            ENDIF
494         END DO
495         jpnj = ifact(imin)
496         jpni = ifact(imin + 1)
497      ENDIF
498      !
499      jpnij = jpni*jpnj
500      !
501   END SUBROUTINE nemo_partition
502
503
504   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
505      !!----------------------------------------------------------------------
506      !!                     ***  ROUTINE factorise  ***
507      !!
508      !! ** Purpose :   return the prime factors of n.
509      !!                knfax factors are returned in array kfax which is of
510      !!                maximum dimension kmaxfax.
511      !! ** Method  :
512      !!----------------------------------------------------------------------
513      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
514      INTEGER                    , INTENT(  out) ::   kerr, knfax
515      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
516      !
517      INTEGER :: ifac, jl, inu
518      INTEGER, PARAMETER :: ntest = 14
519      INTEGER :: ilfax(ntest)
520      !
521      ! lfax contains the set of allowed factors.
522      data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256,  &
523         &                            128,   64,   32,   16,    8,   4,   2  /
524      !!----------------------------------------------------------------------
525
526      ! Clear the error flag and initialise output vars
527      kerr = 0
528      kfax = 1
529      knfax = 0
530
531      ! Find the factors of n.
532      IF( kn == 1 )   GOTO 20
533
534      ! nu holds the unfactorised part of the number.
535      ! knfax holds the number of factors found.
536      ! l points to the allowed factor list.
537      ! ifac holds the current factor.
538
539      inu   = kn
540      knfax = 0
541
542      DO jl = ntest, 1, -1
543         !
544         ifac = ilfax(jl)
545         IF( ifac > inu )   CYCLE
546
547         ! Test whether the factor will divide.
548
549         IF( MOD(inu,ifac) == 0 ) THEN
550            !
551            knfax = knfax + 1            ! Add the factor to the list
552            IF( knfax > kmaxfax ) THEN
553               kerr = 6
554               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
555               return
556            ENDIF
557            kfax(knfax) = ifac
558            ! Store the other factor that goes with this one
559            knfax = knfax + 1
560            kfax(knfax) = inu / ifac
561            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
562         ENDIF
563         !
564      END DO
565
566   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
567      !
568   END SUBROUTINE factorise
569
570#if defined key_mpp_mpi
571   SUBROUTINE nemo_northcomms
572      !!======================================================================
573      !!                     ***  ROUTINE  nemo_northcomms  ***
574      !! nemo_northcomms    :  Setup for north fold exchanges with explicit
575      !!                       point-to-point messaging
576      !!=====================================================================
577      !!----------------------------------------------------------------------
578      !!
579      !! ** Purpose :   Initialization of the northern neighbours lists.
580      !!----------------------------------------------------------------------
581      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
582      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
583      !!----------------------------------------------------------------------
584
585      INTEGER  ::   sxM, dxM, sxT, dxT, jn
586      INTEGER  ::   njmppmax
587
588      njmppmax = MAXVAL( njmppt )
589
590      !initializes the north-fold communication variables
591      isendto(:) = 0
592      nsndto = 0
593
594      !if I am a process in the north
595      IF ( njmpp == njmppmax ) THEN
596          !sxM is the first point (in the global domain) needed to compute the
597          !north-fold for the current process
598          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
599          !dxM is the last point (in the global domain) needed to compute the
600          !north-fold for the current process
601          dxM = jpiglo - nimppt(narea) + 2
602
603          !loop over the other north-fold processes to find the processes
604          !managing the points belonging to the sxT-dxT range
605          DO jn = jpnij - jpni +1, jpnij
606             IF ( njmppt(jn) == njmppmax ) THEN
607                !sxT is the first point (in the global domain) of the jn
608                !process
609                sxT = nimppt(jn)
610                !dxT is the last point (in the global domain) of the jn
611                !process
612                dxT = nimppt(jn) + nlcit(jn) - 1
613                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
614                   nsndto = nsndto + 1
615                   isendto(nsndto) = jn
616                ELSEIF ((sxM .le. sxT) .AND. (dxM .gt. dxT)) THEN
617                   nsndto = nsndto + 1
618                   isendto(nsndto) = jn
619                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
620                   nsndto = nsndto + 1
621                   isendto(nsndto) = jn
622                END IF
623             END IF
624          END DO
625      ENDIF
626      l_north_nogather = .TRUE.
627
628   END SUBROUTINE nemo_northcomms
629#else
630   SUBROUTINE nemo_northcomms      ! Dummy routine
631      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
632   END SUBROUTINE nemo_northcomms
633#endif
634   !!======================================================================
635END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.