New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in branches/2013/dev_r3853_CNRS9_ConfSetting/NEMOGCM/NEMO/OPA_SRC – NEMO

Context Navigation

source: branches/2013/dev_r3853_CNRS9_ConfSetting/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 3993

Last change on this file since 3993 was 3993, checked in by clevy, 11 years ago
Configuration setting/Step3 bugfixes,doc, and redistribute variables in namcfg and namdom see ticket:#1074
Property svn:keywords set to `Id`
File size: 40.4 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code
7	!! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec)
8	!! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9	!! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10	!! - ! 1992-06 (L.Terray) coupling implementation
11	!! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice
12	!! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13	!! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14	!! 8.1 ! 1997-06 (M. Imbard, G. Madec)
15	!! 8.2 ! 1999-11 (M. Imbard, H. Goosse) LIM sea-ice model
16	!! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP
17	!! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER)
18	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules
19	!! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20	!! - ! 2004-08 (C. Talandier) New trends organization
21	!! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility
22	!! - ! 2005-11 (V. Garnier) Surface pressure gradient organization
23	!! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation
24	!! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization
25	!! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26	!! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp
27	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
29	!! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
30	!! 3.4 ! 2011-11 (C. Harris) decomposition changes for running with CICE
31	!!----------------------------------------------------------------------
32
33	!!----------------------------------------------------------------------
34	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
35	!! nemo_init : initialization of the NEMO system
36	!! nemo_ctl : initialisation of the contol print
37	!! nemo_closefile : close remaining open files
38	!! nemo_alloc : dynamical allocation
39	!! nemo_partition : calculate MPP domain decomposition
40	!! factorise : calculate the factors of the no. of MPI processes
41	!!----------------------------------------------------------------------
42	USE step_oce ! module used in the ocean time stepping module
43	USE sbc_oce ! surface boundary condition: ocean
44	USE cla ! cross land advection (tra_cla routine)
45	USE domcfg ! domain configuration (dom_cfg routine)
46	USE mppini ! shared/distributed memory setting (mpp_init routine)
47	USE domain ! domain initialization (dom_init routine)
48	#if defined key_nemocice_decomp
49	USE ice_domain_size, only: nx_global, ny_global
50	#endif
51	USE tideini ! tidal components initialization (tide_ini routine)
52	USE obcini ! open boundary cond. initialization (obc_ini routine)
53	USE bdyini ! open boundary cond. initialization (bdy_init routine)
54	USE bdydta ! open boundary cond. initialization (bdy_dta_init routine)
55	USE bdytides ! open boundary cond. initialization (bdytide_init routine)
56	USE istate ! initial state setting (istate_init routine)
57	USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine)
58	USE ldftra ! lateral diffusivity setting (ldftra_init routine)
59	USE zdfini ! vertical physics setting (zdf_init routine)
60	USE phycst ! physical constant (par_cst routine)
61	USE trdmod ! momentum/tracers trends (trd_mod_init routine)
62	USE asminc ! assimilation increments
63	USE asmbkg ! writing out state trajectory
64	USE diaptr ! poleward transports (dia_ptr_init routine)
65	USE diadct ! sections transports (dia_dct_init routine)
66	USE diaobs ! Observation diagnostics (dia_obs_init routine)
67	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
68	USE step ! NEMO time-stepping (stp routine)
69	USE icbini ! handle bergs, initialisation
70	USE icbstp ! handle bergs, calving, themodynamics and transport
71	#if defined key_oasis3
72	USE cpl_oasis3 ! OASIS3 coupling
73	#elif defined key_oasis4
74	USE cpl_oasis4 ! OASIS4 coupling (not working)
75	#endif
76	USE c1d ! 1D configuration
77	USE step_c1d ! Time stepping loop for the 1D configuration
78	#if defined key_top
79	USE trcini ! passive tracer initialisation
80	#endif
81	USE lib_mpp ! distributed memory computing
82	#if defined key_iomput
83	USE xios
84	#endif
85	USE sbctide, ONLY: lk_tide
86
87	IMPLICIT NONE
88	PRIVATE
89
90	PUBLIC nemo_gcm ! called by model.F90
91	PUBLIC nemo_init ! needed by AGRIF
92	PUBLIC nemo_alloc ! needed by TAM
93
94	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
95
96	!!----------------------------------------------------------------------
97	!! NEMO/OPA 4.0 , NEMO Consortium (2011)
98	!! $Id$
99	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
100	!!----------------------------------------------------------------------
101	CONTAINS
102
103	SUBROUTINE nemo_gcm
104	!!----------------------------------------------------------------------
105	!! * ROUTINE nemo_gcm *
106	!!
107	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
108	!! curvilinear mesh on the sphere.
109	!!
110	!! ** Method : - model general initialization
111	!! - launch the time-stepping (stp routine)
112	!! - finalize the run by closing files and communications
113	!!
114	!! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL.
115	!! Madec, 2008, internal report, IPSL.
116	!!----------------------------------------------------------------------
117	INTEGER :: istp ! time step index
118	!!----------------------------------------------------------------------
119	!
120
121	#if defined key_agrif
122	CALL Agrif_Init_Grids() ! AGRIF: set the meshes
123	#endif
124
125	! !-----------------------!
126	CALL nemo_init !== Initialisations ==!
127	! !-----------------------!
128	#if defined key_agrif
129	CALL Agrif_Declare_Var_dom ! AGRIF: set the meshes for DOM
130	CALL Agrif_Declare_Var ! " " " " " DYN/TRA
131	# if defined key_top
132	CALL Agrif_Declare_Var_top ! " " " " " TOP
133	# endif
134	# if defined key_lim2
135	CALL Agrif_Declare_Var_lim2 ! " " " " " LIM
136	# endif
137	#endif
138
139	! check that all process are still there... If some process have an error,
140	! they will never enter in step and other processes will wait until the end of the cpu time!
141	IF( lk_mpp ) CALL mpp_max( nstop )
142
143	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
144
145	! !-----------------------!
146	! !== time stepping ==!
147	! !-----------------------!
148	istp = nit000
149	#if defined key_c1d
150	DO WHILE ( istp <= nitend .AND. nstop == 0 )
151	CALL stp_c1d( istp )
152	istp = istp + 1
153	END DO
154	#else
155	IF( lk_asminc ) THEN
156	IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 ) ! Output background fields
157	IF( ln_asmdin ) THEN ! Direct initialization
158	IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 ) ! Tracers
159	IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 ) ! Dynamics
160	IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 ) ! SSH
161	ENDIF
162	ENDIF
163
164	DO WHILE ( istp <= nitend .AND. nstop == 0 )
165
166	#if defined key_agrif
167	CALL Agrif_Step( stp ) ! AGRIF: time stepping
168	#else
169	CALL stp( istp ) ! standard time stepping
170	#endif
171
172	istp = istp + 1
173	IF( lk_mpp ) CALL mpp_max( nstop )
174	END DO
175	#endif
176
177	IF( lk_diaobs ) CALL dia_obs_wri
178	!
179	IF( ln_icebergs ) CALL icb_end( nitend )
180
181	! !------------------------!
182	! !== finalize the run ==!
183	! !------------------------!
184	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
185	!
186	IF( nstop /= 0 .AND. lwp ) THEN ! error print
187	WRITE(numout,cform_err)
188	WRITE(numout,*) nstop, ' error have been found'
189	ENDIF
190	!
191	#if defined key_agrif
192	CALL Agrif_ParentGrid_To_ChildGrid()
193	IF( lk_diaobs ) CALL dia_obs_wri
194	IF( nn_timing == 1 ) CALL timing_finalize
195	CALL Agrif_ChildGrid_To_ParentGrid()
196	#endif
197	IF( nn_timing == 1 ) CALL timing_finalize
198	!
199	CALL nemo_closefile
200	#if defined key_iomput
201	CALL xios_finalize ! end mpp communications with xios
202	# if defined key_oasis3 \|\| defined key_oasis4
203	CALL cpl_prism_finalize ! end coupling and mpp communications with OASIS
204	# endif
205	#else
206	# if defined key_oasis3 \|\| defined key_oasis4
207	CALL cpl_prism_finalize ! end coupling and mpp communications with OASIS
208	# else
209	IF( lk_mpp ) CALL mppstop ! end mpp communications
210	# endif
211	#endif
212	!
213	END SUBROUTINE nemo_gcm
214
215
216	SUBROUTINE nemo_init
217	!!----------------------------------------------------------------------
218	!! * ROUTINE nemo_init *
219	!!
220	!! ** Purpose : initialization of the NEMO GCM
221	!!----------------------------------------------------------------------
222	INTEGER :: ji ! dummy loop indices
223	INTEGER :: ilocal_comm ! local integer
224	INTEGER :: ios
225	CHARACTER(len=80), DIMENSION(16) :: cltxt
226	!!
227	NAMELIST/namctl/ ln_ctl, nn_print, nn_ictls, nn_ictle, &
228	& nn_isplt, nn_jsplt, nn_jctls, nn_jctle, &
229	& nn_bench, nn_timing
230	NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
231	& jpizoom, jpjzoom, jperio
232	!!----------------------------------------------------------------------
233	!
234	cltxt = ''
235	!
236	! ! Open reference namelist and configuration namelist files
237	CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
238	CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
239	CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
240	!
241	REWIND( numnam_ref ) ! Namelist namctl in reference namelist : Control prints & Benchmark
242	READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
243	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', lwp )
244
245	REWIND( numnam_cfg ) ! Namelist namctl in confguration namelist : Control prints & Benchmark
246	READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
247	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', lwp )
248	WRITE( numond, namctl )
249
250	!
251	REWIND( numnam_ref ) ! Namelist namcfg in reference namelist : Control prints & Benchmark
252	READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
253	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', lwp )
254
255	REWIND( numnam_cfg ) ! Namelist namcfg in confguration namelist : Control prints & Benchmark
256	READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
257	904 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', lwp )
258	WRITE( numond, namcfg )
259	!
260	! !--------------------------------------------!
261	! ! set communicator & select the local node !
262	! !--------------------------------------------!
263	#if defined key_iomput
264	IF( Agrif_Root() ) THEN
265	# if defined key_oasis3 \|\| defined key_oasis4
266	CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis
267	CALL xios_initialize( "oceanx",local_comm=ilocal_comm )
268	# else
269	CALL xios_initialize( "nemo",return_comm=ilocal_comm )
270	# endif
271	ENDIF
272	narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm ) ! Nodes selection
273	#else
274	# if defined key_oasis3 \|\| defined key_oasis4
275	IF( Agrif_Root() ) THEN
276	CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis
277	ENDIF
278	narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm ) ! Nodes selection (control print return in cltxt)
279	# else
280	ilocal_comm = 0
281	narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop ) ! Nodes selection (control print return in cltxt)
282	# endif
283	#endif
284	narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 )
285
286	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
287
288	! If dimensions of processor grid weren't specified in the namelist file
289	! then we calculate them here now that we have our communicator size
290	IF( (jpni < 1) .OR. (jpnj < 1) )THEN
291	#if defined key_mpp_mpi
292	IF( Agrif_Root() ) CALL nemo_partition(mppsize)
293	#else
294	jpni = 1
295	jpnj = 1
296	jpnij = jpni*jpnj
297	#endif
298	END IF
299
300	! Calculate domain dimensions given calculated jpni and jpnj
301	! This used to be done in par_oce.F90 when they were parameters rather
302	! than variables
303	IF( Agrif_Root() ) THEN
304	#if defined key_nemocice_decomp
305	jpi = ( nx_global+2-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
306	jpj = ( ny_global+2-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
307	#else
308	jpi = ( jpiglo-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
309	jpj = ( jpjglo-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
310	#endif
311	jpk = jpkdta ! third dim
312	jpim1 = jpi-1 ! inner domain indices
313	jpjm1 = jpj-1 ! " "
314	jpkm1 = jpk-1 ! " "
315	jpij = jpi*jpj ! jpi x j
316	ENDIF
317
318	IF(lwp) THEN ! open listing units
319	!
320	CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
321	!
322	WRITE(numout,*)
323	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
324	WRITE(numout,*) ' NEMO team'
325	WRITE(numout,*) ' Ocean General Circulation Model'
326	WRITE(numout,*) ' version 3.4 (2011) '
327	WRITE(numout,*)
328	WRITE(numout,*)
329	DO ji = 1, SIZE(cltxt)
330	IF( TRIM(cltxt(ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode
331	END DO
332	WRITE(numout,cform_aaa) ! Flag AAAAAAA
333	!
334	ENDIF
335
336	! Now we know the dimensions of the grid and numout has been set we can
337	! allocate arrays
338	CALL nemo_alloc()
339
340	! !-------------------------------!
341	! ! NEMO general initialization !
342	! !-------------------------------!
343
344	CALL nemo_ctl ! Control prints & Benchmark
345
346	! ! Domain decomposition
347	IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out
348	ELSE ; CALL mpp_init2 ! eliminate land processors
349	ENDIF
350	!
351	IF( nn_timing == 1 ) CALL timing_init
352	!
353	! ! General initialization
354	CALL phy_cst ! Physical constants
355	CALL eos_init ! Equation of state
356	CALL dom_cfg ! Domain configuration
357	CALL dom_init ! Domain
358
359	IF( ln_nnogather ) CALL nemo_northcomms ! Initialise the northfold neighbour lists (must be done after the masks are defined)
360
361	IF( ln_ctl ) CALL prt_ctl_init ! Print control
362
363	IF( lk_obc ) CALL obc_init ! Open boundaries
364
365	CALL istate_init ! ocean initial state (Dynamics and tracers)
366
367	IF( lk_tide ) CALL tide_init( nit000 ) ! Initialisation of the tidal harmonics
368
369	IF( lk_bdy ) CALL bdy_init ! Open boundaries initialisation
370	IF( lk_bdy ) CALL bdy_dta_init ! Open boundaries initialisation of external data arrays
371	IF( lk_bdy ) CALL bdytide_init ! Open boundaries initialisation of tidal harmonic forcing
372
373	CALL dyn_nept_init ! simplified form of Neptune effect
374
375	! ! Ocean physics
376	CALL sbc_init ! Forcings : surface module
377	! ! Vertical physics
378
379	CALL zdf_init ! namelist read
380
381	CALL zdf_bfr_init ! bottom friction
382
383	IF( lk_zdfric ) CALL zdf_ric_init ! Richardson number dependent Kz
384	IF( lk_zdftke ) CALL zdf_tke_init ! TKE closure scheme
385	IF( lk_zdfgls ) CALL zdf_gls_init ! GLS closure scheme
386	IF( lk_zdfkpp ) CALL zdf_kpp_init ! KPP closure scheme
387	IF( lk_zdftmx ) CALL zdf_tmx_init ! tidal vertical mixing
388	IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) &
389	& CALL zdf_ddm_init ! double diffusive mixing
390	! ! Lateral physics
391	CALL ldf_tra_init ! Lateral ocean tracer physics
392	CALL ldf_dyn_init ! Lateral ocean momentum physics
393	IF( lk_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
394
395	! ! Active tracers
396	CALL tra_qsr_init ! penetrative solar radiation qsr
397	CALL tra_bbc_init ! bottom heat flux
398	IF( lk_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
399	IF( ln_tradmp ) CALL tra_dmp_init ! internal damping trends
400	CALL tra_adv_init ! horizontal & vertical advection
401	CALL tra_ldf_init ! lateral mixing
402	CALL tra_zdf_init ! vertical mixing and after tracer fields
403
404	! ! Dynamics
405	CALL dyn_adv_init ! advection (vector or flux form)
406	CALL dyn_vor_init ! vorticity term including Coriolis
407	CALL dyn_ldf_init ! lateral mixing
408	CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure
409	CALL dyn_zdf_init ! vertical diffusion
410	CALL dyn_spg_init ! surface pressure gradient
411
412	! ! Misc. options
413	IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 ) CALL cla_init ! Cross Land Advection
414	CALL icb_init( rdt, nit000) ! initialise icebergs instance
415
416	#if defined key_top
417	! ! Passive tracers
418	CALL trc_init
419	#endif
420	!
421
422	! Diagnostics
423	IF( lk_floats ) CALL flo_init ! drifting Floats
424	IF( lk_diaar5 ) CALL dia_ar5_init ! ar5 diag
425	CALL dia_ptr_init ! Poleward TRansports initialization
426	IF( lk_diadct ) CALL dia_dct_init ! Sections tranports
427	CALL dia_hsb_init ! heat content, salt content and volume budgets
428	CALL trd_mod_init ! Mixed-layer/Vorticity/Integral constraints trends
429	IF( lk_diaobs ) THEN ! Observation & model comparison
430	CALL dia_obs_init ! Initialize observational data
431	CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
432	ENDIF
433	! ! Assimilation increments
434	IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments
435	IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
436	!
437	END SUBROUTINE nemo_init
438
439
440	SUBROUTINE nemo_ctl
441	!!----------------------------------------------------------------------
442	!! * ROUTINE nemo_ctl *
443	!!
444	!! ** Purpose : control print setting
445	!!
446	!! ** Method : - print namctl information and check some consistencies
447	!!----------------------------------------------------------------------
448	!
449	IF(lwp) THEN ! control print
450	WRITE(numout,*)
451	WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
452	WRITE(numout,*) '~~~~~~~ '
453	WRITE(numout,*) ' Namelist namctl'
454	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
455	WRITE(numout,*) ' level of print nn_print = ', nn_print
456	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
457	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
458	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
459	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
460	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
461	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
462	WRITE(numout,*) ' benchmark parameter (0/1) nn_bench = ', nn_bench
463	WRITE(numout,*) ' timing activated (0/1) nn_timing = ', nn_timing
464	ENDIF
465	!
466	nprint = nn_print ! convert DOCTOR namelist names into OLD names
467	nictls = nn_ictls
468	nictle = nn_ictle
469	njctls = nn_jctls
470	njctle = nn_jctle
471	isplt = nn_isplt
472	jsplt = nn_jsplt
473	nbench = nn_bench
474
475	IF(lwp) THEN ! control print
476	WRITE(numout,*)
477	WRITE(numout,*) 'namcfg : configuration initialization through namelist read'
478	WRITE(numout,*) '~~~~~~~ '
479	WRITE(numout,*) ' Namelist namcfg'
480	WRITE(numout,*) ' configuration name cp_cfg = ', TRIM(cp_cfg)
481	WRITE(numout,*) ' configuration zoom name cp_cfz = ', TRIM(cp_cfz)
482	WRITE(numout,*) ' configuration resolution jp_cfg = ', jp_cfg
483	WRITE(numout,*) ' 1st lateral dimension ( >= jpi ) jpidta = ', jpidta
484	WRITE(numout,*) ' 2nd " " ( >= jpj ) jpjdta = ', jpjdta
485	WRITE(numout,*) ' 3nd " " jpkdta = ', jpkdta
486	WRITE(numout,*) ' 1st dimension of global domain in i jpiglo = ', jpiglo
487	WRITE(numout,*) ' 2nd - - in j jpjglo = ', jpjglo
488	WRITE(numout,*) ' left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
489	WRITE(numout,*) ' left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
490	WRITE(numout,*) ' lateral cond. type (between 0 and 6) jperio = ', jperio
491
492	ENDIF
493	! ! Parameter control
494	!
495	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
496	IF( lk_mpp .AND. jpnij > 1 ) THEN
497	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
498	ELSE
499	IF( isplt == 1 .AND. jsplt == 1 ) THEN
500	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
501	& ' - the print control will be done over the whole domain' )
502	ENDIF
503	ijsplt = isplt * jsplt ! total number of processors ijsplt
504	ENDIF
505	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
506	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
507	!
508	! ! indices used for the SUM control
509	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
510	lsp_area = .FALSE.
511	ELSE ! print control done over a specific area
512	lsp_area = .TRUE.
513	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
514	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
515	nictls = 1
516	ENDIF
517	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
518	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
519	nictle = jpiglo
520	ENDIF
521	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
522	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
523	njctls = 1
524	ENDIF
525	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
526	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
527	njctle = jpjglo
528	ENDIF
529	ENDIF
530	ENDIF
531	!
532	IF( nbench == 1 ) THEN ! Benchmark
533	SELECT CASE ( cp_cfg )
534	CASE ( 'gyre' ) ; CALL ctl_warn( ' The Benchmark is activated ' )
535	CASE DEFAULT ; CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:', &
536	& ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
537	END SELECT
538	ENDIF
539	!
540	IF( lk_c1d .AND. .NOT.lk_iomput ) CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ', &
541	& 'with the IOM Input/Output manager. ' , &
542	& 'Compile with key_iomput enabled' )
543	!
544	IF( 1_wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ', &
545	& 'f2003 standard. ' , &
546	& 'Compile with key_nosignedzero enabled' )
547	!
548	END SUBROUTINE nemo_ctl
549
550
551	SUBROUTINE nemo_closefile
552	!!----------------------------------------------------------------------
553	!! * ROUTINE nemo_closefile *
554	!!
555	!! ** Purpose : Close the files
556	!!----------------------------------------------------------------------
557	!
558	IF( lk_mpp ) CALL mppsync
559	!
560	CALL iom_close ! close all input/output files managed by iom_*
561	!
562	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
563	IF( numsol /= -1 ) CLOSE( numsol ) ! solver file
564	IF( numnam_ref /= -1 ) CLOSE( numnam_ref ) ! oce reference namelist
565	IF( numnam_cfg /= -1 ) CLOSE( numnam_cfg ) ! oce configuration namelist
566	IF( numond /= -1 ) CLOSE( numond ) ! oce output namelist
567	IF( numnam_ice_ref /= -1 ) CLOSE( numnam_ice_ref ) ! ice reference namelist
568	IF( numnam_ice_cfg /= -1 ) CLOSE( numnam_ice_cfg ) ! ice configuration namelist
569	IF( numoni /= -1 ) CLOSE( numoni ) ! ice output namelist
570	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
571	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
572	IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports
573	IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports
574	IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports
575
576	!
577	numout = 6 ! redefine numout in case it is used after this point...
578	!
579	END SUBROUTINE nemo_closefile
580
581
582	SUBROUTINE nemo_alloc
583	!!----------------------------------------------------------------------
584	!! * ROUTINE nemo_alloc *
585	!!
586	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
587	!!
588	!! ** Method :
589	!!----------------------------------------------------------------------
590	USE diawri , ONLY: dia_wri_alloc
591	USE dom_oce , ONLY: dom_oce_alloc
592	USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
593	USE ldftra_oce, ONLY: ldftra_oce_alloc
594	USE trc_oce , ONLY: trc_oce_alloc
595	#if defined key_diadct
596	USE diadct , ONLY: diadct_alloc
597	#endif
598	!
599	INTEGER :: ierr
600	!!----------------------------------------------------------------------
601	!
602	ierr = oce_alloc () ! ocean
603	ierr = ierr + dia_wri_alloc ()
604	ierr = ierr + dom_oce_alloc () ! ocean domain
605	ierr = ierr + ldfdyn_oce_alloc() ! ocean lateral physics : dynamics
606	ierr = ierr + ldftra_oce_alloc() ! ocean lateral physics : tracers
607	ierr = ierr + zdf_oce_alloc () ! ocean vertical physics
608	!
609	ierr = ierr + lib_mpp_alloc (numout) ! mpp exchanges
610	ierr = ierr + trc_oce_alloc () ! shared TRC / TRA arrays
611	!
612	#if defined key_diadct
613	ierr = ierr + diadct_alloc () !
614	#endif
615	!
616	IF( lk_mpp ) CALL mpp_sum( ierr )
617	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
618	!
619	END SUBROUTINE nemo_alloc
620
621
622	SUBROUTINE nemo_partition( num_pes )
623	!!----------------------------------------------------------------------
624	!! * ROUTINE nemo_partition *
625	!!
626	!! ** Purpose :
627	!!
628	!! ** Method :
629	!!----------------------------------------------------------------------
630	INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
631	!
632	INTEGER, PARAMETER :: nfactmax = 20
633	INTEGER :: nfact ! The no. of factors returned
634	INTEGER :: ierr ! Error flag
635	INTEGER :: ji
636	INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
637	INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
638	!!----------------------------------------------------------------------
639
640	ierr = 0
641
642	CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
643
644	IF( nfact <= 1 ) THEN
645	WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
646	WRITE (numout, *) ' : using grid of ',num_pes,' x 1'
647	jpnj = 1
648	jpni = num_pes
649	ELSE
650	! Search through factors for the pair that are closest in value
651	mindiff = 1000000
652	imin = 1
653	DO ji = 1, nfact-1, 2
654	idiff = ABS( ifact(ji) - ifact(ji+1) )
655	IF( idiff < mindiff ) THEN
656	mindiff = idiff
657	imin = ji
658	ENDIF
659	END DO
660	jpnj = ifact(imin)
661	jpni = ifact(imin + 1)
662	ENDIF
663	!
664	jpnij = jpni*jpnj
665	!
666	END SUBROUTINE nemo_partition
667
668
669	SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
670	!!----------------------------------------------------------------------
671	!! * ROUTINE factorise *
672	!!
673	!! ** Purpose : return the prime factors of n.
674	!! knfax factors are returned in array kfax which is of
675	!! maximum dimension kmaxfax.
676	!! ** Method :
677	!!----------------------------------------------------------------------
678	INTEGER , INTENT(in ) :: kn, kmaxfax
679	INTEGER , INTENT( out) :: kerr, knfax
680	INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax
681	!
682	INTEGER :: ifac, jl, inu
683	INTEGER, PARAMETER :: ntest = 14
684	INTEGER :: ilfax(ntest)
685
686	! lfax contains the set of allowed factors.
687	data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256, &
688	& 128, 64, 32, 16, 8, 4, 2 /
689	!!----------------------------------------------------------------------
690
691	! Clear the error flag and initialise output vars
692	kerr = 0
693	kfax = 1
694	knfax = 0
695
696	! Find the factors of n.
697	IF( kn == 1 ) GOTO 20
698
699	! nu holds the unfactorised part of the number.
700	! knfax holds the number of factors found.
701	! l points to the allowed factor list.
702	! ifac holds the current factor.
703
704	inu = kn
705	knfax = 0
706
707	DO jl = ntest, 1, -1
708	!
709	ifac = ilfax(jl)
710	IF( ifac > inu ) CYCLE
711
712	! Test whether the factor will divide.
713
714	IF( MOD(inu,ifac) == 0 ) THEN
715	!
716	knfax = knfax + 1 ! Add the factor to the list
717	IF( knfax > kmaxfax ) THEN
718	kerr = 6
719	write (,) 'FACTOR: insufficient space in factor array ', knfax
720	return
721	ENDIF
722	kfax(knfax) = ifac
723	! Store the other factor that goes with this one
724	knfax = knfax + 1
725	kfax(knfax) = inu / ifac
726	!WRITE (,) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
727	ENDIF
728	!
729	END DO
730
731	20 CONTINUE ! Label 20 is the exit point from the factor search loop.
732	!
733	END SUBROUTINE factorise
734
735	#if defined key_mpp_mpi
736	SUBROUTINE nemo_northcomms
737	!!======================================================================
738	!! * ROUTINE nemo_northcomms *
739	!! nemo_northcomms : Setup for north fold exchanges with explicit peer to peer messaging
740	!!=====================================================================
741	!!----------------------------------------------------------------------
742	!!
743	!! ** Purpose : Initialization of the northern neighbours lists.
744	!!----------------------------------------------------------------------
745	!! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE)
746	!!----------------------------------------------------------------------
747
748	INTEGER :: ji, jj, jk, ij, jtyp ! dummy loop indices
749	INTEGER :: ijpj ! number of rows involved in north-fold exchange
750	INTEGER :: northcomms_alloc ! allocate return status
751	REAL(wp), ALLOCATABLE, DIMENSION ( :,: ) :: znnbrs ! workspace
752	LOGICAL, ALLOCATABLE, DIMENSION ( : ) :: lrankset ! workspace
753
754	IF(lwp) WRITE(numout,*)
755	IF(lwp) WRITE(numout,*) 'nemo_northcomms : Initialization of the northern neighbours lists'
756	IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
757
758	!!----------------------------------------------------------------------
759	ALLOCATE( znnbrs(jpi,jpj), stat = northcomms_alloc )
760	ALLOCATE( lrankset(jpnij), stat = northcomms_alloc )
761	IF( northcomms_alloc /= 0 ) THEN
762	WRITE(numout,cform_war)
763	WRITE(numout,*) 'northcomms_alloc : failed to allocate arrays'
764	CALL ctl_stop( 'STOP', 'nemo_northcomms : unable to allocate temporary arrays' )
765	ENDIF
766	nsndto = 0
767	isendto = -1
768	ijpj = 4
769	!
770	! This routine has been called because ln_nnogather has been set true ( nammpp )
771	! However, these first few exchanges have to use the mpi_allgather method to
772	! establish the neighbour lists to use in subsequent peer to peer exchanges.
773	! Consequently, set l_north_nogather to be false here and set it true only after
774	! the lists have been established.
775	!
776	l_north_nogather = .FALSE.
777	!
778	! Exchange and store ranks on northern rows
779
780	DO jtyp = 1,4
781
782	lrankset = .FALSE.
783	znnbrs = narea
784	SELECT CASE (jtyp)
785	CASE(1)
786	CALL lbc_lnk( znnbrs, 'T', 1. ) ! Type 1: T,W-points
787	CASE(2)
788	CALL lbc_lnk( znnbrs, 'U', 1. ) ! Type 2: U-point
789	CASE(3)
790	CALL lbc_lnk( znnbrs, 'V', 1. ) ! Type 3: V-point
791	CASE(4)
792	CALL lbc_lnk( znnbrs, 'F', 1. ) ! Type 4: F-point
793	END SELECT
794
795	IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
796	DO jj = nlcj-ijpj+1, nlcj
797	ij = jj - nlcj + ijpj
798	DO ji = 1,jpi
799	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
800	& lrankset(INT(znnbrs(ji,jj))) = .true.
801	END DO
802	END DO
803
804	DO jj = 1,jpnij
805	IF ( lrankset(jj) ) THEN
806	nsndto(jtyp) = nsndto(jtyp) + 1
807	IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
808	CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
809	& ' jpmaxngh will need to be increased ')
810	ENDIF
811	isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank
812	ENDIF
813	END DO
814	ENDIF
815
816	END DO
817
818	!
819	! Type 5: I-point
820	!
821	! ICE point exchanges may involve some averaging. The neighbours list is
822	! built up using two exchanges to ensure that the whole stencil is covered.
823	! lrankset should not be reset between these 'J' and 'K' point exchanges
824
825	jtyp = 5
826	lrankset = .FALSE.
827	znnbrs = narea
828	CALL lbc_lnk( znnbrs, 'J', 1. ) ! first ice U-V point
829
830	IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
831	DO jj = nlcj-ijpj+1, nlcj
832	ij = jj - nlcj + ijpj
833	DO ji = 1,jpi
834	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
835	& lrankset(INT(znnbrs(ji,jj))) = .true.
836	END DO
837	END DO
838	ENDIF
839
840	znnbrs = narea
841	CALL lbc_lnk( znnbrs, 'K', 1. ) ! second ice U-V point
842
843	IF ( njmppt(narea) .EQ. MAXVAL( njmppt )) THEN
844	DO jj = nlcj-ijpj+1, nlcj
845	ij = jj - nlcj + ijpj
846	DO ji = 1,jpi
847	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
848	& lrankset( INT(znnbrs(ji,jj))) = .true.
849	END DO
850	END DO
851
852	DO jj = 1,jpnij
853	IF ( lrankset(jj) ) THEN
854	nsndto(jtyp) = nsndto(jtyp) + 1
855	IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
856	CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
857	& ' jpmaxngh will need to be increased ')
858	ENDIF
859	isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank
860	ENDIF
861	END DO
862	!
863	! For northern row areas, set l_north_nogather so that all subsequent exchanges
864	! can use peer to peer communications at the north fold
865	!
866	l_north_nogather = .TRUE.
867	!
868	ENDIF
869	DEALLOCATE( znnbrs )
870	DEALLOCATE( lrankset )
871
872	END SUBROUTINE nemo_northcomms
873	#else
874	SUBROUTINE nemo_northcomms ! Dummy routine
875	WRITE(,) 'nemo_northcomms: You should not have seen this print! error?'
876	END SUBROUTINE nemo_northcomms
877	#endif
878	!!======================================================================
879	END MODULE nemogcm

Note: See TracBrowser for help on using the repository browser.

Download in other formats: