New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
step.F90 in branches/2013/dev_MERGE_2013/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/2013/dev_MERGE_2013/NEMOGCM/NEMO/OPA_SRC/step.F90 @ 4291

Last change on this file since 4291 was 4230, checked in by cetlod, 10 years ago

dev_LOCEAN_CMCC_INGV_2013 : merge LOCEAN & CMCC_INGV branches, see ticket #1182
  • Property svn:keywords set to Id
File size: 18.5 KB
Line 
1MODULE step
2   !!======================================================================
3   !!                       ***  MODULE step  ***
4   !! Time-stepping    : manager of the ocean, tracer and ice time stepping
5   !!======================================================================
6   !! History :  OPA  !  1991-03  (G. Madec)  Original code
7   !!             -   !  1991-11  (G. Madec)
8   !!             -   !  1992-06  (M. Imbard)  add a first output record
9   !!             -   !  1996-04  (G. Madec)  introduction of dynspg
10   !!             -   !  1996-04  (M.A. Foujols)  introduction of passive tracer
11   !!            8.0  !  1997-06  (G. Madec)  new architecture of call
12   !!            8.2  !  1997-06  (G. Madec, M. Imbard, G. Roullet)  free surface
13   !!             -   !  1999-02  (G. Madec, N. Grima)  hpg implicit
14   !!             -   !  2000-07  (J-M Molines, M. Imbard)  Open Bondary Conditions
15   !!   NEMO     1.0  !  2002-06  (G. Madec)  free form, suppress macro-tasking
16   !!             -   !  2004-08  (C. Talandier) New trends organization
17   !!             -   !  2005-01  (C. Ethe) Add the KPP closure scheme
18   !!             -   !  2005-11  (G. Madec)  Reorganisation of tra and dyn calls
19   !!             -   !  2006-01  (L. Debreu, C. Mazauric)  Agrif implementation
20   !!             -   !  2006-07  (S. Masson)  restart using iom
21   !!            3.2  !  2009-02  (G. Madec, R. Benshila)  reintroduicing z*-coordinate
22   !!             -   !  2009-06  (S. Masson, G. Madec)  TKE restart compatible with key_cpl
23   !!            3.3  !  2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
24   !!             -   !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
25   !!            3.4  !  2011-04  (G. Madec, C. Ethe) Merge of dtatem and dtasal
26   !!                 !  2012-07  (J. Simeon, G. Madec. C. Ethe) Online coarsening of outputs
27   !!----------------------------------------------------------------------
28
29   !!----------------------------------------------------------------------
30   !!   stp             : OPA system time-stepping
31   !!----------------------------------------------------------------------
32   USE step_oce         ! time stepping definition modules
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   stp   ! called by opa.F90
38
39   !! * Substitutions
40#  include "domzgr_substitute.h90"
41#  include "zdfddm_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49#if defined key_agrif
50   SUBROUTINE stp( )
51      INTEGER             ::   kstp   ! ocean time-step index
52#else
53   SUBROUTINE stp( kstp )
54      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
55#endif
56      !!----------------------------------------------------------------------
57      !!                     ***  ROUTINE stp  ***
58      !!
59      !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.)
60      !!              - Time stepping of LIM (dynamic and thermodynamic eqs.)
61      !!              - Tme stepping  of TRC (passive tracer eqs.)
62      !!
63      !! ** Method  : -1- Update forcings and data
64      !!              -2- Update ocean physics
65      !!              -3- Compute the t and s trends
66      !!              -4- Update t and s
67      !!              -5- Compute the momentum trends
68      !!              -6- Update the horizontal velocity
69      !!              -7- Compute the diagnostics variables (rd,N2, div,cur,w)
70      !!              -8- Outputs and diagnostics
71      !!----------------------------------------------------------------------
72      INTEGER ::   jk       ! dummy loop indice
73      INTEGER ::   indic    ! error indicator if < 0
74      !! ---------------------------------------------------------------------
75
76#if defined key_agrif
77      kstp = nit000 + Agrif_Nb_Step()
78!      IF ( Agrif_Root() .and. lwp) Write(*,*) '---'
79!      IF (lwp) Write(*,*) 'Grid Number',Agrif_Fixed(),' time step ',kstp
80# if defined key_iomput
81      IF( Agrif_Nbstepint() == 0 )   CALL iom_swap( "nemo" )
82# endif
83#endif
84                             indic = 0           ! reset to no error condition
85      IF( kstp == nit000 ) THEN
86                      CALL iom_init( "nemo" )      ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
87         IF( ln_crs ) CALL iom_init( "nemo_crs" )  ! initialize context for coarse grid
88      ENDIF
89
90      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
91                             CALL iom_setkt( kstp - nit000 + 1, "nemo"     )   ! say to iom that we are at time step kstp
92      IF( ln_crs     )       CALL iom_setkt( kstp - nit000 + 1, "nemo_crs" )   ! say to iom that we are at time step kstp
93
94      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
95      ! Update data, open boundaries, surface boundary condition (including sea-ice)
96      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
97                         CALL sbc    ( kstp )         ! Sea Boundary Condition (including sea-ice)
98
99      IF( lk_tide.AND.(kstp /= nit000 ))   CALL tide_init ( kstp )
100      IF( lk_tide    )   CALL sbc_tide( kstp )
101      IF( lk_obc     )   CALL obc_dta( kstp )         ! update dynamic and tracer data at open boundaries
102      IF( lk_obc     )   CALL obc_rad( kstp )         ! compute phase velocities at open boundaries
103      IF( lk_bdy     )   CALL bdy_dta( kstp, time_offset=+1 ) ! update dynamic and tracer data at open boundaries
104
105      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
106      !  Ocean dynamics : ssh, wn, hdiv, rot                                 !
107      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
108                         CALL ssh_wzv( kstp )         ! after ssh & vertical velocity
109
110      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
111      ! Ocean physics update                (ua, va, tsa used as workspace)
112      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
113                         CALL bn2( tsb, rn2b )        ! before Brunt-Vaisala frequency
114                         CALL bn2( tsn, rn2  )        ! now    Brunt-Vaisala frequency
115      !
116      !  VERTICAL PHYSICS
117                         CALL zdf_bfr( kstp )         ! bottom friction
118
119      !                                               ! Vertical eddy viscosity and diffusivity coefficients
120      IF( lk_zdfric  )   CALL zdf_ric( kstp )            ! Richardson number dependent Kz
121      IF( lk_zdftke  )   CALL zdf_tke( kstp )            ! TKE closure scheme for Kz
122      IF( lk_zdfgls  )   CALL zdf_gls( kstp )            ! GLS closure scheme for Kz
123      IF( lk_zdfkpp  )   CALL zdf_kpp( kstp )            ! KPP closure scheme for Kz
124      IF( lk_zdfcst  )   THEN                            ! Constant Kz (reset avt, avm[uv] to the background value)
125         avt (:,:,:) = rn_avt0 * tmask(:,:,:)
126         avmu(:,:,:) = rn_avm0 * umask(:,:,:)
127         avmv(:,:,:) = rn_avm0 * vmask(:,:,:)
128      ENDIF
129      IF( ln_rnf_mouth ) THEN                         ! increase diffusivity at rivers mouths
130         DO jk = 2, nkrnf   ;   avt(:,:,jk) = avt(:,:,jk) + 2.e0 * rn_avt_rnf * rnfmsk(:,:) * tmask(:,:,jk)   ;   END DO
131      ENDIF
132      IF( ln_zdfevd  )   CALL zdf_evd( kstp )         ! enhanced vertical eddy diffusivity
133
134      IF( lk_zdftmx  )   CALL zdf_tmx( kstp )         ! tidal vertical mixing
135
136      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
137         &               CALL zdf_ddm( kstp )         ! double diffusive mixing
138
139                         CALL zdf_mxl( kstp )         ! mixed layer depth
140
141                                                      ! write TKE or GLS information in the restart file
142      IF( lrst_oce .AND. lk_zdftke )   CALL tke_rst( kstp, 'WRITE' )
143      IF( lrst_oce .AND. lk_zdfgls )   CALL gls_rst( kstp, 'WRITE' )
144      !
145      !  LATERAL  PHYSICS
146      !
147      IF( lk_ldfslp ) THEN                            ! slope of lateral mixing
148                         CALL eos( tsb, rhd )                ! before in situ density
149         IF( ln_zps )    CALL zps_hde( kstp, jpts, tsb, gtsu, gtsv,  &    ! Partial steps: before horizontal gradient
150            &                                      rhd, gru , grv  )      ! of t, s, rd at the last ocean level
151         IF( ln_traldf_grif ) THEN                           ! before slope for Griffies operator
152                         CALL ldf_slp_grif( kstp )
153         ELSE
154                         CALL ldf_slp( kstp, rhd, rn2b )     ! before slope for Madec operator
155         ENDIF
156      ENDIF
157#if defined key_traldf_c2d
158      IF( lk_traldf_eiv )   CALL ldf_eiv( kstp )      ! eddy induced velocity coefficient
159#endif
160#if defined key_traldf_c3d && key_traldf_smag
161                          CALL ldf_tra_smag( kstp )      ! eddy induced velocity coefficient
162#  endif
163#if defined key_dynldf_c3d && key_dynldf_smag
164                          CALL ldf_dyn_smag( kstp )      ! eddy induced velocity coefficient
165#  endif
166
167
168      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
169      ! diagnostics and outputs             (ua, va, tsa used as workspace)
170      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
171      IF( lk_floats  )   CALL flo_stp( kstp )         ! drifting Floats
172      IF( lk_diahth  )   CALL dia_hth( kstp )         ! Thermocline depth (20 degres isotherm depth)
173      IF( lk_diafwb  )   CALL dia_fwb( kstp )         ! Fresh water budget diagnostics
174      IF( ln_diaptr  )   CALL dia_ptr( kstp )         ! Poleward TRansports diagnostics
175      IF( lk_diadct  )   CALL dia_dct( kstp )         ! Transports
176      IF( lk_diaar5  )   CALL dia_ar5( kstp )         ! ar5 diag
177      IF( lk_diaharm )   CALL dia_harm( kstp )        ! Tidal harmonic analysis
178                         CALL dia_wri( kstp )         ! ocean model: outputs
179      !
180      IF( ln_crs     )   CALL crs_fld( kstp )         ! ocean model: online field coarsening & output
181
182
183#if defined key_top
184      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
185      ! Passive Tracer Model
186      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
187                         CALL trc_stp( kstp )         ! time-stepping
188#endif
189
190      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
191      ! Active tracers                              (ua, va used as workspace)
192      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
193                             tsa(:,:,:,:) = 0.e0            ! set tracer trends to zero
194
195!write(numout,*) "MAV kt",kstp
196!write(numout,'(a5,3(1x,f21.18))') "INIn:",tsn(24,11,1,jp_tem),tsn(24,11,1,jp_sal),sshn(24,11)
197!write(numout,'(a5,3(1x,f21.18))') "INIa:",tsa(24,11,1,jp_tem),tsa(24,11,1,jp_sal),ssha(24,11)
198      IF(  ln_asmiau .AND. &
199         & ln_trainc     )   CALL tra_asm_inc( kstp )       ! apply tracer assimilation increment
200                             CALL tra_sbc    ( kstp )       ! surface boundary condition
201      IF( ln_traqsr      )   CALL tra_qsr    ( kstp )       ! penetrative solar radiation qsr
202      IF( ln_trabbc      )   CALL tra_bbc    ( kstp )       ! bottom heat flux
203      IF( lk_trabbl      )   CALL tra_bbl    ( kstp )       ! advective (and/or diffusive) bottom boundary layer scheme
204      IF( ln_tradmp      )   CALL tra_dmp    ( kstp )       ! internal damping trends
205      IF( lk_bdy         )   CALL bdy_tra_dmp( kstp )       ! bdy damping trends
206                             CALL tra_adv    ( kstp )       ! horizontal & vertical advection
207!write(numout,'(a5,3(1x,f21.18))') "ADVn:",tsn(24,11,1,jp_tem),tsn(24,11,1,jp_sal),sshn(24,11)
208!write(numout,'(a5,3(1x,f21.18))') "ADVa:",tsa(24,11,1,jp_tem),tsa(24,11,1,jp_sal),ssha(24,11)
209      IF( lk_zdfkpp      )   CALL tra_kpp    ( kstp )       ! KPP non-local tracer fluxes
210                             CALL tra_ldf    ( kstp )       ! lateral mixing
211!write(numout,'(a5,3(1x,f21.18))') "LDFn:",tsn(24,11,1,jp_tem),tsn(24,11,1,jp_sal),sshn(24,11)
212!write(numout,'(a5,3(1x,f21.18))') "LDFa:",tsa(24,11,1,jp_tem),tsa(24,11,1,jp_sal),ssha(24,11)
213#if defined key_agrif
214      IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_tra          ! tracers sponge
215#endif
216                             CALL tra_zdf    ( kstp )       ! vertical mixing and after tracer fields
217!do jk=1,jpk
218!write(numout,'(a5,3(1x,f21.18))') "ZDFn:",tsn(5,10,jk,jp_tem),tsn(5,10,jk,jp_sal),tmask(5,10,jk)
219!write(numout,'(a5,3(1x,f21.18))') "ZDFa:",tsa(5,10,jk,jp_tem),tsa(5,10,jk,jp_sal),ssha(5,10)
220!end do
221
222      IF( ln_dynhpg_imp  ) THEN                             ! semi-implicit hpg (time stepping then eos)
223         IF( ln_zdfnpc   )   CALL tra_npc( kstp )                ! update after fields by non-penetrative convection
224                             CALL tra_nxt( kstp )                ! tracer fields at next time step
225                             CALL eos    ( tsa, rhd, rhop )      ! Time-filtered in situ density for hpg computation
226         IF( ln_zps      )   CALL zps_hde( kstp, jpts, tsa, gtsu, gtsv,  &    ! zps: time filtered hor. derivative
227            &                                          rhd, gru , grv  )      ! of t, s, rd at the last ocean level
228
229      ELSE                                                  ! centered hpg  (eos then time stepping)
230                             CALL eos    ( tsn, rhd, rhop )      ! now in situ density for hpg computation
231         IF( ln_zps      )   CALL zps_hde( kstp, jpts, tsn, gtsu, gtsv,  &    ! zps: now hor. derivative
232            &                                          rhd, gru , grv  )      ! of t, s, rd at the last ocean level
233!write(numout,'(a5,3(1x,f21.18))') "ZPSn:",tsn(24,11,1,jp_tem),tsn(24,11,1,jp_sal),sshn(24,11)
234!write(numout,'(a5,3(1x,f21.18))') "ZPSa:",tsa(24,11,1,jp_tem),tsa(24,11,1,jp_sal),ssha(24,11)
235         IF( ln_zdfnpc   )   CALL tra_npc( kstp )                ! update after fields by non-penetrative convection
236                             CALL tra_nxt( kstp )                ! tracer fields at next time step
237!write(numout,'(a5,3(1x,f21.18))') "NXTn:",tsn(24,11,1,jp_tem),tsn(24,11,1,jp_sal),sshn(25,11)
238!write(numout,'(a5,3(1x,f21.18))') "NXTa:",tsa(24,11,1,jp_tem),tsa(24,11,1,jp_sal),ssha(24,11)
239      ENDIF
240
241      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
242      ! Dynamics                                    (tsa used as workspace)
243      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
244                               ua(:,:,:) = 0.e0             ! set dynamics trends to zero
245                               va(:,:,:) = 0.e0
246
247      IF(  ln_asmiau .AND. &
248         & ln_dyninc       )   CALL dyn_asm_inc( kstp )     ! apply dynamics assimilation increment
249      IF( ln_bkgwri )          CALL asm_bkg_wri( kstp )     ! output background fields
250      IF( ln_neptsimp )        CALL dyn_nept_cor( kstp )    ! subtract Neptune velocities (simplified)
251      IF( lk_bdy           )   CALL bdy_dyn3d_dmp(kstp )    ! bdy damping trends
252                               CALL dyn_adv( kstp )         ! advection (vector or flux form)
253                               CALL dyn_vor( kstp )         ! vorticity term including Coriolis
254                               CALL dyn_ldf( kstp )         ! lateral mixing
255      IF( ln_neptsimp )        CALL dyn_nept_cor( kstp )    ! add Neptune velocities (simplified)
256#if defined key_agrif
257      IF(.NOT. Agrif_Root())   CALL Agrif_Sponge_dyn        ! momemtum sponge
258#endif
259                               CALL dyn_hpg( kstp )         ! horizontal gradient of Hydrostatic pressure
260                               CALL dyn_bfr( kstp )         ! bottom friction
261                               CALL dyn_zdf( kstp )         ! vertical diffusion
262                               CALL dyn_spg( kstp, indic )  ! surface pressure gradient
263                               CALL dyn_nxt( kstp )         ! lateral velocity at next time step
264
265                               CALL ssh_nxt( kstp )         ! sea surface height at next time step
266
267      IF( ln_diahsb        )   CALL dia_hsb( kstp )         ! - ML - global conservation diagnostics
268      IF( lk_diaobs  )         CALL dia_obs( kstp )         ! obs-minus-model (assimilation) diagnostics (call after dynamics update)
269
270      IF( lrst_oce .AND. ln_diahsb )   CALL dia_hsb_rst( kstp, 'WRITE' )
271      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
272      ! Control and restarts
273      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
274                               CALL stp_ctl( kstp, indic )
275      IF( indic < 0        )   THEN
276                               CALL ctl_stop( 'step: indic < 0' )
277                               CALL dia_wri_state( 'output.abort', kstp )
278      ENDIF
279      IF( kstp == nit000   )   THEN
280         CALL iom_close( numror )     ! close input  ocean restart file
281         CALL FLUSH    ( numond )     ! flush output namelist oce
282         CALL FLUSH    ( numoni )     ! flush output namelist ice   
283      ENDIF
284      IF( lrst_oce         )   CALL rst_write    ( kstp )   ! write output ocean restart file
285      IF( lk_obc           )   CALL obc_rst_write( kstp )   ! write open boundary restart file
286
287      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
288      ! Trends                              (ua, va, tsa used as workspace)
289      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
290      IF( nstop == 0 ) THEN
291         IF( lk_trddyn     )   CALL trd_dwr( kstp )         ! trends: dynamics
292         IF( lk_trdtra     )   CALL trd_twr( kstp )         ! trends: active tracers
293         IF( lk_trdmld     )   CALL trd_mld( kstp )         ! trends: Mixed-layer
294         IF( lk_trdvor     )   CALL trd_vor( kstp )         ! trends: vorticity budget
295      ENDIF
296
297      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
298      ! Coupled mode
299      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
300      IF( lk_cpl           )   CALL sbc_cpl_snd( kstp )     ! coupled mode : field exchanges
301      !
302#if defined key_iomput
303      IF( kstp == nitend .OR. indic < 0 ) THEN
304                      CALL iom_context_finalize( "nemo"     ) ! needed for XIOS+AGRIF
305         IF( ln_crs ) CALL iom_context_finalize( "nemo_crs" ) !
306      ENDIF
307#endif
308      !
309      IF( nn_timing == 1 .AND.  kstp == nit000  )   CALL timing_reset
310      !
311   END SUBROUTINE stp
312
313   !!======================================================================
314END MODULE step
Note: See TracBrowser for help on using the repository browser.