New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limitd_th.F90 in branches/2013/dev_r3406_CNRS_LIM3/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2013/dev_r3406_CNRS_LIM3/NEMOGCM/NEMO/LIM_SRC_3/limitd_th.F90 @ 3938

Last change on this file since 3938 was 3938, checked in by flavoni, 11 years ago

dev_r3406_CNRS_LIM3: update LIM3, see ticket #1116
  • Property svn:keywords set to Id
File size: 48.8 KB
Line 
1MODULE limitd_th
2   !!======================================================================
3   !!                       ***  MODULE limitd_th ***
4   !!              Thermodynamics of ice thickness distribution
5   !!                   computation of changes in g(h)     
6   !!======================================================================
7   !! History :   -   !          (W. H. Lipscomb and E.C. Hunke) CICE (c) original code
8   !!            3.0  ! 2005-12  (M. Vancoppenolle) adaptation to LIM-3
9   !!             -   ! 2006-06  (M. Vancoppenolle) adaptation to include salt, age and types
10   !!             -   ! 2007-04  (M. Vancoppenolle) Mass conservation checked
11   !!----------------------------------------------------------------------
12#if defined key_lim3
13   !!----------------------------------------------------------------------
14   !!   'key_lim3' :                                   LIM3 sea-ice model
15   !!----------------------------------------------------------------------
16   !!   lim_itd_th       : thermodynamics of ice thickness distribution
17   !!   lim_itd_th_rem   :
18   !!   lim_itd_th_reb   :
19   !!   lim_itd_fitline  :
20   !!   lim_itd_shiftice :
21   !!----------------------------------------------------------------------
22   USE dom_ice          ! LIM-3 domain
23   USE par_oce          ! ocean parameters
24   USE dom_oce          ! ocean domain
25   USE phycst           ! physical constants (ocean directory)
26   USE thd_ice          ! LIM-3 thermodynamic variables
27   USE ice              ! LIM-3 variables
28   USE par_ice          ! LIM-3 parameters
29   USE limthd_lac       ! LIM-3 lateral accretion
30   USE limvar           ! LIM-3 variables
31   USE limcons          ! LIM-3 conservation
32   USE prtctl           ! Print control
33   USE in_out_manager   ! I/O manager
34   USE lib_mpp          ! MPP library
35   USE wrk_nemo         ! work arrays
36   USE lib_fortran      ! to use key_nosignedzero
37
38   IMPLICIT NONE
39   PRIVATE
40
41   PUBLIC   lim_itd_th         ! called by ice_stp
42   PUBLIC   lim_itd_th_rem
43   PUBLIC   lim_itd_th_reb
44   PUBLIC   lim_itd_fitline
45   PUBLIC   lim_itd_shiftice
46
47   REAL(wp) ::   epsi20 = 1.e-20_wp   ! constant values
48   REAL(wp) ::   epsi13 = 1.e-13_wp   !
49   REAL(wp) ::   epsi10 = 1.e-10_wp   !
50
51   !!----------------------------------------------------------------------
52   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2010)
53   !! $Id$
54   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
55   !!----------------------------------------------------------------------
56CONTAINS
57
58   SUBROUTINE lim_itd_th( kt )
59      !!------------------------------------------------------------------
60      !!                ***  ROUTINE lim_itd_th ***
61      !!
62      !! ** Purpose :   computes the thermodynamics of ice thickness distribution
63      !!
64      !! ** Method  :
65      !!------------------------------------------------------------------
66      INTEGER, INTENT(in) ::   kt   ! time step index
67      !
68      INTEGER ::   jl, ja, jm, jbnd1, jbnd2   ! ice types    dummy loop index         
69      REAL(wp) :: zchk_v_i, zchk_smv, zchk_fs, zchk_fw, zchk_v_i_b, zchk_smv_b, zchk_fs_b, zchk_fw_b ! Check conservation (C Rousset)
70      !!------------------------------------------------------------------
71      ! -------------------------------
72      !- check conservation (C Rousset)
73      IF (ln_limdiahsb) THEN
74         zchk_v_i_b = glob_sum( SUM(   v_i(:,:,:), dim=3 ) * area(:,:) * tms(:,:) )
75         zchk_smv_b = glob_sum( SUM( smv_i(:,:,:), dim=3 ) * area(:,:) * tms(:,:) )
76         zchk_fw_b  = glob_sum( rdmicif(:,:) * area(:,:) * tms(:,:) )
77         zchk_fs_b  = glob_sum( ( fsbri(:,:) + fseqv(:,:) + fsalt_res(:,:) + fsalt_rpo(:,:) ) * area(:,:) * tms(:,:) )
78      ENDIF
79      !- check conservation (C Rousset)
80      ! -------------------------------
81
82      IF( kt == nit000 .AND. lwp ) THEN
83         WRITE(numout,*)
84         WRITE(numout,*) 'lim_itd_th  : Thermodynamics of the ice thickness distribution'
85         WRITE(numout,*) '~~~~~~~~~~~'
86      ENDIF
87
88      !------------------------------------------------------------------------------|
89      !  1) Transport of ice between thickness categories.                           |
90      !------------------------------------------------------------------------------|
91      ! Given thermodynamic growth rates, transport ice between
92      ! thickness categories.
93      DO jm = 1, jpm
94         jbnd1 = ice_cat_bounds(jm,1)
95         jbnd2 = ice_cat_bounds(jm,2)
96         IF( ice_ncat_types(jm) > 1 )   CALL lim_itd_th_rem( jbnd1, jbnd2, jm, kt )
97      END DO
98      !
99      CALL lim_var_glo2eqv    ! only for info
100      CALL lim_var_agg(1)
101
102      !------------------------------------------------------------------------------|
103      !  3) Add frazil ice growing in leads.
104      !------------------------------------------------------------------------------|
105
106      CALL lim_thd_lac
107      CALL lim_var_glo2eqv    ! only for info
108
109      !----------------------------------------------------------------------------------------
110      !  4) Computation of trend terms and get back to old values     
111      !----------------------------------------------------------------------------------------
112
113      !- Trend terms
114      d_a_i_thd (:,:,:)  = a_i(:,:,:)   - old_a_i(:,:,:) 
115      d_v_s_thd (:,:,:)  = v_s(:,:,:)   - old_v_s(:,:,:)
116      d_v_i_thd (:,:,:)  = v_i(:,:,:)   - old_v_i(:,:,:) 
117      d_e_s_thd(:,:,:,:) = e_s(:,:,:,:) - old_e_s(:,:,:,:) 
118      d_e_i_thd(:,:,:,:) = e_i(:,:,:,:) - old_e_i(:,:,:,:)
119      !?? d_oa_i_thd(:,:,:)  = oa_i (:,:,:) - old_oa_i (:,:,:)
120      d_smv_i_thd(:,:,:) = 0._wp
121      IF( num_sal == 2 .OR. num_sal == 4 )   d_smv_i_thd(:,:,:) = smv_i(:,:,:) - old_smv_i(:,:,:)
122
123      ! diag only (clem)
124      dv_dt_thd(:,:,:) = d_v_i_thd(:,:,:) / rdt_ice * 86400.0
125
126      IF(ln_ctl) THEN   ! Control print
127         CALL prt_ctl_info(' ')
128         CALL prt_ctl_info(' - Cell values : ')
129         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
130         CALL prt_ctl(tab2d_1=area , clinfo1=' lim_itd_th  : cell area :')
131         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_itd_th  : at_i      :')
132         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_itd_th  : vt_i      :')
133         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_itd_th  : vt_s      :')
134         DO jl = 1, jpl
135            CALL prt_ctl_info(' ')
136            CALL prt_ctl_info(' - Category : ', ivar1=jl)
137            CALL prt_ctl_info('   ~~~~~~~~~~')
138            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : a_i      : ')
139            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_i     : ')
140            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_s     : ')
141            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_i      : ')
142            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_s      : ')
143            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : e_s      : ')
144            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_itd_th  : t_su     : ')
145            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : t_snow   : ')
146            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : sm_i     : ')
147            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_itd_th  : smv_i    : ')
148            DO ja = 1, nlay_i
149               CALL prt_ctl_info(' ')
150               CALL prt_ctl_info(' - Layer : ', ivar1=ja)
151               CALL prt_ctl_info('   ~~~~~~~')
152               CALL prt_ctl(tab2d_1=t_i(:,:,ja,jl) , clinfo1= ' lim_itd_th  : t_i      : ')
153               CALL prt_ctl(tab2d_1=e_i(:,:,ja,jl) , clinfo1= ' lim_itd_th  : e_i      : ')
154            END DO
155         END DO
156      ENDIF
157      !
158      ! -------------------------------
159      !- check conservation (C Rousset)
160      IF (ln_limdiahsb) THEN
161         zchk_fs  = glob_sum( ( fsbri(:,:) + fseqv(:,:) + fsalt_res(:,:) + fsalt_rpo(:,:) ) * area(:,:) * tms(:,:) ) - zchk_fs_b
162         zchk_fw  = glob_sum( rdmicif(:,:) * area(:,:) * tms(:,:) ) - zchk_fw_b
163 
164         zchk_v_i = ( glob_sum( SUM(   v_i(:,:,:), dim=3 ) * area(:,:) * tms(:,:) ) - zchk_v_i_b - ( zchk_fw / rhoic ) ) / rdt_ice
165         zchk_smv = ( glob_sum( SUM( smv_i(:,:,:), dim=3 ) * area(:,:) * tms(:,:) ) - zchk_smv_b ) / rdt_ice + ( zchk_fs / rhoic )
166
167         IF(lwp) THEN
168            IF (    ABS( zchk_v_i   ) >  1.e-5 ) WRITE(numout,*) 'violation volume [m3/day]     (limitd_th) = ',(zchk_v_i * 86400.)
169            IF (    ABS( zchk_smv   ) >  1.e-4 ) WRITE(numout,*) 'violation saline [psu*m3/day] (limitd_th) = ',(zchk_smv * 86400.)
170            IF ( MINVAL( v_i(:,:,:) ) <  0.    ) WRITE(numout,*) 'violation v_i<0  [mm]         (limitd_th) = ',(MINVAL(v_i) * 1.e-3)
171            IF ( MAXVAL( SUM(a_i(:,:,:),dim=3) ) >  amax+epsi10 ) WRITE(numout,*) 'violation a_i>amax    (limitd_th) = ',MAXVAL(SUM(a_i,dim=3))
172         ENDIF
173       ENDIF
174      !- check conservation (C Rousset)
175      ! -------------------------------
176      !
177      !- Recover Old values
178      a_i(:,:,:)   = old_a_i (:,:,:)
179      v_s(:,:,:)   = old_v_s (:,:,:)
180      v_i(:,:,:)   = old_v_i (:,:,:)
181      e_s(:,:,:,:) = old_e_s (:,:,:,:)
182      e_i(:,:,:,:) = old_e_i (:,:,:,:)
183      !?? oa_i(:,:,:)  = old_oa_i(:,:,:)
184      IF( num_sal == 2 .OR. num_sal == 4 )   smv_i(:,:,:)       = old_smv_i (:,:,:)
185      !
186   END SUBROUTINE lim_itd_th
187   !
188
189   SUBROUTINE lim_itd_th_rem( klbnd, kubnd, ntyp, kt )
190      !!------------------------------------------------------------------
191      !!                ***  ROUTINE lim_itd_th_rem ***
192      !!
193      !! ** Purpose :   computes the redistribution of ice thickness
194      !!              after thermodynamic growth of ice thickness
195      !!
196      !! ** Method  : Linear remapping
197      !!
198      !! References : W.H. Lipscomb, JGR 2001
199      !!------------------------------------------------------------------
200      INTEGER , INTENT (in) ::   klbnd   ! Start thickness category index point
201      INTEGER , INTENT (in) ::   kubnd   ! End point on which the  the computation is applied
202      INTEGER , INTENT (in) ::   ntyp    ! Number of the type used
203      INTEGER , INTENT (in) ::   kt      ! Ocean time step
204      !
205      INTEGER  ::   ji, jj, jl     ! dummy loop index
206      INTEGER  ::   zji, zjj, nd   ! local integer
207      REAL(wp) ::   zx1, zwk1, zdh0, zetamin, zdamax   ! local scalars
208      REAL(wp) ::   zx2, zwk2, zda0, zetamax, zhimin   !   -      -
209      REAL(wp) ::   zx3,             zareamin, zindb   !   -      -
210      CHARACTER (len = 15) :: fieldid
211
212      INTEGER , POINTER, DIMENSION(:,:,:) ::   zdonor   ! donor category index
213
214      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdhice      ! ice thickness increment
215      REAL(wp), POINTER, DIMENSION(:,:,:) ::   g0          ! coefficients for fitting the line of the ITD
216      REAL(wp), POINTER, DIMENSION(:,:,:) ::   g1          ! coefficients for fitting the line of the ITD
217      REAL(wp), POINTER, DIMENSION(:,:,:) ::   hL          ! left boundary for the ITD for each thickness
218      REAL(wp), POINTER, DIMENSION(:,:,:) ::   hR          ! left boundary for the ITD for each thickness
219      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zht_i_o     ! old ice thickness
220      REAL(wp), POINTER, DIMENSION(:,:,:) ::   dummy_es
221      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdaice, zdvice          ! local increment of ice area and volume
222      REAL(wp), POINTER, DIMENSION(:)     ::   zvetamin, zvetamax      ! maximum values for etas
223      INTEGER , POINTER, DIMENSION(:)     ::   nind_i, nind_j          ! compressed indices for i/j directions
224      INTEGER                             ::   nbrem                   ! number of cells with ice to transfer
225      REAL(wp)                            ::   zslope                  ! used to compute local thermodynamic "speeds"
226      REAL(wp), POINTER, DIMENSION(:,:)   ::   zhb0, zhb1              ! category boundaries for thinnes categories
227      REAL(wp), POINTER, DIMENSION(:,:)   ::   vt_i_init, vt_i_final   !  ice volume summed over categories
228      REAL(wp), POINTER, DIMENSION(:,:)   ::   vt_s_init, vt_s_final   !  snow volume summed over categories
229      REAL(wp), POINTER, DIMENSION(:,:)   ::   et_i_init, et_i_final   !  ice energy summed over categories
230      REAL(wp), POINTER, DIMENSION(:,:)   ::   et_s_init, et_s_final   !  snow energy summed over categories
231      INTEGER , POINTER, DIMENSION(:,:)   ::   zremap_flag      ! compute remapping or not ????
232      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhbnew           ! new boundaries of ice categories
233      !!------------------------------------------------------------------
234
235      CALL wrk_alloc( jpi,jpj, zremap_flag )    ! integer
236      CALL wrk_alloc( jpi,jpj,jpl-1, zdonor )   ! integer
237      CALL wrk_alloc( jpi,jpj,jpl, zdhice, g0, g1, hL, hR, zht_i_o, dummy_es )
238      CALL wrk_alloc( jpi,jpj,jpl-1, zdaice, zdvice )   
239      CALL wrk_alloc( jpi,jpj,jpl+1, zhbnew, kkstart = 0 )   
240      CALL wrk_alloc( (jpi+1)*(jpj+1), zvetamin, zvetamax )   
241      CALL wrk_alloc( (jpi+1)*(jpj+1), nind_i, nind_j )   ! integer
242      CALL wrk_alloc( jpi,jpj, zhb0,zhb1,vt_i_init,vt_i_final,vt_s_init,vt_s_final,et_i_init,et_i_final,et_s_init,et_s_final )
243
244      zhimin   = 0.1      !minimum ice thickness tolerated by the model
245      zareamin = epsi10   !minimum area in thickness categories tolerated by the conceptors of the model
246
247      !!----------------------------------------------------------------------------------------------
248      !! 0) Conservation checkand changes in each ice category
249      !!----------------------------------------------------------------------------------------------
250      IF( con_i ) THEN
251         CALL lim_column_sum (jpl,   v_i, vt_i_init)
252         CALL lim_column_sum (jpl,   v_s, vt_s_init)
253         CALL lim_column_sum_energy (jpl, nlay_i,   e_i, et_i_init)
254         dummy_es(:,:,:) = e_s(:,:,1,:)
255         CALL lim_column_sum (jpl, dummy_es(:,:,:) , et_s_init)
256      ENDIF
257
258      !!----------------------------------------------------------------------------------------------
259      !! 1) Compute thickness and changes in each ice category
260      !!----------------------------------------------------------------------------------------------
261      IF( kt == nit000 .AND. lwp) THEN
262         WRITE(numout,*)
263         WRITE(numout,*) 'lim_itd_th_rem  : Remapping the ice thickness distribution'
264         WRITE(numout,*) '~~~~~~~~~~~~~~~'
265         WRITE(numout,*) ' klbnd :       ', klbnd
266         WRITE(numout,*) ' kubnd :       ', kubnd
267         WRITE(numout,*) ' ntyp  :       ', ntyp 
268      ENDIF
269
270      zdhice(:,:,:) = 0._wp
271      DO jl = klbnd, kubnd
272         DO jj = 1, jpj
273            DO ji = 1, jpi
274               zindb             = 1.0-MAX(0.0,SIGN(1.0,-a_i(ji,jj,jl)+epsi10))     !0 if no ice and 1 if yes
275               ht_i(ji,jj,jl)    = v_i(ji,jj,jl) / MAX(a_i(ji,jj,jl),epsi10) * zindb
276               zindb             = 1.0-MAX(0.0,SIGN(1.0,-old_a_i(ji,jj,jl)+epsi10)) !0 if no ice and 1 if yes
277               zht_i_o(ji,jj,jl) = old_v_i(ji,jj,jl) / MAX(old_a_i(ji,jj,jl),epsi10) * zindb
278               IF( a_i(ji,jj,jl) > 1e-6 )   zdhice(ji,jj,jl) = ht_i(ji,jj,jl) - zht_i_o(ji,jj,jl) 
279            END DO
280         END DO
281      END DO
282
283      !-----------------------------------------------------------------------------------------------
284      !  2) Compute fractional ice area in each grid cell
285      !-----------------------------------------------------------------------------------------------
286      at_i(:,:) = 0._wp
287      DO jl = klbnd, kubnd
288         at_i(:,:) = at_i(:,:) + a_i(:,:,jl)
289      END DO
290
291      !-----------------------------------------------------------------------------------------------
292      !  3) Identify grid cells with ice
293      !-----------------------------------------------------------------------------------------------
294      nbrem = 0
295      DO jj = 1, jpj
296         DO ji = 1, jpi
297            IF ( at_i(ji,jj) .gt. zareamin ) THEN
298               nbrem         = nbrem + 1
299               nind_i(nbrem) = ji
300               nind_j(nbrem) = jj
301               zremap_flag(ji,jj) = 1
302            ELSE
303               zremap_flag(ji,jj) = 0
304            ENDIF
305         END DO !ji
306      END DO !jj
307
308      !-----------------------------------------------------------------------------------------------
309      !  4) Compute new category boundaries
310      !-----------------------------------------------------------------------------------------------
311      !- 4.1 Compute category boundaries
312      ! Tricky trick see limitd_me.F90
313      ! will be soon removed, CT
314      ! hi_max(kubnd) = 999.99
315      zhbnew(:,:,:) = 0._wp
316
317      DO jl = klbnd, kubnd - 1
318         DO ji = 1, nbrem
319            zji = nind_i(ji)
320            zjj = nind_j(ji)
321            !
322            IF ( ( zht_i_o(zji,zjj,jl)  .GT.epsi10 ) .AND. & 
323               ( zht_i_o(zji,zjj,jl+1).GT.epsi10 ) ) THEN
324               !interpolate between adjacent category growth rates
325               zslope = ( zdhice(zji,zjj,jl+1)     - zdhice(zji,zjj,jl) ) / &
326                  ( zht_i_o   (zji,zjj,jl+1) - zht_i_o   (zji,zjj,jl) )
327               zhbnew(zji,zjj,jl) = hi_max(jl) + zdhice(zji,zjj,jl) + &
328                  zslope * ( hi_max(jl) - zht_i_o(zji,zjj,jl) )
329            ELSEIF (zht_i_o(zji,zjj,jl).gt.epsi10) THEN
330               zhbnew(zji,zjj,jl) = hi_max(jl) + zdhice(zji,zjj,jl)
331            ELSEIF (zht_i_o(zji,zjj,jl+1).gt.epsi10) THEN
332               zhbnew(zji,zjj,jl) = hi_max(jl) + zdhice(zji,zjj,jl+1)
333            ELSE
334               zhbnew(zji,zjj,jl) = hi_max(jl)
335            ENDIF
336         END DO
337
338         !- 4.2 Check that each zhbnew lies between adjacent values of ice thickness
339         DO ji = 1, nbrem
340            ! jl, ji
341            zji = nind_i(ji)
342            zjj = nind_j(ji)
343            ! jl, ji
344            IF ( ( a_i(zji,zjj,jl) .GT.epsi10) .AND. & 
345               ( ht_i(zji,zjj,jl).GE. zhbnew(zji,zjj,jl) ) &
346               ) THEN
347               zremap_flag(zji,zjj) = 0
348            ELSEIF ( ( a_i(zji,zjj,jl+1) .GT. epsi10 ) .AND. &
349               ( ht_i(zji,zjj,jl+1).LE. zhbnew(zji,zjj,jl) ) &
350               ) THEN
351               zremap_flag(zji,zjj) = 0
352            ENDIF
353
354            !- 4.3 Check that each zhbnew does not exceed maximal values hi_max 
355            ! jl, ji
356            IF (zhbnew(zji,zjj,jl).gt.hi_max(jl+1)) THEN
357               zremap_flag(zji,zjj) = 0
358            ENDIF
359            ! jl, ji
360            IF (zhbnew(zji,zjj,jl).lt.hi_max(jl-1)) THEN
361               zremap_flag(zji,zjj) = 0
362            ENDIF
363            ! jl, ji
364         END DO !ji
365         ! ji
366      END DO !jl
367
368      !-----------------------------------------------------------------------------------------------
369      !  5) Identify cells where ITD is to be remapped
370      !-----------------------------------------------------------------------------------------------
371      nbrem = 0
372      DO jj = 1, jpj
373         DO ji = 1, jpi
374            IF ( zremap_flag(ji,jj) == 1 ) THEN
375               nbrem         = nbrem + 1
376               nind_i(nbrem) = ji
377               nind_j(nbrem) = jj
378            ENDIF
379         END DO !ji
380      END DO !jj
381
382      !-----------------------------------------------------------------------------------------------
383      !  6) Fill arrays with lowermost / uppermost boundaries of 'new' categories
384      !-----------------------------------------------------------------------------------------------
385      DO jj = 1, jpj
386         DO ji = 1, jpi
387            zhb0(ji,jj) = hi_max_typ(0,ntyp) ! 0eme
388            zhb1(ji,jj) = hi_max_typ(1,ntyp) ! 1er
389
390            zhbnew(ji,jj,klbnd-1) = 0._wp
391
392            IF( a_i(ji,jj,kubnd) > epsi10 ) THEN
393               zhbnew(ji,jj,kubnd) = 3._wp * ht_i(ji,jj,kubnd) - 2._wp * zhbnew(ji,jj,kubnd-1)
394            ELSE
395               zhbnew(ji,jj,kubnd) = hi_max(kubnd)
396            ENDIF
397
398            IF( zhbnew(ji,jj,kubnd) < hi_max(kubnd-1) )   zhbnew(ji,jj,kubnd) = hi_max(kubnd-1)
399
400         END DO !jj
401      END DO !jj
402
403      !-----------------------------------------------------------------------------------------------
404      !  7) Compute g(h)
405      !-----------------------------------------------------------------------------------------------
406      !- 7.1 g(h) for category 1 at start of time step
407      CALL lim_itd_fitline( klbnd, zhb0, zhb1, zht_i_o(:,:,klbnd),         &
408         &                  g0(:,:,klbnd), g1(:,:,klbnd), hL(:,:,klbnd),   &
409         &                  hR(:,:,klbnd), zremap_flag )
410
411      !- 7.2 Area lost due to melting of thin ice (first category,  klbnd)
412      DO ji = 1, nbrem
413         zji = nind_i(ji) 
414         zjj = nind_j(ji) 
415
416         !ji
417         IF (a_i(zji,zjj,klbnd) .gt. epsi10) THEN
418            zdh0 = zdhice(zji,zjj,klbnd) !decrease of ice thickness in the lower category
419            ! ji, a_i > epsi10
420            IF (zdh0 .lt. 0.0) THEN !remove area from category 1
421               ! ji, a_i > epsi10; zdh0 < 0
422               zdh0 = MIN(-zdh0,hi_max(klbnd))
423
424               !Integrate g(1) from 0 to dh0 to estimate area melted
425               zetamax = MIN(zdh0,hR(zji,zjj,klbnd)) - hL(zji,zjj,klbnd)
426               IF (zetamax.gt.0.0) THEN
427                  zx1  = zetamax
428                  zx2  = 0.5 * zetamax*zetamax 
429                  zda0 = g1(zji,zjj,klbnd) * zx2 + g0(zji,zjj,klbnd) * zx1 !ice area removed
430                  ! Constrain new thickness <= ht_i
431                  zdamax = a_i(zji,zjj,klbnd) * & 
432                     (1.0 - ht_i(zji,zjj,klbnd)/zht_i_o(zji,zjj,klbnd)) ! zdamax > 0
433                  !ice area lost due to melting of thin ice
434                  zda0   = MIN(zda0, zdamax)
435
436                  ! Remove area, conserving volume
437                  ht_i(zji,zjj,klbnd) = ht_i(zji,zjj,klbnd) & 
438                     * a_i(zji,zjj,klbnd) / ( a_i(zji,zjj,klbnd) - zda0 )
439                  a_i(zji,zjj,klbnd)  = a_i(zji,zjj,klbnd) - zda0
440                  v_i(zji,zjj,klbnd)  = a_i(zji,zjj,klbnd)*ht_i(zji,zjj,klbnd) ! clem@useless
441               ENDIF     ! zetamax > 0
442               ! ji, a_i > epsi10
443
444            ELSE ! if ice accretion
445               ! ji, a_i > epsi10; zdh0 > 0
446               IF ( ntyp .EQ. 1 ) zhbnew(zji,zjj,klbnd-1) = MIN(zdh0,hi_max(klbnd)) 
447               ! zhbnew was 0, and is shifted to the right to account for thin ice
448               ! growth in openwater (F0 = f1)
449               IF ( ntyp .NE. 1 ) zhbnew(zji,zjj,0) = 0 
450               ! in other types there is
451               ! no open water growth (F0 = 0)
452            ENDIF ! zdh0
453
454            ! a_i > epsi10
455         ENDIF ! a_i > epsi10
456
457      END DO ! ji
458
459      !- 7.3 g(h) for each thickness category 
460      DO jl = klbnd, kubnd
461         CALL lim_itd_fitline(jl, zhbnew(:,:,jl-1), zhbnew(:,:,jl), ht_i(:,:,jl), &
462            g0(:,:,jl), g1(:,:,jl), hL(:,:,jl), hR(:,:,jl),     &
463            zremap_flag)
464      END DO
465
466      !-----------------------------------------------------------------------------------------------
467      !  8) Compute area and volume to be shifted across each boundary
468      !-----------------------------------------------------------------------------------------------
469
470      DO jl = klbnd, kubnd - 1
471         DO jj = 1, jpj
472            DO ji = 1, jpi
473               zdonor(ji,jj,jl) = 0
474               zdaice(ji,jj,jl) = 0.0
475               zdvice(ji,jj,jl) = 0.0
476            END DO
477         END DO
478
479         DO ji = 1, nbrem
480            zji = nind_i(ji)
481            zjj = nind_j(ji)
482
483            IF (zhbnew(zji,zjj,jl) .gt. hi_max(jl)) THEN ! transfer from jl to jl+1
484
485               ! left and right integration limits in eta space
486               zvetamin(ji) = MAX(hi_max(jl), hL(zji,zjj,jl)) - hL(zji,zjj,jl)
487               zvetamax(ji) = MIN(zhbnew(zji,zjj,jl), hR(zji,zjj,jl)) - hL(zji,zjj,jl)
488               zdonor(zji,zjj,jl) = jl
489
490            ELSE  ! zhbnew(jl) <= hi_max(jl) ; transfer from jl+1 to jl
491
492               ! left and right integration limits in eta space
493               zvetamin(ji) = 0.0
494               zvetamax(ji) = MIN(hi_max(jl), hR(zji,zjj,jl+1)) - hL(zji,zjj,jl+1)
495               zdonor(zji,zjj,jl) = jl + 1
496
497            ENDIF  ! zhbnew(jl) > hi_max(jl)
498
499            zetamax = MAX(zvetamax(ji), zvetamin(ji)) ! no transfer if etamax < etamin
500            zetamin = zvetamin(ji)
501
502            zx1  = zetamax - zetamin
503            zwk1 = zetamin*zetamin
504            zwk2 = zetamax*zetamax
505            zx2  = 0.5 * (zwk2 - zwk1)
506            zwk1 = zwk1 * zetamin
507            zwk2 = zwk2 * zetamax
508            zx3  = 1.0/3.0 * (zwk2 - zwk1)
509            nd   = zdonor(zji,zjj,jl)
510            zdaice(zji,zjj,jl) = g1(zji,zjj,nd)*zx2 + g0(zji,zjj,nd)*zx1
511            zdvice(zji,zjj,jl) = g1(zji,zjj,nd)*zx3 + g0(zji,zjj,nd)*zx2 + &
512               zdaice(zji,zjj,jl)*hL(zji,zjj,nd)
513
514         END DO ! ji
515      END DO ! jl klbnd -> kubnd - 1
516
517      !!----------------------------------------------------------------------------------------------
518      !! 9) Shift ice between categories
519      !!----------------------------------------------------------------------------------------------
520      CALL lim_itd_shiftice ( klbnd, kubnd, zdonor, zdaice, zdvice )
521
522      !!----------------------------------------------------------------------------------------------
523      !! 10) Make sure ht_i >= minimum ice thickness hi_min
524      !!----------------------------------------------------------------------------------------------
525
526      DO ji = 1, nbrem
527         zji = nind_i(ji)
528         zjj = nind_j(ji)
529         IF ( ( zhimin .GT. 0.0 ) .AND. & 
530            ( ( a_i(zji,zjj,1) .GT. epsi10 ) .AND. ( ht_i(zji,zjj,1) .LT. zhimin ) ) &
531            ) THEN
532            a_i(zji,zjj,1)  = a_i(zji,zjj,1) * ht_i(zji,zjj,1) / zhimin 
533            ht_i(zji,zjj,1) = zhimin
534            v_i(zji,zjj,1)  = a_i(zji,zjj,1)*ht_i(zji,zjj,1) !clem@useless
535         ENDIF
536      END DO !ji
537
538      !!----------------------------------------------------------------------------------------------
539      !! 11) Conservation check
540      !!----------------------------------------------------------------------------------------------
541      IF ( con_i ) THEN
542         CALL lim_column_sum (jpl,   v_i, vt_i_final)
543         fieldid = ' v_i : limitd_th '
544         CALL lim_cons_check (vt_i_init, vt_i_final, 1.0e-6, fieldid) 
545
546         CALL lim_column_sum_energy (jpl, nlay_i,  e_i, et_i_final)
547         fieldid = ' e_i : limitd_th '
548         CALL lim_cons_check (et_i_init, et_i_final, 1.0e-3, fieldid) 
549
550         CALL lim_column_sum (jpl,   v_s, vt_s_final)
551         fieldid = ' v_s : limitd_th '
552         CALL lim_cons_check (vt_s_init, vt_s_final, 1.0e-6, fieldid) 
553
554         dummy_es(:,:,:) = e_s(:,:,1,:)
555         CALL lim_column_sum (jpl, dummy_es(:,:,:) , et_s_final)
556         fieldid = ' e_s : limitd_th '
557         CALL lim_cons_check (et_s_init, et_s_final, 1.0e-3, fieldid) 
558      ENDIF
559
560      CALL wrk_dealloc( jpi,jpj, zremap_flag )    ! integer
561      CALL wrk_dealloc( jpi,jpj,jpl-1, zdonor )   ! integer
562      CALL wrk_dealloc( jpi,jpj,jpl, zdhice, g0, g1, hL, hR, zht_i_o, dummy_es )
563      CALL wrk_dealloc( jpi,jpj,jpl-1, zdaice, zdvice )   
564      CALL wrk_dealloc( jpi,jpj,jpl+1, zhbnew, kkstart = 0 )   
565      CALL wrk_dealloc( (jpi+1)*(jpj+1), zvetamin, zvetamax )   
566      CALL wrk_dealloc( (jpi+1)*(jpj+1), nind_i, nind_j )   ! integer
567      CALL wrk_dealloc( jpi,jpj, zhb0,zhb1,vt_i_init,vt_i_final,vt_s_init,vt_s_final,et_i_init,et_i_final,et_s_init,et_s_final )
568
569   END SUBROUTINE lim_itd_th_rem
570
571
572   SUBROUTINE lim_itd_fitline( num_cat, HbL, Hbr, hice,   &
573      &                        g0, g1, hL, hR, zremap_flag )
574      !!------------------------------------------------------------------
575      !!                ***  ROUTINE lim_itd_fitline ***
576      !!
577      !! ** Purpose :   fit g(h) with a line using area, volume constraints
578      !!
579      !! ** Method  :   Fit g(h) with a line, satisfying area and volume constraints.
580      !!              To reduce roundoff errors caused by large values of g0 and g1,
581      !!              we actually compute g(eta), where eta = h - hL, and hL is the
582      !!              left boundary.
583      !!------------------------------------------------------------------
584      INTEGER                     , INTENT(in   ) ::   num_cat      ! category index
585      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   HbL, HbR     ! left and right category boundaries
586      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   hice         ! ice thickness
587      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   g0, g1       ! coefficients in linear equation for g(eta)
588      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   hL           ! min value of range over which g(h) > 0
589      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   hR           ! max value of range over which g(h) > 0
590      INTEGER , DIMENSION(jpi,jpj), INTENT(in   ) ::   zremap_flag  !
591      !
592      INTEGER ::   ji,jj           ! horizontal indices
593      REAL(wp) ::   zh13         ! HbL + 1/3 * (HbR - HbL)
594      REAL(wp) ::   zh23         ! HbL + 2/3 * (HbR - HbL)
595      REAL(wp) ::   zdhr         ! 1 / (hR - hL)
596      REAL(wp) ::   zwk1, zwk2   ! temporary variables
597      REAL(wp) ::   zacrith      ! critical minimum concentration in an ice category
598      !!------------------------------------------------------------------
599      !
600      zacrith       = 1.0e-6
601      !
602      DO jj = 1, jpj
603         DO ji = 1, jpi
604            !
605            IF( zremap_flag(ji,jj) == 1 .AND. a_i(ji,jj,num_cat) > zacrith   &
606               &                        .AND. hice(ji,jj)        > 0._wp     ) THEN
607
608               ! Initialize hL and hR
609
610               hL(ji,jj) = HbL(ji,jj)
611               hR(ji,jj) = HbR(ji,jj)
612
613               ! Change hL or hR if hice falls outside central third of range
614
615               zh13 = 1.0/3.0 * (2.0*hL(ji,jj) + hR(ji,jj))
616               zh23 = 1.0/3.0 * (hL(ji,jj) + 2.0*hR(ji,jj))
617
618               IF    ( hice(ji,jj) < zh13 ) THEN   ;   hR(ji,jj) = 3._wp * hice(ji,jj) - 2._wp * hL(ji,jj)
619               ELSEIF( hice(ji,jj) > zh23 ) THEN   ;   hL(ji,jj) = 3._wp * hice(ji,jj) - 2._wp * hR(ji,jj)
620               ENDIF
621
622               ! Compute coefficients of g(eta) = g0 + g1*eta
623
624               zdhr = 1._wp / (hR(ji,jj) - hL(ji,jj))
625               zwk1 = 6._wp * a_i(ji,jj,num_cat) * zdhr
626               zwk2 = ( hice(ji,jj) - hL(ji,jj) ) * zdhr
627               g0(ji,jj) = zwk1 * ( 2._wp/3._wp - zwk2 )
628               g1(ji,jj) = 2._wp * zdhr * zwk1 * (zwk2 - 0.5)
629               !
630            ELSE                   ! remap_flag = .false. or a_i < epsi10
631               hL(ji,jj) = 0._wp
632               hR(ji,jj) = 0._wp
633               g0(ji,jj) = 0._wp
634               g1(ji,jj) = 0._wp
635            ENDIF                  ! a_i > epsi10
636            !
637         END DO
638      END DO
639      !
640   END SUBROUTINE lim_itd_fitline
641
642
643   SUBROUTINE lim_itd_shiftice( klbnd, kubnd, zdonor, zdaice, zdvice )
644      !!------------------------------------------------------------------
645      !!                ***  ROUTINE lim_itd_shiftice ***
646      !!
647      !! ** Purpose :   shift ice across category boundaries, conserving everything
648      !!              ( area, volume, energy, age*vol, and mass of salt )
649      !!
650      !! ** Method  :
651      !!------------------------------------------------------------------
652      INTEGER                           , INTENT(in   ) ::   klbnd    ! Start thickness category index point
653      INTEGER                           , INTENT(in   ) ::   kubnd    ! End point on which the  the computation is applied
654      INTEGER , DIMENSION(jpi,jpj,jpl-1), INTENT(in   ) ::   zdonor   ! donor category index
655      REAL(wp), DIMENSION(jpi,jpj,jpl-1), INTENT(inout) ::   zdaice   ! ice area transferred across boundary
656      REAL(wp), DIMENSION(jpi,jpj,jpl-1), INTENT(inout) ::   zdvice   ! ice volume transferred across boundary
657
658      INTEGER ::   ji, jj, jl, jl2, jl1, jk   ! dummy loop indices
659      INTEGER ::   zji, zjj          ! indices when changing from 2D-1D is done
660
661      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zaTsfn
662      REAL(wp), POINTER, DIMENSION(:,:)   ::   zworka            ! temporary array used here
663
664      REAL(wp) ::   zdvsnow, zdesnow   ! snow volume and energy transferred
665      REAL(wp) ::   zdeice             ! ice energy transferred
666      REAL(wp) ::   zdsm_vice          ! ice salinity times volume transferred
667      REAL(wp) ::   zdo_aice           ! ice age times volume transferred
668      REAL(wp) ::   zdaTsf             ! aicen*Tsfcn transferred
669      REAL(wp) ::   zindsn             ! snow or not
670      REAL(wp) ::   zindb              ! ice or not
671
672      INTEGER, POINTER, DIMENSION(:) ::   nind_i, nind_j   ! compressed indices for i/j directions
673
674      INTEGER ::   nbrem             ! number of cells with ice to transfer
675
676      LOGICAL ::   zdaice_negative         ! true if daice < -puny
677      LOGICAL ::   zdvice_negative         ! true if dvice < -puny
678      LOGICAL ::   zdaice_greater_aicen    ! true if daice > aicen
679      LOGICAL ::   zdvice_greater_vicen    ! true if dvice > vicen
680      !!------------------------------------------------------------------
681
682      CALL wrk_alloc( jpi,jpj,jpl, zaTsfn )
683      CALL wrk_alloc( jpi,jpj, zworka )
684      CALL wrk_alloc( (jpi+1)*(jpj+1), nind_i, nind_j )   ! integer
685
686      !----------------------------------------------------------------------------------------------
687      ! 1) Define a variable equal to a_i*T_su
688      !----------------------------------------------------------------------------------------------
689
690      DO jl = klbnd, kubnd
691         zaTsfn(:,:,jl) = a_i(:,:,jl)*t_su(:,:,jl)
692      END DO
693
694      !----------------------------------------------------------------------------------------------
695      ! 2) Check for daice or dvice out of range, allowing for roundoff error
696      !----------------------------------------------------------------------------------------------
697      ! Note: zdaice < 0 or zdvice < 0 usually happens when category jl
698      ! has a small area, with h(n) very close to a boundary.  Then
699      ! the coefficients of g(h) are large, and the computed daice and
700      ! dvice can be in error. If this happens, it is best to transfer
701      ! either the entire category or nothing at all, depending on which
702      ! side of the boundary hice(n) lies.
703      !-----------------------------------------------------------------
704      DO jl = klbnd, kubnd-1
705
706         zdaice_negative = .false.
707         zdvice_negative = .false.
708         zdaice_greater_aicen = .false.
709         zdvice_greater_vicen = .false.
710
711         DO jj = 1, jpj
712            DO ji = 1, jpi
713
714               IF (zdonor(ji,jj,jl) .GT. 0) THEN
715                  jl1 = zdonor(ji,jj,jl)
716
717                  IF (zdaice(ji,jj,jl) .LT. 0.0) THEN
718                     IF (zdaice(ji,jj,jl) .GT. -epsi10) THEN
719                        IF ( ( jl1.EQ.jl   .AND. ht_i(ji,jj,jl1) .GT. hi_max(jl) )           &
720                           .OR.                                      &
721                           ( jl1.EQ.jl+1 .AND. ht_i(ji,jj,jl1) .LE. hi_max(jl) )           & 
722                           ) THEN                                                             
723                           zdaice(ji,jj,jl) = a_i(ji,jj,jl1)  ! shift entire category
724                           zdvice(ji,jj,jl) = v_i(ji,jj,jl1)
725                        ELSE
726                           zdaice(ji,jj,jl) = 0.0 ! shift no ice
727                           zdvice(ji,jj,jl) = 0.0
728                        ENDIF
729                     ELSE
730                        zdaice_negative = .true.
731                     ENDIF
732                  ENDIF
733
734                  IF (zdvice(ji,jj,jl) .LT. 0.0) THEN
735                     IF (zdvice(ji,jj,jl) .GT. -epsi10 ) THEN
736                        IF ( ( jl1.EQ.jl .AND. ht_i(ji,jj,jl1).GT.hi_max(jl) )     &
737                           .OR.                                     &
738                           ( jl1.EQ.jl+1 .AND. ht_i(ji,jj,jl1) .LE. hi_max(jl) ) &
739                           ) THEN
740                           zdaice(ji,jj,jl) = a_i(ji,jj,jl1) ! shift entire category
741                           zdvice(ji,jj,jl) = v_i(ji,jj,jl1) 
742                        ELSE
743                           zdaice(ji,jj,jl) = 0.0    ! shift no ice
744                           zdvice(ji,jj,jl) = 0.0
745                        ENDIF
746                     ELSE
747                        zdvice_negative = .true.
748                     ENDIF
749                  ENDIF
750
751                  ! If daice is close to aicen, set daice = aicen.
752                  IF (zdaice(ji,jj,jl) .GT. a_i(ji,jj,jl1) - epsi10 ) THEN
753                     IF (zdaice(ji,jj,jl) .LT. a_i(ji,jj,jl1)+epsi10) THEN
754                        zdaice(ji,jj,jl) = a_i(ji,jj,jl1)
755                        zdvice(ji,jj,jl) = v_i(ji,jj,jl1) 
756                     ELSE
757                        zdaice_greater_aicen = .true.
758                     ENDIF
759                  ENDIF
760
761                  IF (zdvice(ji,jj,jl) .GT. v_i(ji,jj,jl1)-epsi10) THEN
762                     IF (zdvice(ji,jj,jl) .LT. v_i(ji,jj,jl1)+epsi10) THEN
763                        zdaice(ji,jj,jl) = a_i(ji,jj,jl1)
764                        zdvice(ji,jj,jl) = v_i(ji,jj,jl1) 
765                     ELSE
766                        zdvice_greater_vicen = .true.
767                     ENDIF
768                  ENDIF
769
770               ENDIF               ! donor > 0
771            END DO                   ! i
772         END DO                 ! j
773
774      END DO !jl
775
776      !-------------------------------------------------------------------------------
777      ! 3) Transfer volume and energy between categories
778      !-------------------------------------------------------------------------------
779
780      DO jl = klbnd, kubnd - 1
781         nbrem = 0
782         DO jj = 1, jpj
783            DO ji = 1, jpi
784               IF (zdaice(ji,jj,jl) .GT. 0.0 ) THEN ! daice(n) can be < puny
785                  nbrem = nbrem + 1
786                  nind_i(nbrem) = ji
787                  nind_j(nbrem) = jj
788               ENDIF ! tmask
789            END DO
790         END DO
791
792         DO ji = 1, nbrem 
793            zji = nind_i(ji)
794            zjj = nind_j(ji)
795
796            jl1 = zdonor(zji,zjj,jl)
797            zindb             = MAX( 0.0 , SIGN( 1.0 , v_i(zji,zjj,jl1) - epsi10 ) )
798            zworka(zji,zjj)   = zdvice(zji,zjj,jl) / MAX(v_i(zji,zjj,jl1),epsi10) * zindb
799            IF( jl1 == jl) THEN   ;   jl2 = jl1+1
800            ELSE                    ;   jl2 = jl 
801            ENDIF
802
803            !--------------
804            ! Ice areas
805            !--------------
806
807            a_i(zji,zjj,jl1) = a_i(zji,zjj,jl1) - zdaice(zji,zjj,jl)
808            a_i(zji,zjj,jl2) = a_i(zji,zjj,jl2) + zdaice(zji,zjj,jl)
809
810            !--------------
811            ! Ice volumes
812            !--------------
813
814            v_i(zji,zjj,jl1) = v_i(zji,zjj,jl1) - zdvice(zji,zjj,jl) 
815            v_i(zji,zjj,jl2) = v_i(zji,zjj,jl2) + zdvice(zji,zjj,jl)
816
817            !--------------
818            ! Snow volumes
819            !--------------
820
821            zdvsnow          = v_s(zji,zjj,jl1) * zworka(zji,zjj)
822            v_s(zji,zjj,jl1) = v_s(zji,zjj,jl1) - zdvsnow
823            v_s(zji,zjj,jl2) = v_s(zji,zjj,jl2) + zdvsnow 
824
825            !--------------------
826            ! Snow heat content 
827            !--------------------
828
829            zdesnow              = e_s(zji,zjj,1,jl1) * zworka(zji,zjj)
830            e_s(zji,zjj,1,jl1)   = e_s(zji,zjj,1,jl1) - zdesnow
831            e_s(zji,zjj,1,jl2)   = e_s(zji,zjj,1,jl2) + zdesnow
832
833            !--------------
834            ! Ice age
835            !--------------
836
837            zdo_aice             = oa_i(zji,zjj,jl1) * zdaice(zji,zjj,jl)
838            oa_i(zji,zjj,jl1)    = oa_i(zji,zjj,jl1) - zdo_aice
839            oa_i(zji,zjj,jl2)    = oa_i(zji,zjj,jl2) + zdo_aice
840
841            !--------------
842            ! Ice salinity
843            !--------------
844
845            zdsm_vice            = smv_i(zji,zjj,jl1) * zworka(zji,zjj)
846            smv_i(zji,zjj,jl1)   = smv_i(zji,zjj,jl1) - zdsm_vice
847            smv_i(zji,zjj,jl2)   = smv_i(zji,zjj,jl2) + zdsm_vice
848
849            !---------------------
850            ! Surface temperature
851            !---------------------
852
853            zdaTsf               = t_su(zji,zjj,jl1) * zdaice(zji,zjj,jl)
854            zaTsfn(zji,zjj,jl1)  = zaTsfn(zji,zjj,jl1) - zdaTsf
855            zaTsfn(zji,zjj,jl2)  = zaTsfn(zji,zjj,jl2) + zdaTsf 
856
857         END DO                 ! ji
858
859         !------------------
860         ! Ice heat content
861         !------------------
862
863         DO jk = 1, nlay_i
864!CDIR NODEP
865            DO ji = 1, nbrem
866               zji = nind_i(ji)
867               zjj = nind_j(ji)
868
869               jl1 = zdonor(zji,zjj,jl)
870               IF (jl1 .EQ. jl) THEN
871                  jl2 = jl+1
872               ELSE             ! n1 = n+1
873                  jl2 = jl 
874               ENDIF
875
876               zdeice = e_i(zji,zjj,jk,jl1) * zworka(zji,zjj)
877               e_i(zji,zjj,jk,jl1) =  e_i(zji,zjj,jk,jl1) - zdeice
878               e_i(zji,zjj,jk,jl2) =  e_i(zji,zjj,jk,jl2) + zdeice 
879            END DO              ! ji
880         END DO                 ! jk
881
882      END DO                   ! boundaries, 1 to ncat-1
883
884      !-----------------------------------------------------------------
885      ! Update ice thickness and temperature
886      !-----------------------------------------------------------------
887
888      DO jl = klbnd, kubnd
889         DO jj = 1, jpj
890            DO ji = 1, jpi 
891               IF ( a_i(ji,jj,jl) > epsi10 ) THEN
892                  ht_i(ji,jj,jl)  =  v_i   (ji,jj,jl) / a_i(ji,jj,jl) 
893                  t_su(ji,jj,jl)  =  zaTsfn(ji,jj,jl) / a_i(ji,jj,jl) 
894                  zindsn          =  1.0 - MAX(0.0,SIGN(1.0,-v_s(ji,jj,jl)+epsi10)) !0 if no ice and 1 if yes
895               ELSE
896                  ht_i(ji,jj,jl)  = 0._wp
897                  t_su(ji,jj,jl)  = rtt
898               ENDIF
899            END DO                 ! ji
900         END DO                 ! jj
901      END DO                    ! jl
902      !
903      CALL wrk_dealloc( jpi,jpj,jpl, zaTsfn )
904      CALL wrk_dealloc( jpi,jpj, zworka )
905      CALL wrk_dealloc( (jpi+1)*(jpj+1), nind_i, nind_j )   ! integer
906      !
907   END SUBROUTINE lim_itd_shiftice
908   
909
910   SUBROUTINE lim_itd_th_reb( klbnd, kubnd, ntyp )
911      !!------------------------------------------------------------------
912      !!                ***  ROUTINE lim_itd_th_reb ***
913      !!
914      !! ** Purpose : rebin - rebins thicknesses into defined categories
915      !!
916      !! ** Method  :
917      !!------------------------------------------------------------------
918      INTEGER , INTENT (in) ::   klbnd   ! Start thickness category index point
919      INTEGER , INTENT (in) ::   kubnd   ! End point on which the  the computation is applied
920      INTEGER , INTENT (in) ::   ntyp    ! number of the ice type involved in the rebinning process
921      !
922      INTEGER ::   ji,jj, jl   ! dummy loop indices
923      INTEGER ::   zshiftflag          ! = .true. if ice must be shifted
924      CHARACTER (len = 15) :: fieldid
925
926      INTEGER , POINTER, DIMENSION(:,:,:) ::   zdonor           ! donor category index
927      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdaice, zdvice   ! ice area and volume transferred
928
929      REAL(wp), POINTER, DIMENSION(:,:) ::   vt_i_init, vt_i_final   ! ice volume summed over categories
930      REAL(wp), POINTER, DIMENSION(:,:) ::   vt_s_init, vt_s_final   ! snow volume summed over categories
931      !!------------------------------------------------------------------
932     
933      CALL wrk_alloc( jpi,jpj,jpl, zdonor )   ! interger
934      CALL wrk_alloc( jpi,jpj,jpl, zdaice, zdvice )
935      CALL wrk_alloc( jpi,jpj, vt_i_init, vt_i_final, vt_s_init, vt_s_final )
936      !     
937      IF( con_i ) THEN                 ! conservation check
938         CALL lim_column_sum (jpl,   v_i, vt_i_init)
939         CALL lim_column_sum (jpl,   v_s, vt_s_init)
940      ENDIF
941
942      !
943      !------------------------------------------------------------------------------
944      ! 1) Compute ice thickness.
945      !------------------------------------------------------------------------------
946      DO jl = klbnd, kubnd
947         DO jj = 1, jpj
948            DO ji = 1, jpi 
949               IF( a_i(ji,jj,jl) > epsi10 ) THEN
950                  ht_i(ji,jj,jl) = v_i(ji,jj,jl) / a_i(ji,jj,jl)
951               ELSE
952                  ht_i(ji,jj,jl) = 0._wp
953               ENDIF
954            END DO
955         END DO
956      END DO
957
958      !------------------------------------------------------------------------------
959      ! 2) Make sure thickness of cat klbnd is at least hi_max_typ(klbnd)
960      !------------------------------------------------------------------------------
961      DO jj = 1, jpj 
962         DO ji = 1, jpi 
963            IF( a_i(ji,jj,klbnd) > epsi10 ) THEN
964               IF( ht_i(ji,jj,klbnd) <= hi_max_typ(0,ntyp) .AND. hi_max_typ(0,ntyp) > 0._wp ) THEN
965                  a_i(ji,jj,klbnd)  = v_i(ji,jj,klbnd) / hi_max_typ(0,ntyp) 
966                  ht_i(ji,jj,klbnd) = hi_max_typ(0,ntyp)
967               ENDIF
968            ENDIF
969         END DO
970      END DO
971
972      !------------------------------------------------------------------------------
973      ! 3) If a category thickness is not in bounds, shift the
974      ! entire area, volume, and energy to the neighboring category
975      !------------------------------------------------------------------------------
976      !-------------------------
977      ! Initialize shift arrays
978      !-------------------------
979      DO jl = klbnd, kubnd
980         zdonor(:,:,jl) = 0
981         zdaice(:,:,jl) = 0._wp
982         zdvice(:,:,jl) = 0._wp
983      END DO
984
985      !-------------------------
986      ! Move thin categories up
987      !-------------------------
988
989      DO jl = klbnd, kubnd - 1  ! loop over category boundaries
990
991         !---------------------------------------
992         ! identify thicknesses that are too big
993         !---------------------------------------
994         zshiftflag = 0
995
996         DO jj = 1, jpj 
997            DO ji = 1, jpi 
998               IF( a_i(ji,jj,jl) > epsi10 .AND. ht_i(ji,jj,jl) > hi_max(jl) ) THEN
999                  zshiftflag        = 1
1000                  zdonor(ji,jj,jl)  = jl 
1001                  zdaice(ji,jj,jl)  = a_i(ji,jj,jl)
1002                  zdvice(ji,jj,jl)  = v_i(ji,jj,jl)
1003                  ! begin TECLIM change
1004                  ! zdaice(ji,jj,jl)  = a_i(ji,jj,jl)
1005                  ! zdvice(ji,jj,jl)  = v_i(ji,jj,jl)
1006                  zdaice(ji,jj,jl)  = a_i(ji,jj,jl)/2
1007                  zdvice(ji,jj,jl)  = v_i(ji,jj,jl)-zdaice(ji,jj,jl)*(hi_max(jl)+hi_max(jl-1))/2
1008                  ! end TECLIM change
1009               ENDIF
1010            END DO                 ! ji
1011         END DO                 ! jj
1012         IF(lk_mpp)   CALL mpp_max( zshiftflag )
1013
1014         IF( zshiftflag == 1 ) THEN            ! Shift ice between categories
1015            CALL lim_itd_shiftice( klbnd, kubnd, zdonor, zdaice, zdvice )
1016            ! Reset shift parameters
1017            zdonor(:,:,jl) = 0
1018            zdaice(:,:,jl) = 0._wp
1019            zdvice(:,:,jl) = 0._wp
1020         ENDIF
1021         !
1022      END DO                    ! jl
1023
1024      !----------------------------
1025      ! Move thick categories down
1026      !----------------------------
1027
1028      DO jl = kubnd - 1, 1, -1       ! loop over category boundaries
1029
1030         !-----------------------------------------
1031         ! Identify thicknesses that are too small
1032         !-----------------------------------------
1033         zshiftflag = 0
1034
1035         DO jj = 1, jpj
1036            DO ji = 1, jpi
1037               IF( a_i(ji,jj,jl+1) >  epsi10 .AND.   &
1038                  ht_i(ji,jj,jl+1) <= hi_max(jl) ) THEN
1039                  !
1040                  zshiftflag = 1
1041                  zdonor(ji,jj,jl) = jl + 1
1042                  zdaice(ji,jj,jl) = a_i(ji,jj,jl+1) 
1043                  zdvice(ji,jj,jl) = v_i(ji,jj,jl+1)
1044               ENDIF
1045            END DO                 ! ji
1046         END DO                 ! jj
1047
1048         IF(lk_mpp)   CALL mpp_max( zshiftflag )
1049         
1050         IF( zshiftflag == 1 ) THEN            ! Shift ice between categories
1051            CALL lim_itd_shiftice( klbnd, kubnd, zdonor, zdaice, zdvice )
1052            ! Reset shift parameters
1053            zdonor(:,:,jl) = 0
1054            zdaice(:,:,jl) = 0._wp
1055            zdvice(:,:,jl) = 0._wp
1056         ENDIF
1057
1058      END DO                    ! jl
1059
1060      !------------------------------------------------------------------------------
1061      ! 4) Conservation check
1062      !------------------------------------------------------------------------------
1063
1064      IF( con_i ) THEN
1065         CALL lim_column_sum (jpl,   v_i, vt_i_final)
1066         fieldid = ' v_i : limitd_reb '
1067         CALL lim_cons_check (vt_i_init, vt_i_final, 1.0e-6, fieldid) 
1068
1069         CALL lim_column_sum (jpl,   v_s, vt_s_final)
1070         fieldid = ' v_s : limitd_reb '
1071         CALL lim_cons_check (vt_s_init, vt_s_final, 1.0e-6, fieldid) 
1072      ENDIF
1073      !
1074      CALL wrk_dealloc( jpi,jpj,jpl, zdonor )   ! interger
1075      CALL wrk_dealloc( jpi,jpj,jpl, zdaice, zdvice )
1076      CALL wrk_dealloc( jpi,jpj, vt_i_init, vt_i_final, vt_s_init, vt_s_final )
1077
1078   END SUBROUTINE lim_itd_th_reb
1079
1080#else
1081   !!----------------------------------------------------------------------
1082   !!   Default option            Dummy module         NO LIM sea-ice model
1083   !!----------------------------------------------------------------------
1084CONTAINS
1085   SUBROUTINE lim_itd_th           ! Empty routines
1086   END SUBROUTINE lim_itd_th
1087   SUBROUTINE lim_itd_th_ini
1088   END SUBROUTINE lim_itd_th_ini
1089   SUBROUTINE lim_itd_th_rem
1090   END SUBROUTINE lim_itd_th_rem
1091   SUBROUTINE lim_itd_fitline
1092   END SUBROUTINE lim_itd_fitline
1093   SUBROUTINE lim_itd_shiftice
1094   END SUBROUTINE lim_itd_shiftice
1095   SUBROUTINE lim_itd_th_reb
1096   END SUBROUTINE lim_itd_th_reb
1097#endif
1098   !!======================================================================
1099END MODULE limitd_th
Note: See TracBrowser for help on using the repository browser.