New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcfwb.F90 in branches/2013/dev_r3406_CNRS_LIM3/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2013/dev_r3406_CNRS_LIM3/NEMOGCM/NEMO/OPA_SRC/SBC/sbcfwb.F90 @ 3952

Last change on this file since 3952 was 3952, checked in by flavoni, 11 years ago

ok for LIM2, still reproducibility error on LIM3 case

  • Property svn:keywords set to Id
File size: 10.7 KB
Line 
1MODULE sbcfwb
2   !!======================================================================
3   !!                       ***  MODULE  sbcfwb  ***
4   !! Ocean fluxes   : domain averaged freshwater budget
5   !!======================================================================
6   !! History :  OPA  ! 2001-02  (E. Durand)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-08  (G. Madec)  Surface module
9   !!            3.2  ! 2009-07  (C. Talandier) emp mean s spread over erp area
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   sbc_fwb      : freshwater budget for global ocean configurations
14   !!                  in free surface and forced mode
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and tracers
17   USE dom_oce         ! ocean space and time domain
18   USE sbc_oce         ! surface ocean boundary condition
19   USE phycst          ! physical constants
20   USE sbcrnf          ! ocean runoffs
21   USE sbcssr          ! SS damping terms
22   USE in_out_manager  ! I/O manager
23   USE lib_mpp         ! distribued memory computing library
24   USE wrk_nemo        ! work arrays
25   USE timing          ! Timing
26   USE lbclnk          ! ocean lateral boundary conditions
27   USE lib_fortran
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   sbc_fwb    ! routine called by step
33
34   REAL(wp) ::   a_fwb_b   ! annual domain averaged freshwater budget
35   REAL(wp) ::   a_fwb     ! for 2 year before (_b) and before year.
36   REAL(wp) ::   fwfold    ! fwfold to be suppressed
37   REAL(wp) ::   area      ! global mean ocean surface (interior domain)
38
39   !! * Substitutions
40#  include "domzgr_substitute.h90"
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc )
50      !!---------------------------------------------------------------------
51      !!                  ***  ROUTINE sbc_fwb  ***
52      !!
53      !! ** Purpose :   Control the mean sea surface drift
54      !!
55      !! ** Method  :   several ways  depending on kn_fwb
56      !!                =0 no control
57      !!                =1 global mean of emp set to zero at each nn_fsbc time step
58      !!                =2 annual global mean corrected from previous year
59      !!                =3 global mean of emp set to zero at each nn_fsbc time step
60      !!                   & spread out over erp area depending its sign
61      !!----------------------------------------------------------------------
62      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
63      INTEGER, INTENT( in ) ::   kn_fsbc  !
64      INTEGER, INTENT( in ) ::   kn_fwb   ! ocean time-step index
65      !
66      INTEGER  ::   inum, ikty, iyear   ! local integers
67      REAL(wp) ::   z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp   ! local scalars
68      REAL(wp) ::   zsurf_neg, zsurf_pos, zsurf_tospread    !   -      -
69      REAL(wp), POINTER, DIMENSION(:,:) ::   ztmsk_neg, ztmsk_pos, ztmsk_tospread, z_wgt, zerp_cor
70      !!----------------------------------------------------------------------
71      !
72      IF( nn_timing == 1 )  CALL timing_start('sbc_fwb')
73      !
74      CALL wrk_alloc( jpi,jpj, ztmsk_neg, ztmsk_pos, ztmsk_tospread, z_wgt, zerp_cor )
75      !
76      IF( kt == nit000 ) THEN
77         IF(lwp) THEN
78            WRITE(numout,*)
79            WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction'
80            WRITE(numout,*) '~~~~~~~'
81            IF( kn_fwb == 1 )   WRITE(numout,*) '          instantaneously set to zero'
82            IF( kn_fwb == 2 )   WRITE(numout,*) '          adjusted from previous year budget'
83            IF( kn_fwb == 3 )   WRITE(numout,*) '          fwf set to zero and spread out over erp area'
84         ENDIF
85         !
86         IF( kn_fwb == 3 .AND. nn_sssr /= 2 )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 requires nn_sssr = 2, we stop ' )
87         !
88         area = glob_sum( e1e2t(:,:) )           ! interior global domain surface
89      ENDIF
90     
91
92      SELECT CASE ( kn_fwb )
93      !
94      CASE ( 1 )                             !==  global mean fwf set to zero  ==!
95         !
96         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
97            z_fwf = glob_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) ) ) / area   ! sum over the global domain
98            emp (:,:) = emp (:,:) - z_fwf 
99            erp (:,:) = erp (:,:) - z_fwf 
100#if defined key_lim2
101            emps(:,:) = emps(:,:) - z_fwf      ! emps is the mass flux in lim2 case
102#endif
103         ENDIF
104         !
105      CASE ( 2 )                             !==  fwf budget adjusted from the previous year  ==!
106         !
107         IF( kt == nit000 ) THEN                   ! initialisation
108            !                                         ! Read the corrective factor on precipitations (fwfold)
109            CALL ctl_opn( inum, 'EMPave_old.dat', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE. )
110            READ ( inum, "(24X,I8,2ES24.16)" ) iyear, a_fwb_b, a_fwb
111            CLOSE( inum )
112            fwfold = a_fwb                            ! current year freshwater budget correction
113            !                                         ! estimate from the previous year budget
114            IF(lwp)WRITE(numout,*)
115            IF(lwp)WRITE(numout,*)'sbc_fwb : year = ',iyear  , ' freshwater budget correction = ', fwfold
116            IF(lwp)WRITE(numout,*)'          year = ',iyear-1, ' freshwater budget read       = ', a_fwb
117            IF(lwp)WRITE(numout,*)'          year = ',iyear-2, ' freshwater budget read       = ', a_fwb_b
118         ENDIF   
119         !                                         ! Update fwfold if new year start
120         ikty = 365 * 86400 / rdttra(1)    !!bug  use of 365 days leap year or 360d year !!!!!!!
121         IF( MOD( kt, ikty ) == 0 ) THEN
122            a_fwb_b = a_fwb
123            a_fwb   = glob_sum( e1e2t(:,:) * sshn(:,:) )   ! sum over the global domain
124            a_fwb   = a_fwb * 1.e+3 / ( area * 86400. * 365. )     ! convert in Kg/m3/s = mm/s
125!!gm        !                                                      !!bug 365d year
126            fwfold =  a_fwb                           ! current year freshwater budget correction
127            !                                         ! estimate from the previous year budget
128         ENDIF
129         !
130         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN      ! correct the freshwater fluxes
131            emp (:,:) = emp (:,:) + fwfold
132            erp (:,:) = erp (:,:) + fwfold
133#if defined key_lim2
134            emps(:,:) = emps(:,:) + fwfold      ! emps is the mass flux in lim2 case
135#endif
136         ENDIF
137         !
138         IF( kt == nitend .AND. lwp ) THEN         ! save fwfold value in a file
139            CALL ctl_opn( inum, 'EMPave.dat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE., narea )
140            WRITE( inum, "(24X,I8,2ES24.16)" ) nyear, a_fwb_b, a_fwb
141            CLOSE( inum )
142         ENDIF
143         !
144      CASE ( 3 )                             !==  global fwf set to zero and spread out over erp area  ==!
145         !
146         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
147            ztmsk_pos(:,:) = tmask_i(:,:)                      ! Select <0 and >0 area of erp
148            WHERE( erp < 0._wp )   ztmsk_pos = 0._wp
149            ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:)
150            !
151            zsurf_neg = glob_sum( e1e2t(:,:)*ztmsk_neg(:,:) )   ! Area filled by <0 and >0 erp
152            zsurf_pos = glob_sum( e1e2t(:,:)*ztmsk_pos(:,:) )
153            !                                                  ! fwf global mean
154            z_fwf = glob_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) ) ) / area
155            !           
156            IF( z_fwf < 0._wp ) THEN         ! spread out over >0 erp area to increase evaporation
157                zsurf_tospread      = zsurf_pos
158                ztmsk_tospread(:,:) = ztmsk_pos(:,:)
159            ELSE                             ! spread out over <0 erp area to increase precipitation
160                zsurf_tospread      = zsurf_neg
161                ztmsk_tospread(:,:) = ztmsk_neg(:,:)
162            ENDIF
163            !
164            zsum_fwf   = glob_sum( e1e2t(:,:) * z_fwf )         ! fwf global mean over <0 or >0 erp area
165!!gm :  zsum_fwf   = z_fwf * area   ???  it is right?  I think so....
166            z_fwf_nsrf =  zsum_fwf / ( zsurf_tospread + rsmall )
167            !                                                  ! weight to respect erp field 2D structure
168            zsum_erp = glob_sum( ztmsk_tospread(:,:) * erp(:,:) * e1e2t(:,:) )
169            z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall )
170            !                                                  ! final correction term to apply
171            zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:)
172            !
173!!gm   ===>>>>  lbc_lnk should be useless as all the computation is done over the whole domain !
174            CALL lbc_lnk( zerp_cor, 'T', 1. )
175            !
176            emp (:,:) = emp (:,:) + zerp_cor(:,:)
177#if defined key_lim2
178            emps(:,:) = emps(:,:) + zerp_cor(:,:)      ! emps is the mass flux in lim2 case
179#endif
180            erp (:,:) = erp (:,:) + zerp_cor(:,:)
181            !
182            IF( nprint == 1 .AND. lwp ) THEN                   ! control print
183               IF( z_fwf < 0._wp ) THEN
184                  WRITE(numout,*)'   z_fwf < 0'
185                  WRITE(numout,*)'   SUM(erp+)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
186               ELSE
187                  WRITE(numout,*)'   z_fwf >= 0'
188                  WRITE(numout,*)'   SUM(erp-)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
189               ENDIF
190               WRITE(numout,*)'   SUM(empG)     = ', SUM( z_fwf*e1e2t(:,:) )*1.e-9,' Sv'
191               WRITE(numout,*)'   z_fwf         = ', z_fwf      ,' Kg/m2/s'
192               WRITE(numout,*)'   z_fwf_nsrf    = ', z_fwf_nsrf ,' Kg/m2/s'
193               WRITE(numout,*)'   MIN(zerp_cor) = ', MINVAL(zerp_cor) 
194               WRITE(numout,*)'   MAX(zerp_cor) = ', MAXVAL(zerp_cor) 
195            ENDIF
196         ENDIF
197         !
198      CASE DEFAULT                           !==  you should never be there  ==!
199         CALL ctl_stop( 'sbc_fwb : wrong nn_fwb value for the FreshWater Budget correction, choose either 1, 2 or 3' )
200         !
201      END SELECT
202      !
203      CALL wrk_dealloc( jpi,jpj, ztmsk_neg, ztmsk_pos, ztmsk_tospread, z_wgt, zerp_cor )
204      !
205      IF( nn_timing == 1 )  CALL timing_stop('sbc_fwb')
206      !
207   END SUBROUTINE sbc_fwb
208
209   !!======================================================================
210END MODULE sbcfwb
Note: See TracBrowser for help on using the repository browser.