New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
ldfdyn_c3d.h90 in branches/2013/dev_r3406_CNRS_LIM3/NEMOGCM/NEMO/OPA_SRC/LDF – NEMO

source: branches/2013/dev_r3406_CNRS_LIM3/NEMOGCM/NEMO/OPA_SRC/LDF/ldfdyn_c3d.h90 @ 3938

Last change on this file since 3938 was 3938, checked in by flavoni, 11 years ago

dev_r3406_CNRS_LIM3: update LIM3, see ticket #1116
  • Property svn:keywords set to Id
File size: 18.8 KB
Line 
1   !!----------------------------------------------------------------------
2   !!                        ***  ldfdyn_c3d.h90  ***
3   !!----------------------------------------------------------------------
4
5   !!----------------------------------------------------------------------
6   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
7   !! $Id$
8   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   'key_dynldf_c3d'             3D lateral eddy viscosity coefficients
13   !!----------------------------------------------------------------------
14
15   SUBROUTINE ldf_dyn_c3d( ld_print )
16      !!----------------------------------------------------------------------
17      !!                  ***  ROUTINE ldf_dyn_c3d  ***
18      !!                   
19      !! ** Purpose :   initializations of the horizontal ocean physics
20      !!
21      !! ** Method  :   3D eddy viscosity coef. ( longitude, latitude, depth )
22      !!       laplacian operator   : ahm1, ahm2 defined at T- and F-points
23      !!                              ahm2, ahm4 never used
24      !!       bilaplacian operator : ahm1, ahm2 never used
25      !!                           :  ahm3, ahm4 defined at U- and V-points
26      !!       ??? explanation of the default is missing
27      !!----------------------------------------------------------------------
28      USE ldftra_oce, ONLY :   aht0
29      !!
30      LOGICAL, INTENT (in) ::   ld_print   ! If true, output arrays on numout
31      !!
32      INTEGER  ::   ji, jj, jk   ! dummy loop indices
33      REAL(wp) ::   zr = 0.2     ! maximum of the reduction factor at the bottom ocean ( 0 < zr < 1 )
34      REAL(wp) ::   zh = 500.    ! depth of at which start the reduction ( > dept(1) )
35      REAL(wp) ::   zd_max       ! maximum grid spacing over the global domain
36      REAL(wp) ::   za00, zc, zd, zetmax, zefmax, zeumax, zevmax   ! local scalars
37      REAL(wp), POINTER, DIMENSION(:)   :: zcoef   
38      INTEGER,  PARAMETER               :: zrim = 5  ! number of grid points over which diffusion is increased linearly
39      REAL(wp), PARAMETER               :: zinc_coef = 0.0 ! coef of diffusion increase 
40      INTEGER  ::   ii0, ii1, ij0, ij1   ! temporary integers
41      !!----------------------------------------------------------------------
42      !
43      CALL wrk_alloc( jpk, zcoef )
44      !
45      IF(lwp) WRITE(numout,*)
46      IF(lwp) WRITE(numout,*) 'ldf_dyn_c3d : 3D lateral eddy viscosity coefficient'
47      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
48
49     
50      ! Set ahm1 and ahm2  ( T- and F- points) (used for laplacian operators
51      ! =================                       whatever its orientation is)
52      IF( ln_dynldf_lap ) THEN
53         ! define ahm1 and ahm2 at the right grid point position
54         ! (USER: modify ahm1 and ahm2 following your desiderata)
55
56         zd_max = MAX( MAXVAL( e1t(:,:) ), MAXVAL( e2t(:,:) ) )
57         IF( lk_mpp )   CALL mpp_max( zd_max )   ! max over the global domain
58
59         IF(lwp) WRITE(numout,*) '              laplacian operator: ahm proportional to e1'
60         IF(lwp) WRITE(numout,*) '              maximum grid-spacing = ', zd_max, ' maximum value for ahm = ', ahm0
61
62         za00 = ahm0 / zd_max
63
64         IF( ln_dynldf_iso ) THEN
65            IF(lwp) WRITE(numout,*) '              Caution, as implemented now, the isopycnal part of momentum'
66            IF(lwp) WRITE(numout,*) '                 mixing use aht0 as eddy viscosity coefficient. Thus, it is'
67            IF(lwp) WRITE(numout,*) '                 uniform and you must be sure that your ahm is greater than'
68            IF(lwp) WRITE(numout,*) '                 aht0 everywhere in the model domain.'
69         ENDIF
70
71         CALL ldf_zpf( .TRUE. , 1000., 500., 0.25, fsdept(:,:,:), ahm1 )   ! vertical profile
72         CALL ldf_zpf( .TRUE. , 1000., 500., 0.25, fsdept(:,:,:), ahm2 )   ! vertical profile
73         DO jk = 1,jpk
74            DO jj = 1, jpj
75               DO ji = 1, jpi
76                  zetmax = MAX( e1t(ji,jj), e2t(ji,jj) )
77                  zefmax = MAX( e1f(ji,jj), e2f(ji,jj) )
78                  ahm1(ji,jj,jk) = za00 * zetmax * ahm1(ji,jj,jk)
79                  ahm2(ji,jj,jk) = za00 * zefmax * ahm2(ji,jj,jk)
80               END DO
81            END DO
82         END DO
83
84
85         ! Special case for ORCA R1, R2 and R4 configurations (overwrite the value of ahm1 ahm2)
86         ! ==============================================
87         IF( cp_cfg == "orca" .AND. ( jp_cfg == 1 .OR. jp_cfg == 2 .OR. jp_cfg == 4 ) ) THEN
88            IF(lwp) WRITE(numout,*)
89            IF(lwp) WRITE(numout,*) '              ORCA R1, R2 or R4: overwrite the previous definition of ahm'
90            IF(lwp) WRITE(numout,*) '              ================='
91            CALL ldf_dyn_c3d_orca( ld_print )
92         ENDIF
93   
94          ! Control print
95         IF(lwp .AND. ld_print ) THEN
96            WRITE(numout,*)
97            WRITE(numout,*) '         3D ahm1 array (k=1)'
98            CALL prihre( ahm1(:,:,1), jpi, jpj, 1, jpi, 1, 1, jpj, 1, 1.e-3, numout )
99            WRITE(numout,*)
100            WRITE(numout,*) '         3D ahm2 array (k=1)'
101            CALL prihre( ahm2(:,:,1), jpi, jpj, 1, jpi, 1, 1, jpj, 1, 1.e-3, numout )
102         ENDIF
103
104      ENDIF
105     
106
107      ! ahm3 and ahm4 at U- and V-points (used for bilaplacian operator
108      ! ================================  whatever its orientation is)
109      ! (USER: modify ahm3 and ahm4 following your desiderata)
110      ! Here: ahm is proportional to the cube of the maximum of the gridspacing
111      !       in the to horizontal direction
112
113      IF( ln_dynldf_bilap ) THEN
114
115         zd_max = MAX( MAXVAL( e1u(:,:) ), MAXVAL( e2u(:,:) ) )
116         IF( lk_mpp )   CALL mpp_max( zd_max )   ! max over the global domain
117
118         IF(lwp) WRITE(numout,*) '              bi-laplacian operator: ahm proportional to e1**3 '
119         IF(lwp) WRITE(numout,*) '              maximum grid-spacing = ', zd_max, ' maximum value for ahm = ', ahm0
120
121         za00 = ahm0_blp / ( zd_max * zd_max * zd_max )
122         DO jj = 1, jpj
123            DO ji = 1, jpi
124               zeumax = MAX( e1u(ji,jj), e2u(ji,jj) )
125               zevmax = MAX( e1v(ji,jj), e2v(ji,jj) )
126               ahm3(ji,jj,1) = za00 * zeumax * zeumax * zeumax
127               ahm4(ji,jj,1) = za00 * zevmax * zevmax * zevmax
128            END DO
129         END DO
130
131         zh = MAX( zh, fsdept(1,1,1) )   ! at least the first reach ahm0
132         IF( ln_zco ) THEN               ! z-coordinate, same profile everywhere
133            IF(lwp) WRITE(numout,'(36x," ahm ", 7x)')
134            DO jk = 1, jpk
135               IF( fsdept(1,1,jk) <= zh ) THEN
136                  zcoef(jk) = 1.e0
137               ELSE
138                  zcoef(jk) = 1.e0 + ( zr - 1.e0 )   &
139                     &               * (  1. - EXP( ( fsdept(1,1,jk   ) - zh ) / zh )  )   &
140                     &               / (  1. - EXP( ( fsdept(1,1,jpkm1) - zh ) / zh )  )
141               ENDIF
142               ahm3(:,:,jk) = ahm3(:,:,1) * zcoef(jk)
143               ahm4(:,:,jk) = ahm4(:,:,1) * zcoef(jk)
144               IF(lwp) WRITE(numout,'(34x,E7.2,8x,i3)') zcoef(jk) * ahm0, jk
145            END DO
146         ELSE                            ! partial steps or s-ccordinate
147            zc = MAXVAL( fsdept(:,:,jpkm1) )
148            IF( lk_mpp )   CALL mpp_max( zc )   ! max over the global domain
149
150            zc = 1. / (  1. - EXP( ( zc - zh ) / zh )  )
151            DO jk = 2, jpkm1
152               DO jj = 1, jpj
153                  DO ji = 1, jpi
154                     IF( fsdept(ji,jj,jk) <= zh ) THEN
155                        ahm3(ji,jj,jk) = ahm3(ji,jj,1)
156                        ahm4(ji,jj,jk) = ahm4(ji,jj,1)
157                     ELSE
158                        zd = 1.e0 + ( zr - 1.e0 ) * (  1. - EXP( ( fsdept(ji,jj,jk) - zh ) / zh )  ) * zc
159                        ahm3(ji,jj,jk) = ahm3(ji,jj,1) * zd
160                        ahm4(ji,jj,jk) = ahm4(ji,jj,1) * zd
161                     ENDIF
162                  END DO
163               END DO
164            END DO
165            ahm3(:,:,jpk) = ahm3(:,:,jpkm1)
166            ahm4(:,:,jpk) = ahm4(:,:,jpkm1)
167            IF(lwp) WRITE(numout,'(36x," ahm ", 7x)')
168            DO jk = 1, jpk
169               IF(lwp) WRITE(numout,'(30x,E10.2,8x,i3)') ahm3(1,1,jk), jk
170            END DO
171         ENDIF
172
173         ! Control print
174         IF( lwp .AND. ld_print ) THEN
175            WRITE(numout,*)
176            WRITE(numout,*) 'inildf: ahm3 array at level 1'
177            CALL prihre(ahm3(:,:,1  ),jpi,jpj,1,jpi,1,1,jpj,1,1.e-12,numout)
178            WRITE(numout,*)
179            WRITE(numout,*) 'inildf: ahm4 array at level 1'
180            CALL prihre(ahm4(:,:,jpk),jpi,jpj,1,jpi,1,1,jpj,1,1.e-12,numout)
181         ENDIF
182      ENDIF
183      !
184      CALL wrk_dealloc( jpk, zcoef )
185      !
186   END SUBROUTINE ldf_dyn_c3d
187
188
189   SUBROUTINE ldf_dyn_c3d_orca( ld_print )
190      !!----------------------------------------------------------------------
191      !!                  ***  ROUTINE ldf_dyn_c3d  ***
192      !!                   
193      !! ** Purpose :   ORCA R1, R2 and R4 only
194      !!
195      !! ** Method  :   blah blah blah ....
196      !!----------------------------------------------------------------------
197      USE ldftra_oce, ONLY:   aht0
198      !!
199      LOGICAL, INTENT(in) ::   ld_print   ! If true, output arrays on numout
200      !!
201      INTEGER ::   ji, jj, jk, jn      ! dummy loop indices
202      INTEGER ::   ii0, ii1, ij0, ij1  ! local integers
203      INTEGER ::   inum, iim, ijm      !
204      INTEGER ::   ifreq, il1, il2, ij, ii
205      REAL(wp) ::   zahmeq, zcoff, zcoft, zmsk   ! local scalars
206      REAL(wp) ::   zemax , zemin, zeref, zahmm
207      CHARACTER (len=15) ::   clexp
208      INTEGER , POINTER, DIMENSION(:,:)  :: icof
209      INTEGER , POINTER, DIMENSION(:,:)  :: idata
210      REAL(wp), POINTER, DIMENSION(:  )  :: zcoef   
211      REAL(wp), POINTER, DIMENSION(:,:)  :: zahm0
212      !!----------------------------------------------------------------------
213      !
214      CALL wrk_alloc( jpi   , jpj   , icof  )
215      CALL wrk_alloc( jpidta, jpjdta, idata )
216      CALL wrk_alloc( jpk   ,         zcoef )
217      CALL wrk_alloc( jpi   , jpj   , zahm0 )
218      !
219      IF(lwp) WRITE(numout,*)
220      IF(lwp) WRITE(numout,*) 'ldfdyn_c3d_orca : 3D eddy viscosity coefficient'
221      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~'
222      IF(lwp) WRITE(numout,*) '        orca R1, R2 or R4 configuration: reduced in the surface Eq. strip '
223
224      ! Read 2d integer array to specify western boundary increase in the
225      ! ===================== equatorial strip (20N-20S) defined at t-points
226
227      CALL ctl_opn( inum, 'ahmcoef', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
228      READ(inum,9101) clexp, iim, ijm
229      READ(inum,'(/)')
230      ifreq = 40
231      il1 = 1
232      DO jn = 1, jpidta/ifreq+1
233         READ(inum,'(/)')
234         il2 = MIN( jpidta, il1+ifreq-1 )
235         READ(inum,9201) ( ii, ji = il1, il2, 5 )
236         READ(inum,'(/)')
237         DO jj = jpjdta, 1, -1
238            READ(inum,9202) ij, ( idata(ji,jj), ji = il1, il2 )
239         END DO
240         il1 = il1 + ifreq
241      END DO
242     
243      DO jj = 1, nlcj
244         DO ji = 1, nlci
245            icof(ji,jj) = idata( mig(ji), mjg(jj) )
246         END DO
247      END DO
248      DO jj = nlcj+1, jpj
249         DO ji = 1, nlci
250            icof(ji,jj) = icof(ji,nlcj)
251         END DO
252      END DO
253      DO jj = 1, jpj
254         DO ji = nlci+1, jpi
255            icof(ji,jj) = icof(nlci,jj)
256         END DO
257      END DO
258     
2599101  FORMAT(1x,a15,2i8)
2609201  FORMAT(3x,13(i3,12x))
2619202  FORMAT(i3,41i3)
262     
263      ! Set ahm1 and ahm2
264      ! =================
265     
266      ! define ahm1 and ahm2 at the right grid point position
267      ! (USER: modify ahm1 and ahm2 following your desiderata)
268      ! biharmonic : ahm1 (ahm2) defined at u- (v-) point
269      ! harmonic   : ahm1 (ahm2) defined at t- (f-) point
270     
271      ! first level : as for 2D coefficients
272     
273      ! Decrease ahm to zahmeq m2/s in the tropics
274      ! (from 90 to 20 degre: ahm = constant
275      ! from 20 to  2.5 degre: ahm = decrease in (1-cos)/2
276      ! from  2.5 to  0 degre: ahm = constant
277      ! symmetric in the south hemisphere)
278     
279      IF( jp_cfg == 4 )   THEN
280         zahmeq = 5.0 * aht0
281         zahmm  = min( 160000.0, ahm0)
282         zemax = MAXVAL ( e1t(:,:) * e2t(:,:), tmask(:,:,1) .GE. 0.5 )
283         zemin = MINVAL ( e1t(:,:) * e2t(:,:), tmask(:,:,1) .GE. 0.5 )
284         zeref = MAXVAL ( e1t(:,:) * e2t(:,:),   &
285             &   tmask(:,:,1) .GE. 0.5 .AND. ABS(gphit(:,:)) .GT. 50. )
286 
287         DO jj = 1, jpj
288           DO ji = 1, jpi
289              zmsk = e1t(ji,jj) * e2t(ji,jj)
290              IF( abs(gphit(ji,jj)) .LE. 15 ) THEN
291                 zahm0(ji,jj) = ahm0
292              ELSE
293                 IF( zmsk .GE. zeref ) THEN
294                    zahm0(ji,jj) = ahm0
295                 ELSE
296                    zahm0(ji,jj) = zahmm + (ahm0-zahmm)*(1.0 -   &
297                        &          cos((rpi*0.5*(zmsk-zemin)/(zeref-zemin))))
298                 ENDIF
299              ENDIF
300           END DO
301         END DO
302      ENDIF
303
304      IF( jp_cfg == 2 )   THEN
305         zahmeq     = aht0
306         zahmm      = ahm0
307         zahm0(:,:) = ahm0
308      ENDIF
309
310      IF( jp_cfg == 1 )   THEN
311         zahmeq     = aht0  ! reduced to aht0 on equator; set to ahm0 if no tropical reduction is required
312         zahmm      = ahm0
313         zahm0(:,:) = ahm0
314      ENDIF
315
316      DO jj = 1, jpj
317         DO ji = 1, jpi
318            IF( ABS(gphif(ji,jj)) >= 20.) THEN
319               ahm2(ji,jj,1) =  zahm0(ji,jj)
320            ELSEIF( ABS(gphif(ji,jj)) <= 2.5) THEN
321               ahm2(ji,jj,1) =  zahmeq
322            ELSE
323               ahm2(ji,jj,1) = zahmeq + (zahm0(ji,jj)-zahmeq)/2.   &
324                  &            *(1.-COS( rad*(ABS(gphif(ji,jj))-2.5)*180./17.5 ) )
325            ENDIF
326            IF( ABS(gphit(ji,jj)) >= 20.) THEN
327               ahm1(ji,jj,1) =  zahm0(ji,jj)
328            ELSEIF( ABS(gphit(ji,jj)) <= 2.5) THEN
329               ahm1(ji,jj,1) =  zahmeq
330            ELSE
331               ahm1(ji,jj,1) = zahmeq + (zahm0(ji,jj)-zahmeq)/2.   &
332                  &            *(1.-COS( rad*(ABS(gphit(ji,jj))-2.5)*180./17.5 ) )
333            ENDIF
334         END DO
335      END DO
336     
337      ! increase along western boundaries of equatorial strip
338      ! t-point
339      DO jj = 1, jpjm1
340         DO ji = 1, jpim1
341            zcoft = float( icof(ji,jj) ) / 100.
342            ahm1(ji,jj,1) = zcoft * zahm0(ji,jj) + (1.-zcoft) * ahm1(ji,jj,1)
343         END DO
344      END DO
345      ! f-point
346      icof(:,:) = icof(:,:) * tmask(:,:,1)
347      DO jj = 1, jpjm1
348         DO ji = 1, jpim1   ! NO vector opt.
349            zmsk = tmask(ji,jj+1,1) + tmask(ji+1,jj+1,1) + tmask(ji,jj,1) + tmask(ji,jj+1,1)
350            IF( zmsk == 0. ) THEN
351               zcoff = 1.
352            ELSE
353               zcoff = FLOAT( icof(ji,jj+1) + icof(ji+1,jj+1) + icof(ji,jj) + icof(ji,jj+1) )   &
354                     / (zmsk * 100.)
355            ENDIF
356            ahm2(ji,jj,1) = zcoff * zahm0(ji,jj) + (1.-zcoff) * ahm2(ji,jj,1)
357         END DO
358      END DO
359
360      ! other level: re-increase the coef in the deep ocean
361      !==================================================================
362      ! Prior to v3.3, zcoeff was hardwired according to k-index jk.
363      !
364      ! From v3.3 onwards this has been generalised to a function of
365      ! depth so that it can be used with any number of levels.
366      !
367      ! The function has been chosen to match the original values (shown
368      ! in the following comments) when using the standard 31 ORCA levels. 
369      !     DO jk = 1, 21
370      !        zcoef(jk) = 1._wp
371      !     END DO
372      !     zcoef(22) = 2._wp
373      !     zcoef(23) = 3._wp
374      !     zcoef(24) = 5._wp
375      !     zcoef(25) = 7._wp
376      !     zcoef(26) = 9._wp
377      !     DO jk = 27, jpk
378      !        zcoef(jk) = 10._wp
379      !     END DO
380      !==================================================================
381
382       IF(lwp) THEN
383          WRITE(numout,*)
384          WRITE(numout,*) '         1D zcoef array '
385          WRITE(numout,*) '         ~~~~~~~~~~~~~~ '
386          WRITE(numout,*)
387          WRITE(numout,*) '    jk        zcoef '
388       ENDIF
389
390      DO jk=1, jpk
391         zcoef(jk) = 1.0_wp + NINT(9.0_wp*(gdept_0(jk)-800.0_wp)/(3000.0_wp-800.0_wp))
392         zcoef(jk) = MIN(10.0_wp, MAX(1.0_wp, zcoef(jk)))
393         IF(lwp) WRITE(numout,'(4x,i3,6x,f7.3)') jk,zcoef(jk)
394      END DO
395
396      DO jk = 2, jpk
397         ahm1(:,:,jk) = MIN( zahm0(:,:), zcoef(jk) * ahm1(:,:,1) )
398         ahm2(:,:,jk) = MIN( zahm0(:,:), zcoef(jk) * ahm2(:,:,1) )
399      END DO
400
401      IF( jp_cfg == 4 )   THEN         ! Limit AHM in Gibraltar strait
402         ij0 = 50   ;   ij1 = 53
403         ii0 = 69   ;   ii1 = 71
404         DO jk = 1, jpk
405            ahm1(mi0(ii0):mi1(ii1),mj0(ij0):mj1(ij1),jk) = MIN( zahmm, ahm1(mi0(ii0):mi1(ii1),mj0(ij0):mj1(ij1),jk) )
406            ahm2(mi0(ii0):mi1(ii1),mj0(ij0):mj1(ij1),jk) = MIN( zahmm, ahm2(mi0(ii0):mi1(ii1),mj0(ij0):mj1(ij1),jk) )
407         END DO
408      ENDIF
409      CALL lbc_lnk( ahm1, 'T', 1. )   ! Lateral boundary conditions (unchanged sign)
410      CALL lbc_lnk( ahm2, 'F', 1. )
411
412
413      IF(lwp) THEN                    ! Control print
414         WRITE(numout,*)
415         WRITE(numout,*) '         3D ahm1 array (k=1)'
416         CALL prihre( ahm1(:,:,1), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1.e-3, numout )
417         WRITE(numout,*)
418         WRITE(numout,*) '         3D ahm2 array (k=1)'
419         CALL prihre( ahm2(:,:,1), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1.e-3, numout )
420         WRITE(numout,*)
421         WRITE(numout,*) '         3D ahm2 array (k=jpk)'
422         CALL prihre( ahm2(:,:,jpk), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1.e-3, numout )
423      ENDIF
424
425
426      ! Set ahm3 and ahm4
427      ! =================
428
429      ! define ahm3 and ahm4 at the right grid point position
430      ! initialization to a constant value
431      !     (USER: modify ahm3 and ahm4 following your desiderata)
432      !     harmonic isopycnal or geopotential:
433      !                          ahm3 (ahm4) defined at u- (v-) point
434      DO jk = 1, jpk
435         DO jj = 2, jpj
436            DO ji = 2, jpi
437               ahm3(ji,jj,jk) = 0.5 * ( ahm2(ji,jj,jk) + ahm2(ji  ,jj-1,jk) )
438               ahm4(ji,jj,jk) = 0.5 * ( ahm2(ji,jj,jk) + ahm2(ji-1,jj  ,jk) )
439            END DO
440         END DO
441      END DO
442      ahm3 ( :, 1, :) = ahm3 ( :, 2, :)
443      ahm4 ( :, 1, :) = ahm4 ( :, 2, :)
444     
445      CALL lbc_lnk( ahm3, 'U', 1. )    ! Lateral boundary conditions (unchanged sign)
446      CALL lbc_lnk( ahm4, 'V', 1. )
447
448      ! Control print
449
450      IF( lwp .AND. ld_print ) THEN
451         WRITE(numout,*)
452         WRITE(numout,*) '         ahm3 array level 1'
453         CALL prihre(ahm3(:,:,1),jpi,jpj,1,jpi,1,1,jpj,1,1.e-3,numout)
454         WRITE(numout,*)
455         WRITE(numout,*) '         ahm4 array level 1'
456         CALL prihre(ahm4(:,:,1),jpi,jpj,1,jpi,1,1,jpj,1,1.e-3,numout)
457      ENDIF
458      !
459      CALL wrk_dealloc( jpi   , jpj   , icof  )
460      CALL wrk_dealloc( jpidta, jpjdta, idata )
461      CALL wrk_dealloc( jpk   ,         zcoef )
462      CALL wrk_dealloc( jpi   , jpj   , zahm0 )
463      !
464   END SUBROUTINE ldf_dyn_c3d_orca
Note: See TracBrowser for help on using the repository browser.