New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traqsr.F90 in branches/2013/dev_r3406_CNRS_LIM3/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2013/dev_r3406_CNRS_LIM3/NEMOGCM/NEMO/OPA_SRC/TRA/traqsr.F90 @ 3980

Last change on this file since 3980 was 3980, checked in by clem, 11 years ago

bug correction on solar flux penetration

  • Property svn:keywords set to Id
File size: 30.1 KB
Line 
1MODULE traqsr
2   !!======================================================================
3   !!                       ***  MODULE  traqsr  ***
4   !! Ocean physics: solar radiation penetration in the top ocean levels
5   !!======================================================================
6   !! History :  OPA  !  1990-10  (B. Blanke)  Original code
7   !!            7.0  !  1991-11  (G. Madec)
8   !!                 !  1996-01  (G. Madec)  s-coordinates
9   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
10   !!             -   !  2005-11  (G. Madec) zco, zps, sco coordinate
11   !!            3.2  !  2009-04  (G. Madec & NEMO team)
12   !!            4.0  !  2012-05  (C. Rousset) store attenuation coef for use in ice model
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   tra_qsr      : trend due to the solar radiation penetration
17   !!   tra_qsr_init : solar radiation penetration initialization
18   !!----------------------------------------------------------------------
19   USE oce             ! ocean dynamics and active tracers
20   USE dom_oce         ! ocean space and time domain
21   USE sbc_oce         ! surface boundary condition: ocean
22   USE trc_oce         ! share SMS/Ocean variables
23   USE trdmod_oce      ! ocean variables trends
24   USE trdtra          ! ocean active tracers trends
25   USE in_out_manager  ! I/O manager
26   USE phycst          ! physical constants
27   USE prtctl          ! Print control
28   USE iom             ! I/O manager
29   USE fldread         ! read input fields
30   USE restart         ! ocean restart
31   USE lib_mpp         ! MPP library
32   USE wrk_nemo       ! Memory Allocation
33   USE timing         ! Timing
34
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   tra_qsr       ! routine called by step.F90 (ln_traqsr=T)
40   PUBLIC   tra_qsr_init  ! routine called by opa.F90
41
42   !                                           !!* Namelist namtra_qsr: penetrative solar radiation
43   LOGICAL , PUBLIC ::   ln_traqsr  = .TRUE.    !: light absorption (qsr) flag
44   LOGICAL , PUBLIC ::   ln_qsr_rgb = .FALSE.   !: Red-Green-Blue light absorption flag 
45   LOGICAL , PUBLIC ::   ln_qsr_2bd = .TRUE.    !: 2 band         light absorption flag
46   LOGICAL , PUBLIC ::   ln_qsr_bio = .FALSE.   !: bio-model      light absorption flag
47   LOGICAL , PUBLIC ::   ln_qsr_ice = .FALSE.   !: light penetration for ice-model LIM3 (clem)
48   INTEGER , PUBLIC ::   nn_chldta  = 0         !: use Chlorophyll data (=1) or not (=0)
49   REAL(wp), PUBLIC ::   rn_abs     = 0.58_wp   !: fraction absorbed in the very near surface (RGB & 2 bands)
50   REAL(wp), PUBLIC ::   rn_si0     = 0.35_wp   !: very near surface depth of extinction      (RGB & 2 bands)
51   REAL(wp), PUBLIC ::   rn_si1     = 23.0_wp   !: deepest depth of extinction (water type I)       (2 bands)
52   
53   ! Module variables
54   REAL(wp) ::   xsi0r                           !: inverse of rn_si0
55   REAL(wp) ::   xsi1r                           !: inverse of rn_si1
56   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_chl   ! structure of input Chl (file informations, fields read)
57   INTEGER, PUBLIC ::   nksr              ! levels below which the light cannot penetrate ( depth larger than 391 m)
58   REAL(wp), DIMENSION(3,61) ::   rkrgb   !: tabulated attenuation coefficients for RGB absorption
59
60   !! * Substitutions
61#  include "domzgr_substitute.h90"
62#  include "vectopt_loop_substitute.h90"
63   !!----------------------------------------------------------------------
64   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
65   !! $Id$
66   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
67   !!----------------------------------------------------------------------
68CONTAINS
69
70   SUBROUTINE tra_qsr( kt )
71      !!----------------------------------------------------------------------
72      !!                  ***  ROUTINE tra_qsr  ***
73      !!
74      !! ** Purpose :   Compute the temperature trend due to the solar radiation
75      !!      penetration and add it to the general temperature trend.
76      !!
77      !! ** Method  : The profile of the solar radiation within the ocean is defined
78      !!      through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs
79      !!      Considering the 2 wavebands case:
80      !!         I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) )
81      !!         The temperature trend associated with the solar radiation penetration
82      !!         is given by : zta = 1/e3t dk[ I ] / (rau0*Cp)
83      !!         At the bottom, boudary condition for the radiation is no flux :
84      !!      all heat which has not been absorbed in the above levels is put
85      !!      in the last ocean level.
86      !!         In z-coordinate case, the computation is only done down to the
87      !!      level where I(k) < 1.e-15 W/m2. In addition, the coefficients
88      !!      used for the computation are calculated one for once as they
89      !!      depends on k only.
90      !!
91      !! ** Action  : - update ta with the penetrative solar radiation trend
92      !!              - save the trend in ttrd ('key_trdtra')
93      !!
94      !! Reference  : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
95      !!              Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516.
96      !!----------------------------------------------------------------------
97      !
98      INTEGER, INTENT(in) ::   kt     ! ocean time-step
99      !
100      INTEGER  ::   ji, jj, jk           ! dummy loop indices
101      INTEGER  ::   irgb                 ! local integers
102      REAL(wp) ::   zchl, zcoef, zfact   ! local scalars
103      REAL(wp) ::   zc0, zc1, zc2, zc3   !    -         -
104      REAL(wp) ::   zzc0, zzc1, zzc2, zzc3   !    -         -
105      REAL(wp) ::   zz0, zz1, z1_e3t     !    -         -
106      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
107      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea, ztrdt
108      !!----------------------------------------------------------------------
109      !
110      IF( nn_timing == 1 )  CALL timing_start('tra_qsr')
111      !
112      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        ) 
113      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
114      !
115      IF( kt == nit000 ) THEN
116         IF(lwp) WRITE(numout,*)
117         IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation'
118         IF(lwp) WRITE(numout,*) '~~~~~~~'
119         IF( .NOT.ln_traqsr )   RETURN
120      ENDIF
121
122      IF( l_trdtra ) THEN      ! Save ta and sa trends
123         CALL wrk_alloc( jpi, jpj, jpk, ztrdt ) 
124         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
125      ENDIF
126
127      !                                        Set before qsr tracer content field
128      !                                        ***********************************
129      IF( kt == nit000 ) THEN                     ! Set the forcing field at nit000 - 1
130         !                                        ! -----------------------------------
131         IF( ln_rstart .AND.    &                    ! Restart: read in restart file
132              & iom_varid( numror, 'qsr_hc_b', ldstop = .FALSE. ) > 0 ) THEN
133            IF(lwp) WRITE(numout,*) '          nit000-1 qsr tracer content forcing field red in the restart file'
134            zfact = 0.5e0
135            CALL iom_get( numror, jpdom_autoglo, 'qsr_hc_b', qsr_hc_b )   ! before heat content trend due to Qsr flux
136         ELSE                                           ! No restart or restart not found: Euler forward time stepping
137            zfact = 1.e0
138            qsr_hc_b(:,:,:) = 0.e0
139         ENDIF
140      ELSE                                        ! Swap of forcing field
141         !                                        ! ---------------------
142         zfact = 0.5e0
143         qsr_hc_b(:,:,:) = qsr_hc(:,:,:)
144      ENDIF
145      !                                        Compute now qsr tracer content field
146      !                                        ************************************
147     
148      !                                           ! ============================================== !
149      IF( lk_qsr_bio .AND. ln_qsr_bio ) THEN      !  bio-model fluxes  : all vertical coordinates  !
150         !                                        ! ============================================== !
151         DO jk = 1, jpkm1
152            qsr_hc(:,:,jk) = ro0cpr * ( etot3(:,:,jk) - etot3(:,:,jk+1) )
153         END DO
154         !                                        Add to the general trend
155         DO jk = 1, jpkm1
156            DO jj = 2, jpjm1 
157               DO ji = fs_2, fs_jpim1   ! vector opt.
158                  z1_e3t = zfact / fse3t(ji,jj,jk)
159                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
160               END DO
161            END DO
162         END DO
163         CALL iom_put( 'qsr3d', etot3 )   ! Shortwave Radiation 3D distribution
164         ! clem: store attenuation coefficient of the first ocean level
165         IF ( ln_qsr_ice ) THEN
166            DO jj = 1, jpj
167               DO ji = 1, jpi
168                  IF ( qsr(ji,jj) /= 0._wp ) THEN
169                     oatte(ji,jj) = ( qsr_hc(ji,jj,1) / ( ro0cpr * qsr(ji,jj) ) )
170                     iatte(ji,jj) = oatte(ji,jj)
171                  ENDIF
172               END DO
173            END DO
174         ENDIF
175         !                                        ! ============================================== !
176      ELSE                                        !  Ocean alone :
177         !                                        ! ============================================== !
178         !
179         !                                                ! ------------------------- !
180         IF( ln_qsr_rgb) THEN                             !  R-G-B  light penetration !
181            !                                             ! ------------------------- !
182            ! Set chlorophyl concentration
183            IF( nn_chldta == 1 .OR. lk_vvl ) THEN            !*  Variable Chlorophyll or ocean volume
184               !
185               IF( nn_chldta == 1 ) THEN                             !*  Variable Chlorophyll
186                  !
187                  CALL fld_read( kt, 1, sf_chl )                         ! Read Chl data and provides it at the current time step
188                  !         
189!CDIR COLLAPSE
190!CDIR NOVERRCHK
191                  DO jj = 1, jpj                                         ! Separation in R-G-B depending of the surface Chl
192!CDIR NOVERRCHK
193                     DO ji = 1, jpi
194                        zchl = MIN( 10. , MAX( 0.03, sf_chl(1)%fnow(ji,jj,1) ) )
195                        irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
196                        zekb(ji,jj) = rkrgb(1,irgb)
197                        zekg(ji,jj) = rkrgb(2,irgb)
198                        zekr(ji,jj) = rkrgb(3,irgb)
199                     END DO
200                  END DO
201               ELSE                                            ! Variable ocean volume but constant chrlorophyll
202                  zchl = 0.05                                     ! constant chlorophyll
203                  irgb = NINT( 41 + 20.*LOG10( zchl ) + 1.e-15 )
204                  zekb(:,:) = rkrgb(1,irgb)                       ! Separation in R-G-B depending of the chlorophyll
205                  zekg(:,:) = rkrgb(2,irgb)
206                  zekr(:,:) = rkrgb(3,irgb)
207               ENDIF
208               !
209               zcoef  = ( 1. - rn_abs ) / 3.e0                        ! equi-partition in R-G-B
210               ze0(:,:,1) = rn_abs  * qsr(:,:)
211               ze1(:,:,1) = zcoef * qsr(:,:)
212               ze2(:,:,1) = zcoef * qsr(:,:)
213               ze3(:,:,1) = zcoef * qsr(:,:)
214               zea(:,:,1) =         qsr(:,:)
215               !
216               DO jk = 2, nksr+1
217!CDIR NOVERRCHK
218                  DO jj = 1, jpj
219!CDIR NOVERRCHK   
220                     DO ji = 1, jpi
221                        zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r     )
222                        zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) )
223                        zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) )
224                        zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) )
225                        ze0(ji,jj,jk) = zc0
226                        ze1(ji,jj,jk) = zc1
227                        ze2(ji,jj,jk) = zc2
228                        ze3(ji,jj,jk) = zc3
229                        zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
230                     END DO
231                  END DO
232               END DO
233               ! clem: store attenuation coefficient of the first ocean level
234               IF ( ln_qsr_ice ) THEN
235                  DO jj = 1, jpj
236                     DO ji = 1, jpi
237                        zzc0 = rn_abs * EXP( - fse3t(ji,jj,1) * xsi0r     )
238                        zzc1 = zcoef  * EXP( - fse3t(ji,jj,1) * zekb(ji,jj) )
239                        zzc2 = zcoef  * EXP( - fse3t(ji,jj,1) * zekg(ji,jj) )
240                        zzc3 = zcoef  * EXP( - fse3t(ji,jj,1) * zekr(ji,jj) )
241                        oatte(ji,jj) = 1.0 - ( zzc0 + zzc1 + zzc2  + zzc3  ) * tmask(ji,jj,2) 
242                        iatte(ji,jj) = 1.0 - ( zzc0 + zzc1 + zcoef + zcoef ) * tmask(ji,jj,2)
243                     END DO
244                  END DO
245               ENDIF
246               !
247               DO jk = 1, nksr                                        ! compute and add qsr trend to ta
248                  qsr_hc(:,:,jk) = ro0cpr * ( zea(:,:,jk) - zea(:,:,jk+1) )
249               END DO
250               zea(:,:,nksr+1:jpk) = 0.e0     ! below 400m set to zero
251               CALL iom_put( 'qsr3d', zea )   ! Shortwave Radiation 3D distribution
252               !
253            ELSE                                                 !*  Constant Chlorophyll
254               DO jk = 1, nksr
255                  qsr_hc(:,:,jk) =  etot3(:,:,jk) * qsr(:,:)
256               END DO
257               ! clem: store attenuation coefficient of the first ocean level
258               IF ( ln_qsr_ice ) THEN
259                  oatte(:,:) = etot3(:,:,1) / ro0cpr
260                  iatte(:,:) = oatte(:,:)
261               ENDIF
262           ENDIF
263
264         ENDIF
265         !                                                ! ------------------------- !
266         IF( ln_qsr_2bd ) THEN                            !  2 band light penetration !
267            !                                             ! ------------------------- !
268            !
269            IF( lk_vvl ) THEN                                  !* variable volume
270               zz0   =        rn_abs   * ro0cpr
271               zz1   = ( 1. - rn_abs ) * ro0cpr
272               DO jk = 1, nksr                    ! solar heat absorbed at T-point in the top 400m
273                  DO jj = 1, jpj
274                     DO ji = 1, jpi
275                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
276                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
277                        qsr_hc(ji,jj,jk) = qsr(ji,jj) * ( zc0*tmask(ji,jj,jk) - zc1*tmask(ji,jj,jk+1) ) 
278                     END DO
279                  END DO
280               END DO
281               ! clem: store attenuation coefficient of the first ocean level
282               IF ( ln_qsr_ice ) THEN
283                  DO jj = 1, jpj
284                     DO ji = 1, jpi
285                        zc0 = zz0 * EXP( -fsdepw(ji,jj,1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,1)*xsi1r )
286                        zc1 = zz0 * EXP( -fsdepw(ji,jj,2)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,2)*xsi1r )
287                        oatte(ji,jj) = ( zc0*tmask(ji,jj,1) - zc1*tmask(ji,jj,2) ) / ro0cpr
288                        iatte(ji,jj) = oatte(ji,jj)
289                     END DO
290                  END DO
291               ENDIF
292            ELSE                                               !* constant volume: coef. computed one for all
293               DO jk = 1, nksr
294                  DO jj = 2, jpjm1
295                     DO ji = fs_2, fs_jpim1   ! vector opt.
296                        qsr_hc(ji,jj,jk) =  etot3(ji,jj,jk) * qsr(ji,jj)
297                     END DO
298                  END DO
299               END DO
300               ! clem: store attenuation coefficient of the first ocean level
301               IF ( ln_qsr_ice ) THEN
302                  oatte(:,:) = etot3(:,:,1) / ro0cpr
303                  iatte(:,:) = oatte(:,:)
304               ENDIF
305               !
306            ENDIF
307            !
308         ENDIF
309         !
310         !                                        Add to the general trend
311         DO jk = 1, nksr
312            DO jj = 2, jpjm1 
313               DO ji = fs_2, fs_jpim1   ! vector opt.
314                  z1_e3t = zfact / fse3t(ji,jj,jk)
315                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
316               END DO
317            END DO
318         END DO
319         !
320      ENDIF
321      ! clem: store attenuation coefficient of the first ocean level
322      !IF (ln_traqsr) THEN
323      !   DO jj = 1, jpj
324      !      DO ji = 1, jpi
325      !         IF ( qsr(ji,jj) /= 0._wp ) THEN
326      !            oatte(ji,jj) = qsr_hc(ji,jj,1) / ( ro0cpr * qsr(ji,jj) )
327      !            iatte(ji,jj) = qsr_hc(ji,jj,1) / ( ro0cpr * qsr(ji,jj) )
328      !         ENDIF
329      !      END DO
330      !   END DO
331      !END IF
332      !
333      IF( lrst_oce ) THEN   !                  Write in the ocean restart file
334         !                                     *******************************
335         IF(lwp) WRITE(numout,*)
336         IF(lwp) WRITE(numout,*) 'qsr tracer content forcing field written in ocean restart file ',   &
337            &                    'at it= ', kt,' date= ', ndastp
338         IF(lwp) WRITE(numout,*) '~~~~'
339         CALL iom_rstput( kt, nitrst, numrow, 'qsr_hc_b', qsr_hc )
340      ENDIF
341
342      IF( l_trdtra ) THEN     ! qsr tracers trends saved for diagnostics
343         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:)
344         CALL trd_tra( kt, 'TRA', jp_tem, jptra_trd_qsr, ztrdt )
345         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt ) 
346      ENDIF
347      !                       ! print mean trends (used for debugging)
348      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' qsr  - Ta: ', mask1=tmask, clinfo3='tra-ta' )
349      !
350      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        ) 
351      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
352      !
353      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr')
354      !
355   END SUBROUTINE tra_qsr
356
357
358   SUBROUTINE tra_qsr_init
359      !!----------------------------------------------------------------------
360      !!                  ***  ROUTINE tra_qsr_init  ***
361      !!
362      !! ** Purpose :   Initialization for the penetrative solar radiation
363      !!
364      !! ** Method  :   The profile of solar radiation within the ocean is set
365      !!      from two length scale of penetration (rn_si0,rn_si1) and a ratio
366      !!      (rn_abs). These parameters are read in the namtra_qsr namelist. The
367      !!      default values correspond to clear water (type I in Jerlov'
368      !!      (1968) classification.
369      !!         called by tra_qsr at the first timestep (nit000)
370      !!
371      !! ** Action  : - initialize rn_si0, rn_si1 and rn_abs
372      !!
373      !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
374      !!----------------------------------------------------------------------
375      !
376      INTEGER  ::   ji, jj, jk     ! dummy loop indices
377      INTEGER  ::   irgb, ierror, ioptio, nqsr   ! local integer
378      REAL(wp) ::   zz0, zc0  , zc1, zcoef       ! local scalars
379      REAL(wp) ::   zz1, zc2  , zc3, zchl        !   -      -
380      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
381      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea
382      !
383      CHARACTER(len=100) ::   cn_dir   ! Root directory for location of ssr files
384      TYPE(FLD_N)        ::   sn_chl   ! informations about the chlorofyl field to be read
385      !!
386      NAMELIST/namtra_qsr/  sn_chl, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio, ln_qsr_ice,  &
387         &                  nn_chldta, rn_abs, rn_si0, rn_si1
388      !!----------------------------------------------------------------------
389
390      !
391      IF( nn_timing == 1 )  CALL timing_start('tra_qsr_init')
392      !
393      ! clem init for oatte and iatte
394      oatte(:,:) = 1._wp
395      iatte(:,:) = 1._wp
396      !
397      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        ) 
398      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
399      !
400      cn_dir = './'       ! directory in which the model is executed
401      ! ... default values (NB: frequency positive => hours, negative => months)
402      !            !     file       ! frequency !  variable  ! time interp !  clim   ! 'yearly' or ! weights  ! rotation   !
403      !            !     name       !  (hours)  !    name    !    (T/F)    !  (T/F)  ! 'monthly'   ! filename ! pairs      !
404      sn_chl = FLD_N( 'chlorophyll' ,    -1     ,  'CHLA'    ,  .true.     , .true.  ,   'yearly'  , ''       , ''         )
405      !
406      REWIND( numnam )            ! Read Namelist namtra_qsr : ratio and length of penetration
407      READ  ( numnam, namtra_qsr )
408      !
409      IF(lwp) THEN                ! control print
410         WRITE(numout,*)
411         WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation'
412         WRITE(numout,*) '~~~~~~~~~~~~'
413         WRITE(numout,*) '   Namelist namtra_qsr : set the parameter of penetration'
414         WRITE(numout,*) '      Light penetration (T) or not (F)         ln_traqsr  = ', ln_traqsr
415         WRITE(numout,*) '      RGB (Red-Green-Blue) light penetration   ln_qsr_rgb = ', ln_qsr_rgb
416         WRITE(numout,*) '      2 band               light penetration   ln_qsr_2bd = ', ln_qsr_2bd
417         WRITE(numout,*) '      bio-model            light penetration   ln_qsr_bio = ', ln_qsr_bio
418         WRITE(numout,*) '      light penetration for ice-model LIM3     ln_qsr_ice = ', ln_qsr_ice
419         WRITE(numout,*) '      RGB : Chl data (=1) or cst value (=0)    nn_chldta  = ', nn_chldta
420         WRITE(numout,*) '      RGB & 2 bands: fraction of light (rn_si1)    rn_abs = ', rn_abs
421         WRITE(numout,*) '      RGB & 2 bands: shortess depth of extinction  rn_si0 = ', rn_si0
422         WRITE(numout,*) '      2 bands: longest depth of extinction         rn_si1 = ', rn_si1
423      ENDIF
424
425      IF( ln_traqsr ) THEN     ! control consistency
426         !                     
427         IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio )   THEN
428            CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' )
429            ln_qsr_bio = .FALSE.
430         ENDIF
431         !
432         ioptio = 0                      ! Parameter control
433         IF( ln_qsr_rgb  )   ioptio = ioptio + 1
434         IF( ln_qsr_2bd  )   ioptio = ioptio + 1
435         IF( ln_qsr_bio  )   ioptio = ioptio + 1
436         !
437         IF( ioptio /= 1 ) &
438            CALL ctl_stop( '          Choose ONE type of light penetration in namelist namtra_qsr',  &
439            &              ' 2 bands, 3 RGB bands or bio-model light penetration' )
440         !
441         IF( ln_qsr_rgb .AND. nn_chldta == 0 )   nqsr =  1 
442         IF( ln_qsr_rgb .AND. nn_chldta == 1 )   nqsr =  2
443         IF( ln_qsr_2bd                      )   nqsr =  3
444         IF( ln_qsr_bio                      )   nqsr =  4
445         !
446         IF(lwp) THEN                   ! Print the choice
447            WRITE(numout,*)
448            IF( nqsr ==  1 )   WRITE(numout,*) '         R-G-B   light penetration - Constant Chlorophyll'
449            IF( nqsr ==  2 )   WRITE(numout,*) '         R-G-B   light penetration - Chl data '
450            IF( nqsr ==  3 )   WRITE(numout,*) '         2 bands light penetration'
451            IF( nqsr ==  4 )   WRITE(numout,*) '         bio-model light penetration'
452         ENDIF
453         !
454      ENDIF
455      !                          ! ===================================== !
456      IF( ln_traqsr  ) THEN      !  Initialisation of Light Penetration  ! 
457         !                       ! ===================================== !
458         !
459         xsi0r = 1.e0 / rn_si0
460         xsi1r = 1.e0 / rn_si1
461         !                                ! ---------------------------------- !
462         IF( ln_qsr_rgb ) THEN            !  Red-Green-Blue light penetration  !
463            !                             ! ---------------------------------- !
464            !
465            CALL trc_oce_rgb( rkrgb )           !* tabulated attenuation coef.
466            !
467            !                                   !* level of light extinction
468            IF(  ln_sco ) THEN   ;   nksr = jpkm1
469            ELSE                 ;   nksr = trc_oce_ext_lev( r_si2, 0.33e2 )
470            ENDIF
471
472            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m'
473            !
474            IF( nn_chldta == 1 ) THEN           !* Chl data : set sf_chl structure
475               IF(lwp) WRITE(numout,*)
476               IF(lwp) WRITE(numout,*) '        Chlorophyll read in a file'
477               ALLOCATE( sf_chl(1), STAT=ierror )
478               IF( ierror > 0 ) THEN
479                  CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' )   ;   RETURN
480               ENDIF
481               ALLOCATE( sf_chl(1)%fnow(jpi,jpj,1)   )
482               IF( sn_chl%ln_tint )ALLOCATE( sf_chl(1)%fdta(jpi,jpj,1,2) )
483               !                                        ! fill sf_chl with sn_chl and control print
484               CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init',   &
485                  &                                         'Solar penetration function of read chlorophyll', 'namtra_qsr' )
486               !
487            ELSE                                !* constant Chl : compute once for all the distribution of light (etot3)
488               IF(lwp) WRITE(numout,*)
489               IF(lwp) WRITE(numout,*) '        Constant Chlorophyll concentration = 0.05'
490               IF( lk_vvl ) THEN                   ! variable volume
491                  IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
492               ELSE                                ! constant volume: computes one for all
493                  IF(lwp) WRITE(numout,*) '        fixed volume: light distribution computed one for all'
494                  !
495                  zchl = 0.05                                 ! constant chlorophyll
496                  irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
497                  zekb(:,:) = rkrgb(1,irgb)                   ! Separation in R-G-B depending of the chlorophyll
498                  zekg(:,:) = rkrgb(2,irgb)
499                  zekr(:,:) = rkrgb(3,irgb)
500                  !
501                  zcoef = ( 1. - rn_abs ) / 3.e0              ! equi-partition in R-G-B
502                  ze0(:,:,1) = rn_abs
503                  ze1(:,:,1) = zcoef
504                  ze2(:,:,1) = zcoef 
505                  ze3(:,:,1) = zcoef
506                  zea(:,:,1) = tmask(:,:,1)                   ! = ( ze0+ze1+z2+ze3 ) * tmask
507               
508                  DO jk = 2, nksr+1
509!CDIR NOVERRCHK
510                     DO jj = 1, jpj
511!CDIR NOVERRCHK   
512                        DO ji = 1, jpi
513                           zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * xsi0r     )
514                           zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * zekb(ji,jj) )
515                           zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * zekg(ji,jj) )
516                           zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * zekr(ji,jj) )
517                           ze0(ji,jj,jk) = zc0
518                           ze1(ji,jj,jk) = zc1
519                           ze2(ji,jj,jk) = zc2
520                           ze3(ji,jj,jk) = zc3
521                           zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
522                        END DO
523                     END DO
524                  END DO 
525                  !
526                  DO jk = 1, nksr
527                     etot3(:,:,jk) = ro0cpr * ( zea(:,:,jk) - zea(:,:,jk+1) ) 
528                  END DO
529                  etot3(:,:,nksr+1:jpk) = 0.e0                ! below 400m set to zero
530               ENDIF
531            ENDIF
532            !
533         ENDIF
534            !                             ! ---------------------------------- !
535         IF( ln_qsr_2bd ) THEN            !    2 bands    light penetration    !
536            !                             ! ---------------------------------- !
537            !
538            !                                ! level of light extinction
539            nksr = trc_oce_ext_lev( rn_si1, 1.e2 )
540            IF(lwp) THEN
541               WRITE(numout,*)
542            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m'
543            ENDIF
544            !
545            IF( lk_vvl ) THEN                   ! variable volume
546               IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
547            ELSE                                ! constant volume: computes one for all
548               zz0 =        rn_abs   * ro0cpr
549               zz1 = ( 1. - rn_abs ) * ro0cpr
550               DO jk = 1, nksr                    !*  solar heat absorbed at T-point computed once for all
551                  DO jj = 1, jpj                              ! top 400 meters
552                     DO ji = 1, jpi
553                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
554                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
555                        etot3(ji,jj,jk) = (  zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1)  ) 
556                     END DO
557                  END DO
558               END DO
559               etot3(:,:,nksr+1:jpk) = 0.e0                   ! below 400m set to zero
560               !
561            ENDIF
562         ENDIF
563         !                       ! ===================================== !
564      ELSE                       !        No light penetration           !                   
565         !                       ! ===================================== !
566         IF(lwp) THEN
567            WRITE(numout,*)
568            WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration'
569            WRITE(numout,*) '~~~~~~~~~~~~'
570         ENDIF
571      ENDIF
572      !
573      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        ) 
574      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
575      !
576      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr_init')
577      !
578   END SUBROUTINE tra_qsr_init
579
580   !!======================================================================
581END MODULE traqsr
Note: See TracBrowser for help on using the repository browser.