source: branches/2013/dev_MERGE_2013/NEMOGCM/NEMO/OPA_SRC/LBC/mppini.F90 @ 4291

Last change on this file since 4291 was 3294, checked in by rblod, 9 years ago

Merge of 3.4beta into the trunk

  • Property svn:keywords set to Id
File size: 17.7 KB
Line 
1MODULE mppini
2   !!==============================================================================
3   !!                       ***  MODULE mppini   ***
4   !! Ocean initialization : distributed memory computing initialization
5   !!==============================================================================
6
7   !!----------------------------------------------------------------------
8   !!   mpp_init       : Lay out the global domain over processors
9   !!   mpp_init2      : Lay out the global domain over processors
10   !!                    with land processor elimination
11   !!   mpp_init_ioispl: IOIPSL initialization in mpp
12   !!----------------------------------------------------------------------
13   !! * Modules used
14   USE dom_oce         ! ocean space and time domain
15   USE in_out_manager  ! I/O Manager
16   USE lib_mpp         ! distribued memory computing library
17   USE ioipsl
18
19   IMPLICIT NONE
20   PRIVATE
21
22   PUBLIC mpp_init       ! called by opa.F90
23   PUBLIC mpp_init2      ! called by opa.F90
24
25   !! * Substitutions
26#  include "domzgr_substitute.h90"
27   !!----------------------------------------------------------------------
28   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
29   !! $Id$
30   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
31   !!----------------------------------------------------------------------
32CONTAINS
33
34#if ! defined key_mpp_mpi
35   !!----------------------------------------------------------------------
36   !!   Default option :                            shared memory computing
37   !!----------------------------------------------------------------------
38
39   SUBROUTINE mpp_init
40      !!----------------------------------------------------------------------
41      !!                  ***  ROUTINE mpp_init  ***
42      !!
43      !! ** Purpose :   Lay out the global domain over processors.
44      !!
45      !! ** Method  :   Shared memory computing, set the local processor
46      !!      variables to the value of the global domain
47      !!
48      !! History :
49      !!   9.0  !  04-01  (G. Madec, J.M. Molines)  F90 : free form, north fold jpni >1
50      !!----------------------------------------------------------------------
51
52      ! No mpp computation
53      nimpp  = 1
54      njmpp  = 1
55      nlci   = jpi
56      nlcj   = jpj
57      nldi   = 1
58      nldj   = 1
59      nlei   = jpi
60      nlej   = jpj
61      nperio = jperio
62      nbondi = 2
63      nbondj = 2
64      nidom  = FLIO_DOM_NONE
65      npolj = jperio
66
67      IF(lwp) THEN
68         WRITE(numout,*)
69         WRITE(numout,*) 'mpp_init(2) : NO massively parallel processing'
70         WRITE(numout,*) '~~~~~~~~~~~: '
71         WRITE(numout,*) '         nperio = ', nperio
72         WRITE(numout,*) '         npolj  = ', npolj
73         WRITE(numout,*) '         nimpp  = ', nimpp
74         WRITE(numout,*) '         njmpp  = ', njmpp
75      ENDIF
76
77      IF(  jpni /= 1 .OR. jpnj /= 1 .OR. jpnij /= 1 ) &
78          CALL ctl_stop( 'equality  jpni = jpnj = jpnij = 1 is not satisfied',   &
79          &              'the domain is lay out for distributed memory computing! ' )
80
81   END SUBROUTINE mpp_init
82
83
84   SUBROUTINE mpp_init2 
85      CALL mpp_init                             ! same routine as mpp_init
86   END SUBROUTINE mpp_init2
87
88#else
89   !!----------------------------------------------------------------------
90   !!   'key_mpp_mpi'          OR         MPI massively parallel processing
91   !!----------------------------------------------------------------------
92
93   SUBROUTINE mpp_init
94      !!----------------------------------------------------------------------
95      !!                  ***  ROUTINE mpp_init  ***
96      !!                   
97      !! ** Purpose :   Lay out the global domain over processors.
98      !!
99      !! ** Method  :   Global domain is distributed in smaller local domains.
100      !!      Periodic condition is a function of the local domain position
101      !!      (global boundary or neighbouring domain) and of the global
102      !!      periodic
103      !!      Type :         jperio global periodic condition
104      !!                     nperio local  periodic condition
105      !!
106      !! ** Action  : - set domain parameters
107      !!                    nimpp     : longitudinal index
108      !!                    njmpp     : latitudinal  index
109      !!                    nperio    : lateral condition type
110      !!                    narea     : number for local area
111      !!                    nlci      : first dimension
112      !!                    nlcj      : second dimension
113      !!                    nbondi    : mark for "east-west local boundary"
114      !!                    nbondj    : mark for "north-south local boundary"
115      !!                    nproc     : number for local processor
116      !!                    noea      : number for local neighboring processor
117      !!                    nowe      : number for local neighboring processor
118      !!                    noso      : number for local neighboring processor
119      !!                    nono      : number for local neighboring processor
120      !!
121      !! History :
122      !!        !  94-11  (M. Guyon)  Original code
123      !!        !  95-04  (J. Escobar, M. Imbard)
124      !!        !  98-02  (M. Guyon)  FETI method
125      !!        !  98-05  (M. Imbard, J. Escobar, L. Colombet )  SHMEM and MPI versions
126      !!   8.5  !  02-08  (G. Madec)  F90 : free form
127      !!   3.4  !  11-11  (C. Harris) decomposition changes for running with CICE
128      !!----------------------------------------------------------------------
129      INTEGER  ::   ji, jj, jn   ! dummy loop indices
130      INTEGER  ::   ii, ij, ifreq, il1, il2            ! local integers
131      INTEGER  ::   iresti, irestj, ijm1, imil, inum   !   -      -
132      REAL(wp) ::   zidom, zjdom                       ! local scalars
133      INTEGER, DIMENSION(jpni,jpnj) ::   iimppt, ijmppt, ilcit, ilcjt   ! local workspace
134      !!----------------------------------------------------------------------
135
136      IF(lwp) WRITE(numout,*)
137      IF(lwp) WRITE(numout,*) 'mpp_init : Message Passing MPI'
138      IF(lwp) WRITE(numout,*) '~~~~~~~~'
139
140
141      !  1. Dimension arrays for subdomains
142      ! -----------------------------------
143      !  Computation of local domain sizes ilcit() ilcjt()
144      !  These dimensions depend on global sizes jpni,jpnj and jpiglo,jpjglo
145      !  The subdomains are squares leeser than or equal to the global
146      !  dimensions divided by the number of processors minus the overlap
147      !  array (cf. par_oce.F90).
148     
149      nreci  = 2 * jpreci
150      nrecj  = 2 * jprecj
151      iresti = MOD( jpiglo - nreci , jpni )
152      irestj = MOD( jpjglo - nrecj , jpnj )
153
154      IF(  iresti == 0 )   iresti = jpni
155
156#if defined key_nemocice_decomp
157      ! In order to match CICE the size of domains in NEMO has to be changed
158      ! The last line of blocks (west) will have fewer points
159
160      DO jj = 1, jpnj
161         DO ji=1, jpni-1
162            ilcit(ji,jj) = jpi
163         END DO
164         ilcit(jpni,jj) = jpiglo - (jpni - 1) * (jpi - nreci)
165      END DO
166
167#else
168
169      DO jj = 1, jpnj
170         DO ji = 1, iresti
171            ilcit(ji,jj) = jpi
172         END DO
173         DO ji = iresti+1, jpni
174            ilcit(ji,jj) = jpi -1
175         END DO
176      END DO
177     
178#endif
179      IF( irestj == 0 )   irestj = jpnj
180
181#if defined key_nemocice_decomp
182      ! Same change to domains in North-South direction as in East-West.
183      DO ji=1,jpni
184         DO jj=1,jpnj-1
185            ilcjt(ji,jj) = jpj
186         END DO
187         ilcjt(ji,jpnj) = jpjglo - (jpnj - 1) * (jpj - nrecj)
188      END DO
189
190#else
191
192      DO ji = 1, jpni
193         DO jj = 1, irestj
194            ilcjt(ji,jj) = jpj
195         END DO
196         DO jj = irestj+1, jpnj
197            ilcjt(ji,jj) = jpj -1
198         END DO
199      END DO
200     
201#endif
202      IF(lwp) THEN
203         WRITE(numout,*)
204         WRITE(numout,*) '           defines mpp subdomains'
205         WRITE(numout,*) '           ----------------------'
206         WRITE(numout,*) '           iresti=',iresti,' irestj=',irestj
207         WRITE(numout,*) '           jpni  =',jpni  ,' jpnj  =',jpnj
208         ifreq = 4
209         il1   = 1
210         DO jn = 1, (jpni-1)/ifreq+1
211            il2 = MIN( jpni, il1+ifreq-1 )
212            WRITE(numout,*)
213            WRITE(numout,9200) ('***',ji = il1,il2-1)
214            DO jj = jpnj, 1, -1
215               WRITE(numout,9203) ('   ',ji = il1,il2-1)
216               WRITE(numout,9202) jj, ( ilcit(ji,jj),ilcjt(ji,jj),ji = il1,il2 )
217               WRITE(numout,9203) ('   ',ji = il1,il2-1)
218               WRITE(numout,9200) ('***',ji = il1,il2-1)
219            END DO
220            WRITE(numout,9201) (ji,ji = il1,il2)
221            il1 = il1+ifreq
222         END DO
223 9200    FORMAT('     ***',20('*************',a3))
224 9203    FORMAT('     *     ',20('         *   ',a3))
225 9201    FORMAT('        ',20('   ',i3,'          '))
226 9202    FORMAT(' ',i3,' *  ',20(i3,'  x',i3,'   *   '))
227      ENDIF
228
229      zidom = nreci
230      DO ji = 1, jpni
231         zidom = zidom + ilcit(ji,1) - nreci
232      END DO
233      IF(lwp) WRITE(numout,*)
234      IF(lwp) WRITE(numout,*)' sum ilcit(i,1) = ', zidom, ' jpiglo = ', jpiglo
235     
236      zjdom = nrecj
237      DO jj = 1, jpnj
238         zjdom = zjdom + ilcjt(1,jj) - nrecj
239      END DO
240      IF(lwp) WRITE(numout,*)' sum ilcit(1,j) = ', zjdom, ' jpjglo = ', jpjglo
241      IF(lwp) WRITE(numout,*)
242     
243
244      !  2. Index arrays for subdomains
245      ! -------------------------------
246     
247      iimppt(:,:) = 1
248      ijmppt(:,:) = 1
249     
250      IF( jpni > 1 ) THEN
251         DO jj = 1, jpnj
252            DO ji = 2, jpni
253               iimppt(ji,jj) = iimppt(ji-1,jj) + ilcit(ji-1,jj) - nreci
254            END DO
255         END DO
256      ENDIF
257
258      IF( jpnj > 1 ) THEN
259         DO jj = 2, jpnj
260            DO ji = 1, jpni
261               ijmppt(ji,jj) = ijmppt(ji,jj-1)+ilcjt(ji,jj-1)-nrecj
262            END DO
263         END DO
264      ENDIF
265     
266      ! 3. Subdomain description
267      ! ------------------------
268
269      DO jn = 1, jpnij
270         ii = 1 + MOD( jn-1, jpni )
271         ij = 1 + (jn-1) / jpni
272         nimppt(jn) = iimppt(ii,ij)
273         njmppt(jn) = ijmppt(ii,ij)
274         nlcit (jn) = ilcit (ii,ij)     
275         nlci       = nlcit (jn)     
276         nlcjt (jn) = ilcjt (ii,ij)     
277         nlcj       = nlcjt (jn)
278         nbondj = -1                                   ! general case
279         IF( jn   >  jpni          )   nbondj = 0      ! first row of processor
280         IF( jn   >  (jpnj-1)*jpni )   nbondj = 1      ! last  row of processor
281         IF( jpnj == 1             )   nbondj = 2      ! one processor only in j-direction
282         ibonjt(jn) = nbondj
283         
284         nbondi = 0                                    !
285         IF( MOD( jn, jpni ) == 1 )   nbondi = -1      !
286         IF( MOD( jn, jpni ) == 0 )   nbondi =  1      !
287         IF( jpni            == 1 )   nbondi =  2      ! one processor only in i-direction
288         ibonit(jn) = nbondi
289         
290         nldi =  1   + jpreci
291         nlei = nlci - jpreci
292         IF( nbondi == -1 .OR. nbondi == 2 )   nldi = 1
293         IF( nbondi ==  1 .OR. nbondi == 2 )   nlei = nlci
294         nldj =  1   + jprecj
295         nlej = nlcj - jprecj
296         IF( nbondj == -1 .OR. nbondj == 2 )   nldj = 1
297         IF( nbondj ==  1 .OR. nbondj == 2 )   nlej = nlcj
298         nldit(jn) = nldi
299         nleit(jn) = nlei
300         nldjt(jn) = nldj
301         nlejt(jn) = nlej
302      END DO
303     
304
305      ! 4. From global to local
306      ! -----------------------
307
308      nperio = 0
309      IF( jperio == 2 .AND. nbondj == -1 )   nperio = 2
310
311
312      ! 5. Subdomain neighbours
313      ! ----------------------
314
315      nproc = narea - 1
316      noso  = nproc - jpni
317      nowe  = nproc - 1
318      noea  = nproc + 1
319      nono  = nproc + jpni
320      ! great neighbours
321      npnw = nono - 1
322      npne = nono + 1
323      npsw = noso - 1
324      npse = noso + 1
325      nbsw = 1
326      nbnw = 1
327      IF( MOD( nproc, jpni ) == 0 ) THEN
328         nbsw = 0
329         nbnw = 0
330      ENDIF
331      nbse = 1
332      nbne = 1
333      IF( MOD( nproc, jpni ) == jpni-1 ) THEN
334         nbse = 0
335         nbne = 0
336      ENDIF
337      IF(nproc < jpni) THEN
338         nbsw = 0
339         nbse = 0
340      ENDIF
341      IF( nproc >= (jpnj-1)*jpni ) THEN
342         nbnw = 0
343         nbne = 0
344      ENDIF
345      nlcj = nlcjt(narea) 
346      nlci = nlcit(narea) 
347      nldi = nldit(narea)
348      nlei = nleit(narea)
349      nldj = nldjt(narea)
350      nlej = nlejt(narea)
351      nbondi = ibonit(narea)
352      nbondj = ibonjt(narea)
353      nimpp  = nimppt(narea) 
354      njmpp  = njmppt(narea) 
355
356     ! Save processor layout in layout.dat file
357       IF (lwp) THEN
358        CALL ctl_opn( inum, 'layout.dat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE., narea )
359        WRITE(inum,'(a)') '   jpnij     jpi     jpj     jpk  jpiglo  jpjglo'
360        WRITE(inum,'(6i8)') jpnij,jpi,jpj,jpk,jpiglo,jpjglo
361        WRITE(inum,'(a)') 'NAREA nlci nlcj nldi nldj nlei nlej nimpp njmpp'
362
363        DO  jn = 1, jpnij
364         WRITE(inum,'(9i5)') jn, nlcit(jn), nlcjt(jn), &
365                                      nldit(jn), nldjt(jn), &
366                                      nleit(jn), nlejt(jn), &
367                                      nimppt(jn), njmppt(jn)
368        END DO
369        CLOSE(inum)   
370      END IF
371
372
373      ! w a r n i n g  narea (zone) /= nproc (processors)!
374
375      IF( jperio == 1 .OR. jperio == 4 .OR. jperio == 6 ) THEN
376         IF( jpni == 1 )THEN
377            nbondi = 2
378            nperio = 1
379         ELSE
380            nbondi = 0
381         ENDIF
382         IF( MOD( narea, jpni ) == 0 ) THEN
383            noea = nproc-(jpni-1)
384            npne = npne-jpni
385            npse = npse-jpni
386         ENDIF
387         IF( MOD( narea, jpni ) == 1 ) THEN
388            nowe = nproc+(jpni-1)
389            npnw = npnw+jpni
390            npsw = npsw+jpni
391         ENDIF
392         nbsw = 1
393         nbnw = 1
394         nbse = 1
395         nbne = 1
396         IF( nproc < jpni ) THEN
397            nbsw = 0
398            nbse = 0
399         ENDIF
400         IF( nproc >= (jpnj-1)*jpni ) THEN
401            nbnw = 0
402            nbne = 0
403         ENDIF
404      ENDIF
405      npolj = 0
406      IF( jperio == 3 .OR. jperio == 4 ) THEN
407         ijm1 = jpni*(jpnj-1)
408         imil = ijm1+(jpni+1)/2
409         IF( narea > ijm1 ) npolj = 3
410         IF( MOD(jpni,2) == 1 .AND. narea == imil ) npolj = 4
411         IF( npolj == 3 ) nono = jpni*jpnj-narea+ijm1
412      ENDIF
413      IF( jperio == 5 .OR. jperio == 6 ) THEN
414          ijm1 = jpni*(jpnj-1)
415          imil = ijm1+(jpni+1)/2
416          IF( narea > ijm1) npolj = 5
417          IF( MOD(jpni,2) == 1 .AND. narea == imil ) npolj = 6
418          IF( npolj == 5 ) nono = jpni*jpnj-narea+ijm1
419      ENDIF
420
421      ! Periodicity : no corner if nbondi = 2 and nperio != 1
422
423      IF(lwp) THEN
424         WRITE(numout,*) ' nproc  = ', nproc
425         WRITE(numout,*) ' nowe   = ', nowe  , ' noea   =  ', noea
426         WRITE(numout,*) ' nono   = ', nono  , ' noso   =  ', noso
427         WRITE(numout,*) ' nbondi = ', nbondi
428         WRITE(numout,*) ' nbondj = ', nbondj
429         WRITE(numout,*) ' npolj  = ', npolj
430         WRITE(numout,*) ' nperio = ', nperio
431         WRITE(numout,*) ' nlci   = ', nlci
432         WRITE(numout,*) ' nlcj   = ', nlcj
433         WRITE(numout,*) ' nimpp  = ', nimpp
434         WRITE(numout,*) ' njmpp  = ', njmpp
435         WRITE(numout,*) ' nbse   = ', nbse  , ' npse   = ', npse
436         WRITE(numout,*) ' nbsw   = ', nbsw  , ' npsw   = ', npsw
437         WRITE(numout,*) ' nbne   = ', nbne  , ' npne   = ', npne
438         WRITE(numout,*) ' nbnw   = ', nbnw  , ' npnw   = ', npnw
439      ENDIF
440
441      IF( nperio == 1 .AND. jpni /= 1 ) CALL ctl_stop( ' mpp_init: error on cyclicity' )
442
443      ! Prepare mpp north fold
444
445      IF (jperio >= 3 .AND. jperio <= 6 .AND. jpni > 1 ) THEN
446         CALL mpp_ini_north
447      END IF
448
449      ! Prepare NetCDF output file (if necessary)
450      CALL mpp_init_ioipsl
451
452   END SUBROUTINE mpp_init
453
454#  include "mppini_2.h90"
455
456# if defined key_dimgout
457   !!----------------------------------------------------------------------
458   !!   'key_dimgout'                  NO use of NetCDF files
459   !!----------------------------------------------------------------------
460   SUBROUTINE mpp_init_ioipsl       ! Dummy routine
461   END SUBROUTINE mpp_init_ioipsl 
462# else
463   SUBROUTINE mpp_init_ioipsl
464      !!----------------------------------------------------------------------
465      !!                  ***  ROUTINE mpp_init_ioipsl  ***
466      !!
467      !! ** Purpose :   
468      !!
469      !! ** Method  :   
470      !!
471      !! History :
472      !!   9.0  !  04-03  (G. Madec )  MPP-IOIPSL
473      !!   " "  !  08-12  (A. Coward)  addition in case of jpni*jpnj < jpnij
474      !!----------------------------------------------------------------------
475      INTEGER, DIMENSION(2) ::   iglo, iloc, iabsf, iabsl, ihals, ihale, idid
476      !!----------------------------------------------------------------------
477
478      ! The domain is split only horizontally along i- or/and j- direction
479      ! So we need at the most only 1D arrays with 2 elements.
480      ! Set idompar values equivalent to the jpdom_local_noextra definition
481      ! used in IOM. This works even if jpnij .ne. jpni*jpnj.
482      iglo(1) = jpiglo
483      iglo(2) = jpjglo
484      iloc(1) = nlci
485      iloc(2) = nlcj
486      iabsf(1) = nimppt(narea)
487      iabsf(2) = njmppt(narea)
488      iabsl(:) = iabsf(:) + iloc(:) - 1
489      ihals(1) = nldi - 1
490      ihals(2) = nldj - 1
491      ihale(1) = nlci - nlei
492      ihale(2) = nlcj - nlej
493      idid(1) = 1
494      idid(2) = 2
495
496      IF(lwp) THEN
497          WRITE(numout,*)
498          WRITE(numout,*) 'mpp_init_ioipsl :   iloc  = ', iloc (1), iloc (2)
499          WRITE(numout,*) '~~~~~~~~~~~~~~~     iabsf = ', iabsf(1), iabsf(2)
500          WRITE(numout,*) '                    ihals = ', ihals(1), ihals(2)
501          WRITE(numout,*) '                    ihale = ', ihale(1), ihale(2)
502      ENDIF
503      !
504      CALL flio_dom_set ( jpnij, nproc, idid, iglo, iloc, iabsf, iabsl, ihals, ihale, 'BOX', nidom)
505      !
506   END SUBROUTINE mpp_init_ioipsl 
507
508# endif
509#endif
510
511   !!======================================================================
512END MODULE mppini
Note: See TracBrowser for help on using the repository browser.