New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in branches/2013/dev_r3853_CNRS9_ConfSetting/NEMOGCM/NEMO/SAS_SRC – NEMO

source: branches/2013/dev_r3853_CNRS9_ConfSetting/NEMOGCM/NEMO/SAS_SRC/nemogcm.F90 @ 3993

Last change on this file since 3993 was 3993, checked in by clevy, 11 years ago

Configuration setting/Step3 bugfixes,doc, and redistribute variables in namcfg and namdom see ticket:#1074

File size: 31.4 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!----------------------------------------------------------------------
32
33   !!----------------------------------------------------------------------
34   !!   nemo_gcm       : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
35   !!   nemo_init      : initialization of the NEMO system
36   !!   nemo_ctl       : initialisation of the contol print
37   !!   nemo_closefile : close remaining open files
38   !!   nemo_alloc     : dynamical allocation
39   !!   nemo_partition : calculate MPP domain decomposition
40   !!   factorise      : calculate the factors of the no. of MPI processes
41   !!----------------------------------------------------------------------
42   USE step_oce        ! module used in the ocean time stepping module
43   USE sbc_oce         ! surface boundary condition: ocean
44   USE cla             ! cross land advection               (tra_cla routine)
45   USE domcfg          ! domain configuration               (dom_cfg routine)
46   USE daymod          ! calendar
47   USE mppini          ! shared/distributed memory setting (mpp_init routine)
48   USE domain          ! domain initialization             (dom_init routine)
49   USE phycst          ! physical constant                  (par_cst routine)
50   USE step            ! NEMO time-stepping                 (stp     routine)
51   USE lib_mpp         ! distributed memory computing
52#if defined key_iomput
53   USE xios
54#endif
55   USE sbcssm
56
57   IMPLICIT NONE
58   PRIVATE
59
60   PUBLIC   nemo_gcm    ! called by model.F90
61   PUBLIC   nemo_init   ! needed by AGRIF
62
63   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
64
65   !!----------------------------------------------------------------------
66   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
67   !! $Id: nemogcm.F90 3294 2012-01-28 16:44:18Z rblod $
68   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
69   !!----------------------------------------------------------------------
70CONTAINS
71
72   SUBROUTINE nemo_gcm
73      !!----------------------------------------------------------------------
74      !!                     ***  ROUTINE nemo_gcm  ***
75      !!
76      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
77      !!              curvilinear mesh on the sphere.
78      !!
79      !! ** Method  : - model general initialization
80      !!              - launch the time-stepping (stp routine)
81      !!              - finalize the run by closing files and communications
82      !!
83      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
84      !!              Madec, 2008, internal report, IPSL.
85      !!----------------------------------------------------------------------
86      INTEGER ::   istp       ! time step index
87      !!----------------------------------------------------------------------
88      !
89#if defined key_agrif
90      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
91#endif
92
93      !                            !-----------------------!
94      CALL nemo_init               !==  Initialisations  ==!
95      !                            !-----------------------!
96#if defined key_agrif
97      CALL Agrif_Declare_Var       ! AGRIF: set the meshes
98#endif
99      ! check that all process are still there... If some process have an error,
100      ! they will never enter in step and other processes will wait until the end of the cpu time!
101      IF( lk_mpp )   CALL mpp_max( nstop )
102
103      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
104
105      !                            !-----------------------!
106      !                            !==   time stepping   ==!
107      !                            !-----------------------!
108      istp = nit000
109       
110      DO WHILE ( istp <= nitend .AND. nstop == 0 )
111#if defined key_agrif
112         CALL Agrif_Step( stp )           ! AGRIF: time stepping
113#else
114         CALL stp( istp )                 ! standard time stepping
115#endif
116         istp = istp + 1
117         IF( lk_mpp )   CALL mpp_max( nstop )
118      END DO
119      !                            !------------------------!
120      !                            !==  finalize the run  ==!
121      !                            !------------------------!
122      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
123      !
124      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
125         WRITE(numout,cform_err)
126         WRITE(numout,*) nstop, ' error have been found' 
127      ENDIF
128      !
129#if defined key_agrif
130      CALL Agrif_ParentGrid_To_ChildGrid()
131      IF( nn_timing == 1 )   CALL timing_finalize
132      CALL Agrif_ChildGrid_To_ParentGrid()
133#endif
134      IF( nn_timing == 1 )   CALL timing_finalize
135      !
136      CALL nemo_closefile
137#if defined key_iomput
138      CALL xios_finalize                ! end mpp communications with xios
139#else
140      IF( lk_mpp )   CALL mppstop       ! end mpp communications
141#endif
142      !
143   END SUBROUTINE nemo_gcm
144
145
146   SUBROUTINE nemo_init
147      !!----------------------------------------------------------------------
148      !!                     ***  ROUTINE nemo_init  ***
149      !!
150      !! ** Purpose :   initialization of the NEMO GCM
151      !!----------------------------------------------------------------------
152      INTEGER ::   ji            ! dummy loop indices
153      INTEGER ::   ilocal_comm   ! local integer     
154      INTEGER ::   ios
155
156      CHARACTER(len=80), DIMENSION(16) ::   cltxt
157      !!
158      NAMELIST/namctl/ ln_ctl  , nn_print, nn_ictls, nn_ictle,   &
159         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
160         &             nn_bench, nn_timing
161      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
162         &             jpizoom, jpjzoom, jperio
163      !!----------------------------------------------------------------------
164      !
165      cltxt = ''      !
166      !                             ! Open reference namelist and configuration namelist files
167      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
168      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
169      CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
170      !
171      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
172      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
173901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', lwp )
174
175      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
176      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
177902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', lwp )
178      WRITE( numond, namctl )
179      !
180      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
181      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
182903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', lwp )
183
184      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
185      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
186904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', lwp )   
187      WRITE( numond, namcfg )
188      !                             !--------------------------------------------!
189      !                             !  set communicator & select the local node  !
190      !                             !--------------------------------------------!
191#if defined key_iomput
192      IF( Agrif_Root() ) THEN
193         CALL  xios_initialize( "nemo",return_comm=ilocal_comm )
194      ENDIF
195      narea = mynode ( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )  ! Nodes selection
196#else
197      ilocal_comm = 0
198      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )        ! Nodes selection (control print return in cltxt)
199#endif
200      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
201
202      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
203
204      ! If dimensions of processor grid weren't specified in the namelist file
205      ! then we calculate them here now that we have our communicator size
206      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
207#if   defined key_mpp_mpi
208         IF( Agrif_Root() ) CALL nemo_partition(mppsize)
209#else
210         jpni  = 1
211         jpnj  = 1
212         jpnij = jpni*jpnj
213#endif
214      END IF
215
216      ! Calculate domain dimensions given calculated jpni and jpnj
217      ! This used to be done in par_oce.F90 when they were parameters rather
218      ! than variables
219      IF( Agrif_Root() ) THEN
220         jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
221#if defined key_nemocice_decomp
222         jpj = ( jpjglo+1-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim.
223#else
224         jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
225#endif
226         jpk = jpkdta                                             ! third dim
227         jpim1 = jpi-1                                            ! inner domain indices
228         jpjm1 = jpj-1                                            !   "           "
229         jpkm1 = jpk-1                                            !   "           "
230         jpij  = jpi*jpj                                          !  jpi x j
231      ENDIF
232
233      IF(lwp) THEN                            ! open listing units
234         !
235         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
236         !
237         WRITE(numout,*)
238         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
239         WRITE(numout,*) '                       NEMO team'
240         WRITE(numout,*) '            Ocean General Circulation Model'
241         WRITE(numout,*) '                  version 3.4  (2011) '
242         WRITE(numout,*) '             StandAlone Surface version (SAS) '
243         WRITE(numout,*)
244         WRITE(numout,*)
245         DO ji = 1, SIZE(cltxt) 
246            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
247         END DO
248         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
249         !
250      ENDIF
251
252      ! Now we know the dimensions of the grid and numout has been set we can
253      ! allocate arrays
254      CALL nemo_alloc()
255
256      !                             !-------------------------------!
257      !                             !  NEMO general initialization  !
258      !                             !-------------------------------!
259
260      CALL nemo_ctl                          ! Control prints & Benchmark
261
262      !                                      ! Domain decomposition
263      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
264      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
265      ENDIF
266      !
267      IF( nn_timing == 1 )  CALL timing_init
268      !
269      !                                     ! General initialization
270                            CALL phy_cst    ! Physical constants
271                            CALL eos_init   ! Equation of state
272                            CALL dom_cfg    ! Domain configuration
273                            CALL dom_init   ! Domain
274
275      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
276
277      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
278                            CALL flush(numout)
279
280                            CALL day_init   ! model calendar (using both namelist and restart infos)
281
282                            CALL sbc_init   ! Forcings : surface module
283     
284      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
285      !
286   END SUBROUTINE nemo_init
287
288
289   SUBROUTINE nemo_ctl
290      !!----------------------------------------------------------------------
291      !!                     ***  ROUTINE nemo_ctl  ***
292      !!
293      !! ** Purpose :   control print setting
294      !!
295      !! ** Method  : - print namctl information and check some consistencies
296      !!----------------------------------------------------------------------
297      !
298      IF(lwp) THEN                  ! control print
299         WRITE(numout,*)
300         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
301         WRITE(numout,*) '~~~~~~~ '
302         WRITE(numout,*) '   Namelist namctl'
303         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
304         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
305         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
306         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
307         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
308         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
309         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
310         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
311         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
312      ENDIF
313      !
314      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
315      nictls    = nn_ictls
316      nictle    = nn_ictle
317      njctls    = nn_jctls
318      njctle    = nn_jctle
319      isplt     = nn_isplt
320      jsplt     = nn_jsplt
321      nbench    = nn_bench
322
323      IF(lwp) THEN                  ! control print
324         WRITE(numout,*)
325         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
326         WRITE(numout,*) '~~~~~~~ '
327         WRITE(numout,*) '   Namelist namcfg'
328         WRITE(numout,*) '      configuration name              cp_cfg      = ', TRIM(cp_cfg)
329         WRITE(numout,*) '      configuration zoom name         cp_cfz      = ', TRIM(cp_cfz)
330         WRITE(numout,*) '      configuration resolution        jp_cfg      = ', jp_cfg
331         WRITE(numout,*) '      1st lateral dimension ( >= jpi ) jpidta     = ', jpidta
332         WRITE(numout,*) '      2nd    "         "    ( >= jpj ) jpjdta     = ', jpjdta
333         WRITE(numout,*) '      3nd    "         "               jpkdta     = ', jpkdta
334         WRITE(numout,*) '      1st dimension of global domain in i jpiglo  = ', jpiglo
335         WRITE(numout,*) '      2nd    -                  -    in j jpjglo  = ', jpjglo
336         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
337         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
338         WRITE(numout,*) '      lateral cond. type (between 0 and 6) jperio = ', jperio   
339      ENDIF
340      !                             ! Parameter control
341      !
342      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
343         IF( lk_mpp .AND. jpnij > 1 ) THEN
344            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
345         ELSE
346            IF( isplt == 1 .AND. jsplt == 1  ) THEN
347               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
348                  &           ' - the print control will be done over the whole domain' )
349            ENDIF
350            ijsplt = isplt * jsplt            ! total number of processors ijsplt
351         ENDIF
352         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
353         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
354         !
355         !                              ! indices used for the SUM control
356         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
357            lsp_area = .FALSE.                       
358         ELSE                                             ! print control done over a specific  area
359            lsp_area = .TRUE.
360            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
361               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
362               nictls = 1
363            ENDIF
364            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
365               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
366               nictle = jpiglo
367            ENDIF
368            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
369               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
370               njctls = 1
371            ENDIF
372            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
373               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
374               njctle = jpjglo
375            ENDIF
376         ENDIF
377      ENDIF
378      !
379      IF( nbench == 1 ) THEN              ! Benchmark
380         SELECT CASE ( cp_cfg )
381         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
382         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
383            &                                 ' cp_cfg="gyre" in namelist &namcfg or set nbench = 0' )
384         END SELECT
385      ENDIF
386      !
387   END SUBROUTINE nemo_ctl
388
389
390   SUBROUTINE nemo_closefile
391      !!----------------------------------------------------------------------
392      !!                     ***  ROUTINE nemo_closefile  ***
393      !!
394      !! ** Purpose :   Close the files
395      !!----------------------------------------------------------------------
396      !
397      IF( lk_mpp )   CALL mppsync
398      !
399      CALL iom_close                                 ! close all input/output files managed by iom_*
400      !
401      IF( numstp          /= -1 )   CLOSE( numstp      )   ! time-step file     
402      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
403      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
404      IF( numond          /= -1 )   CLOSE( numond          )   ! oce output namelist
405      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
406      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
407      IF( numoni          /= -1 )   CLOSE( numoni          )   ! ice output namelist
408      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice  )   ! ice variables (temp. evolution)
409      IF( numout          /=  6 )   CLOSE( numout      )   ! standard model output file
410      !
411      numout = 6                                     ! redefine numout in case it is used after this point...
412      !
413   END SUBROUTINE nemo_closefile
414
415
416   SUBROUTINE nemo_alloc
417      !!----------------------------------------------------------------------
418      !!                     ***  ROUTINE nemo_alloc  ***
419      !!
420      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
421      !!
422      !! ** Method  :
423      !!----------------------------------------------------------------------
424      USE diawri    , ONLY: dia_wri_alloc
425      USE dom_oce   , ONLY: dom_oce_alloc
426      USE oce       , ONLY : sshn, sshb, snwice_mass, snwice_mass_b, snwice_fmass 
427      !
428      INTEGER :: ierr,ierr4
429      !!----------------------------------------------------------------------
430      !
431      ierr =        dia_wri_alloc   ()
432      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
433      ierr = ierr + lib_mpp_alloc   (numout)    ! mpp exchanges
434      ALLOCATE( snwice_mass(jpi,jpj)  , snwice_mass_b(jpi,jpj),             &
435         &      snwice_fmass(jpi,jpj), STAT= ierr4 )
436      ierr = ierr + ierr4
437      !
438      IF( lk_mpp    )   CALL mpp_sum( ierr )
439      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
440      !
441   END SUBROUTINE nemo_alloc
442
443
444   SUBROUTINE nemo_partition( num_pes )
445      !!----------------------------------------------------------------------
446      !!                 ***  ROUTINE nemo_partition  ***
447      !!
448      !! ** Purpose :   
449      !!
450      !! ** Method  :
451      !!----------------------------------------------------------------------
452      INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
453      !
454      INTEGER, PARAMETER :: nfactmax = 20
455      INTEGER :: nfact ! The no. of factors returned
456      INTEGER :: ierr  ! Error flag
457      INTEGER :: ji
458      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
459      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
460      !!----------------------------------------------------------------------
461
462      ierr = 0
463
464      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
465
466      IF( nfact <= 1 ) THEN
467         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
468         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
469         jpnj = 1
470         jpni = num_pes
471      ELSE
472         ! Search through factors for the pair that are closest in value
473         mindiff = 1000000
474         imin    = 1
475         DO ji = 1, nfact-1, 2
476            idiff = ABS( ifact(ji) - ifact(ji+1) )
477            IF( idiff < mindiff ) THEN
478               mindiff = idiff
479               imin = ji
480            ENDIF
481         END DO
482         jpnj = ifact(imin)
483         jpni = ifact(imin + 1)
484      ENDIF
485      !
486      jpnij = jpni*jpnj
487      !
488   END SUBROUTINE nemo_partition
489
490
491   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
492      !!----------------------------------------------------------------------
493      !!                     ***  ROUTINE factorise  ***
494      !!
495      !! ** Purpose :   return the prime factors of n.
496      !!                knfax factors are returned in array kfax which is of
497      !!                maximum dimension kmaxfax.
498      !! ** Method  :
499      !!----------------------------------------------------------------------
500      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
501      INTEGER                    , INTENT(  out) ::   kerr, knfax
502      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
503      !
504      INTEGER :: ifac, jl, inu
505      INTEGER, PARAMETER :: ntest = 14
506      INTEGER :: ilfax(ntest)
507
508      ! lfax contains the set of allowed factors.
509      data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256,  &
510         &                            128,   64,   32,   16,    8,   4,   2  /
511      !!----------------------------------------------------------------------
512
513      ! Clear the error flag and initialise output vars
514      kerr = 0
515      kfax = 1
516      knfax = 0
517
518      ! Find the factors of n.
519      IF( kn == 1 )   GOTO 20
520
521      ! nu holds the unfactorised part of the number.
522      ! knfax holds the number of factors found.
523      ! l points to the allowed factor list.
524      ! ifac holds the current factor.
525
526      inu   = kn
527      knfax = 0
528
529      DO jl = ntest, 1, -1
530         !
531         ifac = ilfax(jl)
532         IF( ifac > inu )   CYCLE
533
534         ! Test whether the factor will divide.
535
536         IF( MOD(inu,ifac) == 0 ) THEN
537            !
538            knfax = knfax + 1            ! Add the factor to the list
539            IF( knfax > kmaxfax ) THEN
540               kerr = 6
541               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
542               return
543            ENDIF
544            kfax(knfax) = ifac
545            ! Store the other factor that goes with this one
546            knfax = knfax + 1
547            kfax(knfax) = inu / ifac
548            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
549         ENDIF
550         !
551      END DO
552
553   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
554      !
555   END SUBROUTINE factorise
556
557#if defined key_mpp_mpi
558   SUBROUTINE nemo_northcomms
559      !!======================================================================
560      !!                     ***  ROUTINE  nemo_northcomms  ***
561      !! nemo_northcomms    :  Setup for north fold exchanges with explicit peer to peer messaging
562      !!=====================================================================
563      !!----------------------------------------------------------------------
564      !!
565      !! ** Purpose :   Initialization of the northern neighbours lists.
566      !!----------------------------------------------------------------------
567      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
568      !!----------------------------------------------------------------------
569
570      INTEGER ::   ji, jj, jk, ij, jtyp    ! dummy loop indices
571      INTEGER ::   ijpj                    ! number of rows involved in north-fold exchange
572      INTEGER ::   northcomms_alloc        ! allocate return status
573      REAL(wp), ALLOCATABLE, DIMENSION ( :,: ) ::   znnbrs     ! workspace
574      LOGICAL,  ALLOCATABLE, DIMENSION ( : )   ::   lrankset   ! workspace
575
576      IF(lwp) WRITE(numout,*)
577      IF(lwp) WRITE(numout,*) 'nemo_northcomms : Initialization of the northern neighbours lists'
578      IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
579
580      !!----------------------------------------------------------------------
581      ALLOCATE( znnbrs(jpi,jpj), stat = northcomms_alloc )
582      ALLOCATE( lrankset(jpnij), stat = northcomms_alloc )
583      IF( northcomms_alloc /= 0 ) THEN
584         WRITE(numout,cform_war)
585         WRITE(numout,*) 'northcomms_alloc : failed to allocate arrays'
586         CALL ctl_stop( 'STOP', 'nemo_northcomms : unable to allocate temporary arrays' )
587      ENDIF
588      nsndto = 0
589      isendto = -1
590      ijpj   = 4
591      !
592      ! This routine has been called because ln_nnogather has been set true ( nammpp )
593      ! However, these first few exchanges have to use the mpi_allgather method to
594      ! establish the neighbour lists to use in subsequent peer to peer exchanges.
595      ! Consequently, set l_north_nogather to be false here and set it true only after
596      ! the lists have been established.
597      !
598      l_north_nogather = .FALSE.
599      !
600      ! Exchange and store ranks on northern rows
601
602      DO jtyp = 1,4
603
604         lrankset = .FALSE.
605         znnbrs = narea
606         SELECT CASE (jtyp)
607            CASE(1)
608               CALL lbc_lnk( znnbrs, 'T', 1. )      ! Type 1: T,W-points
609            CASE(2)
610               CALL lbc_lnk( znnbrs, 'U', 1. )      ! Type 2: U-point
611            CASE(3)
612               CALL lbc_lnk( znnbrs, 'V', 1. )      ! Type 3: V-point
613            CASE(4)
614               CALL lbc_lnk( znnbrs, 'F', 1. )      ! Type 4: F-point
615         END SELECT
616
617         IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
618            DO jj = nlcj-ijpj+1, nlcj
619               ij = jj - nlcj + ijpj
620               DO ji = 1,jpi
621                  IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
622               &     lrankset(INT(znnbrs(ji,jj))) = .true.
623               END DO
624            END DO
625
626            DO jj = 1,jpnij
627               IF ( lrankset(jj) ) THEN
628                  nsndto(jtyp) = nsndto(jtyp) + 1
629                  IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
630                     CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
631                  &                 ' jpmaxngh will need to be increased ')
632                  ENDIF
633                  isendto(nsndto(jtyp),jtyp) = jj-1   ! narea converted to MPI rank
634               ENDIF
635            END DO
636         ENDIF
637
638      END DO
639
640      !
641      ! Type 5: I-point
642      !
643      ! ICE point exchanges may involve some averaging. The neighbours list is
644      ! built up using two exchanges to ensure that the whole stencil is covered.
645      ! lrankset should not be reset between these 'J' and 'K' point exchanges
646
647      jtyp = 5
648      lrankset = .FALSE.
649      znnbrs = narea 
650      CALL lbc_lnk( znnbrs, 'J', 1. ) ! first ice U-V point
651
652      IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
653         DO jj = nlcj-ijpj+1, nlcj
654            ij = jj - nlcj + ijpj
655            DO ji = 1,jpi
656               IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
657            &     lrankset(INT(znnbrs(ji,jj))) = .true.
658         END DO
659        END DO
660      ENDIF
661
662      znnbrs = narea 
663      CALL lbc_lnk( znnbrs, 'K', 1. ) ! second ice U-V point
664
665      IF ( njmppt(narea) .EQ. MAXVAL( njmppt )) THEN
666         DO jj = nlcj-ijpj+1, nlcj
667            ij = jj - nlcj + ijpj
668            DO ji = 1,jpi
669               IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND.  INT(znnbrs(ji,jj)) .NE. narea ) &
670            &       lrankset( INT(znnbrs(ji,jj))) = .true.
671            END DO
672         END DO
673
674         DO jj = 1,jpnij
675            IF ( lrankset(jj) ) THEN
676               nsndto(jtyp) = nsndto(jtyp) + 1
677               IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
678                  CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
679               &                 ' jpmaxngh will need to be increased ')
680               ENDIF
681               isendto(nsndto(jtyp),jtyp) = jj-1   ! narea converted to MPI rank
682            ENDIF
683         END DO
684         !
685         ! For northern row areas, set l_north_nogather so that all subsequent exchanges
686         ! can use peer to peer communications at the north fold
687         !
688         l_north_nogather = .TRUE.
689         !
690      ENDIF
691      DEALLOCATE( znnbrs )
692      DEALLOCATE( lrankset )
693
694   END SUBROUTINE nemo_northcomms
695#else
696   SUBROUTINE nemo_northcomms      ! Dummy routine
697      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
698   END SUBROUTINE nemo_northcomms
699#endif
700   !!======================================================================
701END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.