New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv.F90 in branches/2013/dev_r3853_CNRS9_ConfSetting/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2013/dev_r3853_CNRS9_ConfSetting/NEMOGCM/NEMO/OPA_SRC/TRA/traadv.F90 @ 3901

Last change on this file since 3901 was 3901, checked in by clevy, 11 years ago

Configuration Setting/Step2, see ticket:#1074
  • Property svn:keywords set to Id
File size: 12.5 KB
Line 
1MODULE traadv
2   !!==============================================================================
3   !!                       ***  MODULE  traadv  ***
4   !! Ocean active tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-09  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   tra_adv      : compute ocean tracer advection trend
12   !!   tra_adv_ctl  : control the different options of advection scheme
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and active tracers
15   USE dom_oce         ! ocean space and time domain
16   USE traadv_cen2     ! 2nd order centered scheme (tra_adv_cen2   routine)
17   USE traadv_tvd      ! TVD      scheme           (tra_adv_tvd    routine)
18   USE traadv_muscl    ! MUSCL    scheme           (tra_adv_muscl  routine)
19   USE traadv_muscl2   ! MUSCL2   scheme           (tra_adv_muscl2 routine)
20   USE traadv_ubs      ! UBS      scheme           (tra_adv_ubs    routine)
21   USE traadv_qck      ! QUICKEST scheme           (tra_adv_qck    routine)
22   USE traadv_eiv      ! eddy induced velocity     (tra_adv_eiv    routine)
23   USE cla             ! cross land advection      (cla_traadv     routine)
24   USE ldftra_oce      ! lateral diffusion coefficient on tracers
25   USE in_out_manager  ! I/O manager
26   USE iom             ! I/O module
27   USE prtctl          ! Print control
28   USE lib_mpp         ! MPP library
29   USE wrk_nemo        ! Memory Allocation
30   USE timing          ! Timing
31
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   tra_adv        ! routine called by step module
37   PUBLIC   tra_adv_init   ! routine called by opa module
38
39   !                              !!* Namelist namtra_adv *
40   LOGICAL ::   ln_traadv_cen2     ! 2nd order centered scheme flag
41   LOGICAL ::   ln_traadv_tvd      ! TVD scheme flag
42   LOGICAL ::   ln_traadv_muscl    ! MUSCL scheme flag
43   LOGICAL ::   ln_traadv_muscl2   ! MUSCL2 scheme flag
44   LOGICAL ::   ln_traadv_ubs      ! UBS scheme flag
45   LOGICAL ::   ln_traadv_qck      ! QUICKEST scheme flag
46   LOGICAL ::   ln_traadv_msc_ups  ! use upstream scheme within muscl
47
48
49   INTEGER ::   nadv   ! choice of the type of advection scheme
50
51   !! * Substitutions
52#  include "domzgr_substitute.h90"
53#  include "vectopt_loop_substitute.h90"
54   !!----------------------------------------------------------------------
55   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
56   !! $Id$
57   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
58   !!----------------------------------------------------------------------
59CONTAINS
60
61   SUBROUTINE tra_adv( kt )
62      !!----------------------------------------------------------------------
63      !!                  ***  ROUTINE tra_adv  ***
64      !!
65      !! ** Purpose :   compute the ocean tracer advection trend.
66      !!
67      !! ** Method  : - Update (ua,va) with the advection term following nadv
68      !!----------------------------------------------------------------------
69      !
70      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
71      !
72      INTEGER ::   jk   ! dummy loop index
73      REAL(wp), POINTER, DIMENSION(:,:,:) :: zun, zvn, zwn
74      !!----------------------------------------------------------------------
75      !
76      IF( nn_timing == 1 )  CALL timing_start('tra_adv')
77      !
78      CALL wrk_alloc( jpi, jpj, jpk, zun, zvn, zwn )
79      !                                          ! set time step
80      IF( neuler == 0 .AND. kt == nit000 ) THEN     ! at nit000
81         r2dtra(:) =  rdttra(:)                          ! = rdtra (restarting with Euler time stepping)
82      ELSEIF( kt <= nit000 + 1) THEN                ! at nit000 or nit000+1
83         r2dtra(:) = 2._wp * rdttra(:)                   ! = 2 rdttra (leapfrog)
84      ENDIF
85      !
86      IF( nn_cla == 1 )   CALL cla_traadv( kt )       !==  Cross Land Advection  ==! (hor. advection)
87      !
88      !                                               !==  effective transport  ==!
89      DO jk = 1, jpkm1
90         zun(:,:,jk) = e2u(:,:) * fse3u(:,:,jk) * un(:,:,jk)                  ! eulerian transport only
91         zvn(:,:,jk) = e1v(:,:) * fse3v(:,:,jk) * vn(:,:,jk)
92         zwn(:,:,jk) = e1t(:,:) * e2t(:,:)      * wn(:,:,jk)
93      END DO
94      zun(:,:,jpk) = 0._wp                                                     ! no transport trough the bottom
95      zvn(:,:,jpk) = 0._wp                                                     ! no transport trough the bottom
96      zwn(:,:,jpk) = 0._wp                                                     ! no transport trough the bottom
97      !
98      IF( lk_traldf_eiv .AND. .NOT. ln_traldf_grif )   &
99         &              CALL tra_adv_eiv( kt, nit000, zun, zvn, zwn, 'TRA' )    ! add the eiv transport (if necessary)
100      !
101      CALL iom_put( "uocetr_eff", zun )                                         ! output effective transport     
102      CALL iom_put( "vocetr_eff", zvn )
103      CALL iom_put( "wocetr_eff", zwn )
104
105      SELECT CASE ( nadv )                            !==  compute advection trend and add it to general trend  ==!
106      CASE ( 1 )   ;    CALL tra_adv_cen2  ( kt, nit000, 'TRA',         zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  2nd order centered
107      CASE ( 2 )   ;    CALL tra_adv_tvd   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  TVD
108      CASE ( 3 )   ;    CALL tra_adv_muscl ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb,      tsa, jpts, ln_traadv_msc_ups )   !  MUSCL
109      CASE ( 4 )   ;    CALL tra_adv_muscl2( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  MUSCL2
110      CASE ( 5 )   ;    CALL tra_adv_ubs   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  UBS
111      CASE ( 6 )   ;    CALL tra_adv_qck   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  QUICKEST
112      !
113      CASE (-1 )                                      !==  esopa: test all possibility with control print  ==!
114         CALL tra_adv_cen2  ( kt, nit000, 'TRA',         zun, zvn, zwn, tsb, tsn, tsa, jpts )         
115         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv0 - Ta: ', mask1=tmask,               &
116            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
117         CALL tra_adv_tvd   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
118         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv1 - Ta: ', mask1=tmask,               &
119            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
120         CALL tra_adv_muscl ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb,      tsa, jpts, ln_traadv_msc_ups )         
121         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv3 - Ta: ', mask1=tmask,               &
122            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
123         CALL tra_adv_muscl2( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
124         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv4 - Ta: ', mask1=tmask,               &
125            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
126         CALL tra_adv_ubs   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
127         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv5 - Ta: ', mask1=tmask,               &
128            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
129         CALL tra_adv_qck   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
130         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv6 - Ta: ', mask1=tmask,               &
131            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
132      END SELECT
133      !
134      !                                              ! print mean trends (used for debugging)
135      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv  - Ta: ', mask1=tmask,               &
136         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
137      !
138      IF( nn_timing == 1 )  CALL timing_stop('tra_adv')
139      !
140      CALL wrk_dealloc( jpi, jpj, jpk, zun, zvn, zwn )
141      !                                         
142   END SUBROUTINE tra_adv
143
144
145   SUBROUTINE tra_adv_init
146      !!---------------------------------------------------------------------
147      !!                  ***  ROUTINE tra_adv_init  ***
148      !!               
149      !! ** Purpose :   Control the consistency between namelist options for
150      !!              tracer advection schemes and set nadv
151      !!----------------------------------------------------------------------
152      INTEGER ::   ioptio
153      INTEGER ::   ios                 ! Local integer output status for namelist read
154      !!
155      NAMELIST/namtra_adv/ ln_traadv_cen2 , ln_traadv_tvd,     &
156         &                 ln_traadv_muscl, ln_traadv_muscl2,  &
157         &                 ln_traadv_ubs  , ln_traadv_qck,     &
158         &                 ln_traadv_msc_ups
159      !!----------------------------------------------------------------------
160
161      REWIND( numnam_ref )              ! Namelist namtra_adv in reference namelist : Tracer advection scheme
162      READ  ( numnam_ref, namtra_adv, IOSTAT = ios, ERR = 901)
163901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in reference namelist', lwp )
164
165      REWIND( numnam_cfg )              ! Namelist namtra_adv in configuration namelist : Tracer advection scheme
166      READ  ( numnam_cfg, namtra_adv, IOSTAT = ios, ERR = 902 )
167902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in configuration namelist', lwp )
168      WRITE ( numond, namtra_adv )
169
170      IF(lwp) THEN                    ! Namelist print
171         WRITE(numout,*)
172         WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme'
173         WRITE(numout,*) '~~~~~~~~~~~'
174         WRITE(numout,*) '   Namelist namtra_adv : chose a advection scheme for tracers'
175         WRITE(numout,*) '      2nd order advection scheme     ln_traadv_cen2    = ', ln_traadv_cen2
176         WRITE(numout,*) '      TVD advection scheme           ln_traadv_tvd     = ', ln_traadv_tvd
177         WRITE(numout,*) '      MUSCL  advection scheme        ln_traadv_muscl   = ', ln_traadv_muscl
178         WRITE(numout,*) '      MUSCL2 advection scheme        ln_traadv_muscl2  = ', ln_traadv_muscl2
179         WRITE(numout,*) '      UBS    advection scheme        ln_traadv_ubs     = ', ln_traadv_ubs
180         WRITE(numout,*) '      QUICKEST advection scheme      ln_traadv_qck     = ', ln_traadv_qck
181         WRITE(numout,*) '      upstream scheme within muscl   ln_traadv_msc_ups = ', ln_traadv_msc_ups
182      ENDIF
183
184      ioptio = 0                      ! Parameter control
185      IF( ln_traadv_cen2   )   ioptio = ioptio + 1
186      IF( ln_traadv_tvd    )   ioptio = ioptio + 1
187      IF( ln_traadv_muscl  )   ioptio = ioptio + 1
188      IF( ln_traadv_muscl2 )   ioptio = ioptio + 1
189      IF( ln_traadv_ubs    )   ioptio = ioptio + 1
190      IF( ln_traadv_qck    )   ioptio = ioptio + 1
191      IF( lk_esopa         )   ioptio =          1
192
193      IF( ioptio /= 1 )   CALL ctl_stop( 'Choose ONE advection scheme in namelist namtra_adv' )
194
195      !                              ! Set nadv
196      IF( ln_traadv_cen2   )   nadv =  1
197      IF( ln_traadv_tvd    )   nadv =  2
198      IF( ln_traadv_muscl  )   nadv =  3
199      IF( ln_traadv_muscl2 )   nadv =  4
200      IF( ln_traadv_ubs    )   nadv =  5
201      IF( ln_traadv_qck    )   nadv =  6
202      IF( lk_esopa         )   nadv = -1
203
204      IF(lwp) THEN                   ! Print the choice
205         WRITE(numout,*)
206         IF( nadv ==  1 )   WRITE(numout,*) '         2nd order scheme is used'
207         IF( nadv ==  2 )   WRITE(numout,*) '         TVD       scheme is used'
208         IF( nadv ==  3 )   WRITE(numout,*) '         MUSCL     scheme is used'
209         IF( nadv ==  4 )   WRITE(numout,*) '         MUSCL2    scheme is used'
210         IF( nadv ==  5 )   WRITE(numout,*) '         UBS       scheme is used'
211         IF( nadv ==  6 )   WRITE(numout,*) '         QUICKEST  scheme is used'
212         IF( nadv == -1 )   WRITE(numout,*) '         esopa test: use all advection scheme'
213      ENDIF
214      !
215   END SUBROUTINE tra_adv_init
216
217  !!======================================================================
218END MODULE traadv
Note: See TracBrowser for help on using the repository browser.