New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dtatsd.F90 in branches/2013/dev_r3853_CNRS9_ConfSetting/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: branches/2013/dev_r3853_CNRS9_ConfSetting/NEMOGCM/NEMO/OPA_SRC/DOM/dtatsd.F90 @ 3901

Last change on this file since 3901 was 3901, checked in by clevy, 11 years ago

Configuration Setting/Step2, see ticket:#1074
File size: 16.2 KB
Line 
1MODULE dtatsd
2   !!======================================================================
3   !!                     ***  MODULE  dtatsd  ***
4   !! Ocean data  :  read ocean Temperature & Salinity Data from gridded data
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  ()  Original code
7   !!             -   ! 1992-07  (M. Imbard)
8   !!            8.0  ! 1999-10  (M.A. Foujols, M. Imbard)  NetCDF FORMAT
9   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
10   !!            3.3  ! 2010-10  (C. Bricaud, S. Masson)  use of fldread
11   !!            3.4  ! 2010-11  (G. Madec, C. Ethe) Merge of dtatem and dtasal + suppression of CPP keys
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   dta_tsd      : read and time interpolated ocean Temperature & Salinity Data
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers
18   USE dom_oce         ! ocean space and time domain
19   USE fldread         ! read input fields
20   USE in_out_manager  ! I/O manager
21   USE phycst          ! physical constants
22   USE lib_mpp         ! MPP library
23   USE wrk_nemo        ! Memory allocation
24   USE timing          ! Timing
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   dta_tsd_init   ! called by opa.F90
30   PUBLIC   dta_tsd        ! called by istate.F90 and tradmp.90
31
32   LOGICAL , PUBLIC ::   ln_tsd_init      !: T & S data flag
33   LOGICAL , PUBLIC ::   ln_tsd_tradmp    !: internal damping toward input data flag
34
35   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_tsd   ! structure of input SST (file informations, fields read)
36
37   !! * Substitutions
38#  include "domzgr_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
41   !! $Id: dtatem.F90 2392 2010-11-15 21:20:05Z gm $
42   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE dta_tsd_init( ld_tradmp )
47      !!----------------------------------------------------------------------
48      !!                   ***  ROUTINE dta_tsd_init  ***
49      !!                   
50      !! ** Purpose :   initialisation of T & S input data
51      !!
52      !! ** Method  : - Read namtsd namelist
53      !!              - allocates T & S data structure
54      !!----------------------------------------------------------------------
55      LOGICAL, INTENT(in), OPTIONAL ::   ld_tradmp   ! force the initialization when tradp is used
56      !
57      INTEGER ::   ierr0, ierr1, ierr2, ierr3   ! temporary integers
58      !
59      CHARACTER(len=100)            ::   cn_dir          ! Root directory for location of ssr files
60      TYPE(FLD_N), DIMENSION( jpts) ::   slf_i           ! array of namelist informations on the fields to read
61      TYPE(FLD_N)                   ::   sn_tem, sn_sal
62      !!
63      NAMELIST/namtsd/   ln_tsd_init, ln_tsd_tradmp, cn_dir, sn_tem, sn_sal
64      INTEGER  ::   ios
65      !!----------------------------------------------------------------------
66      !
67      IF( nn_timing == 1 )  CALL timing_start('dta_tsd_init')
68      !
69      !  Initialisation
70      ierr0 = 0  ;  ierr1 = 0  ;  ierr2 = 0  ;  ierr3 = 0
71      !
72      !                             ! set default namelist values
73      cn_dir = './'                       ! directory in which the model is executed
74      !                                   ! sn_... default values (NB: frequency positive => hours, negative => months)
75      !            !   file    ! frequency ! variable  ! time intep !  clim   ! 'yearly' or ! weights  ! rotation !
76      !            !   name    !  (hours)  !  name     !   (T/F)    !  (T/F)  !  'monthly'  ! filename ! pairs    !
77      sn_tem = FLD_N( 'temperature',  -1.  , 'votemper',  .false.   , .true.  ,  'monthly'  , ''       , ''       )
78      sn_sal = FLD_N( 'salinity'   ,  -1.  , 'vosaline',  .false.   , .true.  ,  'monthly'  , ''       , ''       )
79 
80      REWIND( numnam_ref )              ! Namelist namtsd in reference namelist :
81      READ  ( numnam_ref, namtsd, IOSTAT = ios, ERR = 901)
82901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtsd in reference namelist', lwp )
83
84      REWIND( numnam_cfg )              ! Namelist namtsd in configuration namelist : Parameters of the run
85      READ  ( numnam_cfg, namtsd, IOSTAT = ios, ERR = 902 )
86902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtsd in configuration namelist', lwp )
87      WRITE ( numond, namtsd )
88
89      IF( PRESENT( ld_tradmp ) )   ln_tsd_tradmp = .TRUE.     ! forces the initialization when tradmp is used
90     
91      IF(lwp) THEN                  ! control print
92         WRITE(numout,*)
93         WRITE(numout,*) 'dta_tsd_init : Temperature & Salinity data '
94         WRITE(numout,*) '~~~~~~~~~~~~ '
95         WRITE(numout,*) '   Namelist namtsd'
96         WRITE(numout,*) '      Initialisation of ocean T & S with T &S input data   ln_tsd_init   = ', ln_tsd_init
97         WRITE(numout,*) '      damping of ocean T & S toward T &S input data        ln_tsd_tradmp = ', ln_tsd_tradmp
98         WRITE(numout,*)
99         IF( .NOT.ln_tsd_init .AND. .NOT.ln_tsd_tradmp ) THEN
100            WRITE(numout,*)
101            WRITE(numout,*) '   T & S data not used'
102         ENDIF
103      ENDIF
104      !
105      IF( ln_rstart .AND. ln_tsd_init ) THEN
106         CALL ctl_warn( 'dta_tsd_init: ocean restart and T & S data intialisation, ',   &
107            &           'we keep the restart T & S values and set ln_tsd_init to FALSE' )
108         ln_tsd_init = .FALSE.
109      ENDIF
110      !
111      !                             ! allocate the arrays (if necessary)
112      IF(  ln_tsd_init .OR. ln_tsd_tradmp  ) THEN
113         !
114         ALLOCATE( sf_tsd(jpts), STAT=ierr0 )
115         IF( ierr0 > 0 ) THEN
116            CALL ctl_stop( 'dta_tsd_init: unable to allocate sf_tsd structure' )   ;   RETURN
117         ENDIF
118         !
119                                ALLOCATE( sf_tsd(jp_tem)%fnow(jpi,jpj,jpk)   , STAT=ierr0 )
120         IF( sn_tem%ln_tint )   ALLOCATE( sf_tsd(jp_tem)%fdta(jpi,jpj,jpk,2) , STAT=ierr1 )
121                                ALLOCATE( sf_tsd(jp_sal)%fnow(jpi,jpj,jpk)   , STAT=ierr2 )
122         IF( sn_sal%ln_tint )   ALLOCATE( sf_tsd(jp_sal)%fdta(jpi,jpj,jpk,2) , STAT=ierr3 )
123         !
124         IF( ierr0 + ierr1 + ierr2 + ierr3 > 0 ) THEN
125            CALL ctl_stop( 'dta_tsd : unable to allocate T & S data arrays' )   ;   RETURN
126         ENDIF
127         !                         ! fill sf_tsd with sn_tem & sn_sal and control print
128         slf_i(jp_tem) = sn_tem   ;   slf_i(jp_sal) = sn_sal
129         CALL fld_fill( sf_tsd, slf_i, cn_dir, 'dta_tsd', 'Temperature & Salinity data', 'namtsd' )
130         !
131      ENDIF
132      !
133      IF( nn_timing == 1 )  CALL timing_stop('dta_tsd_init')
134      !
135   END SUBROUTINE dta_tsd_init
136
137
138   SUBROUTINE dta_tsd( kt, ptsd )
139      !!----------------------------------------------------------------------
140      !!                   ***  ROUTINE dta_tsd  ***
141      !!                   
142      !! ** Purpose :   provides T and S data at kt
143      !!
144      !! ** Method  : - call fldread routine
145      !!              - ORCA_R2: add some hand made alteration to read data 
146      !!              - 'key_orca_lev10' interpolates on 10 times more levels
147      !!              - s- or mixed z-s coordinate: vertical interpolation on model mesh
148      !!              - ln_tsd_tradmp=F: deallocates the T-S data structure
149      !!                as T-S data are no are used
150      !!
151      !! ** Action  :   ptsd   T-S data on medl mesh and interpolated at time-step kt
152      !!----------------------------------------------------------------------
153      INTEGER                              , INTENT(in   ) ::   kt     ! ocean time-step
154      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(  out) ::   ptsd   ! T & S data
155      !
156      INTEGER ::   ji, jj, jk, jl, jkk   ! dummy loop indicies
157      INTEGER ::   ik, il0, il1, ii0, ii1, ij0, ij1   ! local integers
158      REAL(wp)::   zl, zi
159      REAL(wp), POINTER, DIMENSION(:) ::  ztp, zsp   ! 1D workspace
160      !!----------------------------------------------------------------------
161      !
162      IF( nn_timing == 1 )  CALL timing_start('dta_tsd')
163      !
164      CALL fld_read( kt, 1, sf_tsd )      !==   read T & S data at kt time step   ==!
165      !
166      !
167      !                                   !==   ORCA_R2 configuration and T & S damping   ==!
168      IF( cp_cfg == "orca" .AND. jp_cfg == 2 .AND. ln_tsd_tradmp ) THEN    ! some hand made alterations
169         !
170         ij0 = 101   ;   ij1 = 109                       ! Reduced T & S in the Alboran Sea
171         ii0 = 141   ;   ii1 = 155
172         DO jj = mj0(ij0), mj1(ij1)
173            DO ji = mi0(ii0), mi1(ii1)
174               sf_tsd(jp_tem)%fnow(ji,jj,13:13) = sf_tsd(jp_tem)%fnow(ji,jj,13:13) - 0.20_wp
175               sf_tsd(jp_tem)%fnow(ji,jj,14:15) = sf_tsd(jp_tem)%fnow(ji,jj,14:15) - 0.35_wp
176               sf_tsd(jp_tem)%fnow(ji,jj,16:25) = sf_tsd(jp_tem)%fnow(ji,jj,16:25) - 0.40_wp
177               !
178               sf_tsd(jp_sal)%fnow(ji,jj,13:13) = sf_tsd(jp_sal)%fnow(ji,jj,13:13) - 0.15_wp
179               sf_tsd(jp_sal)%fnow(ji,jj,14:15) = sf_tsd(jp_sal)%fnow(ji,jj,14:15) - 0.25_wp
180               sf_tsd(jp_sal)%fnow(ji,jj,16:17) = sf_tsd(jp_sal)%fnow(ji,jj,16:17) - 0.30_wp
181               sf_tsd(jp_sal)%fnow(ji,jj,18:25) = sf_tsd(jp_sal)%fnow(ji,jj,18:25) - 0.35_wp
182            END DO
183         END DO
184         IF( nn_cla == 1 ) THEN                          ! Cross Land advection
185            il0 = 138   ;   il1 = 138                          ! set T & S profile at Gibraltar Strait
186            ij0 = 101   ;   ij1 = 102
187            ii0 = 139   ;   ii1 = 139
188            DO jl = mi0(il0), mi1(il1)
189               DO jj = mj0(ij0), mj1(ij1)
190                  DO ji = mi0(ii0), mi1(ii1)
191                     sf_tsd(jp_tem)%fnow(ji,jj,:) = sf_tsd(jp_tem)%fnow(jl,jj,:)
192                     sf_tsd(jp_sal)%fnow(ji,jj,:) = sf_tsd(jp_sal)%fnow(jl,jj,:)
193                  END DO
194               END DO
195            END DO
196            il0 = 164   ;   il1 = 164                          ! set T & S profile at Bab el Mandeb Strait
197            ij0 =  87   ;   ij1 =  88
198            ii0 = 161   ;   ii1 = 163
199            DO jl = mi0(il0), mi1(il1)
200               DO jj = mj0(ij0), mj1(ij1)
201                  DO ji = mi0(ii0), mi1(ii1)
202                     sf_tsd(jp_tem)%fnow(ji,jj,:) = sf_tsd(jp_tem)%fnow(jl,jj,:)
203                     sf_tsd(jp_sal)%fnow(ji,jj,:) = sf_tsd(jp_sal)%fnow(jl,jj,:)
204                  END DO
205               END DO
206            END DO
207         ELSE                                            ! No Cross Land advection
208            ij0 =  87   ;   ij1 =  96                          ! Reduced temperature in Red Sea
209            ii0 = 148   ;   ii1 = 160
210            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ,  4:10 ) = 7.0_wp
211            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 11:13 ) = 6.5_wp
212            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 14:20 ) = 6.0_wp
213         ENDIF
214      ENDIF
215      !
216      ptsd(:,:,:,jp_tem) = sf_tsd(jp_tem)%fnow(:,:,:)    ! NO mask
217      ptsd(:,:,:,jp_sal) = sf_tsd(jp_sal)%fnow(:,:,:) 
218      !
219      IF( ln_sco ) THEN                   !==   s- or mixed s-zps-coordinate   ==!
220         !
221         CALL wrk_alloc( jpk, ztp, zsp )
222         !
223         IF( kt == nit000 .AND. lwp )THEN
224            WRITE(numout,*)
225            WRITE(numout,*) 'dta_tsd: interpolates T & S data onto the s- or mixed s-z-coordinate mesh'
226         ENDIF
227         !
228         DO jj = 1, jpj                         ! vertical interpolation of T & S
229            DO ji = 1, jpi
230               DO jk = 1, jpk                        ! determines the intepolated T-S profiles at each (i,j) points
231                  zl = fsdept_0(ji,jj,jk)
232                  IF(     zl < gdept_0(1  ) ) THEN          ! above the first level of data
233                     ztp(jk) =  ptsd(ji,jj,1    ,jp_tem)
234                     zsp(jk) =  ptsd(ji,jj,1    ,jp_sal)
235                  ELSEIF( zl > gdept_0(jpk) ) THEN          ! below the last level of data
236                     ztp(jk) =  ptsd(ji,jj,jpkm1,jp_tem)
237                     zsp(jk) =  ptsd(ji,jj,jpkm1,jp_sal)
238                  ELSE                                      ! inbetween : vertical interpolation between jkk & jkk+1
239                     DO jkk = 1, jpkm1                                  ! when  gdept(jkk) < zl < gdept(jkk+1)
240                        IF( (zl-gdept_0(jkk)) * (zl-gdept_0(jkk+1)) <= 0._wp ) THEN
241                           zi = ( zl - gdept_0(jkk) ) / (gdept_0(jkk+1)-gdept_0(jkk))
242                           ztp(jk) = ptsd(ji,jj,jkk,jp_tem) + ( ptsd(ji,jj,jkk+1,jp_tem) - ptsd(ji,jj,jkk,jp_tem) ) * zi 
243                           zsp(jk) = ptsd(ji,jj,jkk,jp_sal) + ( ptsd(ji,jj,jkk+1,jp_sal) - ptsd(ji,jj,jkk,jp_sal) ) * zi
244                        ENDIF
245                     END DO
246                  ENDIF
247               END DO
248               DO jk = 1, jpkm1
249                  ptsd(ji,jj,jk,jp_tem) = ztp(jk) * tmask(ji,jj,jk)     ! mask required for mixed zps-s-coord
250                  ptsd(ji,jj,jk,jp_sal) = zsp(jk) * tmask(ji,jj,jk)
251               END DO
252               ptsd(ji,jj,jpk,jp_tem) = 0._wp
253               ptsd(ji,jj,jpk,jp_sal) = 0._wp
254            END DO
255         END DO
256         !
257         CALL wrk_dealloc( jpk, ztp, zsp )
258         !
259      ELSE                                !==   z- or zps- coordinate   ==!
260         !                             
261         ptsd(:,:,:,jp_tem) = ptsd(:,:,:,jp_tem) * tmask(:,:,:)    ! Mask
262         ptsd(:,:,:,jp_sal) = ptsd(:,:,:,jp_sal) * tmask(:,:,:)
263         !
264         IF( ln_zps ) THEN                      ! zps-coordinate (partial steps) interpolation at the last ocean level
265            DO jj = 1, jpj
266               DO ji = 1, jpi
267                  ik = mbkt(ji,jj) 
268                  IF( ik > 1 ) THEN
269                     zl = ( gdept_0(ik) - fsdept_0(ji,jj,ik) ) / ( gdept_0(ik) - gdept_0(ik-1) )
270                     ptsd(ji,jj,ik,jp_tem) = (1.-zl) * ptsd(ji,jj,ik,jp_tem) + zl * ptsd(ji,jj,ik-1,jp_tem)
271                     ptsd(ji,jj,ik,jp_sal) = (1.-zl) * ptsd(ji,jj,ik,jp_sal) + zl * ptsd(ji,jj,ik-1,jp_sal)
272                  ENDIF
273               END DO
274            END DO
275         ENDIF
276         !
277      ENDIF
278      !
279      IF( lwp .AND. kt == nit000 ) THEN
280         WRITE(numout,*) ' temperature Levitus '
281         WRITE(numout,*)
282         WRITE(numout,*)'  level = 1'
283         CALL prihre( ptsd(:,:,1    ,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
284         WRITE(numout,*)'  level = ', jpk/2
285         CALL prihre( ptsd(:,:,jpk/2,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
286         WRITE(numout,*)'  level = ', jpkm1
287         CALL prihre( ptsd(:,:,jpkm1,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
288         WRITE(numout,*)
289         WRITE(numout,*) ' salinity Levitus '
290         WRITE(numout,*)
291         WRITE(numout,*)'  level = 1'
292         CALL prihre( ptsd(:,:,1    ,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
293         WRITE(numout,*)'  level = ', jpk/2
294         CALL prihre( ptsd(:,:,jpk/2,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
295         WRITE(numout,*)'  level = ', jpkm1
296         CALL prihre( ptsd(:,:,jpkm1,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
297         WRITE(numout,*)
298      ENDIF
299      !
300      IF( .NOT.ln_tsd_tradmp ) THEN                   !==   deallocate T & S structure   ==!
301         !                                              (data used only for initialisation)
302         IF(lwp) WRITE(numout,*) 'dta_tsd: deallocte T & S arrays as they are only use to initialize the run'
303                                        DEALLOCATE( sf_tsd(jp_tem)%fnow )     ! T arrays in the structure
304         IF( sf_tsd(jp_tem)%ln_tint )   DEALLOCATE( sf_tsd(jp_tem)%fdta )
305                                        DEALLOCATE( sf_tsd(jp_sal)%fnow )     ! S arrays in the structure
306         IF( sf_tsd(jp_sal)%ln_tint )   DEALLOCATE( sf_tsd(jp_sal)%fdta )
307                                        DEALLOCATE( sf_tsd              )     ! the structure itself
308      ENDIF
309      !
310      IF( nn_timing == 1 )  CALL timing_stop('dta_tsd')
311      !
312   END SUBROUTINE dta_tsd
313
314   !!======================================================================
315END MODULE dtatsd
Note: See TracBrowser for help on using the repository browser.