New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in branches/2013/dev_r3853_CNRS9_ConfSetting/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/2013/dev_r3853_CNRS9_ConfSetting/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 3989

Last change on this file since 3989 was 3989, checked in by clevy, 11 years ago

Configuration setting/Step3 and doc, see ticket:#1074
  • Property svn:keywords set to Id
File size: 42.3 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!----------------------------------------------------------------------
32
33   !!----------------------------------------------------------------------
34   !!   nemo_gcm       : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
35   !!   nemo_init      : initialization of the NEMO system
36   !!   nemo_ctl       : initialisation of the contol print
37   !!   nemo_closefile : close remaining open files
38   !!   nemo_alloc     : dynamical allocation
39   !!   nemo_partition : calculate MPP domain decomposition
40   !!   factorise      : calculate the factors of the no. of MPI processes
41   !!----------------------------------------------------------------------
42   USE step_oce        ! module used in the ocean time stepping module
43   USE sbc_oce         ! surface boundary condition: ocean
44   USE cla             ! cross land advection               (tra_cla routine)
45   USE domcfg          ! domain configuration               (dom_cfg routine)
46   USE mppini          ! shared/distributed memory setting (mpp_init routine)
47   USE domain          ! domain initialization             (dom_init routine)
48#if defined key_nemocice_decomp
49   USE ice_domain_size, only: nx_global, ny_global
50#endif
51   USE tideini         ! tidal components initialization   (tide_ini routine)
52   USE obcini          ! open boundary cond. initialization (obc_ini routine)
53   USE bdyini          ! open boundary cond. initialization (bdy_init routine)
54   USE bdydta          ! open boundary cond. initialization (bdy_dta_init routine)
55   USE bdytides        ! open boundary cond. initialization (bdytide_init routine)
56   USE istate          ! initial state setting          (istate_init routine)
57   USE ldfdyn          ! lateral viscosity setting      (ldfdyn_init routine)
58   USE ldftra          ! lateral diffusivity setting    (ldftra_init routine)
59   USE zdfini          ! vertical physics setting          (zdf_init routine)
60   USE phycst          ! physical constant                  (par_cst routine)
61   USE trdmod          ! momentum/tracers trends       (trd_mod_init routine)
62   USE asminc          ! assimilation increments     
63   USE asmbkg          ! writing out state trajectory
64   USE diaptr          ! poleward transports           (dia_ptr_init routine)
65   USE diadct          ! sections transports           (dia_dct_init routine)
66   USE diaobs          ! Observation diagnostics       (dia_obs_init routine)
67   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
68   USE step            ! NEMO time-stepping                 (stp     routine)
69   USE icbini          ! handle bergs, initialisation
70   USE icbstp          ! handle bergs, calving, themodynamics and transport
71#if defined key_oasis3
72   USE cpl_oasis3      ! OASIS3 coupling
73#elif defined key_oasis4
74   USE cpl_oasis4      ! OASIS4 coupling (not working)
75#endif
76   USE c1d             ! 1D configuration
77   USE step_c1d        ! Time stepping loop for the 1D configuration
78#if defined key_top
79   USE trcini          ! passive tracer initialisation
80#endif
81   USE lib_mpp         ! distributed memory computing
82#if defined key_iomput
83   USE xios
84#endif
85   USE sbctide, ONLY: lk_tide
86
87   IMPLICIT NONE
88   PRIVATE
89
90   PUBLIC   nemo_gcm    ! called by model.F90
91   PUBLIC   nemo_init   ! needed by AGRIF
92   PUBLIC   nemo_alloc  ! needed by TAM
93
94   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
95
96   !!----------------------------------------------------------------------
97   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
98   !! $Id$
99   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
100   !!----------------------------------------------------------------------
101CONTAINS
102
103   SUBROUTINE nemo_gcm
104      !!----------------------------------------------------------------------
105      !!                     ***  ROUTINE nemo_gcm  ***
106      !!
107      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
108      !!              curvilinear mesh on the sphere.
109      !!
110      !! ** Method  : - model general initialization
111      !!              - launch the time-stepping (stp routine)
112      !!              - finalize the run by closing files and communications
113      !!
114      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
115      !!              Madec, 2008, internal report, IPSL.
116      !!----------------------------------------------------------------------
117      INTEGER ::   istp       ! time step index
118      !!----------------------------------------------------------------------
119      !
120
121#if defined key_agrif
122      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
123#endif
124
125      !                            !-----------------------!
126      CALL nemo_init               !==  Initialisations  ==!
127      !                            !-----------------------!
128#if defined key_agrif
129      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
130      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
131# if defined key_top
132      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
133# endif
134# if defined key_lim2
135      CALL Agrif_Declare_Var_lim2  !  "      "   "   "      "  LIM
136# endif
137#endif
138
139      ! check that all process are still there... If some process have an error,
140      ! they will never enter in step and other processes will wait until the end of the cpu time!
141      IF( lk_mpp )   CALL mpp_max( nstop )
142
143      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
144
145      !                            !-----------------------!
146      !                            !==   time stepping   ==!
147      !                            !-----------------------!
148      istp = nit000
149#if defined key_c1d
150         DO WHILE ( istp <= nitend .AND. nstop == 0 )
151            CALL stp_c1d( istp )
152            istp = istp + 1
153         END DO
154#else
155          IF( lk_asminc ) THEN
156             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
157             IF( ln_asmdin ) THEN                        ! Direct initialization
158                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
159                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
160                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
161             ENDIF
162          ENDIF
163
164         DO WHILE ( istp <= nitend .AND. nstop == 0 )
165
166#if defined key_agrif
167            CALL Agrif_Step( stp )           ! AGRIF: time stepping
168#else
169            CALL stp( istp )                 ! standard time stepping
170#endif
171
172            istp = istp + 1
173            IF( lk_mpp )   CALL mpp_max( nstop )
174         END DO
175#endif
176
177      IF( lk_diaobs   )   CALL dia_obs_wri
178      !
179      IF( ln_icebergs )   CALL icb_end( nitend )
180
181      !                            !------------------------!
182      !                            !==  finalize the run  ==!
183      !                            !------------------------!
184      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
185      !
186      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
187         WRITE(numout,cform_err)
188         WRITE(numout,*) nstop, ' error have been found'
189      ENDIF
190      !
191#if defined key_agrif
192      CALL Agrif_ParentGrid_To_ChildGrid()
193      IF( lk_diaobs ) CALL dia_obs_wri
194      IF( nn_timing == 1 )   CALL timing_finalize
195      CALL Agrif_ChildGrid_To_ParentGrid()
196#endif
197      IF( nn_timing == 1 )   CALL timing_finalize
198      !
199      CALL nemo_closefile
200#if defined key_iomput
201      CALL xios_finalize                ! end mpp communications with xios
202# if defined key_oasis3 || defined key_oasis4
203      CALL cpl_prism_finalize           ! end coupling and mpp communications with OASIS
204# endif
205#else
206# if defined key_oasis3 || defined key_oasis4
207      CALL cpl_prism_finalize           ! end coupling and mpp communications with OASIS
208# else
209      IF( lk_mpp )   CALL mppstop       ! end mpp communications
210# endif
211#endif
212      !
213   END SUBROUTINE nemo_gcm
214
215
216   SUBROUTINE nemo_init
217      !!----------------------------------------------------------------------
218      !!                     ***  ROUTINE nemo_init  ***
219      !!
220      !! ** Purpose :   initialization of the NEMO GCM
221      !!----------------------------------------------------------------------
222      INTEGER ::   ji            ! dummy loop indices
223      INTEGER ::   ilocal_comm   ! local integer
224      INTEGER ::   ios
225      CHARACTER(len=80), DIMENSION(16) ::   cltxt
226      !!
227      NAMELIST/namctl/ ln_ctl, nn_print, nn_ictls, nn_ictle,   &
228         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
229         &             nn_bench, nn_timing
230      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
231         &             jpizoom, jpjzoom, jperio, jphgr_msh, &
232         &             ppglam0, ppgphi0, ppe1_deg, ppe2_deg, ppe1_m, ppe2_m, &
233         &             ppsur, ppa0, ppa1, ppkth, ppacr, ppdzmin, pphmax, ldbletanh, &
234         &             ppa2, ppkth2, ppacr2
235      !!----------------------------------------------------------------------
236      !
237      cltxt = ''
238      !
239      !                             ! Open reference namelist and configuration namelist files
240      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
241      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
242      CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
243      !
244      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
245      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
246901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', lwp )
247
248      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
249      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
250902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', lwp )
251      WRITE( numond, namctl )
252
253      !
254      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
255      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
256903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', lwp )
257
258      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
259      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
260904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', lwp )   
261      WRITE( numond, namcfg )
262      !
263      !                             !--------------------------------------------!
264      !                             !  set communicator & select the local node  !
265      !                             !--------------------------------------------!
266#if defined key_iomput
267      IF( Agrif_Root() ) THEN
268# if defined key_oasis3 || defined key_oasis4
269         CALL cpl_prism_init( ilocal_comm )      ! nemo local communicator given by oasis
270         CALL xios_initialize( "oceanx",local_comm=ilocal_comm )
271# else
272         CALL  xios_initialize( "nemo",return_comm=ilocal_comm )
273# endif
274      ENDIF
275      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection
276#else
277# if defined key_oasis3 || defined key_oasis4
278      IF( Agrif_Root() ) THEN
279         CALL cpl_prism_init( ilocal_comm )                 ! nemo local communicator given by oasis
280      ENDIF
281      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection (control print return in cltxt)
282# else
283      ilocal_comm = 0
284      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop )                 ! Nodes selection (control print return in cltxt)
285# endif
286#endif
287      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
288
289      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
290
291      ! If dimensions of processor grid weren't specified in the namelist file
292      ! then we calculate them here now that we have our communicator size
293      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
294#if   defined key_mpp_mpi
295         IF( Agrif_Root() ) CALL nemo_partition(mppsize)
296#else
297         jpni  = 1
298         jpnj  = 1
299         jpnij = jpni*jpnj
300#endif
301      END IF
302
303      ! Calculate domain dimensions given calculated jpni and jpnj
304      ! This used to be done in par_oce.F90 when they were parameters rather
305      ! than variables
306      IF( Agrif_Root() ) THEN
307#if defined key_nemocice_decomp
308         jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci ! first  dim.
309         jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim.
310#else
311         jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
312         jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
313#endif
314         jpk = jpkdta                                             ! third dim
315         jpim1 = jpi-1                                            ! inner domain indices
316         jpjm1 = jpj-1                                            !   "           "
317         jpkm1 = jpk-1                                            !   "           "
318         jpij  = jpi*jpj                                          !  jpi x j
319      ENDIF
320
321      IF(lwp) THEN                            ! open listing units
322         !
323         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
324         !
325         WRITE(numout,*)
326         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
327         WRITE(numout,*) '                       NEMO team'
328         WRITE(numout,*) '            Ocean General Circulation Model'
329         WRITE(numout,*) '                  version 3.4  (2011) '
330         WRITE(numout,*)
331         WRITE(numout,*)
332         DO ji = 1, SIZE(cltxt)
333            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
334         END DO
335         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
336         !
337      ENDIF
338
339      ! Now we know the dimensions of the grid and numout has been set we can
340      ! allocate arrays
341      CALL nemo_alloc()
342
343      !                             !-------------------------------!
344      !                             !  NEMO general initialization  !
345      !                             !-------------------------------!
346
347      CALL nemo_ctl                          ! Control prints & Benchmark
348
349      !                                      ! Domain decomposition
350      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
351      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
352      ENDIF
353      !
354      IF( nn_timing == 1 )  CALL timing_init
355      !
356      !                                      ! General initialization
357                            CALL     phy_cst    ! Physical constants
358                            CALL     eos_init   ! Equation of state
359                            CALL     dom_cfg    ! Domain configuration
360                            CALL     dom_init   ! Domain
361
362      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
363
364      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
365
366      IF( lk_obc        )   CALL     obc_init   ! Open boundaries
367
368                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
369
370      IF( lk_tide       )   CALL tide_init( nit000 )    ! Initialisation of the tidal harmonics
371
372      IF( lk_bdy        )   CALL     bdy_init       ! Open boundaries initialisation
373      IF( lk_bdy        )   CALL     bdy_dta_init   ! Open boundaries initialisation of external data arrays
374      IF( lk_bdy        )   CALL     bdytide_init   ! Open boundaries initialisation of tidal harmonic forcing
375
376                            CALL dyn_nept_init  ! simplified form of Neptune effect
377
378      !                                     ! Ocean physics
379                            CALL     sbc_init   ! Forcings : surface module
380      !                                         ! Vertical physics
381
382                            CALL     zdf_init      ! namelist read
383
384                            CALL zdf_bfr_init      ! bottom friction
385
386      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
387      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
388      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
389      IF( lk_zdfkpp     )   CALL zdf_kpp_init      ! KPP closure scheme
390      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
391      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
392         &                  CALL zdf_ddm_init      ! double diffusive mixing
393      !                                         ! Lateral physics
394                            CALL ldf_tra_init      ! Lateral ocean tracer physics
395                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
396      IF( lk_ldfslp     )   CALL ldf_slp_init      ! slope of lateral mixing
397
398      !                                     ! Active tracers
399                            CALL tra_qsr_init   ! penetrative solar radiation qsr
400                            CALL tra_bbc_init   ! bottom heat flux
401      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
402      IF( ln_tradmp     )   CALL tra_dmp_init   ! internal damping trends
403                            CALL tra_adv_init   ! horizontal & vertical advection
404                            CALL tra_ldf_init   ! lateral mixing
405                            CALL tra_zdf_init   ! vertical mixing and after tracer fields
406
407      !                                     ! Dynamics
408                            CALL dyn_adv_init   ! advection (vector or flux form)
409                            CALL dyn_vor_init   ! vorticity term including Coriolis
410                            CALL dyn_ldf_init   ! lateral mixing
411                            CALL dyn_hpg_init   ! horizontal gradient of Hydrostatic pressure
412                            CALL dyn_zdf_init   ! vertical diffusion
413                            CALL dyn_spg_init   ! surface pressure gradient
414
415      !                                     ! Misc. options
416      IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 )   CALL cla_init       ! Cross Land Advection
417                            CALL icb_init( rdt, nit000)   ! initialise icebergs instance
418     
419#if defined key_top
420      !                                     ! Passive tracers
421                            CALL     trc_init
422#endif
423      !
424 
425                                            ! Diagnostics
426      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
427      IF( lk_diaar5     )   CALL dia_ar5_init   ! ar5 diag
428                            CALL dia_ptr_init   ! Poleward TRansports initialization
429      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
430                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
431                            CALL trd_mod_init   ! Mixed-layer/Vorticity/Integral constraints trends
432      IF( lk_diaobs     ) THEN                  ! Observation & model comparison
433                            CALL dia_obs_init            ! Initialize observational data
434                            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
435      ENDIF
436      !                                     ! Assimilation increments
437      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
438      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
439      !
440   END SUBROUTINE nemo_init
441
442
443   SUBROUTINE nemo_ctl
444      !!----------------------------------------------------------------------
445      !!                     ***  ROUTINE nemo_ctl  ***
446      !!
447      !! ** Purpose :   control print setting
448      !!
449      !! ** Method  : - print namctl information and check some consistencies
450      !!----------------------------------------------------------------------
451      !
452      IF(lwp) THEN                  ! control print
453         WRITE(numout,*)
454         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
455         WRITE(numout,*) '~~~~~~~ '
456         WRITE(numout,*) '   Namelist namctl'
457         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
458         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
459         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
460         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
461         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
462         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
463         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
464         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
465         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
466         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
467      ENDIF
468      !
469      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
470      nictls    = nn_ictls
471      nictle    = nn_ictle
472      njctls    = nn_jctls
473      njctle    = nn_jctle
474      isplt     = nn_isplt
475      jsplt     = nn_jsplt
476      nbench    = nn_bench
477
478      IF(lwp) THEN                  ! control print
479         WRITE(numout,*)
480         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
481         WRITE(numout,*) '~~~~~~~ '
482         WRITE(numout,*) '   Namelist namcfg'
483         WRITE(numout,*) '      configuration name              cp_cfg      = ', TRIM(cp_cfg)
484         WRITE(numout,*) '      configuration zoom name         cp_cfz      = ', TRIM(cp_cfz)
485         WRITE(numout,*) '      configuration resolution        jp_cfg      = ', jp_cfg
486         WRITE(numout,*) '      1st lateral dimension ( >= jpi ) jpidta     = ', jpidta
487         WRITE(numout,*) '      2nd    "         "    ( >= jpj ) jpjdta     = ', jpjdta
488         WRITE(numout,*) '      3nd    "         "               jpkdta     = ', jpkdta
489         WRITE(numout,*) '      1st dimension of global domain in i jpiglo  = ', jpiglo
490         WRITE(numout,*) '      2nd    -                  -    in j jpjglo  = ', jpjglo
491         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
492         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
493         WRITE(numout,*) '      lateral cond. type (between 0 and 6) jperio = ', jperio   
494         WRITE(numout,*) '      type of horizontal mesh jphgr_msh           = ', jphgr_msh
495         WRITE(numout,*) '      longitude of first raw and column T-point ppglam0 = ', ppglam0
496         WRITE(numout,*) '      latitude  of first raw and column T-point ppgphi0 = ', ppgphi0
497         WRITE(numout,*) '      zonal      grid-spacing (degrees) ppe1_deg        = ', ppe1_deg
498         WRITE(numout,*) '      meridional grid-spacing (degrees) ppe2_deg        = ', ppe2_deg
499         WRITE(numout,*) '      zonal      grid-spacing (degrees) ppe1_m          = ', ppe1_m
500         WRITE(numout,*) '      meridional grid-spacing (degrees) ppe2_m          = ', ppe2_m
501         WRITE(numout,*) '      ORCA r4, r2 and r05 coefficients  ppsur           = ', ppsur
502         WRITE(numout,*) '                                        ppa0            = ', ppa0
503         WRITE(numout,*) '                                        ppa1            = ', ppa1
504         WRITE(numout,*) '                                        ppkth           = ', ppkth
505         WRITE(numout,*) '                                        ppacr           = ', ppacr
506         WRITE(numout,*) '      Minimum vertical spacing ppdzmin                  = ', ppdzmin
507         WRITE(numout,*) '      Maximum depth pphmax                              = ', pphmax
508         WRITE(numout,*) '      Use double tanf function for vertical coordinates ldbletanh = ', ldbletanh
509         WRITE(numout,*) '      Double tanh function parameters ppa2              = ', ppa2
510         WRITE(numout,*) '                                      ppkth2            = ', ppkth2
511         WRITE(numout,*) '                                      ppacr2            = ', ppacr2
512      ENDIF
513      !                             ! Parameter control
514      !
515      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
516         IF( lk_mpp .AND. jpnij > 1 ) THEN
517            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
518         ELSE
519            IF( isplt == 1 .AND. jsplt == 1  ) THEN
520               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
521                  &           ' - the print control will be done over the whole domain' )
522            ENDIF
523            ijsplt = isplt * jsplt            ! total number of processors ijsplt
524         ENDIF
525         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
526         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
527         !
528         !                              ! indices used for the SUM control
529         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
530            lsp_area = .FALSE.
531         ELSE                                             ! print control done over a specific  area
532            lsp_area = .TRUE.
533            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
534               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
535               nictls = 1
536            ENDIF
537            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
538               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
539               nictle = jpiglo
540            ENDIF
541            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
542               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
543               njctls = 1
544            ENDIF
545            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
546               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
547               njctle = jpjglo
548            ENDIF
549         ENDIF
550      ENDIF
551      !
552      IF( nbench == 1 ) THEN              ! Benchmark
553         SELECT CASE ( cp_cfg )
554         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
555         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
556            &                                 ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
557         END SELECT
558      ENDIF
559      !
560      IF( lk_c1d .AND. .NOT.lk_iomput )   CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ',   &
561         &                                               'with the IOM Input/Output manager. '         ,   &
562         &                                               'Compile with key_iomput enabled' )
563      !
564      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
565         &                                               'f2003 standard. '                              ,  &
566         &                                               'Compile with key_nosignedzero enabled' )
567      !
568   END SUBROUTINE nemo_ctl
569
570
571   SUBROUTINE nemo_closefile
572      !!----------------------------------------------------------------------
573      !!                     ***  ROUTINE nemo_closefile  ***
574      !!
575      !! ** Purpose :   Close the files
576      !!----------------------------------------------------------------------
577      !
578      IF( lk_mpp )   CALL mppsync
579      !
580      CALL iom_close                                 ! close all input/output files managed by iom_*
581      !
582      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
583      IF( numsol          /= -1 )   CLOSE( numsol          )   ! solver file
584      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
585      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
586      IF( numond          /= -1 )   CLOSE( numond          )   ! oce output namelist
587      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
588      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
589      IF( numoni          /= -1 )   CLOSE( numoni          )   ! ice output namelist
590      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
591      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
592      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
593      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
594      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
595
596      !
597      numout = 6                                     ! redefine numout in case it is used after this point...
598      !
599   END SUBROUTINE nemo_closefile
600
601
602   SUBROUTINE nemo_alloc
603      !!----------------------------------------------------------------------
604      !!                     ***  ROUTINE nemo_alloc  ***
605      !!
606      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
607      !!
608      !! ** Method  :
609      !!----------------------------------------------------------------------
610      USE diawri    , ONLY: dia_wri_alloc
611      USE dom_oce   , ONLY: dom_oce_alloc
612      USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
613      USE ldftra_oce, ONLY: ldftra_oce_alloc
614      USE trc_oce   , ONLY: trc_oce_alloc
615#if defined key_diadct 
616      USE diadct    , ONLY: diadct_alloc 
617#endif 
618      !
619      INTEGER :: ierr
620      !!----------------------------------------------------------------------
621      !
622      ierr =        oce_alloc       ()          ! ocean
623      ierr = ierr + dia_wri_alloc   ()
624      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
625      ierr = ierr + ldfdyn_oce_alloc()          ! ocean lateral  physics : dynamics
626      ierr = ierr + ldftra_oce_alloc()          ! ocean lateral  physics : tracers
627      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
628      !
629      ierr = ierr + lib_mpp_alloc   (numout)    ! mpp exchanges
630      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
631      !
632#if defined key_diadct 
633      ierr = ierr + diadct_alloc    ()          !
634#endif 
635      !
636      IF( lk_mpp    )   CALL mpp_sum( ierr )
637      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
638      !
639   END SUBROUTINE nemo_alloc
640
641
642   SUBROUTINE nemo_partition( num_pes )
643      !!----------------------------------------------------------------------
644      !!                 ***  ROUTINE nemo_partition  ***
645      !!
646      !! ** Purpose :
647      !!
648      !! ** Method  :
649      !!----------------------------------------------------------------------
650      INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
651      !
652      INTEGER, PARAMETER :: nfactmax = 20
653      INTEGER :: nfact ! The no. of factors returned
654      INTEGER :: ierr  ! Error flag
655      INTEGER :: ji
656      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
657      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
658      !!----------------------------------------------------------------------
659
660      ierr = 0
661
662      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
663
664      IF( nfact <= 1 ) THEN
665         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
666         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
667         jpnj = 1
668         jpni = num_pes
669      ELSE
670         ! Search through factors for the pair that are closest in value
671         mindiff = 1000000
672         imin    = 1
673         DO ji = 1, nfact-1, 2
674            idiff = ABS( ifact(ji) - ifact(ji+1) )
675            IF( idiff < mindiff ) THEN
676               mindiff = idiff
677               imin = ji
678            ENDIF
679         END DO
680         jpnj = ifact(imin)
681         jpni = ifact(imin + 1)
682      ENDIF
683      !
684      jpnij = jpni*jpnj
685      !
686   END SUBROUTINE nemo_partition
687
688
689   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
690      !!----------------------------------------------------------------------
691      !!                     ***  ROUTINE factorise  ***
692      !!
693      !! ** Purpose :   return the prime factors of n.
694      !!                knfax factors are returned in array kfax which is of
695      !!                maximum dimension kmaxfax.
696      !! ** Method  :
697      !!----------------------------------------------------------------------
698      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
699      INTEGER                    , INTENT(  out) ::   kerr, knfax
700      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
701      !
702      INTEGER :: ifac, jl, inu
703      INTEGER, PARAMETER :: ntest = 14
704      INTEGER :: ilfax(ntest)
705
706      ! lfax contains the set of allowed factors.
707      data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256,  &
708         &                            128,   64,   32,   16,    8,   4,   2  /
709      !!----------------------------------------------------------------------
710
711      ! Clear the error flag and initialise output vars
712      kerr = 0
713      kfax = 1
714      knfax = 0
715
716      ! Find the factors of n.
717      IF( kn == 1 )   GOTO 20
718
719      ! nu holds the unfactorised part of the number.
720      ! knfax holds the number of factors found.
721      ! l points to the allowed factor list.
722      ! ifac holds the current factor.
723
724      inu   = kn
725      knfax = 0
726
727      DO jl = ntest, 1, -1
728         !
729         ifac = ilfax(jl)
730         IF( ifac > inu )   CYCLE
731
732         ! Test whether the factor will divide.
733
734         IF( MOD(inu,ifac) == 0 ) THEN
735            !
736            knfax = knfax + 1            ! Add the factor to the list
737            IF( knfax > kmaxfax ) THEN
738               kerr = 6
739               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
740               return
741            ENDIF
742            kfax(knfax) = ifac
743            ! Store the other factor that goes with this one
744            knfax = knfax + 1
745            kfax(knfax) = inu / ifac
746            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
747         ENDIF
748         !
749      END DO
750
751   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
752      !
753   END SUBROUTINE factorise
754
755#if defined key_mpp_mpi
756   SUBROUTINE nemo_northcomms
757      !!======================================================================
758      !!                     ***  ROUTINE  nemo_northcomms  ***
759      !! nemo_northcomms    :  Setup for north fold exchanges with explicit peer to peer messaging
760      !!=====================================================================
761      !!----------------------------------------------------------------------
762      !!
763      !! ** Purpose :   Initialization of the northern neighbours lists.
764      !!----------------------------------------------------------------------
765      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
766      !!----------------------------------------------------------------------
767
768      INTEGER ::   ji, jj, jk, ij, jtyp    ! dummy loop indices
769      INTEGER ::   ijpj                    ! number of rows involved in north-fold exchange
770      INTEGER ::   northcomms_alloc        ! allocate return status
771      REAL(wp), ALLOCATABLE, DIMENSION ( :,: ) ::   znnbrs     ! workspace
772      LOGICAL,  ALLOCATABLE, DIMENSION ( : )   ::   lrankset   ! workspace
773
774      IF(lwp) WRITE(numout,*)
775      IF(lwp) WRITE(numout,*) 'nemo_northcomms : Initialization of the northern neighbours lists'
776      IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
777
778      !!----------------------------------------------------------------------
779      ALLOCATE( znnbrs(jpi,jpj), stat = northcomms_alloc )
780      ALLOCATE( lrankset(jpnij), stat = northcomms_alloc )
781      IF( northcomms_alloc /= 0 ) THEN
782         WRITE(numout,cform_war)
783         WRITE(numout,*) 'northcomms_alloc : failed to allocate arrays'
784         CALL ctl_stop( 'STOP', 'nemo_northcomms : unable to allocate temporary arrays' )
785      ENDIF
786      nsndto = 0
787      isendto = -1
788      ijpj   = 4
789      !
790      ! This routine has been called because ln_nnogather has been set true ( nammpp )
791      ! However, these first few exchanges have to use the mpi_allgather method to
792      ! establish the neighbour lists to use in subsequent peer to peer exchanges.
793      ! Consequently, set l_north_nogather to be false here and set it true only after
794      ! the lists have been established.
795      !
796      l_north_nogather = .FALSE.
797      !
798      ! Exchange and store ranks on northern rows
799
800      DO jtyp = 1,4
801
802         lrankset = .FALSE.
803         znnbrs = narea
804         SELECT CASE (jtyp)
805            CASE(1)
806               CALL lbc_lnk( znnbrs, 'T', 1. )      ! Type 1: T,W-points
807            CASE(2)
808               CALL lbc_lnk( znnbrs, 'U', 1. )      ! Type 2: U-point
809            CASE(3)
810               CALL lbc_lnk( znnbrs, 'V', 1. )      ! Type 3: V-point
811            CASE(4)
812               CALL lbc_lnk( znnbrs, 'F', 1. )      ! Type 4: F-point
813         END SELECT
814
815         IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
816            DO jj = nlcj-ijpj+1, nlcj
817               ij = jj - nlcj + ijpj
818               DO ji = 1,jpi
819                  IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
820               &     lrankset(INT(znnbrs(ji,jj))) = .true.
821               END DO
822            END DO
823
824            DO jj = 1,jpnij
825               IF ( lrankset(jj) ) THEN
826                  nsndto(jtyp) = nsndto(jtyp) + 1
827                  IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
828                     CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
829                  &                 ' jpmaxngh will need to be increased ')
830                  ENDIF
831                  isendto(nsndto(jtyp),jtyp) = jj-1   ! narea converted to MPI rank
832               ENDIF
833            END DO
834         ENDIF
835
836      END DO
837
838      !
839      ! Type 5: I-point
840      !
841      ! ICE point exchanges may involve some averaging. The neighbours list is
842      ! built up using two exchanges to ensure that the whole stencil is covered.
843      ! lrankset should not be reset between these 'J' and 'K' point exchanges
844
845      jtyp = 5
846      lrankset = .FALSE.
847      znnbrs = narea
848      CALL lbc_lnk( znnbrs, 'J', 1. ) ! first ice U-V point
849
850      IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
851         DO jj = nlcj-ijpj+1, nlcj
852            ij = jj - nlcj + ijpj
853            DO ji = 1,jpi
854               IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
855            &     lrankset(INT(znnbrs(ji,jj))) = .true.
856         END DO
857        END DO
858      ENDIF
859
860      znnbrs = narea
861      CALL lbc_lnk( znnbrs, 'K', 1. ) ! second ice U-V point
862
863      IF ( njmppt(narea) .EQ. MAXVAL( njmppt )) THEN
864         DO jj = nlcj-ijpj+1, nlcj
865            ij = jj - nlcj + ijpj
866            DO ji = 1,jpi
867               IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND.  INT(znnbrs(ji,jj)) .NE. narea ) &
868            &       lrankset( INT(znnbrs(ji,jj))) = .true.
869            END DO
870         END DO
871
872         DO jj = 1,jpnij
873            IF ( lrankset(jj) ) THEN
874               nsndto(jtyp) = nsndto(jtyp) + 1
875               IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
876                  CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
877               &                 ' jpmaxngh will need to be increased ')
878               ENDIF
879               isendto(nsndto(jtyp),jtyp) = jj-1   ! narea converted to MPI rank
880            ENDIF
881         END DO
882         !
883         ! For northern row areas, set l_north_nogather so that all subsequent exchanges
884         ! can use peer to peer communications at the north fold
885         !
886         l_north_nogather = .TRUE.
887         !
888      ENDIF
889      DEALLOCATE( znnbrs )
890      DEALLOCATE( lrankset )
891
892   END SUBROUTINE nemo_northcomms
893#else
894   SUBROUTINE nemo_northcomms      ! Dummy routine
895      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
896   END SUBROUTINE nemo_northcomms
897#endif
898   !!======================================================================
899END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.