New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in branches/2013/dev_r3853_CNRS9_ConfSetting/NEMOGCM/NEMO/OPA_SRC – NEMO

Context Navigation

source: branches/2013/dev_r3853_CNRS9_ConfSetting/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 3875

Last change on this file since 3875 was 3875, checked in by clevy, 11 years ago
Configuration Setting/Step? 1, see ticket:#1074
Property svn:keywords set to `Id`
File size: 38.3 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code
7	!! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec)
8	!! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9	!! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10	!! - ! 1992-06 (L.Terray) coupling implementation
11	!! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice
12	!! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13	!! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14	!! 8.1 ! 1997-06 (M. Imbard, G. Madec)
15	!! 8.2 ! 1999-11 (M. Imbard, H. Goosse) LIM sea-ice model
16	!! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP
17	!! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER)
18	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules
19	!! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20	!! - ! 2004-08 (C. Talandier) New trends organization
21	!! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility
22	!! - ! 2005-11 (V. Garnier) Surface pressure gradient organization
23	!! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation
24	!! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization
25	!! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26	!! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp
27	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
29	!! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
30	!! 3.4 ! 2011-11 (C. Harris) decomposition changes for running with CICE
31	!!----------------------------------------------------------------------
32
33	!!----------------------------------------------------------------------
34	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
35	!! nemo_init : initialization of the NEMO system
36	!! nemo_ctl : initialisation of the contol print
37	!! nemo_closefile : close remaining open files
38	!! nemo_alloc : dynamical allocation
39	!! nemo_partition : calculate MPP domain decomposition
40	!! factorise : calculate the factors of the no. of MPI processes
41	!!----------------------------------------------------------------------
42	USE step_oce ! module used in the ocean time stepping module
43	USE sbc_oce ! surface boundary condition: ocean
44	USE cla ! cross land advection (tra_cla routine)
45	USE domcfg ! domain configuration (dom_cfg routine)
46	USE mppini ! shared/distributed memory setting (mpp_init routine)
47	USE domain ! domain initialization (dom_init routine)
48	#if defined key_nemocice_decomp
49	USE ice_domain_size, only: nx_global, ny_global
50	#endif
51	USE tideini ! tidal components initialization (tide_ini routine)
52	USE obcini ! open boundary cond. initialization (obc_ini routine)
53	USE bdyini ! open boundary cond. initialization (bdy_init routine)
54	USE bdydta ! open boundary cond. initialization (bdy_dta_init routine)
55	USE bdytides ! open boundary cond. initialization (bdytide_init routine)
56	USE istate ! initial state setting (istate_init routine)
57	USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine)
58	USE ldftra ! lateral diffusivity setting (ldftra_init routine)
59	USE zdfini ! vertical physics setting (zdf_init routine)
60	USE phycst ! physical constant (par_cst routine)
61	USE trdmod ! momentum/tracers trends (trd_mod_init routine)
62	USE asminc ! assimilation increments
63	USE asmbkg ! writing out state trajectory
64	USE diaptr ! poleward transports (dia_ptr_init routine)
65	USE diadct ! sections transports (dia_dct_init routine)
66	USE diaobs ! Observation diagnostics (dia_obs_init routine)
67	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
68	USE step ! NEMO time-stepping (stp routine)
69	USE icbini ! handle bergs, initialisation
70	USE icbstp ! handle bergs, calving, themodynamics and transport
71	#if defined key_oasis3
72	USE cpl_oasis3 ! OASIS3 coupling
73	#elif defined key_oasis4
74	USE cpl_oasis4 ! OASIS4 coupling (not working)
75	#endif
76	USE c1d ! 1D configuration
77	USE step_c1d ! Time stepping loop for the 1D configuration
78	#if defined key_top
79	USE trcini ! passive tracer initialisation
80	#endif
81	USE lib_mpp ! distributed memory computing
82	#if defined key_iomput
83	USE xios
84	#endif
85	USE sbctide, ONLY: lk_tide
86
87	IMPLICIT NONE
88	PRIVATE
89
90	PUBLIC nemo_gcm ! called by model.F90
91	PUBLIC nemo_init ! needed by AGRIF
92	PUBLIC nemo_alloc ! needed by TAM
93
94	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
95
96	!!----------------------------------------------------------------------
97	!! NEMO/OPA 4.0 , NEMO Consortium (2011)
98	!! $Id$
99	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
100	!!----------------------------------------------------------------------
101	CONTAINS
102
103	SUBROUTINE nemo_gcm
104	!!----------------------------------------------------------------------
105	!! * ROUTINE nemo_gcm *
106	!!
107	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
108	!! curvilinear mesh on the sphere.
109	!!
110	!! ** Method : - model general initialization
111	!! - launch the time-stepping (stp routine)
112	!! - finalize the run by closing files and communications
113	!!
114	!! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL.
115	!! Madec, 2008, internal report, IPSL.
116	!!----------------------------------------------------------------------
117	INTEGER :: istp ! time step index
118	!!----------------------------------------------------------------------
119	!
120	#if defined key_agrif
121	CALL Agrif_Init_Grids() ! AGRIF: set the meshes
122	#endif
123
124	! !-----------------------!
125	CALL nemo_init !== Initialisations ==!
126	! !-----------------------!
127	#if defined key_agrif
128	CALL Agrif_Declare_Var_dom ! AGRIF: set the meshes for DOM
129	CALL Agrif_Declare_Var ! " " " " " DYN/TRA
130	# if defined key_top
131	CALL Agrif_Declare_Var_top ! " " " " " TOP
132	# endif
133	# if defined key_lim2
134	CALL Agrif_Declare_Var_lim2 ! " " " " " LIM
135	# endif
136	#endif
137	! check that all process are still there... If some process have an error,
138	! they will never enter in step and other processes will wait until the end of the cpu time!
139	IF( lk_mpp ) CALL mpp_max( nstop )
140
141	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
142
143	! !-----------------------!
144	! !== time stepping ==!
145	! !-----------------------!
146	istp = nit000
147	#if defined key_c1d
148	DO WHILE ( istp <= nitend .AND. nstop == 0 )
149	CALL stp_c1d( istp )
150	istp = istp + 1
151	END DO
152	#else
153	IF( lk_asminc ) THEN
154	IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 ) ! Output background fields
155	IF( ln_asmdin ) THEN ! Direct initialization
156	IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 ) ! Tracers
157	IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 ) ! Dynamics
158	IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 ) ! SSH
159	ENDIF
160	ENDIF
161
162	DO WHILE ( istp <= nitend .AND. nstop == 0 )
163	#if defined key_agrif
164	CALL Agrif_Step( stp ) ! AGRIF: time stepping
165	#else
166	CALL stp( istp ) ! standard time stepping
167	#endif
168	istp = istp + 1
169	IF( lk_mpp ) CALL mpp_max( nstop )
170	END DO
171	#endif
172
173	IF( lk_diaobs ) CALL dia_obs_wri
174	!
175	IF( ln_icebergs ) CALL icb_end( nitend )
176
177	! !------------------------!
178	! !== finalize the run ==!
179	! !------------------------!
180	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
181	!
182	IF( nstop /= 0 .AND. lwp ) THEN ! error print
183	WRITE(numout,cform_err)
184	WRITE(numout,*) nstop, ' error have been found'
185	ENDIF
186	!
187	#if defined key_agrif
188	CALL Agrif_ParentGrid_To_ChildGrid()
189	IF( lk_diaobs ) CALL dia_obs_wri
190	IF( nn_timing == 1 ) CALL timing_finalize
191	CALL Agrif_ChildGrid_To_ParentGrid()
192	#endif
193	IF( nn_timing == 1 ) CALL timing_finalize
194	!
195	CALL nemo_closefile
196	#if defined key_iomput
197	CALL xios_finalize ! end mpp communications with xios
198	# if defined key_oasis3 \|\| defined key_oasis4
199	CALL cpl_prism_finalize ! end coupling and mpp communications with OASIS
200	# endif
201	#else
202	# if defined key_oasis3 \|\| defined key_oasis4
203	CALL cpl_prism_finalize ! end coupling and mpp communications with OASIS
204	# else
205	IF( lk_mpp ) CALL mppstop ! end mpp communications
206	# endif
207	#endif
208	!
209	END SUBROUTINE nemo_gcm
210
211
212	SUBROUTINE nemo_init
213	!!----------------------------------------------------------------------
214	!! * ROUTINE nemo_init *
215	!!
216	!! ** Purpose : initialization of the NEMO GCM
217	!!----------------------------------------------------------------------
218	INTEGER :: ji ! dummy loop indices
219	INTEGER :: ilocal_comm ! local integer
220	INTEGER :: ios
221	CHARACTER(len=80), DIMENSION(16) :: cltxt
222	!!
223	NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, &
224	& nn_isplt, nn_jsplt, nn_jctls, nn_jctle, &
225	& nn_bench, nn_timing
226	!!----------------------------------------------------------------------
227	!
228	cltxt = ''
229	!
230	! ! Open reference namelist and configuration namelist files
231	CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
232	CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
233	CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
234	!
235	REWIND( numnam_ref ) ! Namelist namctl in reference namelist : Control prints & Benchmark
236	READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
237	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', lwp )
238
239	REWIND( numnam_cfg ) ! Namelist namctl in confguration namelist : Control prints & Benchmark
240	READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
241	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', lwp )
242	WRITE( numond, namctl )
243	!
244	! !--------------------------------------------!
245	! ! set communicator & select the local node !
246	! !--------------------------------------------!
247	#if defined key_iomput
248	IF( Agrif_Root() ) THEN
249	# if defined key_oasis3 \|\| defined key_oasis4
250	CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis
251	CALL xios_initialize( "oceanx",local_comm=ilocal_comm )
252	# else
253	CALL xios_initialize( "nemo",return_comm=ilocal_comm )
254	# endif
255	ENDIF
256	narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm ) ! Nodes selection
257	#else
258	# if defined key_oasis3 \|\| defined key_oasis4
259	IF( Agrif_Root() ) THEN
260	CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis
261	ENDIF
262	narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm ) ! Nodes selection (control print return in cltxt)
263	# else
264	ilocal_comm = 0
265	narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop ) ! Nodes selection (control print return in cltxt)
266	# endif
267	#endif
268	narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 )
269
270	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
271
272	! If dimensions of processor grid weren't specified in the namelist file
273	! then we calculate them here now that we have our communicator size
274	IF( (jpni < 1) .OR. (jpnj < 1) )THEN
275	#if defined key_mpp_mpi
276	IF( Agrif_Root() ) CALL nemo_partition(mppsize)
277	#else
278	jpni = 1
279	jpnj = 1
280	jpnij = jpni*jpnj
281	#endif
282	END IF
283
284	! Calculate domain dimensions given calculated jpni and jpnj
285	! This used to be done in par_oce.F90 when they were parameters rather
286	! than variables
287	IF( Agrif_Root() ) THEN
288	#if defined key_nemocice_decomp
289	jpi = ( nx_global+2-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
290	jpj = ( ny_global+2-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
291	#else
292	jpi = ( jpiglo-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
293	jpj = ( jpjglo-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
294	#endif
295	jpk = jpkdta ! third dim
296	jpim1 = jpi-1 ! inner domain indices
297	jpjm1 = jpj-1 ! " "
298	jpkm1 = jpk-1 ! " "
299	jpij = jpi*jpj ! jpi x j
300	ENDIF
301
302	IF(lwp) THEN ! open listing units
303	!
304	CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
305	!
306	WRITE(numout,*)
307	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
308	WRITE(numout,*) ' NEMO team'
309	WRITE(numout,*) ' Ocean General Circulation Model'
310	WRITE(numout,*) ' version 3.4 (2011) '
311	WRITE(numout,*)
312	WRITE(numout,*)
313	DO ji = 1, SIZE(cltxt)
314	IF( TRIM(cltxt(ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode
315	END DO
316	WRITE(numout,cform_aaa) ! Flag AAAAAAA
317	!
318	ENDIF
319
320	! Now we know the dimensions of the grid and numout has been set we can
321	! allocate arrays
322	CALL nemo_alloc()
323
324	! !-------------------------------!
325	! ! NEMO general initialization !
326	! !-------------------------------!
327
328	CALL nemo_ctl ! Control prints & Benchmark
329
330	! ! Domain decomposition
331	IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out
332	ELSE ; CALL mpp_init2 ! eliminate land processors
333	ENDIF
334	!
335	IF( nn_timing == 1 ) CALL timing_init
336	!
337	! ! General initialization
338	CALL phy_cst ! Physical constants
339	CALL eos_init ! Equation of state
340	CALL dom_cfg ! Domain configuration
341	CALL dom_init ! Domain
342
343	IF( ln_nnogather ) CALL nemo_northcomms ! Initialise the northfold neighbour lists (must be done after the masks are defined)
344
345	IF( ln_ctl ) CALL prt_ctl_init ! Print control
346
347	IF( lk_obc ) CALL obc_init ! Open boundaries
348
349	CALL istate_init ! ocean initial state (Dynamics and tracers)
350
351	IF( lk_tide ) CALL tide_init( nit000 ) ! Initialisation of the tidal harmonics
352
353	IF( lk_bdy ) CALL bdy_init ! Open boundaries initialisation
354	IF( lk_bdy ) CALL bdy_dta_init ! Open boundaries initialisation of external data arrays
355	IF( lk_bdy ) CALL bdytide_init ! Open boundaries initialisation of tidal harmonic forcing
356
357	CALL dyn_nept_init ! simplified form of Neptune effect
358
359	! ! Ocean physics
360	CALL sbc_init ! Forcings : surface module
361	! ! Vertical physics
362	CALL zdf_init ! namelist read
363	CALL zdf_bfr_init ! bottom friction
364	IF( lk_zdfric ) CALL zdf_ric_init ! Richardson number dependent Kz
365	IF( lk_zdftke ) CALL zdf_tke_init ! TKE closure scheme
366	IF( lk_zdfgls ) CALL zdf_gls_init ! GLS closure scheme
367	IF( lk_zdfkpp ) CALL zdf_kpp_init ! KPP closure scheme
368	IF( lk_zdftmx ) CALL zdf_tmx_init ! tidal vertical mixing
369	IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) &
370	& CALL zdf_ddm_init ! double diffusive mixing
371	! ! Lateral physics
372	CALL ldf_tra_init ! Lateral ocean tracer physics
373	CALL ldf_dyn_init ! Lateral ocean momentum physics
374	IF( lk_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
375
376	! ! Active tracers
377	CALL tra_qsr_init ! penetrative solar radiation qsr
378	CALL tra_bbc_init ! bottom heat flux
379	IF( lk_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
380	IF( ln_tradmp ) CALL tra_dmp_init ! internal damping trends
381	CALL tra_adv_init ! horizontal & vertical advection
382	CALL tra_ldf_init ! lateral mixing
383	CALL tra_zdf_init ! vertical mixing and after tracer fields
384
385	! ! Dynamics
386	CALL dyn_adv_init ! advection (vector or flux form)
387	CALL dyn_vor_init ! vorticity term including Coriolis
388	CALL dyn_ldf_init ! lateral mixing
389	CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure
390	CALL dyn_zdf_init ! vertical diffusion
391	CALL dyn_spg_init ! surface pressure gradient
392
393	! ! Misc. options
394	IF( nn_cla == 1 ) CALL cla_init ! Cross Land Advection
395	CALL icb_init( rdt, nit000) ! initialise icebergs instance
396
397	#if defined key_top
398	! ! Passive tracers
399	CALL trc_init
400	#endif
401	! ! Diagnostics
402	IF( lk_floats ) CALL flo_init ! drifting Floats
403	IF( lk_diaar5 ) CALL dia_ar5_init ! ar5 diag
404	CALL dia_ptr_init ! Poleward TRansports initialization
405	IF( lk_diadct ) CALL dia_dct_init ! Sections tranports
406	CALL dia_hsb_init ! heat content, salt content and volume budgets
407	CALL trd_mod_init ! Mixed-layer/Vorticity/Integral constraints trends
408	IF( lk_diaobs ) THEN ! Observation & model comparison
409	CALL dia_obs_init ! Initialize observational data
410	CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
411	ENDIF
412	! ! Assimilation increments
413	IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments
414	IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
415	!
416	END SUBROUTINE nemo_init
417
418
419	SUBROUTINE nemo_ctl
420	!!----------------------------------------------------------------------
421	!! * ROUTINE nemo_ctl *
422	!!
423	!! ** Purpose : control print setting
424	!!
425	!! ** Method : - print namctl information and check some consistencies
426	!!----------------------------------------------------------------------
427	!
428	IF(lwp) THEN ! control print
429	WRITE(numout,*)
430	WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
431	WRITE(numout,*) '~~~~~~~ '
432	WRITE(numout,*) ' Namelist namctl'
433	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
434	WRITE(numout,*) ' level of print nn_print = ', nn_print
435	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
436	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
437	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
438	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
439	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
440	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
441	WRITE(numout,*) ' benchmark parameter (0/1) nn_bench = ', nn_bench
442	WRITE(numout,*) ' timing activated (0/1) nn_timing = ', nn_timing
443	ENDIF
444	!
445	nprint = nn_print ! convert DOCTOR namelist names into OLD names
446	nictls = nn_ictls
447	nictle = nn_ictle
448	njctls = nn_jctls
449	njctle = nn_jctle
450	isplt = nn_isplt
451	jsplt = nn_jsplt
452	nbench = nn_bench
453	! ! Parameter control
454	!
455	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
456	IF( lk_mpp .AND. jpnij > 1 ) THEN
457	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
458	ELSE
459	IF( isplt == 1 .AND. jsplt == 1 ) THEN
460	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
461	& ' - the print control will be done over the whole domain' )
462	ENDIF
463	ijsplt = isplt * jsplt ! total number of processors ijsplt
464	ENDIF
465	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
466	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
467	!
468	! ! indices used for the SUM control
469	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
470	lsp_area = .FALSE.
471	ELSE ! print control done over a specific area
472	lsp_area = .TRUE.
473	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
474	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
475	nictls = 1
476	ENDIF
477	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
478	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
479	nictle = jpiglo
480	ENDIF
481	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
482	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
483	njctls = 1
484	ENDIF
485	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
486	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
487	njctle = jpjglo
488	ENDIF
489	ENDIF
490	ENDIF
491	!
492	IF( nbench == 1 ) THEN ! Benchmark
493	SELECT CASE ( cp_cfg )
494	CASE ( 'gyre' ) ; CALL ctl_warn( ' The Benchmark is activated ' )
495	CASE DEFAULT ; CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:', &
496	& ' key_gyre must be used or set nbench = 0' )
497	END SELECT
498	ENDIF
499	!
500	IF( lk_c1d .AND. .NOT.lk_iomput ) CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ', &
501	& 'with the IOM Input/Output manager. ' , &
502	& 'Compile with key_iomput enabled' )
503	!
504	IF( 1_wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ', &
505	& 'f2003 standard. ' , &
506	& 'Compile with key_nosignedzero enabled' )
507	!
508	END SUBROUTINE nemo_ctl
509
510
511	SUBROUTINE nemo_closefile
512	!!----------------------------------------------------------------------
513	!! * ROUTINE nemo_closefile *
514	!!
515	!! ** Purpose : Close the files
516	!!----------------------------------------------------------------------
517	!
518	IF( lk_mpp ) CALL mppsync
519	!
520	CALL iom_close ! close all input/output files managed by iom_*
521	!
522	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
523	IF( numsol /= -1 ) CLOSE( numsol ) ! solver file
524	IF( numnam_ref /= -1 ) CLOSE( numnam_ref ) ! oce reference namelist
525	IF( numnam_cfg /= -1 ) CLOSE( numnam_cfg ) ! oce configuration namelist
526	IF( numnam_ice_ref /= -1 ) CLOSE( numnam_ice_ref ) ! ice reference namelist
527	IF( numnam_ice_cfg /= -1 ) CLOSE( numnam_ice_cfg ) ! ice configuration namelist
528	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
529	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
530	IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports
531	IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports
532	IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports
533
534	!
535	numout = 6 ! redefine numout in case it is used after this point...
536	!
537	END SUBROUTINE nemo_closefile
538
539
540	SUBROUTINE nemo_alloc
541	!!----------------------------------------------------------------------
542	!! * ROUTINE nemo_alloc *
543	!!
544	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
545	!!
546	!! ** Method :
547	!!----------------------------------------------------------------------
548	USE diawri , ONLY: dia_wri_alloc
549	USE dom_oce , ONLY: dom_oce_alloc
550	USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
551	USE ldftra_oce, ONLY: ldftra_oce_alloc
552	USE trc_oce , ONLY: trc_oce_alloc
553	#if defined key_diadct
554	USE diadct , ONLY: diadct_alloc
555	#endif
556	!
557	INTEGER :: ierr
558	!!----------------------------------------------------------------------
559	!
560	ierr = oce_alloc () ! ocean
561	ierr = ierr + dia_wri_alloc ()
562	ierr = ierr + dom_oce_alloc () ! ocean domain
563	ierr = ierr + ldfdyn_oce_alloc() ! ocean lateral physics : dynamics
564	ierr = ierr + ldftra_oce_alloc() ! ocean lateral physics : tracers
565	ierr = ierr + zdf_oce_alloc () ! ocean vertical physics
566	!
567	ierr = ierr + lib_mpp_alloc (numout) ! mpp exchanges
568	ierr = ierr + trc_oce_alloc () ! shared TRC / TRA arrays
569	!
570	#if defined key_diadct
571	ierr = ierr + diadct_alloc () !
572	#endif
573	!
574	IF( lk_mpp ) CALL mpp_sum( ierr )
575	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
576	!
577	END SUBROUTINE nemo_alloc
578
579
580	SUBROUTINE nemo_partition( num_pes )
581	!!----------------------------------------------------------------------
582	!! * ROUTINE nemo_partition *
583	!!
584	!! ** Purpose :
585	!!
586	!! ** Method :
587	!!----------------------------------------------------------------------
588	INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
589	!
590	INTEGER, PARAMETER :: nfactmax = 20
591	INTEGER :: nfact ! The no. of factors returned
592	INTEGER :: ierr ! Error flag
593	INTEGER :: ji
594	INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
595	INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
596	!!----------------------------------------------------------------------
597
598	ierr = 0
599
600	CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
601
602	IF( nfact <= 1 ) THEN
603	WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
604	WRITE (numout, *) ' : using grid of ',num_pes,' x 1'
605	jpnj = 1
606	jpni = num_pes
607	ELSE
608	! Search through factors for the pair that are closest in value
609	mindiff = 1000000
610	imin = 1
611	DO ji = 1, nfact-1, 2
612	idiff = ABS( ifact(ji) - ifact(ji+1) )
613	IF( idiff < mindiff ) THEN
614	mindiff = idiff
615	imin = ji
616	ENDIF
617	END DO
618	jpnj = ifact(imin)
619	jpni = ifact(imin + 1)
620	ENDIF
621	!
622	jpnij = jpni*jpnj
623	!
624	END SUBROUTINE nemo_partition
625
626
627	SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
628	!!----------------------------------------------------------------------
629	!! * ROUTINE factorise *
630	!!
631	!! ** Purpose : return the prime factors of n.
632	!! knfax factors are returned in array kfax which is of
633	!! maximum dimension kmaxfax.
634	!! ** Method :
635	!!----------------------------------------------------------------------
636	INTEGER , INTENT(in ) :: kn, kmaxfax
637	INTEGER , INTENT( out) :: kerr, knfax
638	INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax
639	!
640	INTEGER :: ifac, jl, inu
641	INTEGER, PARAMETER :: ntest = 14
642	INTEGER :: ilfax(ntest)
643
644	! lfax contains the set of allowed factors.
645	data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256, &
646	& 128, 64, 32, 16, 8, 4, 2 /
647	!!----------------------------------------------------------------------
648
649	! Clear the error flag and initialise output vars
650	kerr = 0
651	kfax = 1
652	knfax = 0
653
654	! Find the factors of n.
655	IF( kn == 1 ) GOTO 20
656
657	! nu holds the unfactorised part of the number.
658	! knfax holds the number of factors found.
659	! l points to the allowed factor list.
660	! ifac holds the current factor.
661
662	inu = kn
663	knfax = 0
664
665	DO jl = ntest, 1, -1
666	!
667	ifac = ilfax(jl)
668	IF( ifac > inu ) CYCLE
669
670	! Test whether the factor will divide.
671
672	IF( MOD(inu,ifac) == 0 ) THEN
673	!
674	knfax = knfax + 1 ! Add the factor to the list
675	IF( knfax > kmaxfax ) THEN
676	kerr = 6
677	write (,) 'FACTOR: insufficient space in factor array ', knfax
678	return
679	ENDIF
680	kfax(knfax) = ifac
681	! Store the other factor that goes with this one
682	knfax = knfax + 1
683	kfax(knfax) = inu / ifac
684	!WRITE (,) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
685	ENDIF
686	!
687	END DO
688
689	20 CONTINUE ! Label 20 is the exit point from the factor search loop.
690	!
691	END SUBROUTINE factorise
692
693	#if defined key_mpp_mpi
694	SUBROUTINE nemo_northcomms
695	!!======================================================================
696	!! * ROUTINE nemo_northcomms *
697	!! nemo_northcomms : Setup for north fold exchanges with explicit peer to peer messaging
698	!!=====================================================================
699	!!----------------------------------------------------------------------
700	!!
701	!! ** Purpose : Initialization of the northern neighbours lists.
702	!!----------------------------------------------------------------------
703	!! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE)
704	!!----------------------------------------------------------------------
705
706	INTEGER :: ji, jj, jk, ij, jtyp ! dummy loop indices
707	INTEGER :: ijpj ! number of rows involved in north-fold exchange
708	INTEGER :: northcomms_alloc ! allocate return status
709	REAL(wp), ALLOCATABLE, DIMENSION ( :,: ) :: znnbrs ! workspace
710	LOGICAL, ALLOCATABLE, DIMENSION ( : ) :: lrankset ! workspace
711
712	IF(lwp) WRITE(numout,*)
713	IF(lwp) WRITE(numout,*) 'nemo_northcomms : Initialization of the northern neighbours lists'
714	IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
715
716	!!----------------------------------------------------------------------
717	ALLOCATE( znnbrs(jpi,jpj), stat = northcomms_alloc )
718	ALLOCATE( lrankset(jpnij), stat = northcomms_alloc )
719	IF( northcomms_alloc /= 0 ) THEN
720	WRITE(numout,cform_war)
721	WRITE(numout,*) 'northcomms_alloc : failed to allocate arrays'
722	CALL ctl_stop( 'STOP', 'nemo_northcomms : unable to allocate temporary arrays' )
723	ENDIF
724	nsndto = 0
725	isendto = -1
726	ijpj = 4
727	!
728	! This routine has been called because ln_nnogather has been set true ( nammpp )
729	! However, these first few exchanges have to use the mpi_allgather method to
730	! establish the neighbour lists to use in subsequent peer to peer exchanges.
731	! Consequently, set l_north_nogather to be false here and set it true only after
732	! the lists have been established.
733	!
734	l_north_nogather = .FALSE.
735	!
736	! Exchange and store ranks on northern rows
737
738	DO jtyp = 1,4
739
740	lrankset = .FALSE.
741	znnbrs = narea
742	SELECT CASE (jtyp)
743	CASE(1)
744	CALL lbc_lnk( znnbrs, 'T', 1. ) ! Type 1: T,W-points
745	CASE(2)
746	CALL lbc_lnk( znnbrs, 'U', 1. ) ! Type 2: U-point
747	CASE(3)
748	CALL lbc_lnk( znnbrs, 'V', 1. ) ! Type 3: V-point
749	CASE(4)
750	CALL lbc_lnk( znnbrs, 'F', 1. ) ! Type 4: F-point
751	END SELECT
752
753	IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
754	DO jj = nlcj-ijpj+1, nlcj
755	ij = jj - nlcj + ijpj
756	DO ji = 1,jpi
757	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
758	& lrankset(INT(znnbrs(ji,jj))) = .true.
759	END DO
760	END DO
761
762	DO jj = 1,jpnij
763	IF ( lrankset(jj) ) THEN
764	nsndto(jtyp) = nsndto(jtyp) + 1
765	IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
766	CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
767	& ' jpmaxngh will need to be increased ')
768	ENDIF
769	isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank
770	ENDIF
771	END DO
772	ENDIF
773
774	END DO
775
776	!
777	! Type 5: I-point
778	!
779	! ICE point exchanges may involve some averaging. The neighbours list is
780	! built up using two exchanges to ensure that the whole stencil is covered.
781	! lrankset should not be reset between these 'J' and 'K' point exchanges
782
783	jtyp = 5
784	lrankset = .FALSE.
785	znnbrs = narea
786	CALL lbc_lnk( znnbrs, 'J', 1. ) ! first ice U-V point
787
788	IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
789	DO jj = nlcj-ijpj+1, nlcj
790	ij = jj - nlcj + ijpj
791	DO ji = 1,jpi
792	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
793	& lrankset(INT(znnbrs(ji,jj))) = .true.
794	END DO
795	END DO
796	ENDIF
797
798	znnbrs = narea
799	CALL lbc_lnk( znnbrs, 'K', 1. ) ! second ice U-V point
800
801	IF ( njmppt(narea) .EQ. MAXVAL( njmppt )) THEN
802	DO jj = nlcj-ijpj+1, nlcj
803	ij = jj - nlcj + ijpj
804	DO ji = 1,jpi
805	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
806	& lrankset( INT(znnbrs(ji,jj))) = .true.
807	END DO
808	END DO
809
810	DO jj = 1,jpnij
811	IF ( lrankset(jj) ) THEN
812	nsndto(jtyp) = nsndto(jtyp) + 1
813	IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
814	CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
815	& ' jpmaxngh will need to be increased ')
816	ENDIF
817	isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank
818	ENDIF
819	END DO
820	!
821	! For northern row areas, set l_north_nogather so that all subsequent exchanges
822	! can use peer to peer communications at the north fold
823	!
824	l_north_nogather = .TRUE.
825	!
826	ENDIF
827	DEALLOCATE( znnbrs )
828	DEALLOCATE( lrankset )
829
830	END SUBROUTINE nemo_northcomms
831	#else
832	SUBROUTINE nemo_northcomms ! Dummy routine
833	WRITE(,) 'nemo_northcomms: You should not have seen this print! error?'
834	END SUBROUTINE nemo_northcomms
835	#endif
836	!!======================================================================
837	END MODULE nemogcm

Note: See TracBrowser for help on using the repository browser.

Download in other formats: