New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traqsr.F90 in branches/2013/dev_r3853_CNRS9_ConfSetting/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2013/dev_r3853_CNRS9_ConfSetting/NEMOGCM/NEMO/OPA_SRC/TRA/traqsr.F90 @ 3875

Last change on this file since 3875 was 3875, checked in by clevy, 11 years ago

Configuration Setting/Step? 1, see ticket:#1074
  • Property svn:keywords set to Id
File size: 27.6 KB
Line 
1MODULE traqsr
2   !!======================================================================
3   !!                       ***  MODULE  traqsr  ***
4   !! Ocean physics: solar radiation penetration in the top ocean levels
5   !!======================================================================
6   !! History :  OPA  !  1990-10  (B. Blanke)  Original code
7   !!            7.0  !  1991-11  (G. Madec)
8   !!                 !  1996-01  (G. Madec)  s-coordinates
9   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
10   !!             -   !  2005-11  (G. Madec) zco, zps, sco coordinate
11   !!            3.2  !  2009-04  (G. Madec & NEMO team)
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_qsr      : trend due to the solar radiation penetration
16   !!   tra_qsr_init : solar radiation penetration initialization
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and active tracers
19   USE dom_oce         ! ocean space and time domain
20   USE sbc_oce         ! surface boundary condition: ocean
21   USE trc_oce         ! share SMS/Ocean variables
22   USE trdmod_oce      ! ocean variables trends
23   USE trdtra          ! ocean active tracers trends
24   USE in_out_manager  ! I/O manager
25   USE phycst          ! physical constants
26   USE prtctl          ! Print control
27   USE iom             ! I/O manager
28   USE fldread         ! read input fields
29   USE lib_mpp         ! MPP library
30   USE wrk_nemo       ! Memory Allocation
31   USE timing         ! Timing
32
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   tra_qsr       ! routine called by step.F90 (ln_traqsr=T)
38   PUBLIC   tra_qsr_init  ! routine called by opa.F90
39
40   !                                           !!* Namelist namtra_qsr: penetrative solar radiation
41   LOGICAL , PUBLIC ::   ln_traqsr  = .TRUE.    !: light absorption (qsr) flag
42   LOGICAL , PUBLIC ::   ln_qsr_rgb = .FALSE.   !: Red-Green-Blue light absorption flag 
43   LOGICAL , PUBLIC ::   ln_qsr_2bd = .TRUE.    !: 2 band         light absorption flag
44   LOGICAL , PUBLIC ::   ln_qsr_bio = .FALSE.   !: bio-model      light absorption flag
45   INTEGER , PUBLIC ::   nn_chldta  = 0         !: use Chlorophyll data (=1) or not (=0)
46   REAL(wp), PUBLIC ::   rn_abs     = 0.58_wp   !: fraction absorbed in the very near surface (RGB & 2 bands)
47   REAL(wp), PUBLIC ::   rn_si0     = 0.35_wp   !: very near surface depth of extinction      (RGB & 2 bands)
48   REAL(wp), PUBLIC ::   rn_si1     = 23.0_wp   !: deepest depth of extinction (water type I)       (2 bands)
49   
50   ! Module variables
51   REAL(wp) ::   xsi0r                           !: inverse of rn_si0
52   REAL(wp) ::   xsi1r                           !: inverse of rn_si1
53   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_chl   ! structure of input Chl (file informations, fields read)
54   INTEGER, PUBLIC ::   nksr              ! levels below which the light cannot penetrate ( depth larger than 391 m)
55   REAL(wp), DIMENSION(3,61) ::   rkrgb   !: tabulated attenuation coefficients for RGB absorption
56
57   !! * Substitutions
58#  include "domzgr_substitute.h90"
59#  include "vectopt_loop_substitute.h90"
60   !!----------------------------------------------------------------------
61   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
62   !! $Id$
63   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
64   !!----------------------------------------------------------------------
65CONTAINS
66
67   SUBROUTINE tra_qsr( kt )
68      !!----------------------------------------------------------------------
69      !!                  ***  ROUTINE tra_qsr  ***
70      !!
71      !! ** Purpose :   Compute the temperature trend due to the solar radiation
72      !!      penetration and add it to the general temperature trend.
73      !!
74      !! ** Method  : The profile of the solar radiation within the ocean is defined
75      !!      through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs
76      !!      Considering the 2 wavebands case:
77      !!         I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) )
78      !!         The temperature trend associated with the solar radiation penetration
79      !!         is given by : zta = 1/e3t dk[ I ] / (rau0*Cp)
80      !!         At the bottom, boudary condition for the radiation is no flux :
81      !!      all heat which has not been absorbed in the above levels is put
82      !!      in the last ocean level.
83      !!         In z-coordinate case, the computation is only done down to the
84      !!      level where I(k) < 1.e-15 W/m2. In addition, the coefficients
85      !!      used for the computation are calculated one for once as they
86      !!      depends on k only.
87      !!
88      !! ** Action  : - update ta with the penetrative solar radiation trend
89      !!              - save the trend in ttrd ('key_trdtra')
90      !!
91      !! Reference  : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
92      !!              Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516.
93      !!----------------------------------------------------------------------
94      !
95      INTEGER, INTENT(in) ::   kt     ! ocean time-step
96      !
97      INTEGER  ::   ji, jj, jk           ! dummy loop indices
98      INTEGER  ::   irgb                 ! local integers
99      REAL(wp) ::   zchl, zcoef, zfact   ! local scalars
100      REAL(wp) ::   zc0, zc1, zc2, zc3   !    -         -
101      REAL(wp) ::   zz0, zz1, z1_e3t     !    -         -
102      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
103      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea, ztrdt
104      !!----------------------------------------------------------------------
105      !
106      IF( nn_timing == 1 )  CALL timing_start('tra_qsr')
107      !
108      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        ) 
109      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
110      !
111      IF( kt == nit000 ) THEN
112         IF(lwp) WRITE(numout,*)
113         IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation'
114         IF(lwp) WRITE(numout,*) '~~~~~~~'
115         IF( .NOT.ln_traqsr )   RETURN
116      ENDIF
117
118      IF( l_trdtra ) THEN      ! Save ta and sa trends
119         CALL wrk_alloc( jpi, jpj, jpk, ztrdt ) 
120         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
121      ENDIF
122
123      !                                        Set before qsr tracer content field
124      !                                        ***********************************
125      IF( kt == nit000 ) THEN                     ! Set the forcing field at nit000 - 1
126         !                                        ! -----------------------------------
127         IF( ln_rstart .AND.    &                    ! Restart: read in restart file
128              & iom_varid( numror, 'qsr_hc_b', ldstop = .FALSE. ) > 0 ) THEN
129            IF(lwp) WRITE(numout,*) '          nit000-1 qsr tracer content forcing field red in the restart file'
130            zfact = 0.5e0
131            CALL iom_get( numror, jpdom_autoglo, 'qsr_hc_b', qsr_hc_b )   ! before heat content trend due to Qsr flux
132         ELSE                                           ! No restart or restart not found: Euler forward time stepping
133            zfact = 1.e0
134            qsr_hc_b(:,:,:) = 0.e0
135         ENDIF
136      ELSE                                        ! Swap of forcing field
137         !                                        ! ---------------------
138         zfact = 0.5e0
139         qsr_hc_b(:,:,:) = qsr_hc(:,:,:)
140      ENDIF
141      !                                        Compute now qsr tracer content field
142      !                                        ************************************
143     
144      !                                           ! ============================================== !
145      IF( lk_qsr_bio .AND. ln_qsr_bio ) THEN      !  bio-model fluxes  : all vertical coordinates  !
146         !                                        ! ============================================== !
147         DO jk = 1, jpkm1
148            qsr_hc(:,:,jk) = r1_rau0_rcp * ( etot3(:,:,jk) - etot3(:,:,jk+1) )
149         END DO
150         !                                        Add to the general trend
151         DO jk = 1, jpkm1
152            DO jj = 2, jpjm1 
153               DO ji = fs_2, fs_jpim1   ! vector opt.
154                  z1_e3t = zfact / fse3t(ji,jj,jk)
155                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
156               END DO
157            END DO
158         END DO
159         CALL iom_put( 'qsr3d', etot3 )   ! Shortwave Radiation 3D distribution
160         !                                        ! ============================================== !
161      ELSE                                        !  Ocean alone :
162         !                                        ! ============================================== !
163         !
164         !                                                ! ------------------------- !
165         IF( ln_qsr_rgb) THEN                             !  R-G-B  light penetration !
166            !                                             ! ------------------------- !
167            ! Set chlorophyl concentration
168            IF( nn_chldta == 1 .OR. lk_vvl ) THEN            !*  Variable Chlorophyll or ocean volume
169               !
170               IF( nn_chldta == 1 ) THEN                             !*  Variable Chlorophyll
171                  !
172                  CALL fld_read( kt, 1, sf_chl )                         ! Read Chl data and provides it at the current time step
173                  !         
174!CDIR COLLAPSE
175!CDIR NOVERRCHK
176                  DO jj = 1, jpj                                         ! Separation in R-G-B depending of the surface Chl
177!CDIR NOVERRCHK
178                     DO ji = 1, jpi
179                        zchl = MIN( 10. , MAX( 0.03, sf_chl(1)%fnow(ji,jj,1) ) )
180                        irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
181                        zekb(ji,jj) = rkrgb(1,irgb)
182                        zekg(ji,jj) = rkrgb(2,irgb)
183                        zekr(ji,jj) = rkrgb(3,irgb)
184                     END DO
185                  END DO
186               ELSE                                            ! Variable ocean volume but constant chrlorophyll
187                  zchl = 0.05                                     ! constant chlorophyll
188                  irgb = NINT( 41 + 20.*LOG10( zchl ) + 1.e-15 )
189                  zekb(:,:) = rkrgb(1,irgb)                       ! Separation in R-G-B depending of the chlorophyll
190                  zekg(:,:) = rkrgb(2,irgb)
191                  zekr(:,:) = rkrgb(3,irgb)
192               ENDIF
193               !
194               zcoef  = ( 1. - rn_abs ) / 3.e0                        ! equi-partition in R-G-B
195               ze0(:,:,1) = rn_abs  * qsr(:,:)
196               ze1(:,:,1) = zcoef * qsr(:,:)
197               ze2(:,:,1) = zcoef * qsr(:,:)
198               ze3(:,:,1) = zcoef * qsr(:,:)
199               zea(:,:,1) =         qsr(:,:)
200               !
201               DO jk = 2, nksr+1
202!CDIR NOVERRCHK
203                  DO jj = 1, jpj
204!CDIR NOVERRCHK   
205                     DO ji = 1, jpi
206                        zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r     )
207                        zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) )
208                        zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) )
209                        zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) )
210                        ze0(ji,jj,jk) = zc0
211                        ze1(ji,jj,jk) = zc1
212                        ze2(ji,jj,jk) = zc2
213                        ze3(ji,jj,jk) = zc3
214                        zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
215                     END DO
216                  END DO
217               END DO
218               !
219               DO jk = 1, nksr                                        ! compute and add qsr trend to ta
220                  qsr_hc(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) )
221               END DO
222               zea(:,:,nksr+1:jpk) = 0.e0     ! below 400m set to zero
223               CALL iom_put( 'qsr3d', zea )   ! Shortwave Radiation 3D distribution
224               !
225            ELSE                                                 !*  Constant Chlorophyll
226               DO jk = 1, nksr
227                  qsr_hc(:,:,jk) =  etot3(:,:,jk) * qsr(:,:)
228               END DO
229            ENDIF
230
231         ENDIF
232         !                                                ! ------------------------- !
233         IF( ln_qsr_2bd ) THEN                            !  2 band light penetration !
234            !                                             ! ------------------------- !
235            !
236            IF( lk_vvl ) THEN                                  !* variable volume
237               zz0   =        rn_abs   * r1_rau0_rcp
238               zz1   = ( 1. - rn_abs ) * r1_rau0_rcp
239               DO jk = 1, nksr                    ! solar heat absorbed at T-point in the top 400m
240                  DO jj = 1, jpj
241                     DO ji = 1, jpi
242                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
243                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
244                        qsr_hc(ji,jj,jk) = qsr(ji,jj) * ( zc0*tmask(ji,jj,jk) - zc1*tmask(ji,jj,jk+1) ) 
245                     END DO
246                  END DO
247               END DO
248            ELSE                                               !* constant volume: coef. computed one for all
249               DO jk = 1, nksr
250                  DO jj = 2, jpjm1
251                     DO ji = fs_2, fs_jpim1   ! vector opt.
252                        qsr_hc(ji,jj,jk) =  etot3(ji,jj,jk) * qsr(ji,jj)
253                     END DO
254                  END DO
255               END DO
256               !
257            ENDIF
258            !
259         ENDIF
260         !
261         !                                        Add to the general trend
262         DO jk = 1, nksr
263            DO jj = 2, jpjm1 
264               DO ji = fs_2, fs_jpim1   ! vector opt.
265                  z1_e3t = zfact / fse3t(ji,jj,jk)
266                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
267               END DO
268            END DO
269         END DO
270         !
271      ENDIF
272      !
273      IF( lrst_oce ) THEN   !                  Write in the ocean restart file
274         !                                     *******************************
275         IF(lwp) WRITE(numout,*)
276         IF(lwp) WRITE(numout,*) 'qsr tracer content forcing field written in ocean restart file ',   &
277            &                    'at it= ', kt,' date= ', ndastp
278         IF(lwp) WRITE(numout,*) '~~~~'
279         CALL iom_rstput( kt, nitrst, numrow, 'qsr_hc_b', qsr_hc )
280         !
281      ENDIF
282
283      IF( l_trdtra ) THEN     ! qsr tracers trends saved for diagnostics
284         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:)
285         CALL trd_tra( kt, 'TRA', jp_tem, jptra_trd_qsr, ztrdt )
286         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt ) 
287      ENDIF
288      !                       ! print mean trends (used for debugging)
289      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' qsr  - Ta: ', mask1=tmask, clinfo3='tra-ta' )
290      !
291      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        ) 
292      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
293      !
294      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr')
295      !
296   END SUBROUTINE tra_qsr
297
298
299   SUBROUTINE tra_qsr_init
300      !!----------------------------------------------------------------------
301      !!                  ***  ROUTINE tra_qsr_init  ***
302      !!
303      !! ** Purpose :   Initialization for the penetrative solar radiation
304      !!
305      !! ** Method  :   The profile of solar radiation within the ocean is set
306      !!      from two length scale of penetration (rn_si0,rn_si1) and a ratio
307      !!      (rn_abs). These parameters are read in the namtra_qsr namelist. The
308      !!      default values correspond to clear water (type I in Jerlov'
309      !!      (1968) classification.
310      !!         called by tra_qsr at the first timestep (nit000)
311      !!
312      !! ** Action  : - initialize rn_si0, rn_si1 and rn_abs
313      !!
314      !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
315      !!----------------------------------------------------------------------
316      !
317      INTEGER  ::   ji, jj, jk                   ! dummy loop indices
318      INTEGER  ::   irgb, ierror, ioptio, nqsr   ! local integer
319      INTEGER  ::   ios                          ! Local integer output status for namelist read
320      REAL(wp) ::   zz0, zc0  , zc1, zcoef       ! local scalars
321      REAL(wp) ::   zz1, zc2  , zc3, zchl        !   -      -
322      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
323      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea
324      !
325      CHARACTER(len=100) ::   cn_dir   ! Root directory for location of ssr files
326      TYPE(FLD_N)        ::   sn_chl   ! informations about the chlorofyl field to be read
327      !!
328      NAMELIST/namtra_qsr/  sn_chl, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio,   &
329         &                  nn_chldta, rn_abs, rn_si0, rn_si1
330      !!----------------------------------------------------------------------
331
332      !
333      IF( nn_timing == 1 )  CALL timing_start('tra_qsr_init')
334      !
335      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        ) 
336      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
337      !
338
339      cn_dir = './'       ! directory in which the model is executed
340      ! ... default values (NB: frequency positive => hours, negative => months)
341      !            !     file       ! frequency !  variable  ! time interp !  clim   ! 'yearly' or ! weights  ! rotation   !
342      !            !     name       !  (hours)  !    name    !    (T/F)    !  (T/F)  ! 'monthly'   ! filename ! pairs      !
343      sn_chl = FLD_N( 'chlorophyll' ,    -1     ,  'CHLA'    ,  .true.     , .true.  ,   'yearly'  , ''       , ''         )
344      !
345
346      REWIND( numnam_ref )              ! Namelist namtra_qsr in reference namelist : Ratio and length of penetration
347      READ  ( numnam_ref, namtra_qsr, IOSTAT = ios, ERR = 901)
348901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in reference namelist', lwp )
349
350      REWIND( numnam_cfg )              !  Namelist namtra_qsr in configuration namelist : Ratio and length of penetration
351      READ  ( numnam_cfg, namtra_qsr, IOSTAT = ios, ERR = 902 )
352902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in configuration namelist', lwp )
353      WRITE ( numond, namtra_qsr )
354      !
355      IF(lwp) THEN                ! control print
356         WRITE(numout,*)
357         WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation'
358         WRITE(numout,*) '~~~~~~~~~~~~'
359         WRITE(numout,*) '   Namelist namtra_qsr : set the parameter of penetration'
360         WRITE(numout,*) '      Light penetration (T) or not (F)         ln_traqsr  = ', ln_traqsr
361         WRITE(numout,*) '      RGB (Red-Green-Blue) light penetration   ln_qsr_rgb = ', ln_qsr_rgb
362         WRITE(numout,*) '      2 band               light penetration   ln_qsr_2bd = ', ln_qsr_2bd
363         WRITE(numout,*) '      bio-model            light penetration   ln_qsr_bio = ', ln_qsr_bio
364         WRITE(numout,*) '      RGB : Chl data (=1) or cst value (=0)    nn_chldta  = ', nn_chldta
365         WRITE(numout,*) '      RGB & 2 bands: fraction of light (rn_si1)    rn_abs = ', rn_abs
366         WRITE(numout,*) '      RGB & 2 bands: shortess depth of extinction  rn_si0 = ', rn_si0
367         WRITE(numout,*) '      2 bands: longest depth of extinction         rn_si1 = ', rn_si1
368      ENDIF
369
370      IF( ln_traqsr ) THEN     ! control consistency
371         !                     
372         IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio )   THEN
373            CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' )
374            ln_qsr_bio = .FALSE.
375         ENDIF
376         !
377         ioptio = 0                      ! Parameter control
378         IF( ln_qsr_rgb  )   ioptio = ioptio + 1
379         IF( ln_qsr_2bd  )   ioptio = ioptio + 1
380         IF( ln_qsr_bio  )   ioptio = ioptio + 1
381         !
382         IF( ioptio /= 1 ) &
383            CALL ctl_stop( '          Choose ONE type of light penetration in namelist namtra_qsr',  &
384            &              ' 2 bands, 3 RGB bands or bio-model light penetration' )
385         !
386         IF( ln_qsr_rgb .AND. nn_chldta == 0 )   nqsr =  1 
387         IF( ln_qsr_rgb .AND. nn_chldta == 1 )   nqsr =  2
388         IF( ln_qsr_2bd                      )   nqsr =  3
389         IF( ln_qsr_bio                      )   nqsr =  4
390         !
391         IF(lwp) THEN                   ! Print the choice
392            WRITE(numout,*)
393            IF( nqsr ==  1 )   WRITE(numout,*) '         R-G-B   light penetration - Constant Chlorophyll'
394            IF( nqsr ==  2 )   WRITE(numout,*) '         R-G-B   light penetration - Chl data '
395            IF( nqsr ==  3 )   WRITE(numout,*) '         2 bands light penetration'
396            IF( nqsr ==  4 )   WRITE(numout,*) '         bio-model light penetration'
397         ENDIF
398         !
399      ENDIF
400      !                          ! ===================================== !
401      IF( ln_traqsr  ) THEN      !  Initialisation of Light Penetration  ! 
402         !                       ! ===================================== !
403         !
404         xsi0r = 1.e0 / rn_si0
405         xsi1r = 1.e0 / rn_si1
406         !                                ! ---------------------------------- !
407         IF( ln_qsr_rgb ) THEN            !  Red-Green-Blue light penetration  !
408            !                             ! ---------------------------------- !
409            !
410            CALL trc_oce_rgb( rkrgb )           !* tabulated attenuation coef.
411            !
412            !                                   !* level of light extinction
413            IF(  ln_sco ) THEN   ;   nksr = jpkm1
414            ELSE                 ;   nksr = trc_oce_ext_lev( r_si2, 0.33e2 )
415            ENDIF
416
417            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m'
418            !
419            IF( nn_chldta == 1 ) THEN           !* Chl data : set sf_chl structure
420               IF(lwp) WRITE(numout,*)
421               IF(lwp) WRITE(numout,*) '        Chlorophyll read in a file'
422               ALLOCATE( sf_chl(1), STAT=ierror )
423               IF( ierror > 0 ) THEN
424                  CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' )   ;   RETURN
425               ENDIF
426               ALLOCATE( sf_chl(1)%fnow(jpi,jpj,1)   )
427               IF( sn_chl%ln_tint )ALLOCATE( sf_chl(1)%fdta(jpi,jpj,1,2) )
428               !                                        ! fill sf_chl with sn_chl and control print
429               CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init',   &
430                  &                                         'Solar penetration function of read chlorophyll', 'namtra_qsr' )
431               !
432            ELSE                                !* constant Chl : compute once for all the distribution of light (etot3)
433               IF(lwp) WRITE(numout,*)
434               IF(lwp) WRITE(numout,*) '        Constant Chlorophyll concentration = 0.05'
435               IF( lk_vvl ) THEN                   ! variable volume
436                  IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
437               ELSE                                ! constant volume: computes one for all
438                  IF(lwp) WRITE(numout,*) '        fixed volume: light distribution computed one for all'
439                  !
440                  zchl = 0.05                                 ! constant chlorophyll
441                  irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
442                  zekb(:,:) = rkrgb(1,irgb)                   ! Separation in R-G-B depending of the chlorophyll
443                  zekg(:,:) = rkrgb(2,irgb)
444                  zekr(:,:) = rkrgb(3,irgb)
445                  !
446                  zcoef = ( 1. - rn_abs ) / 3.e0              ! equi-partition in R-G-B
447                  ze0(:,:,1) = rn_abs
448                  ze1(:,:,1) = zcoef
449                  ze2(:,:,1) = zcoef 
450                  ze3(:,:,1) = zcoef
451                  zea(:,:,1) = tmask(:,:,1)                   ! = ( ze0+ze1+z2+ze3 ) * tmask
452               
453                  DO jk = 2, nksr+1
454!CDIR NOVERRCHK
455                     DO jj = 1, jpj
456!CDIR NOVERRCHK   
457                        DO ji = 1, jpi
458                           zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * xsi0r     )
459                           zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * zekb(ji,jj) )
460                           zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * zekg(ji,jj) )
461                           zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * zekr(ji,jj) )
462                           ze0(ji,jj,jk) = zc0
463                           ze1(ji,jj,jk) = zc1
464                           ze2(ji,jj,jk) = zc2
465                           ze3(ji,jj,jk) = zc3
466                           zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
467                        END DO
468                     END DO
469                  END DO 
470                  !
471                  DO jk = 1, nksr
472                     etot3(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) ) 
473                  END DO
474                  etot3(:,:,nksr+1:jpk) = 0.e0                ! below 400m set to zero
475               ENDIF
476            ENDIF
477            !
478         ENDIF
479            !                             ! ---------------------------------- !
480         IF( ln_qsr_2bd ) THEN            !    2 bands    light penetration    !
481            !                             ! ---------------------------------- !
482            !
483            !                                ! level of light extinction
484            nksr = trc_oce_ext_lev( rn_si1, 1.e2 )
485            IF(lwp) THEN
486               WRITE(numout,*)
487            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m'
488            ENDIF
489            !
490            IF( lk_vvl ) THEN                   ! variable volume
491               IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
492            ELSE                                ! constant volume: computes one for all
493               zz0 =        rn_abs   * r1_rau0_rcp
494               zz1 = ( 1. - rn_abs ) * r1_rau0_rcp
495               DO jk = 1, nksr                    !*  solar heat absorbed at T-point computed once for all
496                  DO jj = 1, jpj                              ! top 400 meters
497                     DO ji = 1, jpi
498                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
499                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
500                        etot3(ji,jj,jk) = (  zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1)  ) 
501                     END DO
502                  END DO
503               END DO
504               etot3(:,:,nksr+1:jpk) = 0.e0                   ! below 400m set to zero
505               !
506            ENDIF
507         ENDIF
508         !                       ! ===================================== !
509      ELSE                       !        No light penetration           !                   
510         !                       ! ===================================== !
511         IF(lwp) THEN
512            WRITE(numout,*)
513            WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration'
514            WRITE(numout,*) '~~~~~~~~~~~~'
515         ENDIF
516      ENDIF
517      !
518      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        ) 
519      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
520      !
521      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr_init')
522      !
523   END SUBROUTINE tra_qsr_init
524
525   !!======================================================================
526END MODULE traqsr
Note: See TracBrowser for help on using the repository browser.