New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcrnf.F90 in branches/2013/dev_r3853_CNRS9_ConfSetting/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2013/dev_r3853_CNRS9_ConfSetting/NEMOGCM/NEMO/OPA_SRC/SBC/sbcrnf.F90 @ 3875

Last change on this file since 3875 was 3875, checked in by clevy, 11 years ago

Configuration Setting/Step? 1, see ticket:#1074
  • Property svn:keywords set to Id
File size: 27.2 KB
Line 
1MODULE sbcrnf
2   !!======================================================================
3   !!                       ***  MODULE  sbcrnf  ***
4   !! Ocean forcing:  river runoff
5   !!=====================================================================
6   !! History :  OPA  ! 2000-11  (R. Hordoir, E. Durand)  NetCDF FORMAT
7   !!   NEMO     1.0  ! 2002-09  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-07  (G. Madec)  Surface module
9   !!            3.2  ! 2009-04  (B. Lemaire)  Introduce iom_put
10   !!            3.3  ! 2010-10  (R. Furner, G. Madec) runoff distributed over ocean levels
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_rnf      : monthly runoffs read in a NetCDF file
15   !!   sbc_rnf_init : runoffs initialisation
16   !!   rnf_mouth    : set river mouth mask
17   !!----------------------------------------------------------------------
18   USE dom_oce         ! ocean space and time domain
19   USE phycst          ! physical constants
20   USE sbc_oce         ! surface boundary condition variables
21   USE closea          ! closed seas
22   USE fldread         ! read input field at current time step
23   USE in_out_manager  ! I/O manager
24   USE iom             ! I/O module
25   USE lib_mpp         ! MPP library
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   sbc_rnf       ! routine call in sbcmod module
31   PUBLIC   sbc_rnf_div   ! routine called in sshwzv module
32   PUBLIC   sbc_rnf_alloc ! routine call in sbcmod module
33   PUBLIC   sbc_rnf_init  ! (PUBLIC for TAM)
34   !                                                     !!* namsbc_rnf namelist *
35   CHARACTER(len=100), PUBLIC ::   cn_dir       = './'    !: Root directory for location of ssr files
36   LOGICAL           , PUBLIC ::   ln_rnf_depth = .false. !: depth       river runoffs attribute specified in a file
37   LOGICAL           , PUBLIC ::   ln_rnf_tem   = .false. !: temperature river runoffs attribute specified in a file
38   LOGICAL           , PUBLIC ::   ln_rnf_sal   = .false. !: salinity    river runoffs attribute specified in a file
39   LOGICAL           , PUBLIC ::   ln_rnf_emp   = .false. !: runoffs into a file to be read or already into precipitation
40   TYPE(FLD_N)       , PUBLIC ::   sn_rnf                 !: information about the runoff file to be read
41   TYPE(FLD_N)       , PUBLIC ::   sn_cnf                 !: information about the runoff mouth file to be read
42   TYPE(FLD_N)                ::   sn_s_rnf               !: information about the salinities of runoff file to be read
43   TYPE(FLD_N)                ::   sn_t_rnf               !: information about the temperatures of runoff file to be read
44   TYPE(FLD_N)                ::   sn_dep_rnf             !: information about the depth which river inflow affects
45   LOGICAL           , PUBLIC ::   ln_rnf_mouth = .false. !: specific treatment in mouths vicinity
46   REAL(wp)          , PUBLIC ::   rn_hrnf      = 0._wp   !: runoffs, depth over which enhanced vertical mixing is used
47   REAL(wp)          , PUBLIC ::   rn_avt_rnf   = 0._wp   !: runoffs, value of the additional vertical mixing coef. [m2/s]
48   REAL(wp)          , PUBLIC ::   rn_rfact     = 1._wp   !: multiplicative factor for runoff
49
50   INTEGER , PUBLIC  ::   nkrnf = 0         !: nb of levels over which Kz is increased at river mouths
51   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rnfmsk              !: river mouth mask (hori.)
52   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:)     ::   rnfmsk_z            !: river mouth mask (vert.)
53   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   h_rnf               !: depth of runoff in m
54   INTEGER,  PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   nk_rnf              !: depth of runoff in model levels
55   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   rnf_tsc_b, rnf_tsc  !: before and now T & S runoff contents   [K.m/s & PSU.m/s]   
56
57   TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) ::   sf_rnf       ! structure: river runoff (file information, fields read)
58   TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) ::   sf_s_rnf     ! structure: river runoff salinity (file information, fields read) 
59   TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) ::   sf_t_rnf     ! structure: river runoff temperature (file information, fields read) 
60 
61   !! * Substitutions 
62#  include "domzgr_substitute.h90" 
63   !!----------------------------------------------------------------------
64   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
65   !! $Id$
66   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
67   !!----------------------------------------------------------------------
68CONTAINS
69
70   INTEGER FUNCTION sbc_rnf_alloc()
71      !!----------------------------------------------------------------------
72      !!                ***  ROUTINE sbc_rnf_alloc  ***
73      !!----------------------------------------------------------------------
74      ALLOCATE( rnfmsk(jpi,jpj)         , rnfmsk_z(jpk)          ,     &
75         &      h_rnf (jpi,jpj)         , nk_rnf  (jpi,jpj)      ,     &
76         &      rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc )
77         !
78      IF( lk_mpp            )   CALL mpp_sum ( sbc_rnf_alloc )
79      IF( sbc_rnf_alloc > 0 )   CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
80   END FUNCTION sbc_rnf_alloc
81
82
83   SUBROUTINE sbc_rnf( kt )
84      !!----------------------------------------------------------------------
85      !!                  ***  ROUTINE sbc_rnf  ***
86      !!
87      !! ** Purpose :   Introduce a climatological run off forcing
88      !!
89      !! ** Method  :   Set each river mouth with a monthly climatology
90      !!                provided from different data.
91      !!                CAUTION : upward water flux, runoff forced to be < 0
92      !!
93      !! ** Action  :   runoff updated runoff field at time-step kt
94      !!----------------------------------------------------------------------
95      INTEGER, INTENT(in) ::   kt          ! ocean time step
96      !
97      INTEGER  ::   ji, jj    ! dummy loop indices
98      INTEGER  ::   z_err = 0 ! dummy integer for error handling
99      !!----------------------------------------------------------------------
100      !
101      IF( kt == nit000 )   CALL sbc_rnf_init                           ! Read namelist and allocate structures
102
103      !                                            ! ---------------------------------------- !
104      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
105         !                                         ! ---------------------------------------- !
106         rnf_b    (:,:  ) = rnf    (:,:  )               ! Swap the ocean forcing fields except at nit000
107         rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)               ! where before fields are set at the end of the routine
108         !
109      ENDIF
110
111      !                                                   !-------------------!
112      IF( .NOT. ln_rnf_emp ) THEN                         !   Update runoff   !
113         !                                                !-------------------!
114         !
115                             CALL fld_read ( kt, nn_fsbc, sf_rnf   )    ! Read Runoffs data and provide it at kt
116         IF( ln_rnf_tem  )   CALL fld_read ( kt, nn_fsbc, sf_t_rnf )    ! idem for runoffs temperature if required
117         IF( ln_rnf_sal  )   CALL fld_read ( kt, nn_fsbc, sf_s_rnf )    ! idem for runoffs salinity    if required
118         !
119         ! Runoff reduction only associated to the ORCA2_LIM configuration
120         ! when reading the NetCDF file runoff_1m_nomask.nc
121         IF( cp_cfg == 'orca' .AND. jp_cfg == 2 )   THEN
122            WHERE( 40._wp < gphit(:,:) .AND. gphit(:,:) < 65._wp )
123               sf_rnf(1)%fnow(:,:,1) = 0.85 * sf_rnf(1)%fnow(:,:,1)
124            END WHERE
125         ENDIF
126         !
127         IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
128            !
129            rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) )       ! updated runoff value at time step kt
130            !
131            !                                                     ! set temperature & salinity content of runoffs
132            IF( ln_rnf_tem ) THEN                                       ! use runoffs temperature data
133               rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
134               WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp )             ! if missing data value use SST as runoffs temperature
135                   rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
136               END WHERE
137            ELSE                                                        ! use SST as runoffs temperature
138               rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
139            ENDIF
140            !                                                           ! use runoffs salinity data
141            IF( ln_rnf_sal )   rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
142            !                                                           ! else use S=0 for runoffs (done one for all in the init)
143            IF ( ANY( rnf(:,:) < 0._wp ) ) z_err=1
144            IF(lk_mpp) CALL mpp_sum(z_err)
145            IF( z_err > 0 ) CALL ctl_stop( 'sbc_rnf : negative runnoff values exist' )
146            !
147            CALL iom_put( "runoffs", rnf )         ! output runoffs arrays
148         ENDIF
149         !
150      ENDIF
151      !
152      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
153         !                                             ! ---------------------------------------- !
154         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
155            & iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
156            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields red in the restart file'
157            CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b )     ! before runoff
158            CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) )   ! before heat content of runoff
159            CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) )   ! before salinity content of runoff
160         ELSE                                                   !* no restart: set from nit000 values
161            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields set to nit000'
162             rnf_b    (:,:  ) = rnf    (:,:  )
163             rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
164         ENDIF
165      ENDIF
166      !                                                ! ---------------------------------------- !
167      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
168         !                                             ! ---------------------------------------- !
169         IF(lwp) WRITE(numout,*)
170         IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ',   &
171            &                    'at it= ', kt,' date= ', ndastp
172         IF(lwp) WRITE(numout,*) '~~~~'
173         CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf )
174         CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) )
175         CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) )
176      ENDIF
177      !
178   END SUBROUTINE sbc_rnf
179
180
181   SUBROUTINE sbc_rnf_div( phdivn )
182      !!----------------------------------------------------------------------
183      !!                  ***  ROUTINE sbc_rnf  ***
184      !!
185      !! ** Purpose :   update the horizontal divergence with the runoff inflow
186      !!
187      !! ** Method  :
188      !!                CAUTION : rnf is positive (inflow) decreasing the
189      !!                          divergence and expressed in m/s
190      !!
191      !! ** Action  :   phdivn   decreased by the runoff inflow
192      !!----------------------------------------------------------------------
193      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   phdivn   ! horizontal divergence
194      !!
195      INTEGER  ::   ji, jj, jk   ! dummy loop indices
196      REAL(wp) ::   zfact     ! local scalar
197      !!----------------------------------------------------------------------
198      !
199      zfact = 0.5_wp
200      !
201      IF( ln_rnf_depth ) THEN      !==   runoff distributed over several levels   ==!
202         IF( lk_vvl ) THEN             ! variable volume case
203            DO jj = 1, jpj                   ! update the depth over which runoffs are distributed
204               DO ji = 1, jpi
205                  h_rnf(ji,jj) = 0._wp
206                  DO jk = 1, nk_rnf(ji,jj)                           ! recalculates h_rnf to be the depth in metres
207                     h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)   ! to the bottom of the relevant grid box
208                  END DO
209                  !                          ! apply the runoff input flow
210                  DO jk = 1, nk_rnf(ji,jj)
211                     phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
212                  END DO
213               END DO
214            END DO
215         ELSE                          ! constant volume case : just apply the runoff input flow
216            DO jj = 1, jpj
217               DO ji = 1, jpi
218                  DO jk = 1, nk_rnf(ji,jj)
219                     phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
220                  END DO
221               END DO
222            END DO
223         ENDIF
224      ELSE                       !==   runoff put only at the surface   ==!
225         IF( lk_vvl ) THEN              ! variable volume case
226            h_rnf(:,:) = fse3t(:,:,1)   ! recalculate h_rnf to be depth of top box
227         ENDIF
228         phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rau0 / fse3t(:,:,1)
229      ENDIF
230      !
231   END SUBROUTINE sbc_rnf_div
232
233
234   SUBROUTINE sbc_rnf_init
235      !!----------------------------------------------------------------------
236      !!                  ***  ROUTINE sbc_rnf_init  ***
237      !!
238      !! ** Purpose :   Initialisation of the runoffs if (ln_rnf=T)
239      !!
240      !! ** Method  : - read the runoff namsbc_rnf namelist
241      !!
242      !! ** Action  : - read parameters
243      !!----------------------------------------------------------------------
244      CHARACTER(len=32) ::   rn_dep_file   ! runoff file name
245      INTEGER           ::   ji, jj, jk    ! dummy loop indices
246      INTEGER           ::   ierror, inum  ! temporary integer
247      INTEGER           ::   ios           ! Local integer output status for namelist read
248      !
249      NAMELIST/namsbc_rnf/ cn_dir, ln_rnf_emp, ln_rnf_depth, ln_rnf_tem, ln_rnf_sal,   &
250         &                 sn_rnf, sn_cnf    , sn_s_rnf    , sn_t_rnf  , sn_dep_rnf,   &
251         &                 ln_rnf_mouth      , rn_hrnf     , rn_avt_rnf, rn_rfact
252      !!----------------------------------------------------------------------
253      !
254      !                                   ! ============
255      !                                   !   Namelist
256      !                                   ! ============
257      ! (NB: frequency positive => hours, negative => months)
258      !            !   file    ! frequency !  variable  ! time intep !  clim  ! 'yearly' or ! weights  ! rotation   !
259      !            !   name    !  (hours)  !   name     !   (T/F)    !  (T/F) !  'monthly'  ! filename ! pairs      !
260      sn_rnf = FLD_N( 'runoffs',    -1     , 'sorunoff' ,  .TRUE.    , .true. ,   'yearly'  , ''       , ''         )
261      sn_cnf = FLD_N( 'runoffs',     0     , 'sorunoff' ,  .FALSE.   , .true. ,   'yearly'  , ''       , ''         )
262
263      sn_s_rnf = FLD_N( 'runoffs',  24.  , 'rosaline' ,  .TRUE.    , .true. ,   'yearly'  , ''    , ''  )
264      sn_t_rnf = FLD_N( 'runoffs',  24.  , 'rotemper' ,  .TRUE.    , .true. ,   'yearly'  , ''    , ''  )
265      sn_dep_rnf = FLD_N( 'runoffs',   0.  , 'rodepth'  ,  .FALSE.   , .true. ,   'yearly'  , ''    , ''  )
266      !
267      REWIND( numnam_ref )              ! Namelist namsbc_rnf in reference namelist : Runoffs
268      READ  ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
269901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist', lwp )
270
271      REWIND( numnam_cfg )              ! Namelist namsbc_rnf in configuration namelist : Runoffs
272      READ  ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
273902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist', lwp )
274      WRITE ( numond, namsbc_rnf )
275      !
276      !                                         ! Control print
277      IF(lwp) THEN
278         WRITE(numout,*)
279         WRITE(numout,*) 'sbc_rnf : runoff '
280         WRITE(numout,*) '~~~~~~~ '
281         WRITE(numout,*) '   Namelist namsbc_rnf'
282         WRITE(numout,*) '      runoff in a file to be read                ln_rnf_emp   = ', ln_rnf_emp
283         WRITE(numout,*) '      specific river mouths treatment            ln_rnf_mouth = ', ln_rnf_mouth
284         WRITE(numout,*) '      river mouth additional Kz                  rn_avt_rnf   = ', rn_avt_rnf
285         WRITE(numout,*) '      depth of river mouth additional mixing     rn_hrnf      = ', rn_hrnf
286         WRITE(numout,*) '      multiplicative factor for runoff           rn_rfact     = ', rn_rfact
287      ENDIF
288      !
289      !                                   ! ==================
290      !                                   !   Type of runoff
291      !                                   ! ==================
292      !                                         !==  allocate runoff arrays
293      IF( sbc_rnf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
294      !
295      IF( ln_rnf_emp ) THEN                     !==  runoffs directly provided in the precipitations  ==!
296         IF(lwp) WRITE(numout,*)
297         IF(lwp) WRITE(numout,*) '          runoffs directly provided in the precipitations'
298         IF( ln_rnf_depth .OR. ln_rnf_tem .OR. ln_rnf_sal ) THEN
299           CALL ctl_warn( 'runoffs already included in precipitations, so runoff (T,S, depth) attributes will not be used' )
300           ln_rnf_depth = .FALSE.   ;   ln_rnf_tem = .FALSE.   ;   ln_rnf_sal = .FALSE.
301         ENDIF
302         !
303      ELSE                                      !==  runoffs read in a file : set sf_rnf structure  ==!
304         !
305         ALLOCATE( sf_rnf(1), STAT=ierror )         ! Create sf_rnf structure (runoff inflow)
306         IF(lwp) WRITE(numout,*)
307         IF(lwp) WRITE(numout,*) '          runoffs inflow read in a file'
308         IF( ierror > 0 ) THEN
309            CALL ctl_stop( 'sbc_rnf: unable to allocate sf_rnf structure' )   ;   RETURN
310         ENDIF
311         ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1)   )
312         IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
313         !                                          ! fill sf_rnf with the namelist (sn_rnf) and control print
314         CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf' )
315         !
316         IF( ln_rnf_tem ) THEN                      ! Create (if required) sf_t_rnf structure
317            IF(lwp) WRITE(numout,*)
318            IF(lwp) WRITE(numout,*) '          runoffs temperatures read in a file'
319            ALLOCATE( sf_t_rnf(1), STAT=ierror  )
320            IF( ierror > 0 ) THEN
321               CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' )   ;   RETURN
322            ENDIF
323            ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1)   )
324            IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
325            CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf' )
326         ENDIF
327         !
328         IF( ln_rnf_sal  ) THEN                     ! Create (if required) sf_s_rnf and sf_t_rnf structures
329            IF(lwp) WRITE(numout,*)
330            IF(lwp) WRITE(numout,*) '          runoffs salinities read in a file'
331            ALLOCATE( sf_s_rnf(1), STAT=ierror  )
332            IF( ierror > 0 ) THEN
333               CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' )   ;   RETURN
334            ENDIF
335            ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1)   )
336            IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
337            CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf' )
338         ENDIF
339         !
340         IF( ln_rnf_depth ) THEN                    ! depth of runoffs set from a file
341            IF(lwp) WRITE(numout,*)
342            IF(lwp) WRITE(numout,*) '          runoffs depth read in a file'
343            rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
344            IF( .NOT. sn_dep_rnf%ln_clim ) THEN   ;   WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear    ! add year
345               IF( sn_dep_rnf%cltype == 'monthly' )   WRITE(rn_dep_file, '(a,"m",i2)'  ) TRIM( rn_dep_file ), nmonth   ! add month
346            ENDIF
347            CALL iom_open ( rn_dep_file, inum )                           ! open file
348            CALL iom_get  ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf )   ! read the river mouth array
349            CALL iom_close( inum )                                        ! close file
350            !
351            nk_rnf(:,:) = 0                               ! set the number of level over which river runoffs are applied
352            DO jj = 1, jpj
353               DO ji = 1, jpi
354                  IF( h_rnf(ji,jj) > 0._wp ) THEN
355                     jk = 2
356                     DO WHILE ( jk /= mbkt(ji,jj) .AND. fsdept(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1 ;  END DO
357                     nk_rnf(ji,jj) = jk
358                  ELSEIF( h_rnf(ji,jj) == -1._wp   ) THEN   ;  nk_rnf(ji,jj) = 1
359                  ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN   ;  nk_rnf(ji,jj) = mbkt(ji,jj)
360                  ELSE
361                     CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999'  )
362                     WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
363                  ENDIF
364               END DO
365            END DO
366            DO jj = 1, jpj                                ! set the associated depth
367               DO ji = 1, jpi
368                  h_rnf(ji,jj) = 0._wp
369                  DO jk = 1, nk_rnf(ji,jj)
370                     h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
371                  END DO
372               END DO
373            END DO
374         ELSE                                       ! runoffs applied at the surface
375            nk_rnf(:,:) = 1
376            h_rnf (:,:) = fse3t(:,:,1)
377         ENDIF
378         !
379      ENDIF
380      !
381      rnf(:,:) =  0._wp                         ! runoff initialisation
382      rnf_tsc(:,:,:) = 0._wp                    ! runoffs temperature & salinty contents initilisation
383      !
384      !                                   ! ========================
385      !                                   !   River mouth vicinity
386      !                                   ! ========================
387      !
388      IF( ln_rnf_mouth ) THEN                   ! Specific treatment in vicinity of river mouths :
389         !                                      !    - Increase Kz in surface layers ( rn_hrnf > 0 )
390         !                                      !    - set to zero SSS damping (ln_ssr=T)
391         !                                      !    - mixed upstream-centered (ln_traadv_cen2=T)
392         !
393         IF ( ln_rnf_depth )   CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already',   &
394            &                                              'be spread through depth by ln_rnf_depth'               )
395         !
396         nkrnf = 0                                  ! Number of level over which Kz increase
397         IF( rn_hrnf > 0._wp ) THEN
398            nkrnf = 2
399            DO WHILE( nkrnf /= jpkm1 .AND. gdepw_0(nkrnf+1) < rn_hrnf )   ;   nkrnf = nkrnf + 1   ;   END DO
400            IF( ln_sco )   CALL ctl_warn( 'sbc_rnf: number of levels over which Kz is increased is computed for zco...' )
401         ENDIF
402         IF(lwp) WRITE(numout,*)
403         IF(lwp) WRITE(numout,*) '          Specific treatment used in vicinity of river mouths :'
404         IF(lwp) WRITE(numout,*) '             - Increase Kz in surface layers (if rn_hrnf > 0 )'
405         IF(lwp) WRITE(numout,*) '               by ', rn_avt_rnf,' m2/s  over ', nkrnf, ' w-levels'
406         IF(lwp) WRITE(numout,*) '             - set to zero SSS damping       (if ln_ssr=T)'
407         IF(lwp) WRITE(numout,*) '             - mixed upstream-centered       (if ln_traadv_cen2=T)'
408         !
409         CALL rnf_mouth                             ! set river mouth mask
410         !
411      ELSE                                      ! No treatment at river mouths
412         IF(lwp) WRITE(numout,*)
413         IF(lwp) WRITE(numout,*) '          No specific treatment at river mouths'
414         rnfmsk  (:,:) = 0._wp
415         rnfmsk_z(:)   = 0._wp
416         nkrnf = 0
417      ENDIF
418      !
419   END SUBROUTINE sbc_rnf_init
420
421
422   SUBROUTINE rnf_mouth
423      !!----------------------------------------------------------------------
424      !!                  ***  ROUTINE rnf_mouth  ***
425      !!
426      !! ** Purpose :   define the river mouths mask
427      !!
428      !! ** Method  :   read the river mouth mask (=0/1) in the river runoff
429      !!                climatological file. Defined a given vertical structure.
430      !!                CAUTION, the vertical structure is hard coded on the
431      !!                first 5 levels.
432      !!                This fields can be used to:
433      !!                 - set an upstream advection scheme
434      !!                   (ln_rnf_mouth=T and ln_traadv_cen2=T)
435      !!                 - increase vertical on the top nn_krnf vertical levels
436      !!                   at river runoff input grid point (nn_krnf>=2, see step.F90)
437      !!                 - set to zero SSS restoring flux at river mouth grid points
438      !!
439      !! ** Action  :   rnfmsk   set to 1 at river runoff input, 0 elsewhere
440      !!                rnfmsk_z vertical structure
441      !!----------------------------------------------------------------------
442      INTEGER            ::   inum        ! temporary integers
443      CHARACTER(len=140) ::   cl_rnfile   ! runoff file name
444      !!----------------------------------------------------------------------
445      !
446      IF(lwp) WRITE(numout,*)
447      IF(lwp) WRITE(numout,*) 'rnf_mouth : river mouth mask'
448      IF(lwp) WRITE(numout,*) '~~~~~~~~~ '
449      !
450      cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
451      IF( .NOT. sn_cnf%ln_clim ) THEN   ;   WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear    ! add year
452         IF( sn_cnf%cltype == 'monthly' )   WRITE(cl_rnfile, '(a,"m",i2)'  ) TRIM( cl_rnfile ), nmonth   ! add month
453      ENDIF
454      !
455      ! horizontal mask (read in NetCDF file)
456      CALL iom_open ( cl_rnfile, inum )                           ! open file
457      CALL iom_get  ( inum, jpdom_data, sn_cnf%clvar, rnfmsk )    ! read the river mouth array
458      CALL iom_close( inum )                                      ! close file
459      !
460      IF( nn_closea == 1 )   CALL clo_rnf( rnfmsk )               ! closed sea inflow set as ruver mouth
461      !
462      rnfmsk_z(:)   = 0._wp                                       ! vertical structure
463      rnfmsk_z(1)   = 1.0
464      rnfmsk_z(2)   = 1.0                                         ! **********
465      rnfmsk_z(3)   = 0.5                                         ! HARD CODED on the 5 first levels
466      rnfmsk_z(4)   = 0.25                                        ! **********
467      rnfmsk_z(5)   = 0.125
468      !
469   END SUBROUTINE rnf_mouth
470
471   !!======================================================================
472END MODULE sbcrnf
Note: See TracBrowser for help on using the repository browser.