source: branches/2013/dev_MERGE_2013/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 4309

Last change on this file since 4309 was 4309, checked in by cetlod, 7 years ago

dev_MERGE_2013 : fix to lwp use for namelist ice reads

  • Property svn:keywords set to Id
File size: 38.5 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!                 ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!----------------------------------------------------------------------
33
34   !!----------------------------------------------------------------------
35   !!   nemo_gcm       : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
36   !!   nemo_init      : initialization of the NEMO system
37   !!   nemo_ctl       : initialisation of the contol print
38   !!   nemo_closefile : close remaining open files
39   !!   nemo_alloc     : dynamical allocation
40   !!   nemo_partition : calculate MPP domain decomposition
41   !!   factorise      : calculate the factors of the no. of MPI processes
42   !!----------------------------------------------------------------------
43   USE step_oce        ! module used in the ocean time stepping module
44   USE sbc_oce         ! surface boundary condition: ocean
45   USE cla             ! cross land advection               (tra_cla routine)
46   USE domcfg          ! domain configuration               (dom_cfg routine)
47   USE mppini          ! shared/distributed memory setting (mpp_init routine)
48   USE domain          ! domain initialization             (dom_init routine)
49#if defined key_nemocice_decomp
50   USE ice_domain_size, only: nx_global, ny_global
51#endif
52   USE tideini         ! tidal components initialization   (tide_ini routine)
53   USE obcini          ! open boundary cond. initialization (obc_ini routine)
54   USE bdyini          ! open boundary cond. initialization (bdy_init routine)
55   USE bdydta          ! open boundary cond. initialization (bdy_dta_init routine)
56   USE bdytides        ! open boundary cond. initialization (bdytide_init routine)
57   USE istate          ! initial state setting          (istate_init routine)
58   USE ldfdyn          ! lateral viscosity setting      (ldfdyn_init routine)
59   USE ldftra          ! lateral diffusivity setting    (ldftra_init routine)
60   USE zdfini          ! vertical physics setting          (zdf_init routine)
61   USE phycst          ! physical constant                  (par_cst routine)
62   USE trdmod          ! momentum/tracers trends       (trd_mod_init routine)
63   USE asminc          ! assimilation increments     
64   USE asmbkg          ! writing out state trajectory
65   USE diaptr          ! poleward transports           (dia_ptr_init routine)
66   USE diadct          ! sections transports           (dia_dct_init routine)
67   USE diaobs          ! Observation diagnostics       (dia_obs_init routine)
68   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
69   USE step            ! NEMO time-stepping                 (stp     routine)
70   USE icbini          ! handle bergs, initialisation
71   USE icbstp          ! handle bergs, calving, themodynamics and transport
72#if defined key_oasis3
73   USE cpl_oasis3      ! OASIS3 coupling
74#elif defined key_oasis4
75   USE cpl_oasis4      ! OASIS4 coupling (not working)
76#endif
77   USE c1d             ! 1D configuration
78   USE step_c1d        ! Time stepping loop for the 1D configuration
79   USE dyndmp          ! Momentum damping
80#if defined key_top
81   USE trcini          ! passive tracer initialisation
82#endif
83   USE lib_mpp         ! distributed memory computing
84#if defined key_iomput
85   USE xios
86#endif
87   USE sbctide, ONLY: lk_tide
88   USE crsini          ! initialise grid coarsening utility
89   USE lbcnfd, ONLY: isendto, nsndto ! Setup of north fold exchanges
90
91   IMPLICIT NONE
92   PRIVATE
93
94   PUBLIC   nemo_gcm    ! called by model.F90
95   PUBLIC   nemo_init   ! needed by AGRIF
96   PUBLIC   nemo_alloc  ! needed by TAM
97
98   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
99
100   !!----------------------------------------------------------------------
101   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
102   !! $Id$
103   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
104   !!----------------------------------------------------------------------
105CONTAINS
106
107   SUBROUTINE nemo_gcm
108      !!----------------------------------------------------------------------
109      !!                     ***  ROUTINE nemo_gcm  ***
110      !!
111      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
112      !!              curvilinear mesh on the sphere.
113      !!
114      !! ** Method  : - model general initialization
115      !!              - launch the time-stepping (stp routine)
116      !!              - finalize the run by closing files and communications
117      !!
118      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
119      !!              Madec, 2008, internal report, IPSL.
120      !!----------------------------------------------------------------------
121      INTEGER ::   istp       ! time step index
122      !!----------------------------------------------------------------------
123      !
124
125#if defined key_agrif
126      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
127#endif
128
129      !                            !-----------------------!
130      CALL nemo_init               !==  Initialisations  ==!
131      !                            !-----------------------!
132#if defined key_agrif
133      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
134      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
135# if defined key_top
136      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
137# endif
138# if defined key_lim2
139      CALL Agrif_Declare_Var_lim2  !  "      "   "   "      "  LIM
140# endif
141#endif
142
143      ! check that all process are still there... If some process have an error,
144      ! they will never enter in step and other processes will wait until the end of the cpu time!
145      IF( lk_mpp )   CALL mpp_max( nstop )
146
147      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
148
149      !                            !-----------------------!
150      !                            !==   time stepping   ==!
151      !                            !-----------------------!
152      istp = nit000
153#if defined key_c1d
154         DO WHILE ( istp <= nitend .AND. nstop == 0 )
155            CALL stp_c1d( istp )
156            istp = istp + 1
157         END DO
158#else
159          IF( lk_asminc ) THEN
160             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
161             IF( ln_asmdin ) THEN                        ! Direct initialization
162                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
163                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
164                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
165             ENDIF
166          ENDIF
167
168         DO WHILE ( istp <= nitend .AND. nstop == 0 )
169
170#if defined key_agrif
171            CALL Agrif_Step( stp )           ! AGRIF: time stepping
172#else
173            CALL stp( istp )                 ! standard time stepping
174#endif
175
176            istp = istp + 1
177            IF( lk_mpp )   CALL mpp_max( nstop )
178         END DO
179#endif
180
181      IF( lk_diaobs   )   CALL dia_obs_wri
182      !
183      IF( ln_icebergs )   CALL icb_end( nitend )
184
185      !                            !------------------------!
186      !                            !==  finalize the run  ==!
187      !                            !------------------------!
188      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
189      !
190      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
191         WRITE(numout,cform_err)
192         WRITE(numout,*) nstop, ' error have been found'
193      ENDIF
194      !
195#if defined key_agrif
196      CALL Agrif_ParentGrid_To_ChildGrid()
197      IF( lk_diaobs ) CALL dia_obs_wri
198      IF( nn_timing == 1 )   CALL timing_finalize
199      CALL Agrif_ChildGrid_To_ParentGrid()
200#endif
201      IF( nn_timing == 1 )   CALL timing_finalize
202      !
203      CALL nemo_closefile
204#if defined key_iomput
205      CALL xios_finalize                ! end mpp communications with xios
206# if defined key_oasis3 || defined key_oasis4
207      CALL cpl_prism_finalize           ! end coupling and mpp communications with OASIS
208# endif
209#else
210# if defined key_oasis3 || defined key_oasis4
211      CALL cpl_prism_finalize           ! end coupling and mpp communications with OASIS
212# else
213      IF( lk_mpp )   CALL mppstop       ! end mpp communications
214# endif
215#endif
216      !
217   END SUBROUTINE nemo_gcm
218
219
220   SUBROUTINE nemo_init
221      !!----------------------------------------------------------------------
222      !!                     ***  ROUTINE nemo_init  ***
223      !!
224      !! ** Purpose :   initialization of the NEMO GCM
225      !!----------------------------------------------------------------------
226      INTEGER ::   ji            ! dummy loop indices
227      INTEGER ::   ilocal_comm   ! local integer
228      INTEGER ::   ios
229      CHARACTER(len=80), DIMENSION(16) ::   cltxt
230      !!
231      NAMELIST/namctl/ ln_ctl, nn_print, nn_ictls, nn_ictle,   &
232         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
233         &             nn_bench, nn_timing
234      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
235         &             jpizoom, jpjzoom, jperio
236      !!----------------------------------------------------------------------
237      !
238      cltxt = ''
239      !
240      !                             ! Open reference namelist and configuration namelist files
241      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
242      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
243      CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. , 1 )
244      !
245      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
246      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
247901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
248
249      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
250      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
251902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
252      WRITE( numond, namctl )
253
254      !
255      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
256      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
257903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
258
259      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
260      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
261904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
262      WRITE( numond, namcfg )
263
264! Force values for AGRIF zoom (cf. agrif_user.F90)
265#if defined key_agrif
266   IF( .NOT. Agrif_Root() ) THEN
267      jpiglo  = nbcellsx + 2 + 2*nbghostcells
268      jpjglo  = nbcellsy + 2 + 2*nbghostcells
269      jpi     = ( jpiglo-2*jpreci + (jpni-1+0) ) / jpni + 2*jpreci
270      jpj     = ( jpjglo-2*jprecj + (jpnj-1+0) ) / jpnj + 2*jprecj
271      jpidta  = jpiglo
272      jpjdta  = jpjglo
273      jpizoom = 1
274      jpjzoom = 1
275      nperio  = 0
276      jperio  = 0
277   ENDIF
278#endif
279      !
280      !                             !--------------------------------------------!
281      !                             !  set communicator & select the local node  !
282      !                             !--------------------------------------------!
283#if defined key_iomput
284      IF( Agrif_Root() ) THEN
285# if defined key_oasis3 || defined key_oasis4
286         CALL cpl_prism_init( ilocal_comm )      ! nemo local communicator given by oasis
287         CALL xios_initialize( "oceanx",local_comm=ilocal_comm )
288# else
289         CALL  xios_initialize( "nemo",return_comm=ilocal_comm )
290# endif
291      ENDIF
292      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection
293#else
294# if defined key_oasis3 || defined key_oasis4
295      IF( Agrif_Root() ) THEN
296         CALL cpl_prism_init( ilocal_comm )                 ! nemo local communicator given by oasis
297      ENDIF
298      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection (control print return in cltxt)
299# else
300      ilocal_comm = 0
301      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop )                 ! Nodes selection (control print return in cltxt)
302# endif
303#endif
304      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
305
306      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
307
308      ! If dimensions of processor grid weren't specified in the namelist file
309      ! then we calculate them here now that we have our communicator size
310      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
311#if   defined key_mpp_mpi
312         IF( Agrif_Root() ) CALL nemo_partition(mppsize)
313#else
314         jpni  = 1
315         jpnj  = 1
316         jpnij = jpni*jpnj
317#endif
318      END IF
319
320      ! Calculate domain dimensions given calculated jpni and jpnj
321      ! This used to be done in par_oce.F90 when they were parameters rather
322      ! than variables
323      IF( Agrif_Root() ) THEN
324#if defined key_nemocice_decomp
325         jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci ! first  dim.
326         jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim.
327#else
328         jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
329         jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
330#endif
331      ENDIF
332         jpk = jpkdta                                             ! third dim
333         jpim1 = jpi-1                                            ! inner domain indices
334         jpjm1 = jpj-1                                            !   "           "
335         jpkm1 = jpk-1                                            !   "           "
336         jpij  = jpi*jpj                                          !  jpi x j
337
338      IF(lwp) THEN                            ! open listing units
339         !
340         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
341         !
342         WRITE(numout,*)
343         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
344         WRITE(numout,*) '                       NEMO team'
345         WRITE(numout,*) '            Ocean General Circulation Model'
346         WRITE(numout,*) '                  version 3.4  (2011) '
347         WRITE(numout,*)
348         WRITE(numout,*)
349         DO ji = 1, SIZE(cltxt)
350            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
351         END DO
352         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
353         !
354      ENDIF
355
356      ! Now we know the dimensions of the grid and numout has been set we can
357      ! allocate arrays
358      CALL nemo_alloc()
359
360      !                             !-------------------------------!
361      !                             !  NEMO general initialization  !
362      !                             !-------------------------------!
363
364      CALL nemo_ctl                          ! Control prints & Benchmark
365
366      !                                      ! Domain decomposition
367      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
368      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
369      ENDIF
370      !
371      IF( nn_timing == 1 )  CALL timing_init
372      !
373      !                                      ! General initialization
374                            CALL     phy_cst    ! Physical constants
375                            CALL     eos_init   ! Equation of state
376      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
377                            CALL     dom_cfg    ! Domain configuration
378                            CALL     dom_init   ! Domain
379
380      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
381
382      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
383
384      IF( lk_obc        )   CALL     obc_init   ! Open boundaries
385
386                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
387
388      IF( lk_tide       )   CALL    tide_init( nit000 )    ! Initialisation of the tidal harmonics
389
390      IF( lk_bdy        )   CALL      bdy_init  ! Open boundaries initialisation
391      IF( lk_bdy        )   CALL  bdy_dta_init  ! Open boundaries initialisation of external data arrays
392      IF( lk_bdy .AND. lk_tide )   &
393         &                  CALL  bdytide_init  ! Open boundaries initialisation of tidal harmonic forcing
394
395                            CALL dyn_nept_init  ! simplified form of Neptune effect
396
397      !     
398      IF( ln_crs        )   CALL     crs_init   ! Domain initialization of coarsened grid
399      !
400                                ! Ocean physics
401                            CALL     sbc_init   ! Forcings : surface module
402      !                                         ! Vertical physics
403
404                            CALL     zdf_init      ! namelist read
405
406                            CALL zdf_bfr_init      ! bottom friction
407
408      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
409      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
410      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
411      IF( lk_zdfkpp     )   CALL zdf_kpp_init      ! KPP closure scheme
412      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
413      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
414         &                  CALL zdf_ddm_init      ! double diffusive mixing
415      !                                         ! Lateral physics
416                            CALL ldf_tra_init      ! Lateral ocean tracer physics
417                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
418      IF( lk_ldfslp     )   CALL ldf_slp_init      ! slope of lateral mixing
419
420      !                                     ! Active tracers
421                            CALL tra_qsr_init   ! penetrative solar radiation qsr
422                            CALL tra_bbc_init   ! bottom heat flux
423      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
424                            CALL tra_dmp_init   ! internal damping trends- tracers
425                            CALL tra_adv_init   ! horizontal & vertical advection
426                            CALL tra_ldf_init   ! lateral mixing
427                            CALL tra_zdf_init   ! vertical mixing and after tracer fields
428
429      !                                     ! Dynamics
430      IF( lk_c1d        )   CALL dyn_dmp_init   ! internal damping trends- momentum
431                            CALL dyn_adv_init   ! advection (vector or flux form)
432                            CALL dyn_vor_init   ! vorticity term including Coriolis
433                            CALL dyn_ldf_init   ! lateral mixing
434                            CALL dyn_hpg_init   ! horizontal gradient of Hydrostatic pressure
435                            CALL dyn_zdf_init   ! vertical diffusion
436                            CALL dyn_spg_init   ! surface pressure gradient
437
438      !                                     ! Misc. options
439      IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 )   CALL cla_init       ! Cross Land Advection
440                            CALL icb_init( rdt, nit000)   ! initialise icebergs instance
441     
442#if defined key_top
443      !                                     ! Passive tracers
444                            CALL     trc_init
445#endif
446      !
447 
448                                            ! Diagnostics
449      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
450      IF( lk_diaar5     )   CALL dia_ar5_init   ! ar5 diag
451                            CALL dia_ptr_init   ! Poleward TRansports initialization
452      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
453                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
454                            CALL trd_mod_init   ! Mixed-layer/Vorticity/Integral constraints trends
455      IF( lk_diaobs     ) THEN                  ! Observation & model comparison
456                            CALL dia_obs_init            ! Initialize observational data
457                            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
458      ENDIF
459      !                                     ! Assimilation increments
460      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
461      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
462      !
463   END SUBROUTINE nemo_init
464
465
466   SUBROUTINE nemo_ctl
467      !!----------------------------------------------------------------------
468      !!                     ***  ROUTINE nemo_ctl  ***
469      !!
470      !! ** Purpose :   control print setting
471      !!
472      !! ** Method  : - print namctl information and check some consistencies
473      !!----------------------------------------------------------------------
474      !
475      IF(lwp) THEN                  ! control print
476         WRITE(numout,*)
477         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
478         WRITE(numout,*) '~~~~~~~ '
479         WRITE(numout,*) '   Namelist namctl'
480         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
481         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
482         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
483         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
484         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
485         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
486         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
487         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
488         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
489         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
490      ENDIF
491      !
492      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
493      nictls    = nn_ictls
494      nictle    = nn_ictle
495      njctls    = nn_jctls
496      njctle    = nn_jctle
497      isplt     = nn_isplt
498      jsplt     = nn_jsplt
499      nbench    = nn_bench
500
501      IF(lwp) THEN                  ! control print
502         WRITE(numout,*)
503         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
504         WRITE(numout,*) '~~~~~~~ '
505         WRITE(numout,*) '   Namelist namcfg'
506         WRITE(numout,*) '      configuration name              cp_cfg      = ', TRIM(cp_cfg)
507         WRITE(numout,*) '      configuration zoom name         cp_cfz      = ', TRIM(cp_cfz)
508         WRITE(numout,*) '      configuration resolution        jp_cfg      = ', jp_cfg
509         WRITE(numout,*) '      1st lateral dimension ( >= jpi ) jpidta     = ', jpidta
510         WRITE(numout,*) '      2nd    "         "    ( >= jpj ) jpjdta     = ', jpjdta
511         WRITE(numout,*) '      3nd    "         "               jpkdta     = ', jpkdta
512         WRITE(numout,*) '      1st dimension of global domain in i jpiglo  = ', jpiglo
513         WRITE(numout,*) '      2nd    -                  -    in j jpjglo  = ', jpjglo
514         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
515         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
516         WRITE(numout,*) '      lateral cond. type (between 0 and 6) jperio = ', jperio   
517      ENDIF
518      !                             ! Parameter control
519      !
520      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
521         IF( lk_mpp .AND. jpnij > 1 ) THEN
522            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
523         ELSE
524            IF( isplt == 1 .AND. jsplt == 1  ) THEN
525               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
526                  &           ' - the print control will be done over the whole domain' )
527            ENDIF
528            ijsplt = isplt * jsplt            ! total number of processors ijsplt
529         ENDIF
530         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
531         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
532         !
533         !                              ! indices used for the SUM control
534         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
535            lsp_area = .FALSE.
536         ELSE                                             ! print control done over a specific  area
537            lsp_area = .TRUE.
538            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
539               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
540               nictls = 1
541            ENDIF
542            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
543               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
544               nictle = jpiglo
545            ENDIF
546            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
547               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
548               njctls = 1
549            ENDIF
550            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
551               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
552               njctle = jpjglo
553            ENDIF
554         ENDIF
555      ENDIF
556      !
557      IF( nbench == 1 ) THEN              ! Benchmark
558         SELECT CASE ( cp_cfg )
559         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
560         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
561            &                                 ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
562         END SELECT
563      ENDIF
564      !
565      IF( lk_c1d .AND. .NOT.lk_iomput )   CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ',   &
566         &                                               'with the IOM Input/Output manager. '         ,   &
567         &                                               'Compile with key_iomput enabled' )
568      !
569      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
570         &                                               'f2003 standard. '                              ,  &
571         &                                               'Compile with key_nosignedzero enabled' )
572      !
573   END SUBROUTINE nemo_ctl
574
575
576   SUBROUTINE nemo_closefile
577      !!----------------------------------------------------------------------
578      !!                     ***  ROUTINE nemo_closefile  ***
579      !!
580      !! ** Purpose :   Close the files
581      !!----------------------------------------------------------------------
582      !
583      IF( lk_mpp )   CALL mppsync
584      !
585      CALL iom_close                                 ! close all input/output files managed by iom_*
586      !
587      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
588      IF( numsol          /= -1 )   CLOSE( numsol          )   ! solver file
589      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
590      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
591      IF( numond          /= -1 )   CLOSE( numond          )   ! oce output namelist
592      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
593      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
594      IF( numoni          /= -1 )   CLOSE( numoni          )   ! ice output namelist
595      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
596      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
597      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
598      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
599      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
600
601      !
602      numout = 6                                     ! redefine numout in case it is used after this point...
603      !
604   END SUBROUTINE nemo_closefile
605
606
607   SUBROUTINE nemo_alloc
608      !!----------------------------------------------------------------------
609      !!                     ***  ROUTINE nemo_alloc  ***
610      !!
611      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
612      !!
613      !! ** Method  :
614      !!----------------------------------------------------------------------
615      USE diawri    , ONLY: dia_wri_alloc
616      USE dom_oce   , ONLY: dom_oce_alloc
617      USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
618      USE ldftra_oce, ONLY: ldftra_oce_alloc
619      USE trc_oce   , ONLY: trc_oce_alloc
620#if defined key_diadct 
621      USE diadct    , ONLY: diadct_alloc 
622#endif 
623      !
624      INTEGER :: ierr
625      !!----------------------------------------------------------------------
626      !
627      ierr =        oce_alloc       ()          ! ocean
628      ierr = ierr + dia_wri_alloc   ()
629      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
630      ierr = ierr + ldfdyn_oce_alloc()          ! ocean lateral  physics : dynamics
631      ierr = ierr + ldftra_oce_alloc()          ! ocean lateral  physics : tracers
632      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
633      !
634      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
635      !
636#if defined key_diadct 
637      ierr = ierr + diadct_alloc    ()          !
638#endif 
639      !
640      IF( lk_mpp    )   CALL mpp_sum( ierr )
641      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
642      !
643   END SUBROUTINE nemo_alloc
644
645
646   SUBROUTINE nemo_partition( num_pes )
647      !!----------------------------------------------------------------------
648      !!                 ***  ROUTINE nemo_partition  ***
649      !!
650      !! ** Purpose :
651      !!
652      !! ** Method  :
653      !!----------------------------------------------------------------------
654      INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
655      !
656      INTEGER, PARAMETER :: nfactmax = 20
657      INTEGER :: nfact ! The no. of factors returned
658      INTEGER :: ierr  ! Error flag
659      INTEGER :: ji
660      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
661      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
662      !!----------------------------------------------------------------------
663
664      ierr = 0
665
666      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
667
668      IF( nfact <= 1 ) THEN
669         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
670         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
671         jpnj = 1
672         jpni = num_pes
673      ELSE
674         ! Search through factors for the pair that are closest in value
675         mindiff = 1000000
676         imin    = 1
677         DO ji = 1, nfact-1, 2
678            idiff = ABS( ifact(ji) - ifact(ji+1) )
679            IF( idiff < mindiff ) THEN
680               mindiff = idiff
681               imin = ji
682            ENDIF
683         END DO
684         jpnj = ifact(imin)
685         jpni = ifact(imin + 1)
686      ENDIF
687      !
688      jpnij = jpni*jpnj
689      !
690   END SUBROUTINE nemo_partition
691
692
693   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
694      !!----------------------------------------------------------------------
695      !!                     ***  ROUTINE factorise  ***
696      !!
697      !! ** Purpose :   return the prime factors of n.
698      !!                knfax factors are returned in array kfax which is of
699      !!                maximum dimension kmaxfax.
700      !! ** Method  :
701      !!----------------------------------------------------------------------
702      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
703      INTEGER                    , INTENT(  out) ::   kerr, knfax
704      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
705      !
706      INTEGER :: ifac, jl, inu
707      INTEGER, PARAMETER :: ntest = 14
708      INTEGER :: ilfax(ntest)
709
710      ! lfax contains the set of allowed factors.
711      data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256,  &
712         &                            128,   64,   32,   16,    8,   4,   2  /
713      !!----------------------------------------------------------------------
714
715      ! Clear the error flag and initialise output vars
716      kerr = 0
717      kfax = 1
718      knfax = 0
719
720      ! Find the factors of n.
721      IF( kn == 1 )   GOTO 20
722
723      ! nu holds the unfactorised part of the number.
724      ! knfax holds the number of factors found.
725      ! l points to the allowed factor list.
726      ! ifac holds the current factor.
727
728      inu   = kn
729      knfax = 0
730
731      DO jl = ntest, 1, -1
732         !
733         ifac = ilfax(jl)
734         IF( ifac > inu )   CYCLE
735
736         ! Test whether the factor will divide.
737
738         IF( MOD(inu,ifac) == 0 ) THEN
739            !
740            knfax = knfax + 1            ! Add the factor to the list
741            IF( knfax > kmaxfax ) THEN
742               kerr = 6
743               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
744               return
745            ENDIF
746            kfax(knfax) = ifac
747            ! Store the other factor that goes with this one
748            knfax = knfax + 1
749            kfax(knfax) = inu / ifac
750            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
751         ENDIF
752         !
753      END DO
754
755   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
756      !
757   END SUBROUTINE factorise
758
759#if defined key_mpp_mpi
760   SUBROUTINE nemo_northcomms
761      !!======================================================================
762      !!                     ***  ROUTINE  nemo_northcomms  ***
763      !! nemo_northcomms    :  Setup for north fold exchanges with explicit
764      !!                       point-to-point messaging
765      !!=====================================================================
766      !!----------------------------------------------------------------------
767      !!
768      !! ** Purpose :   Initialization of the northern neighbours lists.
769      !!----------------------------------------------------------------------
770      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
771      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
772      !!----------------------------------------------------------------------
773
774      INTEGER  ::   sxM, dxM, sxT, dxT, jn
775      INTEGER  ::   njmppmax
776
777      njmppmax = MAXVAL( njmppt )
778   
779      !initializes the north-fold communication variables
780      isendto(:) = 0
781      nsndto = 0
782
783      !if I am a process in the north
784      IF ( njmpp == njmppmax ) THEN
785          !sxM is the first point (in the global domain) needed to compute the
786          !north-fold for the current process
787          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
788          !dxM is the last point (in the global domain) needed to compute the
789          !north-fold for the current process
790          dxM = jpiglo - nimppt(narea) + 2
791
792          !loop over the other north-fold processes to find the processes
793          !managing the points belonging to the sxT-dxT range
794          DO jn = jpnij - jpni +1, jpnij
795             IF ( njmppt(jn) == njmppmax ) THEN
796                !sxT is the first point (in the global domain) of the jn
797                !process
798                sxT = nimppt(jn)
799                !dxT is the last point (in the global domain) of the jn
800                !process
801                dxT = nimppt(jn) + nlcit(jn) - 1
802                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
803                   nsndto = nsndto + 1
804                   isendto(nsndto) = jn
805                ELSEIF ((sxM .le. sxT) .AND. (dxM .gt. dxT)) THEN
806                   nsndto = nsndto + 1
807                   isendto(nsndto) = jn
808                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
809                   nsndto = nsndto + 1
810                   isendto(nsndto) = jn
811                END IF
812             END IF
813          END DO
814      ENDIF
815      l_north_nogather = .TRUE.
816   END SUBROUTINE nemo_northcomms
817#else
818   SUBROUTINE nemo_northcomms      ! Dummy routine
819      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
820   END SUBROUTINE nemo_northcomms
821#endif
822   !!======================================================================
823END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.