New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in branches/2013/dev_r3853_CNRS9_ConfSetting/NEMOGCM/NEMO/OPA_SRC – NEMO

Context Navigation

source: branches/2013/dev_r3853_CNRS9_ConfSetting/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 4020

Last change on this file since 4020 was 4020, checked in by clevy, 11 years ago
Configuration setting/correct my error, see ticket:#1074
Property svn:keywords set to `Id`
File size: 42.5 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code
7	!! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec)
8	!! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9	!! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10	!! - ! 1992-06 (L.Terray) coupling implementation
11	!! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice
12	!! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13	!! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14	!! 8.1 ! 1997-06 (M. Imbard, G. Madec)
15	!! 8.2 ! 1999-11 (M. Imbard, H. Goosse) LIM sea-ice model
16	!! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP
17	!! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER)
18	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules
19	!! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20	!! - ! 2004-08 (C. Talandier) New trends organization
21	!! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility
22	!! - ! 2005-11 (V. Garnier) Surface pressure gradient organization
23	!! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation
24	!! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization
25	!! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26	!! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp
27	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
29	!! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
30	!! 3.4 ! 2011-11 (C. Harris) decomposition changes for running with CICE
31	!!----------------------------------------------------------------------
32
33	!!----------------------------------------------------------------------
34	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
35	!! nemo_init : initialization of the NEMO system
36	!! nemo_ctl : initialisation of the contol print
37	!! nemo_closefile : close remaining open files
38	!! nemo_alloc : dynamical allocation
39	!! nemo_partition : calculate MPP domain decomposition
40	!! factorise : calculate the factors of the no. of MPI processes
41	!!----------------------------------------------------------------------
42	USE step_oce ! module used in the ocean time stepping module
43	USE sbc_oce ! surface boundary condition: ocean
44	USE cla ! cross land advection (tra_cla routine)
45	USE domcfg ! domain configuration (dom_cfg routine)
46	USE mppini ! shared/distributed memory setting (mpp_init routine)
47	USE domain ! domain initialization (dom_init routine)
48	#if defined key_nemocice_decomp
49	USE ice_domain_size, only: nx_global, ny_global
50	#endif
51	USE tideini ! tidal components initialization (tide_ini routine)
52	USE obcini ! open boundary cond. initialization (obc_ini routine)
53	USE bdyini ! open boundary cond. initialization (bdy_init routine)
54	USE bdydta ! open boundary cond. initialization (bdy_dta_init routine)
55	USE bdytides ! open boundary cond. initialization (bdytide_init routine)
56	USE istate ! initial state setting (istate_init routine)
57	USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine)
58	USE ldftra ! lateral diffusivity setting (ldftra_init routine)
59	USE zdfini ! vertical physics setting (zdf_init routine)
60	USE phycst ! physical constant (par_cst routine)
61	USE trdmod ! momentum/tracers trends (trd_mod_init routine)
62	USE asminc ! assimilation increments
63	USE asmbkg ! writing out state trajectory
64	USE diaptr ! poleward transports (dia_ptr_init routine)
65	USE diadct ! sections transports (dia_dct_init routine)
66	USE diaobs ! Observation diagnostics (dia_obs_init routine)
67	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
68	USE step ! NEMO time-stepping (stp routine)
69	USE icbini ! handle bergs, initialisation
70	USE icbstp ! handle bergs, calving, themodynamics and transport
71	#if defined key_oasis3
72	USE cpl_oasis3 ! OASIS3 coupling
73	#elif defined key_oasis4
74	USE cpl_oasis4 ! OASIS4 coupling (not working)
75	#endif
76	USE c1d ! 1D configuration
77	USE step_c1d ! Time stepping loop for the 1D configuration
78	#if defined key_top
79	USE trcini ! passive tracer initialisation
80	#endif
81	USE lib_mpp ! distributed memory computing
82	#if defined key_iomput
83	USE xios
84	#endif
85	USE sbctide, ONLY: lk_tide
86
87	IMPLICIT NONE
88	PRIVATE
89
90	PUBLIC nemo_gcm ! called by model.F90
91	PUBLIC nemo_init ! needed by AGRIF
92	PUBLIC nemo_alloc ! needed by TAM
93
94	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
95
96	!!----------------------------------------------------------------------
97	!! NEMO/OPA 4.0 , NEMO Consortium (2011)
98	!! $Id$
99	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
100	!!----------------------------------------------------------------------
101	CONTAINS
102
103	SUBROUTINE nemo_gcm
104	!!----------------------------------------------------------------------
105	!! * ROUTINE nemo_gcm *
106	!!
107	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
108	!! curvilinear mesh on the sphere.
109	!!
110	!! ** Method : - model general initialization
111	!! - launch the time-stepping (stp routine)
112	!! - finalize the run by closing files and communications
113	!!
114	!! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL.
115	!! Madec, 2008, internal report, IPSL.
116	!!----------------------------------------------------------------------
117	INTEGER :: istp ! time step index
118	!!----------------------------------------------------------------------
119	!
120
121	#if defined key_agrif
122	CALL Agrif_Init_Grids() ! AGRIF: set the meshes
123	#endif
124
125	! !-----------------------!
126	CALL nemo_init !== Initialisations ==!
127	! !-----------------------!
128	#if defined key_agrif
129	CALL Agrif_Declare_Var_dom ! AGRIF: set the meshes for DOM
130	CALL Agrif_Declare_Var ! " " " " " DYN/TRA
131	# if defined key_top
132	CALL Agrif_Declare_Var_top ! " " " " " TOP
133	# endif
134	# if defined key_lim2
135	CALL Agrif_Declare_Var_lim2 ! " " " " " LIM
136	# endif
137	#endif
138
139	! check that all process are still there... If some process have an error,
140	! they will never enter in step and other processes will wait until the end of the cpu time!
141	IF( lk_mpp ) CALL mpp_max( nstop )
142
143	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
144
145	! !-----------------------!
146	! !== time stepping ==!
147	! !-----------------------!
148	istp = nit000
149	#if defined key_c1d
150	DO WHILE ( istp <= nitend .AND. nstop == 0 )
151	CALL stp_c1d( istp )
152	istp = istp + 1
153	END DO
154	#else
155	IF( lk_asminc ) THEN
156	IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 ) ! Output background fields
157	IF( ln_asmdin ) THEN ! Direct initialization
158	IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 ) ! Tracers
159	IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 ) ! Dynamics
160	IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 ) ! SSH
161	ENDIF
162	ENDIF
163
164	DO WHILE ( istp <= nitend .AND. nstop == 0 )
165
166	#if defined key_agrif
167	CALL Agrif_Step( stp ) ! AGRIF: time stepping
168	#else
169	CALL stp( istp ) ! standard time stepping
170	#endif
171
172	istp = istp + 1
173	IF( lk_mpp ) CALL mpp_max( nstop )
174	END DO
175	#endif
176
177	IF( lk_diaobs ) CALL dia_obs_wri
178	!
179	IF( ln_icebergs ) CALL icb_end( nitend )
180
181	! !------------------------!
182	! !== finalize the run ==!
183	! !------------------------!
184	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
185	!
186	IF( nstop /= 0 .AND. lwp ) THEN ! error print
187	WRITE(numout,cform_err)
188	WRITE(numout,*) nstop, ' error have been found'
189	ENDIF
190	!
191	#if defined key_agrif
192	CALL Agrif_ParentGrid_To_ChildGrid()
193	IF( lk_diaobs ) CALL dia_obs_wri
194	IF( nn_timing == 1 ) CALL timing_finalize
195	CALL Agrif_ChildGrid_To_ParentGrid()
196	#endif
197	IF( nn_timing == 1 ) CALL timing_finalize
198	!
199	CALL nemo_closefile
200	#if defined key_iomput
201	CALL xios_finalize ! end mpp communications with xios
202	# if defined key_oasis3 \|\| defined key_oasis4
203	CALL cpl_prism_finalize ! end coupling and mpp communications with OASIS
204	# endif
205	#else
206	# if defined key_oasis3 \|\| defined key_oasis4
207	CALL cpl_prism_finalize ! end coupling and mpp communications with OASIS
208	# else
209	IF( lk_mpp ) CALL mppstop ! end mpp communications
210	# endif
211	#endif
212	!
213	END SUBROUTINE nemo_gcm
214
215
216	SUBROUTINE nemo_init
217	!!----------------------------------------------------------------------
218	!! * ROUTINE nemo_init *
219	!!
220	!! ** Purpose : initialization of the NEMO GCM
221	!!----------------------------------------------------------------------
222	INTEGER :: ji ! dummy loop indices
223	INTEGER :: ilocal_comm ! local integer
224	INTEGER :: ios
225	CHARACTER(len=80), DIMENSION(16) :: cltxt
226	!!
227	NAMELIST/namctl/ ln_ctl, nn_print, nn_ictls, nn_ictle, &
228	& nn_isplt, nn_jsplt, nn_jctls, nn_jctle, &
229	& nn_bench, nn_timing
230	NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
231	& jpizoom, jpjzoom, jperio
232	!!----------------------------------------------------------------------
233	!
234	cltxt = ''
235	!
236	! ! Open reference namelist and configuration namelist files
237	CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
238	CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
239	CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
240	!
241	REWIND( numnam_ref ) ! Namelist namctl in reference namelist : Control prints & Benchmark
242	READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
243	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', lwp )
244
245	REWIND( numnam_cfg ) ! Namelist namctl in confguration namelist : Control prints & Benchmark
246	READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
247	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', lwp )
248	WRITE( numond, namctl )
249
250	!
251	REWIND( numnam_ref ) ! Namelist namcfg in reference namelist : Control prints & Benchmark
252	READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
253	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', lwp )
254
255	REWIND( numnam_cfg ) ! Namelist namcfg in confguration namelist : Control prints & Benchmark
256	READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
257	904 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', lwp )
258	WRITE( numond, namcfg )
259	! Force values for AGRIF zoom (cf. agrif_user.F90)
260	#if defined key_agrif
261	IF( .NOT. Agrif_Root() ) THEN
262	jpiglo = nbcellsx + 2 + 2*nbghostcells
263	jpjglo = nbcellsy + 2 + 2*nbghostcells
264	jpi = ( jpiglo-2jpreci + (jpni-1+0) ) / jpni + 2jpreci
265	jpj = ( jpjglo-2jprecj + (jpnj-1+0) ) / jpnj + 2jprecj
266	jpidta = jpiglo
267	jpjdta = jpjglo
268	jpizoom = 1
269	jpjzoom = 1
270	nperio = 0
271	jperio = 0
272	ENDIF
273	#endif
274	!
275	! !--------------------------------------------!
276	! ! set communicator & select the local node !
277	! !--------------------------------------------!
278	#if defined key_iomput
279	IF( Agrif_Root() ) THEN
280	# if defined key_oasis3 \|\| defined key_oasis4
281	CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis
282	CALL xios_initialize( "oceanx",local_comm=ilocal_comm )
283	# else
284	CALL xios_initialize( "nemo",return_comm=ilocal_comm )
285	# endif
286	ENDIF
287	narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm ) ! Nodes selection
288	#else
289	# if defined key_oasis3 \|\| defined key_oasis4
290	IF( Agrif_Root() ) THEN
291	CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis
292	ENDIF
293	narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm ) ! Nodes selection (control print return in cltxt)
294	# else
295	ilocal_comm = 0
296	narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop ) ! Nodes selection (control print return in cltxt)
297	# endif
298	#endif
299	narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 )
300
301	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
302
303	! If dimensions of processor grid weren't specified in the namelist file
304	! then we calculate them here now that we have our communicator size
305	IF( (jpni < 1) .OR. (jpnj < 1) )THEN
306	#if defined key_mpp_mpi
307	IF( Agrif_Root() ) CALL nemo_partition(mppsize)
308	#else
309	jpni = 1
310	jpnj = 1
311	jpnij = jpni*jpnj
312	#endif
313	END IF
314
315	! Calculate domain dimensions given calculated jpni and jpnj
316	! This used to be done in par_oce.F90 when they were parameters rather
317	! than variables
318	IF( Agrif_Root() ) THEN
319	#if defined key_nemocice_decomp
320	jpi = ( nx_global+2-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
321	jpj = ( ny_global+2-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
322	#else
323	jpi = ( jpiglo-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
324	jpj = ( jpjglo-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
325	#endif
326	ENDIF
327	jpk = jpkdta ! third dim
328	jpim1 = jpi-1 ! inner domain indices
329	jpjm1 = jpj-1 ! " "
330	jpkm1 = jpk-1 ! " "
331	jpij = jpi*jpj ! jpi x j
332
333	IF(lwp) THEN ! open listing units
334	!
335	CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
336	!
337	WRITE(numout,*)
338	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
339	WRITE(numout,*) ' NEMO team'
340	WRITE(numout,*) ' Ocean General Circulation Model'
341	WRITE(numout,*) ' version 3.4 (2011) '
342	WRITE(numout,*)
343	WRITE(numout,*)
344	DO ji = 1, SIZE(cltxt)
345	IF( TRIM(cltxt(ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode
346	END DO
347	WRITE(numout,cform_aaa) ! Flag AAAAAAA
348	!
349	ENDIF
350
351	! Now we know the dimensions of the grid and numout has been set we can
352	! allocate arrays
353	CALL nemo_alloc()
354
355	! !-------------------------------!
356	! ! NEMO general initialization !
357	! !-------------------------------!
358
359	CALL nemo_ctl ! Control prints & Benchmark
360
361	! ! Domain decomposition
362	IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out
363	ELSE ; CALL mpp_init2 ! eliminate land processors
364	ENDIF
365	!
366	IF( nn_timing == 1 ) CALL timing_init
367	!
368	! ! General initialization
369	CALL phy_cst ! Physical constants
370	CALL eos_init ! Equation of state
371	CALL dom_cfg ! Domain configuration
372	CALL dom_init ! Domain
373
374	IF( ln_nnogather ) CALL nemo_northcomms ! Initialise the northfold neighbour lists (must be done after the masks are defined)
375
376	IF( ln_ctl ) CALL prt_ctl_init ! Print control
377
378	IF( lk_obc ) CALL obc_init ! Open boundaries
379
380	CALL istate_init ! ocean initial state (Dynamics and tracers)
381
382	IF( lk_tide ) CALL tide_init( nit000 ) ! Initialisation of the tidal harmonics
383
384	IF( lk_bdy ) CALL bdy_init ! Open boundaries initialisation
385	IF( lk_bdy ) CALL bdy_dta_init ! Open boundaries initialisation of external data arrays
386	IF( lk_bdy ) CALL bdytide_init ! Open boundaries initialisation of tidal harmonic forcing
387
388	CALL dyn_nept_init ! simplified form of Neptune effect
389
390	! ! Ocean physics
391	CALL sbc_init ! Forcings : surface module
392	! ! Vertical physics
393
394	CALL zdf_init ! namelist read
395
396	CALL zdf_bfr_init ! bottom friction
397
398	IF( lk_zdfric ) CALL zdf_ric_init ! Richardson number dependent Kz
399	IF( lk_zdftke ) CALL zdf_tke_init ! TKE closure scheme
400	IF( lk_zdfgls ) CALL zdf_gls_init ! GLS closure scheme
401	IF( lk_zdfkpp ) CALL zdf_kpp_init ! KPP closure scheme
402	IF( lk_zdftmx ) CALL zdf_tmx_init ! tidal vertical mixing
403	IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) &
404	& CALL zdf_ddm_init ! double diffusive mixing
405	! ! Lateral physics
406	CALL ldf_tra_init ! Lateral ocean tracer physics
407	CALL ldf_dyn_init ! Lateral ocean momentum physics
408	IF( lk_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
409
410	! ! Active tracers
411	CALL tra_qsr_init ! penetrative solar radiation qsr
412	CALL tra_bbc_init ! bottom heat flux
413	IF( lk_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
414	IF( ln_tradmp ) CALL tra_dmp_init ! internal damping trends
415	CALL tra_adv_init ! horizontal & vertical advection
416	CALL tra_ldf_init ! lateral mixing
417	CALL tra_zdf_init ! vertical mixing and after tracer fields
418
419	! ! Dynamics
420	CALL dyn_adv_init ! advection (vector or flux form)
421	CALL dyn_vor_init ! vorticity term including Coriolis
422	CALL dyn_ldf_init ! lateral mixing
423	CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure
424	CALL dyn_zdf_init ! vertical diffusion
425	CALL dyn_spg_init ! surface pressure gradient
426
427	! ! Misc. options
428	IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 ) CALL cla_init ! Cross Land Advection
429	CALL icb_init( rdt, nit000) ! initialise icebergs instance
430
431	#if defined key_top
432	! ! Passive tracers
433	CALL trc_init
434	#endif
435	!
436
437	! Diagnostics
438	IF( lk_floats ) CALL flo_init ! drifting Floats
439	IF( lk_diaar5 ) CALL dia_ar5_init ! ar5 diag
440	CALL dia_ptr_init ! Poleward TRansports initialization
441	IF( lk_diadct ) CALL dia_dct_init ! Sections tranports
442	CALL dia_hsb_init ! heat content, salt content and volume budgets
443	CALL trd_mod_init ! Mixed-layer/Vorticity/Integral constraints trends
444	IF( lk_diaobs ) THEN ! Observation & model comparison
445	CALL dia_obs_init ! Initialize observational data
446	CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
447	ENDIF
448	! ! Assimilation increments
449	IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments
450	IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
451	!
452	END SUBROUTINE nemo_init
453
454
455	SUBROUTINE nemo_ctl
456	!!----------------------------------------------------------------------
457	!! * ROUTINE nemo_ctl *
458	!!
459	!! ** Purpose : control print setting
460	!!
461	!! ** Method : - print namctl information and check some consistencies
462	!!----------------------------------------------------------------------
463	!
464	IF(lwp) THEN ! control print
465	WRITE(numout,*)
466	WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
467	WRITE(numout,*) '~~~~~~~ '
468	WRITE(numout,*) ' Namelist namctl'
469	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
470	WRITE(numout,*) ' level of print nn_print = ', nn_print
471	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
472	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
473	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
474	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
475	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
476	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
477	WRITE(numout,*) ' benchmark parameter (0/1) nn_bench = ', nn_bench
478	WRITE(numout,*) ' timing activated (0/1) nn_timing = ', nn_timing
479	ENDIF
480	!
481	nprint = nn_print ! convert DOCTOR namelist names into OLD names
482	nictls = nn_ictls
483	nictle = nn_ictle
484	njctls = nn_jctls
485	njctle = nn_jctle
486	isplt = nn_isplt
487	jsplt = nn_jsplt
488	nbench = nn_bench
489
490	IF(lwp) THEN ! control print
491	WRITE(numout,*)
492	WRITE(numout,*) 'namcfg : configuration initialization through namelist read'
493	WRITE(numout,*) '~~~~~~~ '
494	WRITE(numout,*) ' Namelist namcfg'
495	WRITE(numout,*) ' configuration name cp_cfg = ', TRIM(cp_cfg)
496	WRITE(numout,*) ' configuration zoom name cp_cfz = ', TRIM(cp_cfz)
497	WRITE(numout,*) ' configuration resolution jp_cfg = ', jp_cfg
498	WRITE(numout,*) ' 1st lateral dimension ( >= jpi ) jpidta = ', jpidta
499	WRITE(numout,*) ' 2nd " " ( >= jpj ) jpjdta = ', jpjdta
500	WRITE(numout,*) ' 3nd " " jpkdta = ', jpkdta
501	WRITE(numout,*) ' 1st dimension of global domain in i jpiglo = ', jpiglo
502	WRITE(numout,*) ' 2nd - - in j jpjglo = ', jpjglo
503	WRITE(numout,*) ' left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
504	WRITE(numout,*) ' left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
505	WRITE(numout,*) ' lateral cond. type (between 0 and 6) jperio = ', jperio
506	WRITE(numout,*) ' type of horizontal mesh jphgr_msh = ', jphgr_msh
507	WRITE(numout,*) ' longitude of first raw and column T-point ppglam0 = ', ppglam0
508	WRITE(numout,*) ' latitude of first raw and column T-point ppgphi0 = ', ppgphi0
509	WRITE(numout,*) ' zonal grid-spacing (degrees) ppe1_deg = ', ppe1_deg
510	WRITE(numout,*) ' meridional grid-spacing (degrees) ppe2_deg = ', ppe2_deg
511	WRITE(numout,*) ' zonal grid-spacing (degrees) ppe1_m = ', ppe1_m
512	WRITE(numout,*) ' meridional grid-spacing (degrees) ppe2_m = ', ppe2_m
513	WRITE(numout,*) ' ORCA r4, r2 and r05 coefficients ppsur = ', ppsur
514	WRITE(numout,*) ' ppa0 = ', ppa0
515	WRITE(numout,*) ' ppa1 = ', ppa1
516	WRITE(numout,*) ' ppkth = ', ppkth
517	WRITE(numout,*) ' ppacr = ', ppacr
518	WRITE(numout,*) ' Minimum vertical spacing ppdzmin = ', ppdzmin
519	WRITE(numout,*) ' Maximum depth pphmax = ', pphmax
520	WRITE(numout,*) ' Use double tanf function for vertical coordinates ldbletanh = ', ldbletanh
521	WRITE(numout,*) ' Double tanh function parameters ppa2 = ', ppa2
522	WRITE(numout,*) ' ppkth2 = ', ppkth2
523	WRITE(numout,*) ' ppacr2 = ', ppacr2
524	ENDIF
525	! ! Parameter control
526	!
527	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
528	IF( lk_mpp .AND. jpnij > 1 ) THEN
529	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
530	ELSE
531	IF( isplt == 1 .AND. jsplt == 1 ) THEN
532	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
533	& ' - the print control will be done over the whole domain' )
534	ENDIF
535	ijsplt = isplt * jsplt ! total number of processors ijsplt
536	ENDIF
537	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
538	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
539	!
540	! ! indices used for the SUM control
541	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
542	lsp_area = .FALSE.
543	ELSE ! print control done over a specific area
544	lsp_area = .TRUE.
545	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
546	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
547	nictls = 1
548	ENDIF
549	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
550	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
551	nictle = jpiglo
552	ENDIF
553	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
554	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
555	njctls = 1
556	ENDIF
557	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
558	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
559	njctle = jpjglo
560	ENDIF
561	ENDIF
562	ENDIF
563	!
564	IF( nbench == 1 ) THEN ! Benchmark
565	SELECT CASE ( cp_cfg )
566	CASE ( 'gyre' ) ; CALL ctl_warn( ' The Benchmark is activated ' )
567	CASE DEFAULT ; CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:', &
568	& ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
569	END SELECT
570	ENDIF
571	!
572	IF( lk_c1d .AND. .NOT.lk_iomput ) CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ', &
573	& 'with the IOM Input/Output manager. ' , &
574	& 'Compile with key_iomput enabled' )
575	!
576	IF( 1_wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ', &
577	& 'f2003 standard. ' , &
578	& 'Compile with key_nosignedzero enabled' )
579	!
580	END SUBROUTINE nemo_ctl
581
582
583	SUBROUTINE nemo_closefile
584	!!----------------------------------------------------------------------
585	!! * ROUTINE nemo_closefile *
586	!!
587	!! ** Purpose : Close the files
588	!!----------------------------------------------------------------------
589	!
590	IF( lk_mpp ) CALL mppsync
591	!
592	CALL iom_close ! close all input/output files managed by iom_*
593	!
594	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
595	IF( numsol /= -1 ) CLOSE( numsol ) ! solver file
596	IF( numnam_ref /= -1 ) CLOSE( numnam_ref ) ! oce reference namelist
597	IF( numnam_cfg /= -1 ) CLOSE( numnam_cfg ) ! oce configuration namelist
598	IF( numond /= -1 ) CLOSE( numond ) ! oce output namelist
599	IF( numnam_ice_ref /= -1 ) CLOSE( numnam_ice_ref ) ! ice reference namelist
600	IF( numnam_ice_cfg /= -1 ) CLOSE( numnam_ice_cfg ) ! ice configuration namelist
601	IF( numoni /= -1 ) CLOSE( numoni ) ! ice output namelist
602	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
603	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
604	IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports
605	IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports
606	IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports
607
608	!
609	numout = 6 ! redefine numout in case it is used after this point...
610	!
611	END SUBROUTINE nemo_closefile
612
613
614	SUBROUTINE nemo_alloc
615	!!----------------------------------------------------------------------
616	!! * ROUTINE nemo_alloc *
617	!!
618	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
619	!!
620	!! ** Method :
621	!!----------------------------------------------------------------------
622	USE diawri , ONLY: dia_wri_alloc
623	USE dom_oce , ONLY: dom_oce_alloc
624	USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
625	USE ldftra_oce, ONLY: ldftra_oce_alloc
626	USE trc_oce , ONLY: trc_oce_alloc
627	#if defined key_diadct
628	USE diadct , ONLY: diadct_alloc
629	#endif
630	!
631	INTEGER :: ierr
632	!!----------------------------------------------------------------------
633	!
634	ierr = oce_alloc () ! ocean
635	ierr = ierr + dia_wri_alloc ()
636	ierr = ierr + dom_oce_alloc () ! ocean domain
637	ierr = ierr + ldfdyn_oce_alloc() ! ocean lateral physics : dynamics
638	ierr = ierr + ldftra_oce_alloc() ! ocean lateral physics : tracers
639	ierr = ierr + zdf_oce_alloc () ! ocean vertical physics
640	!
641	ierr = ierr + lib_mpp_alloc (numout) ! mpp exchanges
642	ierr = ierr + trc_oce_alloc () ! shared TRC / TRA arrays
643	!
644	#if defined key_diadct
645	ierr = ierr + diadct_alloc () !
646	#endif
647	!
648	IF( lk_mpp ) CALL mpp_sum( ierr )
649	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
650	!
651	END SUBROUTINE nemo_alloc
652
653
654	SUBROUTINE nemo_partition( num_pes )
655	!!----------------------------------------------------------------------
656	!! * ROUTINE nemo_partition *
657	!!
658	!! ** Purpose :
659	!!
660	!! ** Method :
661	!!----------------------------------------------------------------------
662	INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
663	!
664	INTEGER, PARAMETER :: nfactmax = 20
665	INTEGER :: nfact ! The no. of factors returned
666	INTEGER :: ierr ! Error flag
667	INTEGER :: ji
668	INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
669	INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
670	!!----------------------------------------------------------------------
671
672	ierr = 0
673
674	CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
675
676	IF( nfact <= 1 ) THEN
677	WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
678	WRITE (numout, *) ' : using grid of ',num_pes,' x 1'
679	jpnj = 1
680	jpni = num_pes
681	ELSE
682	! Search through factors for the pair that are closest in value
683	mindiff = 1000000
684	imin = 1
685	DO ji = 1, nfact-1, 2
686	idiff = ABS( ifact(ji) - ifact(ji+1) )
687	IF( idiff < mindiff ) THEN
688	mindiff = idiff
689	imin = ji
690	ENDIF
691	END DO
692	jpnj = ifact(imin)
693	jpni = ifact(imin + 1)
694	ENDIF
695	!
696	jpnij = jpni*jpnj
697	!
698	END SUBROUTINE nemo_partition
699
700
701	SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
702	!!----------------------------------------------------------------------
703	!! * ROUTINE factorise *
704	!!
705	!! ** Purpose : return the prime factors of n.
706	!! knfax factors are returned in array kfax which is of
707	!! maximum dimension kmaxfax.
708	!! ** Method :
709	!!----------------------------------------------------------------------
710	INTEGER , INTENT(in ) :: kn, kmaxfax
711	INTEGER , INTENT( out) :: kerr, knfax
712	INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax
713	!
714	INTEGER :: ifac, jl, inu
715	INTEGER, PARAMETER :: ntest = 14
716	INTEGER :: ilfax(ntest)
717
718	! lfax contains the set of allowed factors.
719	data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256, &
720	& 128, 64, 32, 16, 8, 4, 2 /
721	!!----------------------------------------------------------------------
722
723	! Clear the error flag and initialise output vars
724	kerr = 0
725	kfax = 1
726	knfax = 0
727
728	! Find the factors of n.
729	IF( kn == 1 ) GOTO 20
730
731	! nu holds the unfactorised part of the number.
732	! knfax holds the number of factors found.
733	! l points to the allowed factor list.
734	! ifac holds the current factor.
735
736	inu = kn
737	knfax = 0
738
739	DO jl = ntest, 1, -1
740	!
741	ifac = ilfax(jl)
742	IF( ifac > inu ) CYCLE
743
744	! Test whether the factor will divide.
745
746	IF( MOD(inu,ifac) == 0 ) THEN
747	!
748	knfax = knfax + 1 ! Add the factor to the list
749	IF( knfax > kmaxfax ) THEN
750	kerr = 6
751	write (,) 'FACTOR: insufficient space in factor array ', knfax
752	return
753	ENDIF
754	kfax(knfax) = ifac
755	! Store the other factor that goes with this one
756	knfax = knfax + 1
757	kfax(knfax) = inu / ifac
758	!WRITE (,) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
759	ENDIF
760	!
761	END DO
762
763	20 CONTINUE ! Label 20 is the exit point from the factor search loop.
764	!
765	END SUBROUTINE factorise
766
767	#if defined key_mpp_mpi
768	SUBROUTINE nemo_northcomms
769	!!======================================================================
770	!! * ROUTINE nemo_northcomms *
771	!! nemo_northcomms : Setup for north fold exchanges with explicit peer to peer messaging
772	!!=====================================================================
773	!!----------------------------------------------------------------------
774	!!
775	!! ** Purpose : Initialization of the northern neighbours lists.
776	!!----------------------------------------------------------------------
777	!! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE)
778	!!----------------------------------------------------------------------
779
780	INTEGER :: ji, jj, jk, ij, jtyp ! dummy loop indices
781	INTEGER :: ijpj ! number of rows involved in north-fold exchange
782	INTEGER :: northcomms_alloc ! allocate return status
783	REAL(wp), ALLOCATABLE, DIMENSION ( :,: ) :: znnbrs ! workspace
784	LOGICAL, ALLOCATABLE, DIMENSION ( : ) :: lrankset ! workspace
785
786	IF(lwp) WRITE(numout,*)
787	IF(lwp) WRITE(numout,*) 'nemo_northcomms : Initialization of the northern neighbours lists'
788	IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
789
790	!!----------------------------------------------------------------------
791	ALLOCATE( znnbrs(jpi,jpj), stat = northcomms_alloc )
792	ALLOCATE( lrankset(jpnij), stat = northcomms_alloc )
793	IF( northcomms_alloc /= 0 ) THEN
794	WRITE(numout,cform_war)
795	WRITE(numout,*) 'northcomms_alloc : failed to allocate arrays'
796	CALL ctl_stop( 'STOP', 'nemo_northcomms : unable to allocate temporary arrays' )
797	ENDIF
798	nsndto = 0
799	isendto = -1
800	ijpj = 4
801	!
802	! This routine has been called because ln_nnogather has been set true ( nammpp )
803	! However, these first few exchanges have to use the mpi_allgather method to
804	! establish the neighbour lists to use in subsequent peer to peer exchanges.
805	! Consequently, set l_north_nogather to be false here and set it true only after
806	! the lists have been established.
807	!
808	l_north_nogather = .FALSE.
809	!
810	! Exchange and store ranks on northern rows
811
812	DO jtyp = 1,4
813
814	lrankset = .FALSE.
815	znnbrs = narea
816	SELECT CASE (jtyp)
817	CASE(1)
818	CALL lbc_lnk( znnbrs, 'T', 1. ) ! Type 1: T,W-points
819	CASE(2)
820	CALL lbc_lnk( znnbrs, 'U', 1. ) ! Type 2: U-point
821	CASE(3)
822	CALL lbc_lnk( znnbrs, 'V', 1. ) ! Type 3: V-point
823	CASE(4)
824	CALL lbc_lnk( znnbrs, 'F', 1. ) ! Type 4: F-point
825	END SELECT
826
827	IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
828	DO jj = nlcj-ijpj+1, nlcj
829	ij = jj - nlcj + ijpj
830	DO ji = 1,jpi
831	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
832	& lrankset(INT(znnbrs(ji,jj))) = .true.
833	END DO
834	END DO
835
836	DO jj = 1,jpnij
837	IF ( lrankset(jj) ) THEN
838	nsndto(jtyp) = nsndto(jtyp) + 1
839	IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
840	CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
841	& ' jpmaxngh will need to be increased ')
842	ENDIF
843	isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank
844	ENDIF
845	END DO
846	ENDIF
847
848	END DO
849
850	!
851	! Type 5: I-point
852	!
853	! ICE point exchanges may involve some averaging. The neighbours list is
854	! built up using two exchanges to ensure that the whole stencil is covered.
855	! lrankset should not be reset between these 'J' and 'K' point exchanges
856
857	jtyp = 5
858	lrankset = .FALSE.
859	znnbrs = narea
860	CALL lbc_lnk( znnbrs, 'J', 1. ) ! first ice U-V point
861
862	IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
863	DO jj = nlcj-ijpj+1, nlcj
864	ij = jj - nlcj + ijpj
865	DO ji = 1,jpi
866	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
867	& lrankset(INT(znnbrs(ji,jj))) = .true.
868	END DO
869	END DO
870	ENDIF
871
872	znnbrs = narea
873	CALL lbc_lnk( znnbrs, 'K', 1. ) ! second ice U-V point
874
875	IF ( njmppt(narea) .EQ. MAXVAL( njmppt )) THEN
876	DO jj = nlcj-ijpj+1, nlcj
877	ij = jj - nlcj + ijpj
878	DO ji = 1,jpi
879	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
880	& lrankset( INT(znnbrs(ji,jj))) = .true.
881	END DO
882	END DO
883
884	DO jj = 1,jpnij
885	IF ( lrankset(jj) ) THEN
886	nsndto(jtyp) = nsndto(jtyp) + 1
887	IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
888	CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
889	& ' jpmaxngh will need to be increased ')
890	ENDIF
891	isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank
892	ENDIF
893	END DO
894	!
895	! For northern row areas, set l_north_nogather so that all subsequent exchanges
896	! can use peer to peer communications at the north fold
897	!
898	l_north_nogather = .TRUE.
899	!
900	ENDIF
901	DEALLOCATE( znnbrs )
902	DEALLOCATE( lrankset )
903
904	END SUBROUTINE nemo_northcomms
905	#else
906	SUBROUTINE nemo_northcomms ! Dummy routine
907	WRITE(,) 'nemo_northcomms: You should not have seen this print! error?'
908	END SUBROUTINE nemo_northcomms
909	#endif
910	!!======================================================================
911	END MODULE nemogcm

Note: See TracBrowser for help on using the repository browser.

Download in other formats: