| 1 | MODULE nemogcm |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE nemogcm *** |
|---|
| 4 | !! Off-line Ocean : passive tracer evolution, dynamics read in files |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.3 ! 2010-05 (C. Ethe) Full reorganization of the off-line: phasing with the on-line |
|---|
| 7 | !! 4.0 ! 2011-01 (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation |
|---|
| 8 | !!---------------------------------------------------------------------- |
|---|
| 9 | |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | !! nemo_gcm : off-line: solve ocean tracer only |
|---|
| 12 | !! nemo_init : initialization of the nemo model |
|---|
| 13 | !! nemo_ctl : initialisation of algorithm flag |
|---|
| 14 | !! nemo_closefile : close remaining files |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | USE dom_oce ! ocean space domain variables |
|---|
| 17 | USE oce ! dynamics and tracers variables |
|---|
| 18 | USE c1d ! 1D configuration |
|---|
| 19 | USE domcfg ! domain configuration (dom_cfg routine) |
|---|
| 20 | USE domain ! domain initialization (dom_init routine) |
|---|
| 21 | USE istate ! initial state setting (istate_init routine) |
|---|
| 22 | USE eosbn2 ! equation of state (eos bn2 routine) |
|---|
| 23 | ! ! ocean physics |
|---|
| 24 | USE ldftra ! lateral diffusivity setting (ldf_tra_init routine) |
|---|
| 25 | USE ldfslp ! slopes of neutral surfaces (ldf_slp_init routine) |
|---|
| 26 | USE traqsr ! solar radiation penetration (tra_qsr_init routine) |
|---|
| 27 | USE trabbl ! bottom boundary layer (tra_bbl_init routine) |
|---|
| 28 | USE zdfini ! vertical physics: initialization |
|---|
| 29 | USE sbcmod ! surface boundary condition (sbc_init routine) |
|---|
| 30 | USE phycst ! physical constant (par_cst routine) |
|---|
| 31 | USE dtadyn ! Lecture and Interpolation of the dynamical fields |
|---|
| 32 | USE trcini ! Initilization of the passive tracers |
|---|
| 33 | USE daymod ! calendar (day routine) |
|---|
| 34 | USE trcstp ! passive tracer time-stepping (trc_stp routine) |
|---|
| 35 | USE dtadyn ! Lecture and interpolation of the dynamical fields |
|---|
| 36 | USE stpctl ! time stepping control (stp_ctl routine) |
|---|
| 37 | ! ! I/O & MPP |
|---|
| 38 | USE iom ! I/O library |
|---|
| 39 | USE in_out_manager ! I/O manager |
|---|
| 40 | USE mppini ! shared/distributed memory setting (mpp_init routine) |
|---|
| 41 | USE lib_mpp ! distributed memory computing |
|---|
| 42 | #if defined key_iomput |
|---|
| 43 | USE xios |
|---|
| 44 | #endif |
|---|
| 45 | USE prtctl ! Print control (prt_ctl_init routine) |
|---|
| 46 | USE timing ! Timing |
|---|
| 47 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 48 | |
|---|
| 49 | IMPLICIT NONE |
|---|
| 50 | PRIVATE |
|---|
| 51 | |
|---|
| 52 | PUBLIC nemo_gcm ! called by nemo.F90 |
|---|
| 53 | |
|---|
| 54 | CHARACTER (len=64) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing |
|---|
| 55 | |
|---|
| 56 | !!---------------------------------------------------------------------- |
|---|
| 57 | !! NEMO/OFF 3.3 , NEMO Consortium (2010) |
|---|
| 58 | !! $Id: nemogcm.F90 2528 2010-12-27 17:33:53Z rblod $ |
|---|
| 59 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 60 | !!---------------------------------------------------------------------- |
|---|
| 61 | CONTAINS |
|---|
| 62 | |
|---|
| 63 | SUBROUTINE nemo_gcm |
|---|
| 64 | !!---------------------------------------------------------------------- |
|---|
| 65 | !! *** ROUTINE nemo_gcm *** |
|---|
| 66 | !! |
|---|
| 67 | !! ** Purpose : nemo solves the primitive equations on an orthogonal |
|---|
| 68 | !! curvilinear mesh on the sphere. |
|---|
| 69 | !! |
|---|
| 70 | !! ** Method : - model general initialization |
|---|
| 71 | !! - launch the time-stepping (dta_dyn and trc_stp) |
|---|
| 72 | !! - finalize the run by closing files and communications |
|---|
| 73 | !! |
|---|
| 74 | !! References : Madec, Delecluse,Imbard, and Levy, 1997: internal report, IPSL. |
|---|
| 75 | !! Madec, 2008, internal report, IPSL. |
|---|
| 76 | !!---------------------------------------------------------------------- |
|---|
| 77 | INTEGER :: istp, indic ! time step index |
|---|
| 78 | !!---------------------------------------------------------------------- |
|---|
| 79 | |
|---|
| 80 | CALL nemo_init ! Initializations |
|---|
| 81 | |
|---|
| 82 | ! check that all process are still there... If some process have an error, |
|---|
| 83 | ! they will never enter in step and other processes will wait until the end of the cpu time! |
|---|
| 84 | IF( lk_mpp ) CALL mpp_max( nstop ) |
|---|
| 85 | |
|---|
| 86 | ! !-----------------------! |
|---|
| 87 | ! !== time stepping ==! |
|---|
| 88 | ! !-----------------------! |
|---|
| 89 | istp = nit000 |
|---|
| 90 | ! |
|---|
| 91 | CALL iom_init ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS) |
|---|
| 92 | ! |
|---|
| 93 | DO WHILE ( istp <= nitend .AND. nstop == 0 ) ! time stepping |
|---|
| 94 | ! |
|---|
| 95 | IF( istp /= nit000 ) CALL day ( istp ) ! Calendar (day was already called at nit000 in day_init) |
|---|
| 96 | CALL iom_setkt( istp - nit000 + 1 ) ! say to iom that we are at time step kstp |
|---|
| 97 | CALL dta_dyn ( istp ) ! Interpolation of the dynamical fields |
|---|
| 98 | CALL trc_stp ( istp ) ! time-stepping |
|---|
| 99 | CALL stp_ctl ( istp, indic ) ! Time loop: control and print |
|---|
| 100 | istp = istp + 1 |
|---|
| 101 | IF( lk_mpp ) CALL mpp_max( nstop ) |
|---|
| 102 | END DO |
|---|
| 103 | #if defined key_iomput |
|---|
| 104 | CALL xios_context_finalize() ! needed for XIOS+AGRIF |
|---|
| 105 | #endif |
|---|
| 106 | |
|---|
| 107 | ! !------------------------! |
|---|
| 108 | ! !== finalize the run ==! |
|---|
| 109 | ! !------------------------! |
|---|
| 110 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 111 | |
|---|
| 112 | IF( nstop /= 0 .AND. lwp ) THEN ! error print |
|---|
| 113 | WRITE(numout,cform_err) |
|---|
| 114 | WRITE(numout,*) nstop, ' error have been found' |
|---|
| 115 | ENDIF |
|---|
| 116 | ! |
|---|
| 117 | IF( nn_timing == 1 ) CALL timing_finalize |
|---|
| 118 | ! |
|---|
| 119 | CALL nemo_closefile |
|---|
| 120 | ! |
|---|
| 121 | # if defined key_iomput |
|---|
| 122 | CALL xios_finalize ! end mpp communications |
|---|
| 123 | # else |
|---|
| 124 | IF( lk_mpp ) CALL mppstop ! end mpp communications |
|---|
| 125 | # endif |
|---|
| 126 | ! |
|---|
| 127 | END SUBROUTINE nemo_gcm |
|---|
| 128 | |
|---|
| 129 | |
|---|
| 130 | SUBROUTINE nemo_init |
|---|
| 131 | !!---------------------------------------------------------------------- |
|---|
| 132 | !! *** ROUTINE nemo_init *** |
|---|
| 133 | !! |
|---|
| 134 | !! ** Purpose : initialization of the nemo model in off-line mode |
|---|
| 135 | !!---------------------------------------------------------------------- |
|---|
| 136 | INTEGER :: ji ! dummy loop indices |
|---|
| 137 | INTEGER :: ilocal_comm ! local integer |
|---|
| 138 | INTEGER :: ios |
|---|
| 139 | CHARACTER(len=80), DIMENSION(16) :: cltxt |
|---|
| 140 | !! |
|---|
| 141 | NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, & |
|---|
| 142 | & nn_isplt, nn_jsplt, nn_jctls, nn_jctle, & |
|---|
| 143 | & nn_bench, nn_timing |
|---|
| 144 | NAMELIST/namcfg/ cp_cfg, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, & |
|---|
| 145 | & jpizoom, jpjzoom, jperio, jphgr_msh, & |
|---|
| 146 | & ppglam0, ppgphi0, ppe1_deg, ppe2_deg, ppe1_m, ppe2_m, & |
|---|
| 147 | & ppsur, ppa0, ppa1, ppkth, ppacr, ppdzmin, pphmax, ldbletanh, & |
|---|
| 148 | & ppa2, ppkth2, ppacr2 |
|---|
| 149 | !!---------------------------------------------------------------------- |
|---|
| 150 | ! |
|---|
| 151 | cltxt = '' |
|---|
| 152 | ! |
|---|
| 153 | ! ! Open reference namelist and configuration namelist files |
|---|
| 154 | CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. ) |
|---|
| 155 | CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. ) |
|---|
| 156 | CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea ) |
|---|
| 157 | ! |
|---|
| 158 | ! |
|---|
| 159 | REWIND( numnam_ref ) ! Namelist namctl in reference namelist : Control prints & Benchmark |
|---|
| 160 | READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 ) |
|---|
| 161 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', lwp ) |
|---|
| 162 | |
|---|
| 163 | REWIND( numnam_cfg ) ! Namelist namctl in confguration namelist : Control prints & Benchmark |
|---|
| 164 | READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 ) |
|---|
| 165 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', lwp ) |
|---|
| 166 | WRITE( numond, namctl ) |
|---|
| 167 | ! |
|---|
| 168 | REWIND( numnam_ref ) ! Namelist namcfg in reference namelist : Control prints & Benchmark |
|---|
| 169 | READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 ) |
|---|
| 170 | 903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', lwp ) |
|---|
| 171 | |
|---|
| 172 | REWIND( numnam_cfg ) ! Namelist namcfg in confguration namelist : Control prints & Benchmark |
|---|
| 173 | READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 ) |
|---|
| 174 | 904 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', lwp ) |
|---|
| 175 | WRITE( numond, namcfg ) |
|---|
| 176 | ! !--------------------------------------------! |
|---|
| 177 | ! ! set communicator & select the local node ! |
|---|
| 178 | ! !--------------------------------------------! |
|---|
| 179 | #if defined key_iomput |
|---|
| 180 | CALL xios_initialize( "nemo",return_comm=ilocal_comm ) |
|---|
| 181 | narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm ) ! Nodes selection |
|---|
| 182 | #else |
|---|
| 183 | ilocal_comm = 0 |
|---|
| 184 | narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop ) ! Nodes selection (control print return in cltxt) |
|---|
| 185 | #endif |
|---|
| 186 | |
|---|
| 187 | narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 ) |
|---|
| 188 | |
|---|
| 189 | lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print |
|---|
| 190 | |
|---|
| 191 | ! If dimensions of processor grid weren't specified in the namelist file |
|---|
| 192 | ! then we calculate them here now that we have our communicator size |
|---|
| 193 | IF( (jpni < 1) .OR. (jpnj < 1) )THEN |
|---|
| 194 | #if defined key_mpp_mpi |
|---|
| 195 | CALL nemo_partition(mppsize) |
|---|
| 196 | #else |
|---|
| 197 | jpni = 1 |
|---|
| 198 | jpnj = 1 |
|---|
| 199 | jpnij = jpni*jpnj |
|---|
| 200 | #endif |
|---|
| 201 | END IF |
|---|
| 202 | |
|---|
| 203 | ! Calculate domain dimensions given calculated jpni and jpnj |
|---|
| 204 | ! This used to be done in par_oce.F90 when they were parameters rather |
|---|
| 205 | ! than variables |
|---|
| 206 | jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci ! first dim. |
|---|
| 207 | jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim. |
|---|
| 208 | jpk = jpkdta ! third dim |
|---|
| 209 | jpim1 = jpi-1 ! inner domain indices |
|---|
| 210 | jpjm1 = jpj-1 ! " " |
|---|
| 211 | jpkm1 = jpk-1 ! " " |
|---|
| 212 | jpij = jpi*jpj ! jpi x j |
|---|
| 213 | |
|---|
| 214 | |
|---|
| 215 | IF(lwp) THEN ! open listing units |
|---|
| 216 | ! |
|---|
| 217 | CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea ) |
|---|
| 218 | ! |
|---|
| 219 | WRITE(numout,*) |
|---|
| 220 | WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC' |
|---|
| 221 | WRITE(numout,*) ' NEMO team' |
|---|
| 222 | WRITE(numout,*) ' Ocean General Circulation Model' |
|---|
| 223 | WRITE(numout,*) ' version 3.5 (2012) ' |
|---|
| 224 | WRITE(numout,*) |
|---|
| 225 | WRITE(numout,*) |
|---|
| 226 | DO ji = 1, SIZE(cltxt) |
|---|
| 227 | IF( TRIM(cltxt(ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode |
|---|
| 228 | END DO |
|---|
| 229 | WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 230 | ! |
|---|
| 231 | ENDIF |
|---|
| 232 | |
|---|
| 233 | ! Now we know the dimensions of the grid and numout has been set we can |
|---|
| 234 | ! allocate arrays |
|---|
| 235 | CALL nemo_alloc() |
|---|
| 236 | |
|---|
| 237 | ! !--------------------------------! |
|---|
| 238 | ! ! Model general initialization ! |
|---|
| 239 | ! !--------------------------------! |
|---|
| 240 | |
|---|
| 241 | CALL nemo_ctl ! Control prints & Benchmark |
|---|
| 242 | |
|---|
| 243 | ! ! Domain decomposition |
|---|
| 244 | IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out |
|---|
| 245 | ELSE ; CALL mpp_init2 ! eliminate land processors |
|---|
| 246 | ENDIF |
|---|
| 247 | ! |
|---|
| 248 | IF( nn_timing == 1 ) CALL timing_init |
|---|
| 249 | ! |
|---|
| 250 | |
|---|
| 251 | ! ! General initialization |
|---|
| 252 | IF( nn_timing == 1 ) CALL timing_start( 'nemo_init') |
|---|
| 253 | ! |
|---|
| 254 | CALL phy_cst ! Physical constants |
|---|
| 255 | CALL eos_init ! Equation of state |
|---|
| 256 | CALL dom_cfg ! Domain configuration |
|---|
| 257 | CALL dom_init ! Domain |
|---|
| 258 | CALL istate_init ! ocean initial state (Dynamics and tracers) |
|---|
| 259 | |
|---|
| 260 | IF( ln_nnogather ) CALL nemo_northcomms ! Initialise the northfold neighbour lists (must be done after the masks are defined) |
|---|
| 261 | |
|---|
| 262 | IF( ln_ctl ) CALL prt_ctl_init ! Print control |
|---|
| 263 | |
|---|
| 264 | ! ! Ocean physics |
|---|
| 265 | CALL sbc_init ! Forcings : surface module |
|---|
| 266 | #if ! defined key_degrad |
|---|
| 267 | CALL ldf_tra_init ! Lateral ocean tracer physics |
|---|
| 268 | #endif |
|---|
| 269 | IF( lk_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing |
|---|
| 270 | |
|---|
| 271 | ! ! Active tracers |
|---|
| 272 | CALL tra_qsr_init ! penetrative solar radiation qsr |
|---|
| 273 | IF( lk_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme |
|---|
| 274 | |
|---|
| 275 | ! ! Passive tracers |
|---|
| 276 | CALL trc_init ! Passive tracers initialization |
|---|
| 277 | ! ! Dynamics |
|---|
| 278 | CALL dta_dyn_init ! Initialization for the dynamics |
|---|
| 279 | |
|---|
| 280 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 281 | ! |
|---|
| 282 | IF( nn_timing == 1 ) CALL timing_stop( 'nemo_init') |
|---|
| 283 | ! |
|---|
| 284 | END SUBROUTINE nemo_init |
|---|
| 285 | |
|---|
| 286 | |
|---|
| 287 | SUBROUTINE nemo_ctl |
|---|
| 288 | !!---------------------------------------------------------------------- |
|---|
| 289 | !! *** ROUTINE nemo_ctl *** |
|---|
| 290 | !! |
|---|
| 291 | !! ** Purpose : control print setting |
|---|
| 292 | !! |
|---|
| 293 | !! ** Method : - print namctl information and check some consistencies |
|---|
| 294 | !!---------------------------------------------------------------------- |
|---|
| 295 | ! |
|---|
| 296 | IF(lwp) THEN ! Parameter print |
|---|
| 297 | WRITE(numout,*) |
|---|
| 298 | WRITE(numout,*) 'nemo_flg: Control prints & Benchmark' |
|---|
| 299 | WRITE(numout,*) '~~~~~~~ ' |
|---|
| 300 | WRITE(numout,*) ' Namelist namctl' |
|---|
| 301 | WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl |
|---|
| 302 | WRITE(numout,*) ' level of print nn_print = ', nn_print |
|---|
| 303 | WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls |
|---|
| 304 | WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle |
|---|
| 305 | WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls |
|---|
| 306 | WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle |
|---|
| 307 | WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt |
|---|
| 308 | WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt |
|---|
| 309 | WRITE(numout,*) ' benchmark parameter (0/1) nn_bench = ', nn_bench |
|---|
| 310 | ENDIF |
|---|
| 311 | ! |
|---|
| 312 | nprint = nn_print ! convert DOCTOR namelist names into OLD names |
|---|
| 313 | nictls = nn_ictls |
|---|
| 314 | nictle = nn_ictle |
|---|
| 315 | njctls = nn_jctls |
|---|
| 316 | njctle = nn_jctle |
|---|
| 317 | isplt = nn_isplt |
|---|
| 318 | jsplt = nn_jsplt |
|---|
| 319 | nbench = nn_bench |
|---|
| 320 | IF(lwp) THEN ! control print |
|---|
| 321 | WRITE(numout,*) |
|---|
| 322 | WRITE(numout,*) 'namcfg : configuration initialization through namelist read' |
|---|
| 323 | WRITE(numout,*) '~~~~~~~ ' |
|---|
| 324 | WRITE(numout,*) ' Namelist namcfg' |
|---|
| 325 | WRITE(numout,*) ' configuration name cp_cfg = ', TRIM(cp_cfg) |
|---|
| 326 | WRITE(numout,*) ' configuration resolution jp_cfg = ', jp_cfg |
|---|
| 327 | WRITE(numout,*) ' 1st lateral dimension ( >= jpi ) jpidta = ', jpidta |
|---|
| 328 | WRITE(numout,*) ' 2nd " " ( >= jpj ) jpjdta = ', jpjdta |
|---|
| 329 | WRITE(numout,*) ' 3nd " " jpkdta = ', jpkdta |
|---|
| 330 | WRITE(numout,*) ' 1st dimension of global domain in i jpiglo = ', jpiglo |
|---|
| 331 | WRITE(numout,*) ' 2nd - - in j jpjglo = ', jpjglo |
|---|
| 332 | WRITE(numout,*) ' left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom |
|---|
| 333 | WRITE(numout,*) ' left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom |
|---|
| 334 | WRITE(numout,*) ' lateral cond. type (between 0 and 6) jperio = ', jperio |
|---|
| 335 | WRITE(numout,*) ' type of horizontal mesh jphgr_msh = ', jphgr_msh |
|---|
| 336 | WRITE(numout,*) ' longitude of first raw and column T-point ppglam0 = ', ppglam0 |
|---|
| 337 | WRITE(numout,*) ' latitude of first raw and column T-point ppgphi0 = ', ppgphi0 |
|---|
| 338 | WRITE(numout,*) ' zonal grid-spacing (degrees) ppe1_deg = ', ppe1_deg |
|---|
| 339 | WRITE(numout,*) ' meridional grid-spacing (degrees) ppe2_deg = ', ppe2_deg |
|---|
| 340 | WRITE(numout,*) ' zonal grid-spacing (degrees) ppe1_m = ', ppe1_m |
|---|
| 341 | WRITE(numout,*) ' meridional grid-spacing (degrees) ppe2_m = ', ppe2_m |
|---|
| 342 | WRITE(numout,*) ' ORCA r4, r2 and r05 coefficients ppsur = ', ppsur |
|---|
| 343 | WRITE(numout,*) ' ppa0 = ', ppa0 |
|---|
| 344 | WRITE(numout,*) ' ppa1 = ', ppa1 |
|---|
| 345 | WRITE(numout,*) ' ppkth = ', ppkth |
|---|
| 346 | WRITE(numout,*) ' ppacr = ', ppacr |
|---|
| 347 | WRITE(numout,*) ' Minimum vertical spacing ppdzmin = ', ppdzmin |
|---|
| 348 | WRITE(numout,*) ' Maximum depth pphmax = ', pphmax |
|---|
| 349 | WRITE(numout,*) ' Use double tanf function for vertical coordinates ldbletanh = ', ldbletanh |
|---|
| 350 | WRITE(numout,*) ' Double tanh function parameters ppa2 = ', ppa2 |
|---|
| 351 | WRITE(numout,*) ' ppkth2 = ', ppkth2 |
|---|
| 352 | WRITE(numout,*) ' ppacr2 = ', ppacr2 |
|---|
| 353 | ENDIF |
|---|
| 354 | ! ! Parameter control |
|---|
| 355 | ! |
|---|
| 356 | IF( ln_ctl ) THEN ! sub-domain area indices for the control prints |
|---|
| 357 | IF( lk_mpp ) THEN |
|---|
| 358 | isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real splitted domain |
|---|
| 359 | ELSE |
|---|
| 360 | IF( isplt == 1 .AND. jsplt == 1 ) THEN |
|---|
| 361 | CALL ctl_warn( ' - isplt & jsplt are equal to 1', & |
|---|
| 362 | & ' - the print control will be done over the whole domain' ) |
|---|
| 363 | ENDIF |
|---|
| 364 | ijsplt = isplt * jsplt ! total number of processors ijsplt |
|---|
| 365 | ENDIF |
|---|
| 366 | IF(lwp) WRITE(numout,*)' - The total number of processors over which the' |
|---|
| 367 | IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt |
|---|
| 368 | ! |
|---|
| 369 | ! ! indices used for the SUM control |
|---|
| 370 | IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area |
|---|
| 371 | lsp_area = .FALSE. |
|---|
| 372 | ELSE ! print control done over a specific area |
|---|
| 373 | lsp_area = .TRUE. |
|---|
| 374 | IF( nictls < 1 .OR. nictls > jpiglo ) THEN |
|---|
| 375 | CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' ) |
|---|
| 376 | nictls = 1 |
|---|
| 377 | ENDIF |
|---|
| 378 | IF( nictle < 1 .OR. nictle > jpiglo ) THEN |
|---|
| 379 | CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' ) |
|---|
| 380 | nictle = jpiglo |
|---|
| 381 | ENDIF |
|---|
| 382 | IF( njctls < 1 .OR. njctls > jpjglo ) THEN |
|---|
| 383 | CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' ) |
|---|
| 384 | njctls = 1 |
|---|
| 385 | ENDIF |
|---|
| 386 | IF( njctle < 1 .OR. njctle > jpjglo ) THEN |
|---|
| 387 | CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' ) |
|---|
| 388 | njctle = jpjglo |
|---|
| 389 | ENDIF |
|---|
| 390 | ENDIF |
|---|
| 391 | ENDIF |
|---|
| 392 | ! |
|---|
| 393 | IF( nbench == 1 ) THEN ! Benchmark |
|---|
| 394 | SELECT CASE ( cp_cfg ) |
|---|
| 395 | CASE ( 'gyre' ) ; CALL ctl_warn( ' The Benchmark is activated ' ) |
|---|
| 396 | CASE DEFAULT ; CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:', & |
|---|
| 397 | & ' cp_cfg="gyre" in namelsit &namcfg or set nbench = 0' ) |
|---|
| 398 | END SELECT |
|---|
| 399 | ENDIF |
|---|
| 400 | ! |
|---|
| 401 | IF( lk_c1d .AND. .NOT.lk_iomput ) CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ', & |
|---|
| 402 | & 'with the IOM Input/Output manager. ' , & |
|---|
| 403 | & 'Compile with key_iomput enabled' ) |
|---|
| 404 | ! |
|---|
| 405 | IF( 1_wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ', & |
|---|
| 406 | & 'f2003 standard. ' , & |
|---|
| 407 | & 'Compile with key_nosignedzero enabled' ) |
|---|
| 408 | ! |
|---|
| 409 | END SUBROUTINE nemo_ctl |
|---|
| 410 | |
|---|
| 411 | |
|---|
| 412 | SUBROUTINE nemo_closefile |
|---|
| 413 | !!---------------------------------------------------------------------- |
|---|
| 414 | !! *** ROUTINE nemo_closefile *** |
|---|
| 415 | !! |
|---|
| 416 | !! ** Purpose : Close the files |
|---|
| 417 | !!---------------------------------------------------------------------- |
|---|
| 418 | ! |
|---|
| 419 | IF ( lk_mpp ) CALL mppsync |
|---|
| 420 | ! |
|---|
| 421 | CALL iom_close ! close all input/output files managed by iom_* |
|---|
| 422 | ! |
|---|
| 423 | IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file |
|---|
| 424 | IF( numnam_ref /= -1 ) CLOSE( numnam_ref ) ! oce reference namelist |
|---|
| 425 | IF( numnam_cfg /= -1 ) CLOSE( numnam_cfg ) ! oce configuration namelist |
|---|
| 426 | IF( numout /= 6 ) CLOSE( numout ) ! standard model output file |
|---|
| 427 | numout = 6 ! redefine numout in case it is used after this point... |
|---|
| 428 | ! |
|---|
| 429 | END SUBROUTINE nemo_closefile |
|---|
| 430 | |
|---|
| 431 | |
|---|
| 432 | SUBROUTINE nemo_alloc |
|---|
| 433 | !!---------------------------------------------------------------------- |
|---|
| 434 | !! *** ROUTINE nemo_alloc *** |
|---|
| 435 | !! |
|---|
| 436 | !! ** Purpose : Allocate all the dynamic arrays of the OPA modules |
|---|
| 437 | !! |
|---|
| 438 | !! ** Method : |
|---|
| 439 | !!---------------------------------------------------------------------- |
|---|
| 440 | USE diawri, ONLY: dia_wri_alloc |
|---|
| 441 | USE dom_oce, ONLY: dom_oce_alloc |
|---|
| 442 | USE zdf_oce, ONLY: zdf_oce_alloc |
|---|
| 443 | USE ldftra_oce, ONLY: ldftra_oce_alloc |
|---|
| 444 | USE trc_oce, ONLY: trc_oce_alloc |
|---|
| 445 | ! |
|---|
| 446 | INTEGER :: ierr |
|---|
| 447 | !!---------------------------------------------------------------------- |
|---|
| 448 | ! |
|---|
| 449 | ierr = oce_alloc () ! ocean |
|---|
| 450 | ierr = ierr + dia_wri_alloc () |
|---|
| 451 | ierr = ierr + dom_oce_alloc () ! ocean domain |
|---|
| 452 | ierr = ierr + ldftra_oce_alloc() ! ocean lateral physics : tracers |
|---|
| 453 | ierr = ierr + zdf_oce_alloc () ! ocean vertical physics |
|---|
| 454 | ! |
|---|
| 455 | ierr = ierr + lib_mpp_alloc (numout) ! mpp exchanges |
|---|
| 456 | ierr = ierr + trc_oce_alloc () ! shared TRC / TRA arrays |
|---|
| 457 | ! |
|---|
| 458 | IF( lk_mpp ) CALL mpp_sum( ierr ) |
|---|
| 459 | IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' ) |
|---|
| 460 | ! |
|---|
| 461 | END SUBROUTINE nemo_alloc |
|---|
| 462 | |
|---|
| 463 | |
|---|
| 464 | SUBROUTINE nemo_partition( num_pes ) |
|---|
| 465 | !!---------------------------------------------------------------------- |
|---|
| 466 | !! *** ROUTINE nemo_partition *** |
|---|
| 467 | !! |
|---|
| 468 | !! ** Purpose : |
|---|
| 469 | !! |
|---|
| 470 | !! ** Method : |
|---|
| 471 | !!---------------------------------------------------------------------- |
|---|
| 472 | INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have |
|---|
| 473 | ! |
|---|
| 474 | INTEGER, PARAMETER :: nfactmax = 20 |
|---|
| 475 | INTEGER :: nfact ! The no. of factors returned |
|---|
| 476 | INTEGER :: ierr ! Error flag |
|---|
| 477 | INTEGER :: ji |
|---|
| 478 | INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value |
|---|
| 479 | INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors |
|---|
| 480 | !!---------------------------------------------------------------------- |
|---|
| 481 | |
|---|
| 482 | ierr = 0 |
|---|
| 483 | |
|---|
| 484 | CALL factorise( ifact, nfactmax, nfact, num_pes, ierr ) |
|---|
| 485 | |
|---|
| 486 | IF( nfact <= 1 ) THEN |
|---|
| 487 | WRITE (numout, *) 'WARNING: factorisation of number of PEs failed' |
|---|
| 488 | WRITE (numout, *) ' : using grid of ',num_pes,' x 1' |
|---|
| 489 | jpnj = 1 |
|---|
| 490 | jpni = num_pes |
|---|
| 491 | ELSE |
|---|
| 492 | ! Search through factors for the pair that are closest in value |
|---|
| 493 | mindiff = 1000000 |
|---|
| 494 | imin = 1 |
|---|
| 495 | DO ji = 1, nfact-1, 2 |
|---|
| 496 | idiff = ABS( ifact(ji) - ifact(ji+1) ) |
|---|
| 497 | IF( idiff < mindiff ) THEN |
|---|
| 498 | mindiff = idiff |
|---|
| 499 | imin = ji |
|---|
| 500 | ENDIF |
|---|
| 501 | END DO |
|---|
| 502 | jpnj = ifact(imin) |
|---|
| 503 | jpni = ifact(imin + 1) |
|---|
| 504 | ENDIF |
|---|
| 505 | ! |
|---|
| 506 | jpnij = jpni*jpnj |
|---|
| 507 | ! |
|---|
| 508 | END SUBROUTINE nemo_partition |
|---|
| 509 | |
|---|
| 510 | |
|---|
| 511 | SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr ) |
|---|
| 512 | !!---------------------------------------------------------------------- |
|---|
| 513 | !! *** ROUTINE factorise *** |
|---|
| 514 | !! |
|---|
| 515 | !! ** Purpose : return the prime factors of n. |
|---|
| 516 | !! knfax factors are returned in array kfax which is of |
|---|
| 517 | !! maximum dimension kmaxfax. |
|---|
| 518 | !! ** Method : |
|---|
| 519 | !!---------------------------------------------------------------------- |
|---|
| 520 | INTEGER , INTENT(in ) :: kn, kmaxfax |
|---|
| 521 | INTEGER , INTENT( out) :: kerr, knfax |
|---|
| 522 | INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax |
|---|
| 523 | ! |
|---|
| 524 | INTEGER :: ifac, jl, inu |
|---|
| 525 | INTEGER, PARAMETER :: ntest = 14 |
|---|
| 526 | INTEGER :: ilfax(ntest) |
|---|
| 527 | ! |
|---|
| 528 | ! lfax contains the set of allowed factors. |
|---|
| 529 | data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256, & |
|---|
| 530 | & 128, 64, 32, 16, 8, 4, 2 / |
|---|
| 531 | !!---------------------------------------------------------------------- |
|---|
| 532 | |
|---|
| 533 | ! Clear the error flag and initialise output vars |
|---|
| 534 | kerr = 0 |
|---|
| 535 | kfax = 1 |
|---|
| 536 | knfax = 0 |
|---|
| 537 | |
|---|
| 538 | ! Find the factors of n. |
|---|
| 539 | IF( kn == 1 ) GOTO 20 |
|---|
| 540 | |
|---|
| 541 | ! nu holds the unfactorised part of the number. |
|---|
| 542 | ! knfax holds the number of factors found. |
|---|
| 543 | ! l points to the allowed factor list. |
|---|
| 544 | ! ifac holds the current factor. |
|---|
| 545 | |
|---|
| 546 | inu = kn |
|---|
| 547 | knfax = 0 |
|---|
| 548 | |
|---|
| 549 | DO jl = ntest, 1, -1 |
|---|
| 550 | ! |
|---|
| 551 | ifac = ilfax(jl) |
|---|
| 552 | IF( ifac > inu ) CYCLE |
|---|
| 553 | |
|---|
| 554 | ! Test whether the factor will divide. |
|---|
| 555 | |
|---|
| 556 | IF( MOD(inu,ifac) == 0 ) THEN |
|---|
| 557 | ! |
|---|
| 558 | knfax = knfax + 1 ! Add the factor to the list |
|---|
| 559 | IF( knfax > kmaxfax ) THEN |
|---|
| 560 | kerr = 6 |
|---|
| 561 | write (*,*) 'FACTOR: insufficient space in factor array ', knfax |
|---|
| 562 | return |
|---|
| 563 | ENDIF |
|---|
| 564 | kfax(knfax) = ifac |
|---|
| 565 | ! Store the other factor that goes with this one |
|---|
| 566 | knfax = knfax + 1 |
|---|
| 567 | kfax(knfax) = inu / ifac |
|---|
| 568 | !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax) |
|---|
| 569 | ENDIF |
|---|
| 570 | ! |
|---|
| 571 | END DO |
|---|
| 572 | |
|---|
| 573 | 20 CONTINUE ! Label 20 is the exit point from the factor search loop. |
|---|
| 574 | ! |
|---|
| 575 | END SUBROUTINE factorise |
|---|
| 576 | |
|---|
| 577 | #if defined key_mpp_mpi |
|---|
| 578 | SUBROUTINE nemo_northcomms |
|---|
| 579 | !!====================================================================== |
|---|
| 580 | !! *** ROUTINE nemo_northcomms *** |
|---|
| 581 | !! nemo_northcomms : Setup for north fold exchanges with explicit peer to peer messaging |
|---|
| 582 | !!===================================================================== |
|---|
| 583 | !!---------------------------------------------------------------------- |
|---|
| 584 | !! |
|---|
| 585 | !! ** Purpose : Initialization of the northern neighbours lists. |
|---|
| 586 | !!---------------------------------------------------------------------- |
|---|
| 587 | !! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE) |
|---|
| 588 | !!---------------------------------------------------------------------- |
|---|
| 589 | |
|---|
| 590 | INTEGER :: ji, jj, jk, ij, jtyp ! dummy loop indices |
|---|
| 591 | INTEGER :: ijpj ! number of rows involved in north-fold exchange |
|---|
| 592 | INTEGER :: northcomms_alloc ! allocate return status |
|---|
| 593 | REAL(wp), ALLOCATABLE, DIMENSION ( :,: ) :: znnbrs ! workspace |
|---|
| 594 | LOGICAL, ALLOCATABLE, DIMENSION ( : ) :: lrankset ! workspace |
|---|
| 595 | |
|---|
| 596 | IF(lwp) WRITE(numout,*) |
|---|
| 597 | IF(lwp) WRITE(numout,*) 'nemo_northcomms : Initialization of the northern neighbours lists' |
|---|
| 598 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~' |
|---|
| 599 | |
|---|
| 600 | !!---------------------------------------------------------------------- |
|---|
| 601 | ALLOCATE( znnbrs(jpi,jpj), stat = northcomms_alloc ) |
|---|
| 602 | ALLOCATE( lrankset(jpnij), stat = northcomms_alloc ) |
|---|
| 603 | IF( northcomms_alloc /= 0 ) THEN |
|---|
| 604 | WRITE(numout,cform_war) |
|---|
| 605 | WRITE(numout,*) 'northcomms_alloc : failed to allocate arrays' |
|---|
| 606 | CALL ctl_stop( 'STOP', 'nemo_northcomms : unable to allocate temporary arrays' ) |
|---|
| 607 | ENDIF |
|---|
| 608 | nsndto = 0 |
|---|
| 609 | isendto = -1 |
|---|
| 610 | ijpj = 4 |
|---|
| 611 | ! |
|---|
| 612 | ! This routine has been called because ln_nnogather has been set true ( nammpp ) |
|---|
| 613 | ! However, these first few exchanges have to use the mpi_allgather method to |
|---|
| 614 | ! establish the neighbour lists to use in subsequent peer to peer exchanges. |
|---|
| 615 | ! Consequently, set l_north_nogather to be false here and set it true only after |
|---|
| 616 | ! the lists have been established. |
|---|
| 617 | ! |
|---|
| 618 | l_north_nogather = .FALSE. |
|---|
| 619 | ! |
|---|
| 620 | ! Exchange and store ranks on northern rows |
|---|
| 621 | |
|---|
| 622 | DO jtyp = 1,4 |
|---|
| 623 | |
|---|
| 624 | lrankset = .FALSE. |
|---|
| 625 | znnbrs = narea |
|---|
| 626 | SELECT CASE (jtyp) |
|---|
| 627 | CASE(1) |
|---|
| 628 | CALL lbc_lnk( znnbrs, 'T', 1. ) ! Type 1: T,W-points |
|---|
| 629 | CASE(2) |
|---|
| 630 | CALL lbc_lnk( znnbrs, 'U', 1. ) ! Type 2: U-point |
|---|
| 631 | CASE(3) |
|---|
| 632 | CALL lbc_lnk( znnbrs, 'V', 1. ) ! Type 3: V-point |
|---|
| 633 | CASE(4) |
|---|
| 634 | CALL lbc_lnk( znnbrs, 'F', 1. ) ! Type 4: F-point |
|---|
| 635 | END SELECT |
|---|
| 636 | |
|---|
| 637 | IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN |
|---|
| 638 | DO jj = nlcj-ijpj+1, nlcj |
|---|
| 639 | ij = jj - nlcj + ijpj |
|---|
| 640 | DO ji = 1,jpi |
|---|
| 641 | IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) & |
|---|
| 642 | & lrankset(INT(znnbrs(ji,jj))) = .true. |
|---|
| 643 | END DO |
|---|
| 644 | END DO |
|---|
| 645 | |
|---|
| 646 | DO jj = 1,jpnij |
|---|
| 647 | IF ( lrankset(jj) ) THEN |
|---|
| 648 | nsndto(jtyp) = nsndto(jtyp) + 1 |
|---|
| 649 | IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN |
|---|
| 650 | CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', & |
|---|
| 651 | & ' jpmaxngh will need to be increased ') |
|---|
| 652 | ENDIF |
|---|
| 653 | isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank |
|---|
| 654 | ENDIF |
|---|
| 655 | END DO |
|---|
| 656 | ENDIF |
|---|
| 657 | |
|---|
| 658 | END DO |
|---|
| 659 | |
|---|
| 660 | ! |
|---|
| 661 | ! Type 5: I-point |
|---|
| 662 | ! |
|---|
| 663 | ! ICE point exchanges may involve some averaging. The neighbours list is |
|---|
| 664 | ! built up using two exchanges to ensure that the whole stencil is covered. |
|---|
| 665 | ! lrankset should not be reset between these 'J' and 'K' point exchanges |
|---|
| 666 | |
|---|
| 667 | jtyp = 5 |
|---|
| 668 | lrankset = .FALSE. |
|---|
| 669 | znnbrs = narea |
|---|
| 670 | CALL lbc_lnk( znnbrs, 'J', 1. ) ! first ice U-V point |
|---|
| 671 | |
|---|
| 672 | IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN |
|---|
| 673 | DO jj = nlcj-ijpj+1, nlcj |
|---|
| 674 | ij = jj - nlcj + ijpj |
|---|
| 675 | DO ji = 1,jpi |
|---|
| 676 | IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) & |
|---|
| 677 | & lrankset(INT(znnbrs(ji,jj))) = .true. |
|---|
| 678 | END DO |
|---|
| 679 | END DO |
|---|
| 680 | ENDIF |
|---|
| 681 | |
|---|
| 682 | znnbrs = narea |
|---|
| 683 | CALL lbc_lnk( znnbrs, 'K', 1. ) ! second ice U-V point |
|---|
| 684 | |
|---|
| 685 | IF ( njmppt(narea) .EQ. MAXVAL( njmppt )) THEN |
|---|
| 686 | DO jj = nlcj-ijpj+1, nlcj |
|---|
| 687 | ij = jj - nlcj + ijpj |
|---|
| 688 | DO ji = 1,jpi |
|---|
| 689 | IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) & |
|---|
| 690 | & lrankset( INT(znnbrs(ji,jj))) = .true. |
|---|
| 691 | END DO |
|---|
| 692 | END DO |
|---|
| 693 | |
|---|
| 694 | DO jj = 1,jpnij |
|---|
| 695 | IF ( lrankset(jj) ) THEN |
|---|
| 696 | nsndto(jtyp) = nsndto(jtyp) + 1 |
|---|
| 697 | IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN |
|---|
| 698 | CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', & |
|---|
| 699 | & ' jpmaxngh will need to be increased ') |
|---|
| 700 | ENDIF |
|---|
| 701 | isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank |
|---|
| 702 | ENDIF |
|---|
| 703 | END DO |
|---|
| 704 | ! |
|---|
| 705 | ! For northern row areas, set l_north_nogather so that all subsequent exchanges |
|---|
| 706 | ! can use peer to peer communications at the north fold |
|---|
| 707 | ! |
|---|
| 708 | l_north_nogather = .TRUE. |
|---|
| 709 | ! |
|---|
| 710 | ENDIF |
|---|
| 711 | DEALLOCATE( znnbrs ) |
|---|
| 712 | DEALLOCATE( lrankset ) |
|---|
| 713 | |
|---|
| 714 | END SUBROUTINE nemo_northcomms |
|---|
| 715 | #else |
|---|
| 716 | SUBROUTINE nemo_northcomms ! Dummy routine |
|---|
| 717 | WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?' |
|---|
| 718 | END SUBROUTINE nemo_northcomms |
|---|
| 719 | #endif |
|---|
| 720 | !!====================================================================== |
|---|
| 721 | END MODULE nemogcm |
|---|
