New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcfwb.F90 in branches/2013/dev_r3406_CNRS_LIM3/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2013/dev_r3406_CNRS_LIM3/NEMOGCM/NEMO/OPA_SRC/SBC/sbcfwb.F90 @ 3962

Last change on this file since 3962 was 3962, checked in by gm, 11 years ago

dev_r3406_CNRS_LIM3: fix a bug in the freshwater budget correction, see ticket #1116

  • Property svn:keywords set to Id
File size: 11.4 KB
Line 
1MODULE sbcfwb
2   !!======================================================================
3   !!                       ***  MODULE  sbcfwb  ***
4   !! Ocean fluxes   : domain averaged freshwater budget
5   !!======================================================================
6   !! History :  OPA  ! 2001-02  (E. Durand)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-08  (G. Madec)  Surface module
9   !!            3.2  ! 2009-07  (C. Talandier) emp mean s spread over erp area
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   sbc_fwb      : freshwater budget for global ocean configurations
14   !!                  in free surface and forced mode
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and tracers
17   USE dom_oce         ! ocean space and time domain
18   USE sbc_oce         ! surface ocean boundary condition
19   USE phycst          ! physical constants
20   USE sbcrnf          ! ocean runoffs
21   USE sbcssr          ! SS damping terms
22   USE in_out_manager  ! I/O manager
23   USE lib_mpp         ! distribued memory computing library
24   USE wrk_nemo        ! work arrays
25   USE timing          ! Timing
26   USE lbclnk          ! ocean lateral boundary conditions
27   USE lib_fortran
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   sbc_fwb    ! routine called by step
33
34   REAL(wp) ::   a_fwb_b   ! annual domain averaged freshwater budget
35   REAL(wp) ::   a_fwb     ! for 2 year before (_b) and before year.
36   REAL(wp) ::   fwfold    ! fwfold to be suppressed
37   REAL(wp) ::   area      ! global mean ocean surface (interior domain)
38
39   !! * Substitutions
40#  include "domzgr_substitute.h90"
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc )
50      !!---------------------------------------------------------------------
51      !!                  ***  ROUTINE sbc_fwb  ***
52      !!
53      !! ** Purpose :   Control the mean sea surface drift
54      !!
55      !! ** Method  :   several ways  depending on kn_fwb
56      !!                =0 no control
57      !!                =1 global mean of emp set to zero at each nn_fsbc time step
58      !!                =2 annual global mean corrected from previous year
59      !!                =3 global mean of emp set to zero at each nn_fsbc time step
60      !!                   & spread out over erp area depending its sign
61      !! Note: if mass exchanges between ice and ocean, it is taken into account
62      !!       when computing the budget
63      !!----------------------------------------------------------------------
64      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
65      INTEGER, INTENT( in ) ::   kn_fsbc  !
66      INTEGER, INTENT( in ) ::   kn_fwb   ! ocean time-step index
67      !
68      INTEGER  ::   inum, ikty, iyear   ! local integers
69      REAL(wp) ::   z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp   ! local scalars
70      REAL(wp) ::   zsurf_neg, zsurf_pos, zsurf_tospread    !   -      -
71      REAL(wp), POINTER, DIMENSION(:,:) ::   ztmsk_neg, ztmsk_pos, ztmsk_tospread, z_wgt, zerp_cor
72      !!----------------------------------------------------------------------
73      !
74      IF( nn_timing == 1 )  CALL timing_start('sbc_fwb')
75      !
76      CALL wrk_alloc( jpi,jpj, ztmsk_neg, ztmsk_pos, ztmsk_tospread, z_wgt, zerp_cor )
77      !
78      IF( kt == nit000 ) THEN
79         IF(lwp) THEN
80            WRITE(numout,*)
81            WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction'
82            WRITE(numout,*) '~~~~~~~'
83            IF( kn_fwb == 1 )   WRITE(numout,*) '          instantaneously set to zero'
84            IF( kn_fwb == 2 )   WRITE(numout,*) '          adjusted from previous year budget'
85            IF( kn_fwb == 3 )   WRITE(numout,*) '          fwf set to zero and spread out over erp area'
86         ENDIF
87         !
88         IF( kn_fwb == 3 .AND. nn_sssr /= 2 )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 requires nn_sssr = 2, we stop ' )
89         !
90         area = glob_sum( e1e2t(:,:) )           ! interior global domain surface
91         !
92!!#if ! defined key_lim2 &&  ! defined key_lim3 && ! defined key_cice
93#if ! defined key_lim3
94         snwice_mass_b(:,:) = 0._wp              ! no sea-ice model is being used : no snow+ice mass
95         snwice_mass  (:,:) = 0._wp
96         snwice_fmass (:,:) = 0._wp 
97#endif
98         !
99      ENDIF
100     
101
102      SELECT CASE ( kn_fwb )
103      !
104      CASE ( 1 )                             !==  global mean fwf set to zero  ==!
105         !
106         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
107            z_fwf = glob_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) - snwice_fmass(:,:) ) ) / area   ! sum over the global domain
108            emp (:,:) = emp (:,:) - z_fwf 
109            erp (:,:) = erp (:,:) - z_fwf 
110#if defined key_lim2
111            emps(:,:) = emps(:,:) - z_fwf      ! emps is the mass flux in lim2 case
112#endif
113         ENDIF
114         !
115      CASE ( 2 )                             !==  fwf budget adjusted from the previous year  ==!
116         !
117         IF( kt == nit000 ) THEN                   ! initialisation
118            !                                         ! Read the corrective factor on precipitations (fwfold)
119            CALL ctl_opn( inum, 'EMPave_old.dat', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE. )
120            READ ( inum, "(24X,I8,2ES24.16)" ) iyear, a_fwb_b, a_fwb
121            CLOSE( inum )
122            fwfold = a_fwb                            ! current year freshwater budget correction
123            !                                         ! estimate from the previous year budget
124            IF(lwp)WRITE(numout,*)
125            IF(lwp)WRITE(numout,*)'sbc_fwb : year = ',iyear  , ' freshwater budget correction = ', fwfold
126            IF(lwp)WRITE(numout,*)'          year = ',iyear-1, ' freshwater budget read       = ', a_fwb
127            IF(lwp)WRITE(numout,*)'          year = ',iyear-2, ' freshwater budget read       = ', a_fwb_b
128         ENDIF   
129         !                                         ! Update fwfold if new year start
130         ikty = 365 * 86400 / rdttra(1)    !!bug  use of 365 days leap year or 360d year !!!!!!!
131         IF( MOD( kt, ikty ) == 0 ) THEN
132            a_fwb_b = a_fwb                           ! mean sea level taking into account the ice+snow
133                                                      ! sum over the global domain
134            a_fwb   = glob_sum( e1e2t(:,:) * ( sshn(:,:) + snwice_mass(:,:) * r1_rau0 ) )
135            a_fwb   = a_fwb * 1.e+3 / ( area * 86400. * 365. )     ! convert in Kg/m3/s = mm/s
136!!gm        !                                                      !!bug 365d year
137            fwfold =  a_fwb                           ! current year freshwater budget correction
138            !                                         ! estimate from the previous year budget
139         ENDIF
140         !
141         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN      ! correct the freshwater fluxes
142            emp (:,:) = emp (:,:) + fwfold
143            erp (:,:) = erp (:,:) + fwfold
144#if defined key_lim2
145            emps(:,:) = emps(:,:) + fwfold      ! emps is the mass flux in lim2 case
146#endif
147         ENDIF
148         !
149         IF( kt == nitend .AND. lwp ) THEN         ! save fwfold value in a file
150            CALL ctl_opn( inum, 'EMPave.dat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE., narea )
151            WRITE( inum, "(24X,I8,2ES24.16)" ) nyear, a_fwb_b, a_fwb
152            CLOSE( inum )
153         ENDIF
154         !
155      CASE ( 3 )                             !==  global fwf set to zero and spread out over erp area  ==!
156         !
157         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
158            ztmsk_pos(:,:) = tmask_i(:,:)                      ! Select <0 and >0 area of erp
159            WHERE( erp < 0._wp )   ztmsk_pos = 0._wp
160            ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:)
161            !
162            zsurf_neg = glob_sum( e1e2t(:,:)*ztmsk_neg(:,:) )   ! Area filled by <0 and >0 erp
163            zsurf_pos = glob_sum( e1e2t(:,:)*ztmsk_pos(:,:) )
164            !                                                  ! fwf global mean (excluding ocean to ice/snow exchanges)
165            z_fwf     = glob_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) - snwice_fmass(:,:) ) ) / area
166            !           
167            IF( z_fwf < 0._wp ) THEN         ! spread out over >0 erp area to increase evaporation
168                zsurf_tospread      = zsurf_pos
169                ztmsk_tospread(:,:) = ztmsk_pos(:,:)
170            ELSE                             ! spread out over <0 erp area to increase precipitation
171                zsurf_tospread      = zsurf_neg
172                ztmsk_tospread(:,:) = ztmsk_neg(:,:)
173            ENDIF
174            !
175            zsum_fwf   = glob_sum( e1e2t(:,:) * z_fwf )         ! fwf global mean over <0 or >0 erp area
176!!gm :  zsum_fwf   = z_fwf * area   ???  it is right?  I think so....
177            z_fwf_nsrf =  zsum_fwf / ( zsurf_tospread + rsmall )
178            !                                                  ! weight to respect erp field 2D structure
179            zsum_erp   = glob_sum( ztmsk_tospread(:,:) * erp(:,:) * e1e2t(:,:) )
180            z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall )
181            !                                                  ! final correction term to apply
182            zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:)
183            !
184!!gm   ===>>>>  lbc_lnk should be useless as all the computation is done over the whole domain !
185            CALL lbc_lnk( zerp_cor, 'T', 1. )
186            !
187            emp (:,:) = emp (:,:) + zerp_cor(:,:)
188#if defined key_lim2
189            emps(:,:) = emps(:,:) + zerp_cor(:,:)      ! emps is the mass flux in lim2 case
190#endif
191            erp (:,:) = erp (:,:) + zerp_cor(:,:)
192            !
193            IF( nprint == 1 .AND. lwp ) THEN                   ! control print
194               IF( z_fwf < 0._wp ) THEN
195                  WRITE(numout,*)'   z_fwf < 0'
196                  WRITE(numout,*)'   SUM(erp+)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
197               ELSE
198                  WRITE(numout,*)'   z_fwf >= 0'
199                  WRITE(numout,*)'   SUM(erp-)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
200               ENDIF
201               WRITE(numout,*)'   SUM(empG)     = ', SUM( z_fwf*e1e2t(:,:) )*1.e-9,' Sv'
202               WRITE(numout,*)'   z_fwf         = ', z_fwf      ,' Kg/m2/s'
203               WRITE(numout,*)'   z_fwf_nsrf    = ', z_fwf_nsrf ,' Kg/m2/s'
204               WRITE(numout,*)'   MIN(zerp_cor) = ', MINVAL(zerp_cor) 
205               WRITE(numout,*)'   MAX(zerp_cor) = ', MAXVAL(zerp_cor) 
206            ENDIF
207         ENDIF
208         !
209      CASE DEFAULT                           !==  you should never be there  ==!
210         CALL ctl_stop( 'sbc_fwb : wrong nn_fwb value for the FreshWater Budget correction, choose either 1, 2 or 3' )
211         !
212      END SELECT
213      !
214      CALL wrk_dealloc( jpi,jpj, ztmsk_neg, ztmsk_pos, ztmsk_tospread, z_wgt, zerp_cor )
215      !
216      IF( nn_timing == 1 )  CALL timing_stop('sbc_fwb')
217      !
218   END SUBROUTINE sbc_fwb
219
220   !!======================================================================
221END MODULE sbcfwb
Note: See TracBrowser for help on using the repository browser.