source: branches/2013/dev_MERGE_2013/NEMOGCM/NEMO/OPA_SRC/step.F90 @ 4328

Last change on this file since 4328 was 4328, checked in by davestorkey, 7 years ago

Remove OBC module at NEMO 3.6. See ticket #1189.

  • Property svn:keywords set to Id
File size: 20.6 KB
Line 
1MODULE step
2   !!======================================================================
3   !!                       ***  MODULE step  ***
4   !! Time-stepping    : manager of the ocean, tracer and ice time stepping
5   !!======================================================================
6   !! History :  OPA  !  1991-03  (G. Madec)  Original code
7   !!             -   !  1991-11  (G. Madec)
8   !!             -   !  1992-06  (M. Imbard)  add a first output record
9   !!             -   !  1996-04  (G. Madec)  introduction of dynspg
10   !!             -   !  1996-04  (M.A. Foujols)  introduction of passive tracer
11   !!            8.0  !  1997-06  (G. Madec)  new architecture of call
12   !!            8.2  !  1997-06  (G. Madec, M. Imbard, G. Roullet)  free surface
13   !!             -   !  1999-02  (G. Madec, N. Grima)  hpg implicit
14   !!             -   !  2000-07  (J-M Molines, M. Imbard)  Open Bondary Conditions
15   !!   NEMO     1.0  !  2002-06  (G. Madec)  free form, suppress macro-tasking
16   !!             -   !  2004-08  (C. Talandier) New trends organization
17   !!             -   !  2005-01  (C. Ethe) Add the KPP closure scheme
18   !!             -   !  2005-11  (G. Madec)  Reorganisation of tra and dyn calls
19   !!             -   !  2006-01  (L. Debreu, C. Mazauric)  Agrif implementation
20   !!             -   !  2006-07  (S. Masson)  restart using iom
21   !!            3.2  !  2009-02  (G. Madec, R. Benshila)  reintroduicing z*-coordinate
22   !!             -   !  2009-06  (S. Masson, G. Madec)  TKE restart compatible with key_cpl
23   !!            3.3  !  2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
24   !!             -   !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
25   !!            3.4  !  2011-04  (G. Madec, C. Ethe) Merge of dtatem and dtasal
26   !!                 !  2012-07  (J. Simeon, G. Madec. C. Ethe) Online coarsening of outputs
27   !!----------------------------------------------------------------------
28
29   !!----------------------------------------------------------------------
30   !!   stp             : OPA system time-stepping
31   !!----------------------------------------------------------------------
32   USE step_oce         ! time stepping definition modules
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   stp   ! called by opa.F90
38
39   !! * Substitutions
40#  include "domzgr_substitute.h90"
41#  include "zdfddm_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49#if defined key_agrif
50   SUBROUTINE stp( )
51      INTEGER             ::   kstp   ! ocean time-step index
52#else
53   SUBROUTINE stp( kstp )
54      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
55#endif
56      !!----------------------------------------------------------------------
57      !!                     ***  ROUTINE stp  ***
58      !!
59      !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.)
60      !!              - Time stepping of LIM (dynamic and thermodynamic eqs.)
61      !!              - Tme stepping  of TRC (passive tracer eqs.)
62      !!
63      !! ** Method  : -1- Update forcings and data
64      !!              -2- Update ocean physics
65      !!              -3- Compute the t and s trends
66      !!              -4- Update t and s
67      !!              -5- Compute the momentum trends
68      !!              -6- Update the horizontal velocity
69      !!              -7- Compute the diagnostics variables (rd,N2, div,cur,w)
70      !!              -8- Outputs and diagnostics
71      !!----------------------------------------------------------------------
72      INTEGER ::   jk       ! dummy loop indice
73      INTEGER ::   indic    ! error indicator if < 0
74      !! ---------------------------------------------------------------------
75
76#if defined key_agrif
77      kstp = nit000 + Agrif_Nb_Step()
78!      IF ( Agrif_Root() .and. lwp) Write(*,*) '---'
79!      IF (lwp) Write(*,*) 'Grid Number',Agrif_Fixed(),' time step ',kstp
80# if defined key_iomput
81      IF( Agrif_Nbstepint() == 0 )   CALL iom_swap( "nemo" )
82# endif
83#endif
84                             indic = 0           ! reset to no error condition
85      IF( kstp == nit000 ) THEN
86                      CALL iom_init( "nemo" )      ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
87         IF( ln_crs ) CALL iom_init( "nemo_crs" )  ! initialize context for coarse grid
88      ENDIF
89
90      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
91                             CALL iom_setkt( kstp - nit000 + 1, "nemo"     )   ! say to iom that we are at time step kstp
92      IF( ln_crs     )       CALL iom_setkt( kstp - nit000 + 1, "nemo_crs" )   ! say to iom that we are at time step kstp
93
94      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
95      ! Update data, open boundaries, surface boundary condition (including sea-ice)
96      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
97      IF( lk_tide    )   CALL sbc_tide( kstp )
98      IF( lk_bdy     )   CALL bdy_dta ( kstp, time_offset=+1 )   ! update dynamic & tracer data at open boundaries
99
100                         CALL sbc    ( kstp )         ! Sea Boundary Condition (including sea-ice)
101                                                      ! clem: moved here for bdy ice purpose
102      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
103      !  Ocean dynamics : hdiv, rot, ssh, e3, wn
104      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
105                         CALL zdf_bfr( kstp )         ! bottom friction (if quadratic)
106                         CALL ssh_nxt       ( kstp )  ! after ssh (includes call to div_cur)
107      IF( lk_dynspg_ts ) THEN
108                                  CALL wzv           ( kstp )  ! now cross-level velocity
109          ! In case the time splitting case, update almost all momentum trends here:
110          ! Note that the computation of vertical velocity above, hence "after" sea level
111          ! is necessary to compute momentum advection for the rhs of barotropic loop:
112                                  CALL eos    ( tsn, rhd, rhop, fsdept_n(:,:,:) )                 ! now in situ density for hpg computation
113          IF( ln_zps      )       CALL zps_hde( kstp, jpts, tsn, gtsu, gtsv,  &  ! zps: now hor. derivative
114                &                                          rhd, gru , grv  )     ! of t, s, rd at the last ocean level
115
116                                  ua(:,:,:) = 0.e0             ! set dynamics trends to zero
117                                  va(:,:,:) = 0.e0
118          IF(  ln_asmiau .AND. &
119             & ln_dyninc       )  CALL dyn_asm_inc  ( kstp )   ! apply dynamics assimilation increment
120          IF( ln_neptsimp )       CALL dyn_nept_cor ( kstp )   ! subtract Neptune velocities (simplified)
121          IF( lk_bdy           )  CALL bdy_dyn3d_dmp( kstp )   ! bdy damping trends
122                                  CALL dyn_adv      ( kstp )   ! advection (vector or flux form)
123                                  CALL dyn_vor      ( kstp )   ! vorticity term including Coriolis
124                                  CALL dyn_ldf      ( kstp )   ! lateral mixing
125          IF( ln_neptsimp )       CALL dyn_nept_cor ( kstp )   ! add Neptune velocities (simplified)
126#if defined key_agrif
127          IF(.NOT. Agrif_Root())  CALL Agrif_Sponge_dyn        ! momentum sponge
128#endif
129                                  CALL dyn_hpg( kstp )         ! horizontal gradient of Hydrostatic pressure
130                                  CALL dyn_spg( kstp, indic )  ! surface pressure gradient
131
132                                  ua_sv(:,:,:) = ua(:,:,:)     ! Save trends (barotropic trend has been fully updated at this stage)
133                                  va_sv(:,:,:) = va(:,:,:)
134
135                                  CALL div_cur( kstp )         ! Horizontal divergence & Relative vorticity (2nd call in time-split case)
136      ENDIF
137      IF( lk_vvl     )   CALL dom_vvl_sf_nxt( kstp )  ! after vertical scale factors
138                         CALL wzv           ( kstp )  ! now cross-level velocity
139
140      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
141      ! Ocean physics update                (ua, va, tsa used as workspace)
142      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
143                         CALL bn2( tsb, rn2b )        ! before Brunt-Vaisala frequency
144                         CALL bn2( tsn, rn2  )        ! now    Brunt-Vaisala frequency
145      !
146      !  VERTICAL PHYSICS
147      !                                               ! Vertical eddy viscosity and diffusivity coefficients
148      IF( lk_zdfric  )   CALL zdf_ric( kstp )            ! Richardson number dependent Kz
149      IF( lk_zdftke  )   CALL zdf_tke( kstp )            ! TKE closure scheme for Kz
150      IF( lk_zdfgls  )   CALL zdf_gls( kstp )            ! GLS closure scheme for Kz
151      IF( lk_zdfkpp  )   CALL zdf_kpp( kstp )            ! KPP closure scheme for Kz
152      IF( lk_zdfcst  ) THEN                              ! Constant Kz (reset avt, avm[uv] to the background value)
153         avt (:,:,:) = rn_avt0 * tmask(:,:,:)
154         avmu(:,:,:) = rn_avm0 * umask(:,:,:)
155         avmv(:,:,:) = rn_avm0 * vmask(:,:,:)
156      ENDIF
157      IF( ln_rnf_mouth ) THEN                         ! increase diffusivity at rivers mouths
158         DO jk = 2, nkrnf   ;   avt(:,:,jk) = avt(:,:,jk) + 2.e0 * rn_avt_rnf * rnfmsk(:,:) * tmask(:,:,jk)   ;   END DO
159      ENDIF
160      IF( ln_zdfevd  )   CALL zdf_evd( kstp )         ! enhanced vertical eddy diffusivity
161
162      IF( lk_zdftmx  )   CALL zdf_tmx( kstp )         ! tidal vertical mixing
163
164      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
165         &               CALL zdf_ddm( kstp )         ! double diffusive mixing
166
167                         CALL zdf_mxl( kstp )         ! mixed layer depth
168
169                                                      ! write TKE or GLS information in the restart file
170      IF( lrst_oce .AND. lk_zdftke )   CALL tke_rst( kstp, 'WRITE' )
171      IF( lrst_oce .AND. lk_zdfgls )   CALL gls_rst( kstp, 'WRITE' )
172      !
173      !  LATERAL  PHYSICS
174      !
175      IF( lk_ldfslp ) THEN                            ! slope of lateral mixing
176                         CALL eos( tsb, rhd, gdept_0(:,:,:) )             ! before in situ density
177         IF( ln_zps )    CALL zps_hde( kstp, jpts, tsb, gtsu, gtsv,  &    ! Partial steps: before horizontal gradient
178            &                                      rhd, gru , grv  )      ! of t, s, rd at the last ocean level
179         IF( ln_traldf_grif ) THEN                           ! before slope for Griffies operator
180                         CALL ldf_slp_grif( kstp )
181         ELSE
182                         CALL ldf_slp( kstp, rhd, rn2b )     ! before slope for Madec operator
183         ENDIF
184      ENDIF
185#if defined key_traldf_c2d
186      IF( lk_traldf_eiv )   CALL ldf_eiv( kstp )      ! eddy induced velocity coefficient
187#endif
188#if defined key_traldf_c3d && key_traldf_smag
189                          CALL ldf_tra_smag( kstp )      ! eddy induced velocity coefficient
190#  endif
191#if defined key_dynldf_c3d && key_dynldf_smag
192                          CALL ldf_dyn_smag( kstp )      ! eddy induced velocity coefficient
193#  endif
194
195
196      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
197      ! diagnostics and outputs             (ua, va, tsa used as workspace)
198      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
199      IF( lk_floats  )   CALL flo_stp( kstp )         ! drifting Floats
200      IF( lk_diahth  )   CALL dia_hth( kstp )         ! Thermocline depth (20 degres isotherm depth)
201      IF( lk_diafwb  )   CALL dia_fwb( kstp )         ! Fresh water budget diagnostics
202      IF( ln_diaptr  )   CALL dia_ptr( kstp )         ! Poleward TRansports diagnostics
203      IF( lk_diadct  )   CALL dia_dct( kstp )         ! Transports
204      IF( lk_diaar5  )   CALL dia_ar5( kstp )         ! ar5 diag
205      IF( lk_diaharm )   CALL dia_harm( kstp )        ! Tidal harmonic analysis
206                         CALL dia_wri( kstp )         ! ocean model: outputs
207      !
208      IF( ln_crs     )   CALL crs_fld( kstp )         ! ocean model: online field coarsening & output
209
210
211#if defined key_top
212      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
213      ! Passive Tracer Model
214      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
215                         CALL trc_stp( kstp )         ! time-stepping
216#endif
217
218      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
219      ! Active tracers                              (ua, va used as workspace)
220      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
221                             tsa(:,:,:,:) = 0.e0            ! set tracer trends to zero
222
223      IF(  ln_asmiau .AND. &
224         & ln_trainc     )   CALL tra_asm_inc( kstp )       ! apply tracer assimilation increment
225                             CALL tra_sbc    ( kstp )       ! surface boundary condition
226      IF( ln_traqsr      )   CALL tra_qsr    ( kstp )       ! penetrative solar radiation qsr
227      IF( ln_trabbc      )   CALL tra_bbc    ( kstp )       ! bottom heat flux
228      IF( lk_trabbl      )   CALL tra_bbl    ( kstp )       ! advective (and/or diffusive) bottom boundary layer scheme
229      IF( ln_tradmp      )   CALL tra_dmp    ( kstp )       ! internal damping trends
230      IF( lk_bdy         )   CALL bdy_tra_dmp( kstp )       ! bdy damping trends
231                             CALL tra_adv    ( kstp )       ! horizontal & vertical advection
232      IF( lk_zdfkpp      )   CALL tra_kpp    ( kstp )       ! KPP non-local tracer fluxes
233                             CALL tra_ldf    ( kstp )       ! lateral mixing
234#if defined key_agrif
235      IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_tra          ! tracers sponge
236#endif
237                             CALL tra_zdf    ( kstp )       ! vertical mixing and after tracer fields
238
239      IF( ln_dynhpg_imp  ) THEN                             ! semi-implicit hpg (time stepping then eos)
240         IF( ln_zdfnpc   )   CALL tra_npc( kstp )                ! update after fields by non-penetrative convection
241                             CALL tra_nxt( kstp )                ! tracer fields at next time step
242                             CALL eos    ( tsa, rhd, rhop, fsdept_n(:,:,:) )  ! Time-filtered in situ density for hpg computation
243         IF( ln_zps      )   CALL zps_hde( kstp, jpts, tsa, gtsu, gtsv,  &    ! zps: time filtered hor. derivative
244            &                                          rhd, gru , grv  )      ! of t, s, rd at the last ocean level
245
246      ELSE                                                  ! centered hpg  (eos then time stepping)
247         IF ( .NOT. lk_dynspg_ts ) THEN                     ! eos already called in time-split case
248                                CALL eos    ( tsn, rhd, rhop, fsdept_n(:,:,:) )  ! now in situ density for hpg computation
249            IF( ln_zps      )   CALL zps_hde( kstp, jpts, tsn, gtsu, gtsv,  &    ! zps: now hor. derivative
250            &                                          rhd, gru , grv  )      ! of t, s, rd at the last ocean level
251         ENDIF
252         IF( ln_zdfnpc   )   CALL tra_npc( kstp )                ! update after fields by non-penetrative convection
253                             CALL tra_nxt( kstp )                ! tracer fields at next time step
254      ENDIF
255
256      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
257      ! Dynamics                                    (tsa used as workspace)
258      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
259      IF( lk_dynspg_ts   )  THEN
260                                                             ! revert to previously computed momentum tendencies
261                                                             ! (not using ua, va as temporary arrays during tracers' update could avoid that)
262                               ua(:,:,:) = ua_sv(:,:,:)
263                               va(:,:,:) = va_sv(:,:,:)
264                                                             ! Revert now divergence and rotational to previously computed ones
265                                                             !(needed because of the time swap in div_cur, at the beginning of each time step)
266                               hdivn(:,:,:) = hdivb(:,:,:)
267                               rotn(:,:,:)  = rotb(:,:,:) 
268
269                               CALL dyn_bfr( kstp )         ! bottom friction
270                               CALL dyn_zdf( kstp )         ! vertical diffusion
271      ELSE
272                               ua(:,:,:) = 0.e0             ! set dynamics trends to zero
273                               va(:,:,:) = 0.e0
274
275        IF(  ln_asmiau .AND. &
276           & ln_dyninc      )  CALL dyn_asm_inc( kstp )     ! apply dynamics assimilation increment
277        IF( ln_bkgwri )        CALL asm_bkg_wri( kstp )     ! output background fields
278        IF( ln_neptsimp )      CALL dyn_nept_cor( kstp )    ! subtract Neptune velocities (simplified)
279        IF( lk_bdy          )  CALL bdy_dyn3d_dmp(kstp )    ! bdy damping trends
280                               CALL dyn_adv( kstp )         ! advection (vector or flux form)
281                               CALL dyn_vor( kstp )         ! vorticity term including Coriolis
282                               CALL dyn_ldf( kstp )         ! lateral mixing
283        IF( ln_neptsimp )      CALL dyn_nept_cor( kstp )    ! add Neptune velocities (simplified)
284#if defined key_agrif
285        IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_dyn        ! momemtum sponge
286#endif
287                               CALL dyn_hpg( kstp )         ! horizontal gradient of Hydrostatic pressure
288                               CALL dyn_bfr( kstp )         ! bottom friction
289                               CALL dyn_zdf( kstp )         ! vertical diffusion
290                               CALL dyn_spg( kstp, indic )  ! surface pressure gradient
291      ENDIF
292                               CALL dyn_nxt( kstp )         ! lateral velocity at next time step
293
294                               CALL ssh_swp( kstp )         ! swap of sea surface height
295      IF( lk_vvl           )   CALL dom_vvl_sf_swp( kstp )  ! swap of vertical scale factors
296
297      IF( ln_diahsb        )   CALL dia_hsb( kstp )         ! - ML - global conservation diagnostics
298      IF( lk_diaobs  )         CALL dia_obs( kstp )         ! obs-minus-model (assimilation) diagnostics (call after dynamics update)
299
300      IF( lrst_oce .AND. ln_diahsb )   CALL dia_hsb_rst( kstp, 'WRITE' )
301      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
302      ! Control and restarts
303      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
304                               CALL stp_ctl( kstp, indic )
305      IF( indic < 0        )   THEN
306                               CALL ctl_stop( 'step: indic < 0' )
307                               CALL dia_wri_state( 'output.abort', kstp )
308      ENDIF
309      IF( kstp == nit000   )   THEN
310         CALL iom_close( numror )     ! close input  ocean restart file
311         CALL FLUSH    ( numond )     ! flush output namelist oce
312         CALL FLUSH    ( numoni )     ! flush output namelist ice   
313      ENDIF
314      IF( lrst_oce         )   CALL rst_write    ( kstp )   ! write output ocean restart file
315
316      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
317      ! Trends                              (ua, va, tsa used as workspace)
318      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
319      IF( nstop == 0 ) THEN
320         IF( lk_trddyn     )   CALL trd_dwr( kstp )         ! trends: dynamics
321         IF( lk_trdtra     )   CALL trd_twr( kstp )         ! trends: active tracers
322         IF( lk_trdmld     )   CALL trd_mld( kstp )         ! trends: Mixed-layer
323         IF( lk_trdvor     )   CALL trd_vor( kstp )         ! trends: vorticity budget
324      ENDIF
325
326      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
327      ! Coupled mode
328      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
329      IF( lk_cpl           )   CALL sbc_cpl_snd( kstp )     ! coupled mode : field exchanges
330      !
331#if defined key_iomput
332      IF( kstp == nitend .OR. indic < 0 ) THEN
333                      CALL iom_context_finalize( "nemo"     ) ! needed for XIOS+AGRIF
334         IF( ln_crs ) CALL iom_context_finalize( "nemo_crs" ) !
335      ENDIF
336#endif
337      !
338      IF( nn_timing == 1 .AND.  kstp == nit000  )   CALL timing_reset
339      !
340   END SUBROUTINE stp
341
342   !!======================================================================
343END MODULE step
Note: See TracBrowser for help on using the repository browser.