New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
bdytides.F90 in branches/2013/dev_MERGE_2013/NEMOGCM/NEMO/OPA_SRC/BDY – NEMO

source: branches/2013/dev_MERGE_2013/NEMOGCM/NEMO/OPA_SRC/BDY/bdytides.F90 @ 4317

Last change on this file since 4317 was 4292, checked in by cetlod, 10 years ago

dev_MERGE_2013 : 1st step of the merge, see ticket #1185
  • Property svn:keywords set to Id
File size: 29.0 KB
Line 
1MODULE bdytides
2   !!======================================================================
3   !!                       ***  MODULE  bdytides  ***
4   !! Ocean dynamics:   Tidal forcing at open boundaries
5   !!======================================================================
6   !! History :  2.0  !  2007-01  (D.Storkey)  Original code
7   !!            2.3  !  2008-01  (J.Holt)  Add date correction. Origins POLCOMS v6.3 2007
8   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
9   !!            3.3  !  2010-09  (D.Storkey and E.O'Dea)  bug fixes
10   !!            3.4  !  2012-09  (G. Reffray and J. Chanut) New inputs + mods
11   !!            3.5  !  2013-07  (J. Chanut) Compliant with time splitting changes
12   !!----------------------------------------------------------------------
13#if defined key_bdy
14   !!----------------------------------------------------------------------
15   !!   'key_bdy'     Open Boundary Condition
16   !!----------------------------------------------------------------------
17   !!   PUBLIC
18   !!      bdytide_init     : read of namelist and initialisation of tidal harmonics data
19   !!      tide_update   : calculation of tidal forcing at each timestep
20   !!----------------------------------------------------------------------
21   USE timing          ! Timing
22   USE oce             ! ocean dynamics and tracers
23   USE dom_oce         ! ocean space and time domain
24   USE iom
25   USE in_out_manager  ! I/O units
26   USE phycst          ! physical constants
27   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
28   USE bdy_par         ! Unstructured boundary parameters
29   USE bdy_oce         ! ocean open boundary conditions
30   USE daymod          ! calendar
31   USE wrk_nemo        ! Memory allocation
32   USE tideini
33!   USE tide_mod       ! Useless ??
34   USE fldread, ONLY: fld_map
35   USE dynspg_oce, ONLY: lk_dynspg_ts
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   bdytide_init     ! routine called in bdy_init
41   PUBLIC   bdytide_update   ! routine called in bdy_dta
42   PUBLIC   bdy_dta_tides    ! routine called in dyn_spg_ts
43
44   TYPE, PUBLIC ::   TIDES_DATA     !: Storage for external tidal harmonics data
45      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   ssh0       !: Tidal constituents : SSH0 (read in file)
46      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   u0         !: Tidal constituents : U0   (read in file)
47      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   v0         !: Tidal constituents : V0   (read in file)
48      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   ssh        !: Tidal constituents : SSH  (after nodal cor.)
49      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   u          !: Tidal constituents : U    (after nodal cor.)
50      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   v          !: Tidal constituents : V    (after nodal cor.)
51   END TYPE TIDES_DATA
52
53   TYPE(TIDES_DATA), PUBLIC, DIMENSION(jp_bdy), TARGET :: tides  !: External tidal harmonics data
54   TYPE(OBC_DATA)  , PRIVATE, DIMENSION(jp_bdy) :: dta_bdy_s  !: bdy external data (slow component)
55
56   !!----------------------------------------------------------------------
57   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
58   !! $Id$
59   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   SUBROUTINE bdytide_init
64      !!----------------------------------------------------------------------
65      !!                    ***  SUBROUTINE bdytide_init  ***
66      !!                     
67      !! ** Purpose : - Read in namelist for tides and initialise external
68      !!                tidal harmonics data
69      !!
70      !!----------------------------------------------------------------------
71      !! namelist variables
72      !!-------------------
73      CHARACTER(len=80)                         ::   filtide             !: Filename root for tidal input files
74      LOGICAL                                   ::   ln_bdytide_2ddta    !: If true, read 2d harmonic data
75      LOGICAL                                   ::   ln_bdytide_conj     !: If true, assume complex conjugate tidal data
76      !!
77      INTEGER                                   ::   ib_bdy, itide, ib   !: dummy loop indices
78      INTEGER                                   ::   ii, ij              !: dummy loop indices
79      INTEGER                                   ::   inum, igrd
80      INTEGER, DIMENSION(3)                     ::   ilen0       !: length of boundary data (from OBC arrays)
81      INTEGER, POINTER, DIMENSION(:)            ::   nblen, nblenrim     ! short cuts
82      INTEGER                                   ::   ios                 ! Local integer output status for namelist read
83      CHARACTER(len=80)                         ::   clfile              !: full file name for tidal input file
84      REAL(wp),ALLOCATABLE, DIMENSION(:,:,:)    ::   dta_read            !: work space to read in tidal harmonics data
85      REAL(wp), POINTER, DIMENSION(:,:)         ::   ztr, zti            !:  "     "    "   "   "   "        "      "
86      !!
87      TYPE(TIDES_DATA),  POINTER                ::   td                  !: local short cut   
88      !!
89      NAMELIST/nambdy_tide/filtide, ln_bdytide_2ddta, ln_bdytide_conj
90      !!----------------------------------------------------------------------
91
92      IF( nn_timing == 1 ) CALL timing_start('bdytide_init')
93
94      IF (nb_bdy>0) THEN
95         IF(lwp) WRITE(numout,*)
96         IF(lwp) WRITE(numout,*) 'bdytide_init : initialization of tidal harmonic forcing at open boundaries'
97         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
98      ENDIF
99
100      REWIND(numnam_cfg)
101
102      DO ib_bdy = 1, nb_bdy
103         IF( nn_dyn2d_dta(ib_bdy) .ge. 2 ) THEN
104
105            td => tides(ib_bdy)
106            nblen => idx_bdy(ib_bdy)%nblen
107            nblenrim => idx_bdy(ib_bdy)%nblenrim
108
109            ! Namelist nambdy_tide : tidal harmonic forcing at open boundaries
110            filtide(:) = ''
111
112            ! Don't REWIND here - may need to read more than one of these namelists.
113            READ  ( numnam_ref, nambdy_tide, IOSTAT = ios, ERR = 901)
114901         IF( ios /= 0 ) CALL ctl_nam ( ios , 'nambdy_tide in reference namelist', lwp )
115            READ  ( numnam_cfg, nambdy_tide, IOSTAT = ios, ERR = 902 )
116902         IF( ios /= 0 ) CALL ctl_nam ( ios , 'nambdy_tide in configuration namelist', lwp )
117            WRITE ( numond, nambdy_tide )
118            !                                               ! Parameter control and print
119            IF(lwp) WRITE(numout,*) '  '
120            IF(lwp) WRITE(numout,*) '          Namelist nambdy_tide : tidal harmonic forcing at open boundaries'
121            IF(lwp) WRITE(numout,*) '             read tidal data in 2d files: ', ln_bdytide_2ddta
122            IF(lwp) WRITE(numout,*) '             assume complex conjugate   : ', ln_bdytide_conj
123            IF(lwp) WRITE(numout,*) '             Number of tidal components to read: ', nb_harmo
124            IF(lwp) THEN
125                    WRITE(numout,*) '             Tidal cpt name    -     Phase speed (deg/hr)'           
126               DO itide = 1, nb_harmo
127                  WRITE(numout,*)  '             ', Wave(ntide(itide))%cname_tide, omega_tide(itide)   
128               END DO
129            ENDIF
130            IF(lwp) WRITE(numout,*) ' '
131
132            ! Allocate space for tidal harmonics data - get size from OBC data arrays
133            ! -----------------------------------------------------------------------
134
135            ! JC: If FRS scheme is used, we assume that tidal is needed over the whole
136            ! relaxation area     
137            IF( cn_dyn2d(ib_bdy) == 'frs' ) THEN
138               ilen0(:)=nblen(:)
139            ELSE
140               ilen0(:)=nblenrim(:)
141            ENDIF
142
143            ALLOCATE( td%ssh0( ilen0(1), nb_harmo, 2 ) )
144            ALLOCATE( td%ssh ( ilen0(1), nb_harmo, 2 ) )
145
146            ALLOCATE( td%u0( ilen0(2), nb_harmo, 2 ) )
147            ALLOCATE( td%u ( ilen0(2), nb_harmo, 2 ) )
148
149            ALLOCATE( td%v0( ilen0(3), nb_harmo, 2 ) )
150            ALLOCATE( td%v ( ilen0(3), nb_harmo, 2 ) )
151
152            td%ssh0(:,:,:) = 0._wp
153            td%ssh (:,:,:) = 0._wp
154            td%u0  (:,:,:) = 0._wp
155            td%u   (:,:,:) = 0._wp
156            td%v0  (:,:,:) = 0._wp
157            td%v   (:,:,:) = 0._wp
158
159            IF (ln_bdytide_2ddta) THEN
160               ! It is assumed that each data file contains all complex harmonic amplitudes
161               ! given on the data domain (ie global, jpidta x jpjdta)
162               !
163               CALL wrk_alloc( jpi, jpj, zti, ztr )
164               !
165               ! SSH fields
166               clfile = TRIM(filtide)//'_grid_T.nc'
167               CALL iom_open (clfile , inum ) 
168               igrd = 1                       ! Everything is at T-points here
169               DO itide = 1, nb_harmo
170                  CALL iom_get  ( inum, jpdom_data, TRIM(Wave(ntide(itide))%cname_tide)//'_z1', ztr(:,:) )
171                  CALL iom_get  ( inum, jpdom_data, TRIM(Wave(ntide(itide))%cname_tide)//'_z2', zti(:,:) ) 
172                  DO ib = 1, ilen0(igrd)
173                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
174                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
175                     td%ssh0(ib,itide,1) = ztr(ii,ij)
176                     td%ssh0(ib,itide,2) = zti(ii,ij)
177                  END DO
178               END DO
179               CALL iom_close( inum )
180               !
181               ! U fields
182               clfile = TRIM(filtide)//'_grid_U.nc'
183               CALL iom_open (clfile , inum ) 
184               igrd = 2                       ! Everything is at U-points here
185               DO itide = 1, nb_harmo
186                  CALL iom_get  ( inum, jpdom_data, TRIM(Wave(ntide(itide))%cname_tide)//'_u1', ztr(:,:) )
187                  CALL iom_get  ( inum, jpdom_data, TRIM(Wave(ntide(itide))%cname_tide)//'_u2', zti(:,:) )
188                  DO ib = 1, ilen0(igrd)
189                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
190                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
191                     td%u0(ib,itide,1) = ztr(ii,ij)
192                     td%u0(ib,itide,2) = zti(ii,ij)
193                  END DO
194               END DO
195               CALL iom_close( inum )
196               !
197               ! V fields
198               clfile = TRIM(filtide)//'_grid_V.nc'
199               CALL iom_open (clfile , inum ) 
200               igrd = 3                       ! Everything is at V-points here
201               DO itide = 1, nb_harmo
202                  CALL iom_get  ( inum, jpdom_data, TRIM(Wave(ntide(itide))%cname_tide)//'_v1', ztr(:,:) )
203                  CALL iom_get  ( inum, jpdom_data, TRIM(Wave(ntide(itide))%cname_tide)//'_v2', zti(:,:) )
204                  DO ib = 1, ilen0(igrd)
205                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
206                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
207                     td%v0(ib,itide,1) = ztr(ii,ij)
208                     td%v0(ib,itide,2) = zti(ii,ij)
209                  END DO
210               END DO 
211               CALL iom_close( inum )
212               !
213               CALL wrk_dealloc( jpi, jpj, ztr, zti ) 
214               !
215            ELSE           
216               !
217               ! Read tidal data only on bdy segments
218               !
219               ALLOCATE( dta_read( MAXVAL(ilen0(1:3)), 1, 1 ) )
220
221               ! Open files and read in tidal forcing data
222               ! -----------------------------------------
223
224               DO itide = 1, nb_harmo
225                  !                                                              ! SSH fields
226                  clfile = TRIM(filtide)//TRIM(Wave(ntide(itide))%cname_tide)//'_grid_T.nc'
227                  CALL iom_open( clfile, inum )
228                  CALL fld_map( inum, 'z1' , dta_read(1:ilen0(1),1:1,1:1) , 1, idx_bdy(ib_bdy)%nbmap(:,1) )
229                  td%ssh0(:,itide,1) = dta_read(1:ilen0(1),1,1)
230                  CALL fld_map( inum, 'z2' , dta_read(1:ilen0(1),1:1,1:1) , 1, idx_bdy(ib_bdy)%nbmap(:,1) )
231                  td%ssh0(:,itide,2) = dta_read(1:ilen0(1),1,1)
232                  CALL iom_close( inum )
233                  !                                                              ! U fields
234                  clfile = TRIM(filtide)//TRIM(Wave(ntide(itide))%cname_tide)//'_grid_U.nc'
235                  CALL iom_open( clfile, inum )
236                  CALL fld_map( inum, 'u1' , dta_read(1:ilen0(2),1:1,1:1) , 1, idx_bdy(ib_bdy)%nbmap(:,2) )
237                  td%u0(:,itide,1) = dta_read(1:ilen0(2),1,1)
238                  CALL fld_map( inum, 'u2' , dta_read(1:ilen0(2),1:1,1:1) , 1, idx_bdy(ib_bdy)%nbmap(:,2) )
239                  td%u0(:,itide,2) = dta_read(1:ilen0(2),1,1)
240                  CALL iom_close( inum )
241                  !                                                              ! V fields
242                  clfile = TRIM(filtide)//TRIM(Wave(ntide(itide))%cname_tide)//'_grid_V.nc'
243                  CALL iom_open( clfile, inum )
244                  CALL fld_map( inum, 'v1' , dta_read(1:ilen0(3),1:1,1:1) , 1, idx_bdy(ib_bdy)%nbmap(:,3) )
245                  td%v0(:,itide,1) = dta_read(1:ilen0(3),1,1)
246                  CALL fld_map( inum, 'v2' , dta_read(1:ilen0(3),1:1,1:1) , 1, idx_bdy(ib_bdy)%nbmap(:,3) )
247                  td%v0(:,itide,2) = dta_read(1:ilen0(3),1,1)
248                  CALL iom_close( inum )
249                  !
250               END DO ! end loop on tidal components
251               !
252               DEALLOCATE( dta_read )
253            ENDIF ! ln_bdytide_2ddta=.true.
254            !
255            IF ( ln_bdytide_conj ) THEN ! assume complex conjugate in data files
256               td%ssh0(:,:,2) = - td%ssh0(:,:,2)
257               td%u0  (:,:,2) = - td%u0  (:,:,2)
258               td%v0  (:,:,2) = - td%v0  (:,:,2)
259            ENDIF
260            !
261            IF ( lk_dynspg_ts ) THEN ! Allocate arrays to save slowly varying boundary data during
262                                     ! time splitting integration
263               ALLOCATE( dta_bdy_s(ib_bdy)%ssh ( ilen0(1) ) )
264               ALLOCATE( dta_bdy_s(ib_bdy)%u2d ( ilen0(2) ) )
265               ALLOCATE( dta_bdy_s(ib_bdy)%v2d ( ilen0(3) ) )
266               dta_bdy_s(ib_bdy)%ssh(:) = 0.e0
267               dta_bdy_s(ib_bdy)%u2d(:) = 0.e0
268               dta_bdy_s(ib_bdy)%v2d(:) = 0.e0
269            ENDIF
270            !
271         ENDIF ! nn_dyn2d_dta(ib_bdy) .ge. 2
272         !
273      END DO ! loop on ib_bdy
274
275      IF( nn_timing == 1 ) CALL timing_stop('bdytide_init')
276
277   END SUBROUTINE bdytide_init
278
279   SUBROUTINE bdytide_update ( kt, idx, dta, td, jit, time_offset )
280      !!----------------------------------------------------------------------
281      !!                 ***  SUBROUTINE bdytide_update  ***
282      !!               
283      !! ** Purpose : - Add tidal forcing to ssh, u2d and v2d OBC data arrays.
284      !!               
285      !!----------------------------------------------------------------------
286      INTEGER, INTENT( in )            ::   kt          ! Main timestep counter
287      TYPE(OBC_INDEX), INTENT( in )    ::   idx         ! OBC indices
288      TYPE(OBC_DATA),  INTENT(inout)   ::   dta         ! OBC external data
289      TYPE(TIDES_DATA),INTENT( inout ) ::   td          ! tidal harmonics data
290      INTEGER,INTENT(in),OPTIONAL      ::   jit         ! Barotropic timestep counter (for timesplitting option)
291      INTEGER,INTENT( in ), OPTIONAL   ::   time_offset ! time offset in units of timesteps. NB. if jit
292                                                        ! is present then units = subcycle timesteps.
293                                                        ! time_offset = 0  => get data at "now"    time level
294                                                        ! time_offset = -1 => get data at "before" time level
295                                                        ! time_offset = +1 => get data at "after"  time level
296                                                        ! etc.
297      !!
298      INTEGER, DIMENSION(3)            ::   ilen0       !: length of boundary data (from OBC arrays)
299      INTEGER                          :: itide, igrd, ib   ! dummy loop indices
300      INTEGER                          :: time_add          ! time offset in units of timesteps
301      REAL(wp)                         :: z_arg, z_sarg, zflag, zramp     
302      REAL(wp), DIMENSION(jpmax_harmo) :: z_sist, z_cost
303      !!----------------------------------------------------------------------
304
305      IF( nn_timing == 1 ) CALL timing_start('bdytide_update')
306
307      ilen0(1) =  SIZE(td%ssh(:,1,1))
308      ilen0(2) =  SIZE(td%u(:,1,1))
309      ilen0(3) =  SIZE(td%v(:,1,1))
310
311      zflag=1
312      IF ( PRESENT(jit) ) THEN
313        IF ( jit /= 1 ) zflag=0
314      ENDIF
315
316      IF ( nsec_day == NINT(0.5_wp * rdttra(1)) .AND. zflag==1 ) THEN
317        !
318        kt_tide = kt
319        !
320        IF(lwp) THEN
321           WRITE(numout,*)
322           WRITE(numout,*) 'bdytide_update : (re)Initialization of the tidal bdy forcing at kt=',kt
323           WRITE(numout,*) '~~~~~~~~~~~~~~ '
324        ENDIF
325        !
326        CALL tide_init_elevation ( idx, td )
327        CALL tide_init_velocities( idx, td )
328        !
329      ENDIF
330
331      time_add = 0
332      IF( PRESENT(time_offset) ) THEN
333         time_add = time_offset
334      ENDIF
335         
336      IF( PRESENT(jit) ) THEN 
337         z_arg = ((kt-kt_tide) * rdt + (jit+0.5_wp*(time_add-1)) * rdt / REAL(nn_baro,wp) )
338      ELSE                             
339         z_arg = ((kt-kt_tide)+time_add) * rdt
340      ENDIF
341
342      ! Linear ramp on tidal component at open boundaries
343      zramp = 1._wp
344      IF (ln_tide_ramp) zramp = MIN(MAX( (z_arg + (kt_tide-nit000)*rdt)/(rdttideramp*rday),0._wp),1._wp)
345
346      DO itide = 1, nb_harmo
347         z_sarg = z_arg * omega_tide(itide)
348         z_cost(itide) = COS( z_sarg )
349         z_sist(itide) = SIN( z_sarg )
350      END DO
351
352      DO itide = 1, nb_harmo
353         igrd=1                              ! SSH on tracer grid
354         DO ib = 1, ilen0(igrd)
355            dta%ssh(ib) = dta%ssh(ib) + zramp*(td%ssh(ib,itide,1)*z_cost(itide) + td%ssh(ib,itide,2)*z_sist(itide))
356         END DO
357         igrd=2                              ! U grid
358         DO ib = 1, ilen0(igrd)
359            dta%u2d(ib) = dta%u2d(ib) + zramp*(td%u  (ib,itide,1)*z_cost(itide) + td%u  (ib,itide,2)*z_sist(itide))
360         END DO
361         igrd=3                              ! V grid
362         DO ib = 1, ilen0(igrd) 
363            dta%v2d(ib) = dta%v2d(ib) + zramp*(td%v  (ib,itide,1)*z_cost(itide) + td%v  (ib,itide,2)*z_sist(itide))
364         END DO
365      END DO
366      !
367      IF( nn_timing == 1 ) CALL timing_stop('bdytide_update')
368      !
369   END SUBROUTINE bdytide_update
370
371   SUBROUTINE bdy_dta_tides( kt, kit, time_offset )
372      !!----------------------------------------------------------------------
373      !!                 ***  SUBROUTINE bdy_dta_tides  ***
374      !!               
375      !! ** Purpose : - Add tidal forcing to ssh, u2d and v2d OBC data arrays.
376      !!               
377      !!----------------------------------------------------------------------
378      INTEGER, INTENT( in )            ::   kt          ! Main timestep counter
379      INTEGER, INTENT( in ),OPTIONAL   ::   kit         ! Barotropic timestep counter (for timesplitting option)
380      INTEGER, INTENT( in ),OPTIONAL   ::   time_offset ! time offset in units of timesteps. NB. if kit
381                                                        ! is present then units = subcycle timesteps.
382                                                        ! time_offset = 0  => get data at "now"    time level
383                                                        ! time_offset = -1 => get data at "before" time level
384                                                        ! time_offset = +1 => get data at "after"  time level
385                                                        ! etc.
386      !!
387      LOGICAL  :: lk_first_btstp  ! =.TRUE. if time splitting and first barotropic step
388      INTEGER,          DIMENSION(jpbgrd) :: ilen0 
389      INTEGER, DIMENSION(1:jpbgrd) :: nblen, nblenrim  ! short cuts
390      INTEGER  :: itide, ib_bdy, ib, igrd                     ! loop indices
391      INTEGER  :: time_add                                    ! time offset in units of timesteps
392      REAL(wp) :: z_arg, z_sarg, zramp, zoff, z_cost, z_sist     
393      !!----------------------------------------------------------------------
394
395      IF( nn_timing == 1 ) CALL timing_start('bdy_dta_tides')
396
397      lk_first_btstp=.TRUE.
398      IF ( PRESENT(kit).AND.( kit /= 1 ) ) THEN ; lk_first_btstp=.FALSE. ; ENDIF
399
400      time_add = 0
401      IF( PRESENT(time_offset) ) THEN
402         time_add = time_offset
403      ENDIF
404     
405      ! Absolute time from model initialization:   
406      IF( PRESENT(kit) ) THEN 
407         z_arg = ( kt + (kit+0.5_wp*(time_add-1)) / REAL(nn_baro,wp) ) * rdt
408      ELSE                             
409         z_arg = ( kt + time_add ) * rdt
410      ENDIF
411
412      ! Linear ramp on tidal component at open boundaries
413      zramp = 1.
414      IF (ln_tide_ramp) zramp = MIN(MAX( (z_arg - nit000*rdt)/(rdttideramp*rday),0.),1.)
415
416      DO ib_bdy = 1,nb_bdy
417
418         ! line below should be simplified (runoff case)
419!! CHANUT: TO BE SORTED OUT
420!!         IF (( nn_dyn2d_dta(ib_bdy) .ge. 2 ).AND.(nn_tra(ib_bdy).NE.4)) THEN
421         IF ( nn_dyn2d_dta(ib_bdy) .ge. 2 ) THEN
422
423            nblen(1:jpbgrd) = idx_bdy(ib_bdy)%nblen(1:jpbgrd)
424            nblenrim(1:jpbgrd) = idx_bdy(ib_bdy)%nblenrim(1:jpbgrd)
425
426            IF( cn_dyn2d(ib_bdy) == 'frs' ) THEN
427               ilen0(:)=nblen(:)
428            ELSE
429               ilen0(:)=nblenrim(:)
430            ENDIF     
431
432            ! We refresh nodal factors every day below
433            ! This should be done somewhere else
434            IF ( nsec_day == NINT(0.5_wp * rdttra(1)) .AND. lk_first_btstp ) THEN
435               !
436               kt_tide = kt               
437               !
438               IF(lwp) THEN
439               WRITE(numout,*)
440               WRITE(numout,*) 'bdy_tide_dta : Refresh nodal factors for tidal open bdy data at kt=',kt
441               WRITE(numout,*) '~~~~~~~~~~~~~~ '
442               ENDIF
443               !
444               CALL tide_init_elevation ( idx=idx_bdy(ib_bdy), td=tides(ib_bdy) )
445               CALL tide_init_velocities( idx=idx_bdy(ib_bdy), td=tides(ib_bdy) )
446               !
447            ENDIF
448            zoff = -kt_tide * rdt ! time offset relative to nodal factor computation time
449            !
450            ! If time splitting, save data at first barotropic iteration
451            IF ( PRESENT(kit) ) THEN
452               IF ( lk_first_btstp ) THEN ! Save slow varying open boundary data:
453                  dta_bdy_s(ib_bdy)%ssh(1:ilen0(1)) = dta_bdy(ib_bdy)%ssh(1:ilen0(1))
454                  dta_bdy_s(ib_bdy)%u2d(1:ilen0(2)) = dta_bdy(ib_bdy)%u2d(1:ilen0(2))
455                  dta_bdy_s(ib_bdy)%v2d(1:ilen0(3)) = dta_bdy(ib_bdy)%v2d(1:ilen0(3))
456
457               ELSE ! Initialize arrays from slow varying open boundary data:           
458                  dta_bdy(ib_bdy)%ssh(1:ilen0(1)) = dta_bdy_s(ib_bdy)%ssh(1:ilen0(1))
459                  dta_bdy(ib_bdy)%u2d(1:ilen0(2)) = dta_bdy_s(ib_bdy)%u2d(1:ilen0(2))
460                  dta_bdy(ib_bdy)%v2d(1:ilen0(3)) = dta_bdy_s(ib_bdy)%v2d(1:ilen0(3))
461               ENDIF
462            ENDIF
463            !
464            ! Update open boundary data arrays:
465            DO itide = 1, nb_harmo
466               !
467               z_sarg = (z_arg + zoff) * omega_tide(itide)
468               z_cost = zramp * COS( z_sarg )
469               z_sist = zramp * SIN( z_sarg )
470               !
471               igrd=1                              ! SSH on tracer grid
472               DO ib = 1, ilen0(igrd)
473                  dta_bdy(ib_bdy)%ssh(ib) = dta_bdy(ib_bdy)%ssh(ib) + &
474                     &                      ( tides(ib_bdy)%ssh(ib,itide,1)*z_cost + &
475                     &                        tides(ib_bdy)%ssh(ib,itide,2)*z_sist )
476               END DO
477               !
478               igrd=2                              ! U grid
479               DO ib = 1, ilen0(igrd)
480                  dta_bdy(ib_bdy)%u2d(ib) = dta_bdy(ib_bdy)%u2d(ib) + &
481                     &                      ( tides(ib_bdy)%u(ib,itide,1)*z_cost + &
482                     &                        tides(ib_bdy)%u(ib,itide,2)*z_sist )
483               END DO
484               !
485               igrd=3                              ! V grid
486               DO ib = 1, ilen0(igrd) 
487                  dta_bdy(ib_bdy)%v2d(ib) = dta_bdy(ib_bdy)%v2d(ib) + &
488                     &                      ( tides(ib_bdy)%v(ib,itide,1)*z_cost + &
489                     &                        tides(ib_bdy)%v(ib,itide,2)*z_sist )
490               END DO
491            END DO
492         END IF
493      END DO
494      !
495      IF( nn_timing == 1 ) CALL timing_stop('bdy_dta_tides')
496      !
497   END SUBROUTINE bdy_dta_tides
498
499   SUBROUTINE tide_init_elevation( idx, td )
500      !!----------------------------------------------------------------------
501      !!                 ***  ROUTINE tide_init_elevation  ***
502      !!----------------------------------------------------------------------
503      TYPE(OBC_INDEX), INTENT( in )      ::   idx     ! OBC indices
504      TYPE(TIDES_DATA),INTENT( inout )   ::   td      ! tidal harmonics data
505      !! * Local declarations
506      INTEGER, DIMENSION(1)            ::   ilen0       !: length of boundary data (from OBC arrays)
507      REAL(wp),ALLOCATABLE, DIMENSION(:) ::   mod_tide, phi_tide
508      INTEGER                            ::   itide, igrd, ib      ! dummy loop indices
509
510      igrd=1   
511                              ! SSH on tracer grid.
512   
513      ilen0(1) =  SIZE(td%ssh0(:,1,1))
514
515      ALLOCATE(mod_tide(ilen0(igrd)),phi_tide(ilen0(igrd)))
516
517      DO itide = 1, nb_harmo
518         DO ib = 1, ilen0(igrd)
519            mod_tide(ib)=SQRT(td%ssh0(ib,itide,1)**2.+td%ssh0(ib,itide,2)**2.)
520            phi_tide(ib)=ATAN2(-td%ssh0(ib,itide,2),td%ssh0(ib,itide,1))
521         END DO
522         DO ib = 1 , ilen0(igrd)
523            mod_tide(ib)=mod_tide(ib)*ftide(itide)
524            phi_tide(ib)=phi_tide(ib)+v0tide(itide)+utide(itide)
525         ENDDO
526         DO ib = 1 , ilen0(igrd)
527            td%ssh(ib,itide,1)= mod_tide(ib)*COS(phi_tide(ib))
528            td%ssh(ib,itide,2)=-mod_tide(ib)*SIN(phi_tide(ib))
529         ENDDO
530      END DO
531
532      DEALLOCATE(mod_tide,phi_tide)
533
534   END SUBROUTINE tide_init_elevation
535
536   SUBROUTINE tide_init_velocities( idx, td )
537      !!----------------------------------------------------------------------
538      !!                 ***  ROUTINE tide_init_elevation  ***
539      !!----------------------------------------------------------------------
540      TYPE(OBC_INDEX), INTENT( in )      ::   idx     ! OBC indices
541      TYPE(TIDES_DATA),INTENT( inout )      ::   td      ! tidal harmonics data
542      !! * Local declarations
543      INTEGER, DIMENSION(3)            ::   ilen0       !: length of boundary data (from OBC arrays)
544      REAL(wp),ALLOCATABLE, DIMENSION(:) ::   mod_tide, phi_tide
545      INTEGER                            ::   itide, igrd, ib      ! dummy loop indices
546
547      ilen0(2) =  SIZE(td%u0(:,1,1))
548      ilen0(3) =  SIZE(td%v0(:,1,1))
549
550      igrd=2                                 ! U grid.
551
552      ALLOCATE(mod_tide(ilen0(igrd)),phi_tide(ilen0(igrd)))
553
554      DO itide = 1, nb_harmo
555         DO ib = 1, ilen0(igrd)
556            mod_tide(ib)=SQRT(td%u0(ib,itide,1)**2.+td%u0(ib,itide,2)**2.)
557            phi_tide(ib)=ATAN2(-td%u0(ib,itide,2),td%u0(ib,itide,1))
558         END DO
559         DO ib = 1, ilen0(igrd)
560            mod_tide(ib)=mod_tide(ib)*ftide(itide)
561            phi_tide(ib)=phi_tide(ib)+v0tide(itide)+utide(itide)
562         ENDDO
563         DO ib = 1, ilen0(igrd)
564            td%u(ib,itide,1)= mod_tide(ib)*COS(phi_tide(ib))
565            td%u(ib,itide,2)=-mod_tide(ib)*SIN(phi_tide(ib))
566         ENDDO
567      END DO
568
569      DEALLOCATE(mod_tide,phi_tide)
570
571      igrd=3                                 ! V grid.
572
573      ALLOCATE(mod_tide(ilen0(igrd)),phi_tide(ilen0(igrd)))
574
575      DO itide = 1, nb_harmo
576         DO ib = 1, ilen0(igrd)
577            mod_tide(ib)=SQRT(td%v0(ib,itide,1)**2.+td%v0(ib,itide,2)**2.)
578            phi_tide(ib)=ATAN2(-td%v0(ib,itide,2),td%v0(ib,itide,1))
579         END DO
580         DO ib = 1, ilen0(igrd)
581            mod_tide(ib)=mod_tide(ib)*ftide(itide)
582            phi_tide(ib)=phi_tide(ib)+v0tide(itide)+utide(itide)
583         ENDDO
584         DO ib = 1, ilen0(igrd)
585            td%v(ib,itide,1)= mod_tide(ib)*COS(phi_tide(ib))
586            td%v(ib,itide,2)=-mod_tide(ib)*SIN(phi_tide(ib))
587         ENDDO
588      END DO
589
590      DEALLOCATE(mod_tide,phi_tide)
591
592  END SUBROUTINE tide_init_velocities
593#else
594   !!----------------------------------------------------------------------
595   !!   Dummy module         NO Unstruct Open Boundary Conditions for tides
596   !!----------------------------------------------------------------------
597CONTAINS
598   SUBROUTINE bdytide_init             ! Empty routine
599      WRITE(*,*) 'bdytide_init: You should not have seen this print! error?'
600   END SUBROUTINE bdytide_init
601   SUBROUTINE bdytide_update( kt, jit )   ! Empty routine
602      WRITE(*,*) 'bdytide_update: You should not have seen this print! error?', kt, jit
603   END SUBROUTINE bdytide_update
604   SUBROUTINE bdy_dta_tides( kt, kit, time_offset )     ! Empty routine
605      INTEGER, INTENT( in )            ::   kt          ! Dummy argument empty routine     
606      INTEGER, INTENT( in ),OPTIONAL   ::   kit         ! Dummy argument empty routine
607      INTEGER, INTENT( in ),OPTIONAL   ::   time_offset ! Dummy argument empty routine
608      WRITE(*,*) 'bdy_dta_tides: You should not have seen this print! error?', kt, jit
609   END SUBROUTINE bdy_dta_tides
610#endif
611
612   !!======================================================================
613END MODULE bdytides
614
Note: See TracBrowser for help on using the repository browser.