New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsbc.F90 in branches/2013/dev_r3853_CNRS9_ConfSetting/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2013/dev_r3853_CNRS9_ConfSetting/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zsbc.F90 @ 3875

Last change on this file since 3875 was 3875, checked in by clevy, 11 years ago

Configuration Setting/Step? 1, see ticket:#1074
File size: 28.1 KB
Line 
1MODULE p4zsbc
2   !!======================================================================
3   !!                         ***  MODULE p4sbc  ***
4   !! TOP :   PISCES surface boundary conditions of external inputs of nutrients
5   !!======================================================================
6   !! History :   3.5  !  2012-07 (O. Aumont, C. Ethe) Original code
7   !!----------------------------------------------------------------------
8#if defined key_pisces
9   !!----------------------------------------------------------------------
10   !!   'key_pisces'                                       PISCES bio-model
11   !!----------------------------------------------------------------------
12   !!   p4z_sbc        :  Read and interpolate time-varying nutrients fluxes
13   !!   p4z_sbc_init   :  Initialization of p4z_sbc
14   !!----------------------------------------------------------------------
15   USE oce_trc         !  shared variables between ocean and passive tracers
16   USE trc             !  passive tracers common variables
17   USE sms_pisces      !  PISCES Source Minus Sink variables
18   USE iom             !  I/O manager
19   USE fldread         !  time interpolation
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   p4z_sbc
25   PUBLIC   p4z_sbc_init   
26
27   !! * Shared module variables
28   LOGICAL , PUBLIC  :: ln_dust     = .FALSE.    !: boolean for dust input from the atmosphere
29   LOGICAL , PUBLIC  :: ln_solub    = .FALSE.    !: boolean for variable solubility of atmospheric iron
30   LOGICAL , PUBLIC  :: ln_river    = .FALSE.    !: boolean for river input of nutrients
31   LOGICAL , PUBLIC  :: ln_ndepo    = .FALSE.    !: boolean for atmospheric deposition of N
32   LOGICAL , PUBLIC  :: ln_ironsed  = .FALSE.    !: boolean for Fe input from sediments
33   LOGICAL , PUBLIC  :: ln_hydrofe  = .FALSE.    !: boolean for Fe input from hydrothermal vents
34   LOGICAL , PUBLIC  :: ln_ironice  = .FALSE.    !: boolean for Fe input from sea ice
35   REAL(wp), PUBLIC  :: sedfeinput  = 1.E-9_wp   !: Coastal release of Iron
36   REAL(wp), PUBLIC  :: dustsolub   = 0.014_wp   !: Solubility of the dust
37   REAL(wp), PUBLIC  :: icefeinput  = 10E-9_wp   !: Iron concentration in sea ice
38   REAL(wp), PUBLIC  :: wdust       = 2.0_wp     !: Sinking speed of the dust
39   REAL(wp), PUBLIC  :: nitrfix     = 1E-7_wp    !: Nitrogen fixation rate   
40   REAL(wp), PUBLIC  :: diazolight  = 50._wp     !: Nitrogen fixation sensitivty to light
41   REAL(wp), PUBLIC  :: concfediaz  = 1.E-10_wp  !: Fe half-saturation Cste for diazotrophs
42   REAL(wp)          :: hratio      = 9.E-5_wp   !: Fe:3He ratio assumed for vent iron supply
43
44   LOGICAL , PUBLIC  :: ll_sbc
45
46   !! * Module variables
47   LOGICAL  ::  ll_solub
48
49   INTEGER , PARAMETER  :: jpriv  = 7   !: Maximum number of river input fields
50   INTEGER , PARAMETER  :: jr_dic = 1   !: index of dissolved inorganic carbon
51   INTEGER , PARAMETER  :: jr_doc = 2   !: index of dissolved organic carbon
52   INTEGER , PARAMETER  :: jr_din = 3   !: index of dissolved inorganic nitrogen
53   INTEGER , PARAMETER  :: jr_don = 4   !: index of dissolved organic nitrogen
54   INTEGER , PARAMETER  :: jr_dip = 5   !: index of dissolved inorganic phosporus
55   INTEGER , PARAMETER  :: jr_dop = 6   !: index of dissolved organic phosphorus
56   INTEGER , PARAMETER  :: jr_dsi = 7   !: index of dissolved silicate
57
58
59   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_dust      ! structure of input dust
60   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_solub      ! structure of input dust
61   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_river  ! structure of input riverdic
62   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_ndepo     ! structure of input nitrogen deposition
63   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_ironsed   ! structure of input iron from sediment
64   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_hydrofe   ! structure of input iron from hydrothermal vents
65
66   INTEGER , PARAMETER :: nbtimes = 365  !: maximum number of times record in a file
67   INTEGER  :: ntimes_dust, ntimes_riv, ntimes_ndep       ! number of time steps in a file
68   INTEGER  :: ntimes_solub, ntimes_hydro                 ! number of time steps in a file
69
70   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: dust, solub       !: dust fields
71   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdic, rivalk    !: river input fields
72   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdin, rivdip    !: river input fields
73   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdsi    !: river input fields
74   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: nitdep    !: atmospheric N deposition
75   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: ironsed   !: Coastal supply of iron
76   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: hydrofe   !: Hydrothermal vent supply of iron
77
78   REAL(wp), PUBLIC :: sumdepsi, rivalkinput, rivdicinput, nitdepinput
79   REAL(wp), PUBLIC :: rivdininput, rivdipinput, rivdsiinput
80
81   REAL(wp) :: ryyss                    !: number of seconds per year
82
83   !!* Substitution
84#  include "top_substitute.h90"
85   !!----------------------------------------------------------------------
86   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
87   !! $Header:$
88   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
89   !!----------------------------------------------------------------------
90
91CONTAINS
92
93   SUBROUTINE p4z_sbc( kt )
94      !!----------------------------------------------------------------------
95      !!                  ***  routine p4z_sbc  ***
96      !!
97      !! ** purpose :   read and interpolate the external sources of nutrients
98      !!
99      !! ** method  :   read the files and interpolate the appropriate variables
100      !!
101      !! ** input   :   external netcdf files
102      !!
103      !!----------------------------------------------------------------------
104      !! * arguments
105      INTEGER, INTENT( in  ) ::   kt   ! ocean time step
106
107      !! * local declarations
108      INTEGER  :: ji,jj 
109      REAL(wp) :: zcoef, zyyss
110      !!---------------------------------------------------------------------
111      !
112      IF( nn_timing == 1 )  CALL timing_start('p4z_sbc')
113
114      !
115      ! Compute dust at nit000 or only if there is more than 1 time record in dust file
116      IF( ln_dust ) THEN
117         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_dust > 1 ) ) THEN
118            CALL fld_read( kt, 1, sf_dust )
119            dust(:,:) = sf_dust(1)%fnow(:,:,1)
120         ENDIF
121      ENDIF
122
123      IF( ll_solub ) THEN
124         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_solub > 1 ) ) THEN
125            CALL fld_read( kt, 1, sf_solub )
126            solub(:,:) = sf_solub(1)%fnow(:,:,1)
127         ENDIF
128      ENDIF
129
130      ! N/P and Si releases due to coastal rivers
131      ! Compute river at nit000 or only if there is more than 1 time record in river file
132      ! -----------------------------------------
133      IF( ln_river ) THEN
134         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_riv > 1 ) ) THEN
135            CALL fld_read( kt, 1, sf_river )
136            DO jj = 1, jpj
137               DO ji = 1, jpi
138                  zcoef = ryyss * cvol(ji,jj,1) 
139                  rivalk(ji,jj) =   sf_river(jr_dic)%fnow(ji,jj,1)                                    &
140                     &              * 1.E3        / ( 12. * zcoef + rtrn )
141                  rivdic(ji,jj) = ( sf_river(jr_dic)%fnow(ji,jj,1) + sf_river(jr_doc)%fnow(ji,jj,1) ) &
142                     &              * 1.E3         / ( 12. * zcoef + rtrn )
143                  rivdin(ji,jj) = ( sf_river(jr_din)%fnow(ji,jj,1) + sf_river(jr_don)%fnow(ji,jj,1) ) &
144                     &              * 1.E3 / rno3 / ( 14. * zcoef + rtrn )
145                  rivdip(ji,jj) = ( sf_river(jr_dip)%fnow(ji,jj,1) + sf_river(jr_dop)%fnow(ji,jj,1) ) &
146                     &              * 1.E3 / po4r / ( 31. * zcoef + rtrn )
147                  rivdsi(ji,jj) =   sf_river(jr_dsi)%fnow(ji,jj,1)                                    &
148                     &              * 1.E3        / ( 28.1 * zcoef + rtrn )
149               END DO
150            END DO
151         ENDIF
152      ENDIF
153
154      ! Compute N deposition at nit000 or only if there is more than 1 time record in N deposition file
155      IF( ln_ndepo ) THEN
156         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_ndep > 1 ) ) THEN
157            CALL fld_read( kt, 1, sf_ndepo )
158            DO jj = 1, jpj
159               DO ji = 1, jpi
160                  nitdep(ji,jj) = sf_ndepo(1)%fnow(ji,jj,1) / rno3 / ( 14E6 * ryyss * fse3t(ji,jj,1) + rtrn )
161               END DO
162            END DO
163         ENDIF
164      ENDIF
165      !
166      IF( nn_timing == 1 )  CALL timing_stop('p4z_sbc')
167      !
168   END SUBROUTINE p4z_sbc
169
170   SUBROUTINE p4z_sbc_init
171
172      !!----------------------------------------------------------------------
173      !!                  ***  routine p4z_sbc_init  ***
174      !!
175      !! ** purpose :   initialization of the external sources of nutrients
176      !!
177      !! ** method  :   read the files and compute the budget
178      !!                called at the first timestep (nittrc000)
179      !!
180      !! ** input   :   external netcdf files
181      !!
182      !!----------------------------------------------------------------------
183      !
184      INTEGER  :: ji, jj, jk, jm, ifpr
185      INTEGER  :: ii0, ii1, ij0, ij1
186      INTEGER  :: numdust, numsolub, numriv, numiron, numdepo, numhydro
187      INTEGER  :: ierr, ierr1, ierr2, ierr3
188      INTEGER  :: ios                 ! Local integer output status for namelist read
189      REAL(wp) :: zexpide, zdenitide, zmaskt
190      REAL(wp) :: ztimes_dust, ztimes_riv, ztimes_ndep 
191      REAL(wp), DIMENSION(nbtimes) :: zsteps                 ! times records
192      REAL(wp), DIMENSION(:), ALLOCATABLE :: rivinput
193      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zdust, zndepo, zriver, zcmask
194      !
195      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
196      TYPE(FLD_N), DIMENSION(jpriv) ::  slf_river    ! array of namelist informations on the fields to read
197      TYPE(FLD_N) ::   sn_dust, sn_solub, sn_ndepo, sn_ironsed, sn_hydrofe   ! informations about the fields to be read
198      TYPE(FLD_N) ::   sn_riverdoc, sn_riverdic, sn_riverdsi   ! informations about the fields to be read
199      TYPE(FLD_N) ::   sn_riverdin, sn_riverdon, sn_riverdip, sn_riverdop
200      !
201      NAMELIST/nampissbc/cn_dir, sn_dust, sn_solub, sn_riverdic, sn_riverdoc, sn_riverdin, sn_riverdon,     &
202        &                sn_riverdip, sn_riverdop, sn_riverdsi, sn_ndepo, sn_ironsed, sn_hydrofe, &
203        &                ln_dust, ln_solub, ln_river, ln_ndepo, ln_ironsed, ln_ironice, ln_hydrofe,    &
204        &                sedfeinput, dustsolub, icefeinput, wdust, nitrfix, diazolight, concfediaz, hratio
205      !!----------------------------------------------------------------------
206      !
207      IF( nn_timing == 1 )  CALL timing_start('p4z_sbc_init')
208      !
209      ryyss   = nyear_len(1) * rday    ! number of seconds per year and per month
210      !
211      !                            !* set file information
212      cn_dir  = './'            ! directory in which the model is executed
213      ! ... default values (NB: frequency positive => hours, negative => months)
214      !                  !   file       ! frequency !  variable   ! time intep !  clim   ! 'yearly' or ! weights  ! rotation   !
215      !                  !   name       !  (hours)  !   name      !   (T/F)    !  (T/F)  !  'monthly'  ! filename ! pairs      !
216      sn_dust     = FLD_N( 'dust'       ,    -1     ,  'dust'     ,  .true.    , .true.  ,   'yearly'  , ''       , ''         )
217      sn_solub    = FLD_N( 'solubility' ,    -12    ,  'solub'    ,  .true.    , .true.  ,   'yearly'  , ''       , ''         )
218      sn_riverdic = FLD_N( 'river'      ,   -12     ,  'riverdic' ,  .false.   , .true.  ,   'yearly'  , ''       , ''         )
219      sn_riverdoc = FLD_N( 'river'      ,   -12     ,  'riverdoc' ,  .false.   , .true.  ,   'yearly'  , ''       , ''         )
220      sn_riverdin = FLD_N( 'river'      ,   -12     ,  'riverdin' ,  .false.   , .true.  ,   'yearly'  , ''       , ''         )
221      sn_riverdon = FLD_N( 'river'      ,   -12     ,  'riverdon' ,  .false.   , .true.  ,   'yearly'  , ''       , ''         )
222      sn_riverdip = FLD_N( 'river'      ,   -12     ,  'riverdip' ,  .false.   , .true.  ,   'yearly'  , ''       , ''         )
223      sn_riverdop = FLD_N( 'river'      ,   -12     ,  'riverdop' ,  .false.   , .true.  ,   'yearly'  , ''       , ''         )
224      sn_riverdsi = FLD_N( 'river'      ,   -12     ,  'riverdsi' ,  .false.   , .true.  ,   'yearly'  , ''       , ''         )
225      sn_ndepo    = FLD_N( 'ndeposition',   -12     ,  'ndep'     ,  .false.   , .true.  ,   'yearly'  , ''       , ''         )
226      sn_ironsed  = FLD_N( 'ironsed'    ,   -12     ,  'bathy'    ,  .false.   , .true.  ,   'yearly'  , ''       , ''         )
227      sn_hydrofe  = FLD_N( 'hydrofe'    ,   -12     ,  'hydro'    ,  .false.   , .true.  ,   'yearly'  , ''       , ''         )
228
229      REWIND( numnatp_ref )              ! Namelist nampissbc in reference namelist : Pisces external sources of nutrients
230      READ  ( numnatp_ref, nampissbc, IOSTAT = ios, ERR = 901)
231901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampissbc in reference namelist', lwp )
232
233      REWIND( numnatp_cfg )              ! Namelist nampissbc in configuration namelist : Pisces external sources of nutrients
234      READ  ( numnatp_cfg, nampissbc, IOSTAT = ios, ERR = 902 )
235902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampissbc in configuration namelist', lwp )
236      WRITE ( numonp, nampissbc )
237
238      IF(lwp) THEN
239         WRITE(numout,*) ' '
240         WRITE(numout,*) ' namelist : nampissbc '
241         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~ '
242         WRITE(numout,*) '    dust input from the atmosphere           ln_dust     = ', ln_dust
243         WRITE(numout,*) '    Variable solubility of iron input        ln_solub    = ', ln_solub
244         WRITE(numout,*) '    river input of nutrients                 ln_river    = ', ln_river
245         WRITE(numout,*) '    atmospheric deposition of n              ln_ndepo    = ', ln_ndepo
246         WRITE(numout,*) '    Fe input from sediments                  ln_ironsed  = ', ln_ironsed
247         WRITE(numout,*) '    Fe input from seaice                     ln_ironice  = ', ln_ironice
248         WRITE(numout,*) '    fe input from hydrothermal vents         ln_hydrofe  = ', ln_hydrofe
249         WRITE(numout,*) '    coastal release of iron                  sedfeinput  = ', sedfeinput
250         WRITE(numout,*) '    solubility of the dust                   dustsolub   = ', dustsolub
251         WRITE(numout,*) '    Iron concentration in sea ice            icefeinput  = ', icefeinput
252         WRITE(numout,*) '    sinking speed of the dust                wdust       = ', wdust
253         WRITE(numout,*) '    nitrogen fixation rate                   nitrfix     = ', nitrfix
254         WRITE(numout,*) '    nitrogen fixation sensitivty to light    diazolight  = ', diazolight
255         WRITE(numout,*) '    fe half-saturation cste for diazotrophs  concfediaz  = ', concfediaz
256         WRITE(numout,*) '    Fe to 3He ratio assumed for vent iron supply hratio  = ', hratio
257      END IF
258
259      IF( ln_dust .OR. ln_river .OR. ln_ndepo ) THEN  ;  ll_sbc = .TRUE.
260      ELSE                                            ;  ll_sbc = .FALSE.
261      ENDIF
262
263      IF( ln_dust .AND. ln_solub ) THEN               ;  ll_solub = .TRUE.
264      ELSE                                            ;  ll_solub = .FALSE.
265      ENDIF
266
267      ! dust input from the atmosphere
268      ! ------------------------------
269      IF( ln_dust ) THEN 
270         !
271         IF(lwp) WRITE(numout,*) '    initialize dust input from atmosphere '
272         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ '
273         !
274         ALLOCATE( dust(jpi,jpj) )    ! allocation
275         !
276         ALLOCATE( sf_dust(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
277         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_dust structure' )
278         !
279         CALL fld_fill( sf_dust, (/ sn_dust /), cn_dir, 'p4z_sed_init', 'Atmospheric dust deposition', 'nampissed' )
280                                   ALLOCATE( sf_dust(1)%fnow(jpi,jpj,1)   )
281         IF( sn_dust%ln_tint )     ALLOCATE( sf_dust(1)%fdta(jpi,jpj,1,2) )
282         !
283         IF( Agrif_Root() ) THEN   !  Only on the master grid
284            ! Get total input dust ; need to compute total atmospheric supply of Si in a year
285            CALL iom_open (  TRIM( sn_dust%clname ) , numdust )
286            CALL iom_gettime( numdust, zsteps, kntime=ntimes_dust)  ! get number of record in file
287            ALLOCATE( zdust(jpi,jpj,ntimes_dust) )
288            DO jm = 1, ntimes_dust
289               CALL iom_get( numdust, jpdom_data, TRIM( sn_dust%clvar ), zdust(:,:,jm), jm )
290            END DO
291            CALL iom_close( numdust )
292            ztimes_dust = 1._wp / FLOAT( ntimes_dust ) 
293            sumdepsi = 0.e0
294            DO jm = 1, ntimes_dust
295               sumdepsi = sumdepsi + glob_sum( zdust(:,:,jm) * e1e2t(:,:) * tmask(:,:,1) * ztimes_dust )
296            ENDDO
297            sumdepsi = sumdepsi / ( nyear_len(1) * rday ) * 12. * 8.8 * 0.075 / 28.1 
298            DEALLOCATE( zdust)
299         ENDIF
300      ELSE
301         sumdepsi  = 0._wp
302      END IF
303
304      ! Solubility of dust deposition of iron
305      ! Only if ln_dust and ln_solubility set to true (ll_solub = .true.)
306      ! -----------------------------------------------------------------
307      IF( ll_solub ) THEN
308         !
309         IF(lwp) WRITE(numout,*) '    initialize variable solubility of Fe '
310         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ '
311         !
312         ALLOCATE( solub(jpi,jpj) )    ! allocation
313         !
314         ALLOCATE( sf_solub(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
315         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_solub structure' )
316         !
317         CALL fld_fill( sf_solub, (/ sn_solub /), cn_dir, 'p4z_sed_init', 'Solubility of atm. iron ', 'nampissed' )
318                                   ALLOCATE( sf_solub(1)%fnow(jpi,jpj,1)   )
319         IF( sn_solub%ln_tint )    ALLOCATE( sf_solub(1)%fdta(jpi,jpj,1,2) )
320         ! get number of record in file
321         CALL iom_open (  TRIM( sn_solub%clname ) , numsolub )
322         CALL iom_gettime( numsolub, zsteps, kntime=ntimes_solub)  ! get number of record in file
323         CALL iom_close( numsolub )
324      ENDIF
325
326      ! nutrient input from rivers
327      ! --------------------------
328      IF( ln_river ) THEN
329         !
330         slf_river(jr_dic) = sn_riverdic  ;  slf_river(jr_doc) = sn_riverdoc  ;  slf_river(jr_din) = sn_riverdin 
331         slf_river(jr_don) = sn_riverdon  ;  slf_river(jr_dip) = sn_riverdip  ;  slf_river(jr_dop) = sn_riverdop
332         slf_river(jr_dsi) = sn_riverdsi 
333         !
334         ALLOCATE( rivdic(jpi,jpj), rivalk(jpi,jpj), rivdin(jpi,jpj), rivdip(jpi,jpj), rivdsi(jpi,jpj) ) 
335         !
336         ALLOCATE( sf_river(jpriv), rivinput(jpriv), STAT=ierr1 )           !* allocate and fill sf_river (forcing structure) with sn_river_
337         rivinput(:) = 0.0
338
339         IF( ierr1 > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_irver structure' )
340         !
341         CALL fld_fill( sf_river, slf_river, cn_dir, 'p4z_sed_init', 'Input from river ', 'nampissed' )
342         DO ifpr = 1, jpriv
343                                          ALLOCATE( sf_river(ifpr)%fnow(jpi,jpj,1  ) )
344            IF( slf_river(ifpr)%ln_tint ) ALLOCATE( sf_river(ifpr)%fdta(jpi,jpj,1,2) )
345         END DO
346         IF( Agrif_Root() ) THEN   !  Only on the master grid
347            ! Get total input rivers ; need to compute total river supply in a year
348            DO ifpr = 1, jpriv
349               CALL iom_open ( TRIM( slf_river(ifpr)%clname ), numriv )
350               CALL iom_gettime( numriv, zsteps, kntime=ntimes_riv)
351               ALLOCATE( zriver(jpi,jpj,ntimes_riv) )
352               DO jm = 1, ntimes_riv
353                  CALL iom_get( numriv, jpdom_data, TRIM( slf_river(ifpr)%clvar ), zriver(:,:,jm), jm )
354               END DO
355               CALL iom_close( numriv )
356               ztimes_riv = 1._wp / FLOAT(ntimes_riv) 
357               DO jm = 1, ntimes_riv
358                  rivinput(ifpr) = rivinput(ifpr) + glob_sum( zriver(:,:,jm) * tmask(:,:,1) * ztimes_riv ) 
359               END DO
360               DEALLOCATE( zriver)
361            END DO
362            ! N/P and Si releases due to coastal rivers
363            ! -----------------------------------------
364            rivdicinput = (rivinput(jr_dic) + rivinput(jr_doc) ) * 1E3 / 12._wp
365            rivdininput = (rivinput(jr_din) + rivinput(jr_don) ) * 1E3 / rno3 / 14._wp
366            rivdipinput = (rivinput(jr_dip) + rivinput(jr_dop) ) * 1E3 / po4r / 31._wp
367            rivdsiinput = rivinput(jr_dsi) * 1E3 / 28.1_wp
368            rivalkinput = rivinput(jr_dic) * 1E3 / 12._wp
369            !
370         ENDIF
371      ELSE
372         rivdicinput = 0._wp
373         rivdininput = 0._wp
374         rivdipinput = 0._wp
375         rivdsiinput = 0._wp
376         rivalkinput = 0._wp
377      END IF 
378
379      ! nutrient input from dust
380      ! ------------------------
381      IF( ln_ndepo ) THEN
382         !
383         IF(lwp) WRITE(numout,*) '    initialize the nutrient input by dust from ndeposition.orca.nc'
384         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
385         !
386         ALLOCATE( nitdep(jpi,jpj) )    ! allocation
387         !
388         ALLOCATE( sf_ndepo(1), STAT=ierr3 )           !* allocate and fill sf_sst (forcing structure) with sn_sst
389         IF( ierr3 > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_ndepo structure' )
390         !
391         CALL fld_fill( sf_ndepo, (/ sn_ndepo /), cn_dir, 'p4z_sed_init', 'Nutrient atmospheric depositon ', 'nampissed' )
392                                   ALLOCATE( sf_ndepo(1)%fnow(jpi,jpj,1)   )
393         IF( sn_ndepo%ln_tint )    ALLOCATE( sf_ndepo(1)%fdta(jpi,jpj,1,2) )
394         !
395         IF( Agrif_Root() ) THEN   !  Only on the master grid
396            ! Get total input dust ; need to compute total atmospheric supply of N in a year
397            CALL iom_open ( TRIM( sn_ndepo%clname ), numdepo )
398            CALL iom_gettime( numdepo, zsteps, kntime=ntimes_ndep)
399            ALLOCATE( zndepo(jpi,jpj,ntimes_ndep) )
400            DO jm = 1, ntimes_ndep
401               CALL iom_get( numdepo, jpdom_data, TRIM( sn_ndepo%clvar ), zndepo(:,:,jm), jm )
402            END DO
403            CALL iom_close( numdepo )
404            ztimes_ndep = 1._wp / FLOAT( ntimes_ndep ) 
405            nitdepinput = 0._wp
406            DO jm = 1, ntimes_ndep
407              nitdepinput = nitdepinput + glob_sum( zndepo(:,:,jm) * e1e2t(:,:) * tmask(:,:,1) * ztimes_ndep )
408            ENDDO
409            nitdepinput = nitdepinput / rno3 / 14E6 
410            DEALLOCATE( zndepo)
411         ENDIF
412      ELSE
413         nitdepinput = 0._wp
414      ENDIF
415
416      ! coastal and island masks
417      ! ------------------------
418      IF( ln_ironsed ) THEN     
419         !
420         IF(lwp) WRITE(numout,*) '    computation of an island mask to enhance coastal supply of iron'
421         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
422         !
423         ALLOCATE( ironsed(jpi,jpj,jpk) )    ! allocation
424         !
425         CALL iom_open ( TRIM( sn_ironsed%clname ), numiron )
426         ALLOCATE( zcmask(jpi,jpj,jpk) )
427         CALL iom_get  ( numiron, jpdom_data, TRIM( sn_ironsed%clvar ), zcmask(:,:,:), 1 )
428         CALL iom_close( numiron )
429         !
430         DO jk = 1, 5
431            DO jj = 2, jpjm1
432               DO ji = fs_2, fs_jpim1
433                  IF( tmask(ji,jj,jk) /= 0. ) THEN
434                     zmaskt = tmask(ji+1,jj,jk) * tmask(ji-1,jj,jk) * tmask(ji,jj+1,jk)    &
435                        &                       * tmask(ji,jj-1,jk) * tmask(ji,jj,jk+1)
436                     IF( zmaskt == 0. )   zcmask(ji,jj,jk ) = MAX( 0.1, zcmask(ji,jj,jk) ) 
437                  END IF
438               END DO
439            END DO
440         END DO
441         IF( cp_cfg == 'orca' .AND. jp_cfg == 2 ) THEN
442            ii0 = 176   ;   ii1 =  176        ! Southern Island : Kerguelen
443            ij0 =  37   ;   ij1 =   37  ;   zcmask( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1), 1:jpk ) =  0.3_wp 
444            !
445            ii0 = 119   ;   ii1 =  119        ! South Georgia
446            ij0 =  29   ;   ij1 =   29  ;   zcmask( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1), 1:jpk ) =  0.3_wp 
447            !
448            ii0 = 111   ;   ii1 =  111        ! Falklands
449            ij0 =  35   ;   ij1 =   35  ;   zcmask( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1), 1:jpk ) =  0.3_wp 
450            !
451            ii0 = 168   ;   ii1 =  168        ! Crozet
452            ij0 =  40   ;   ij1 =   40  ;   zcmask( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1), 1:jpk ) =  0.3_wp 
453            !
454            ii0 = 119   ;   ii1 =  119        ! South Orkney
455            ij0 =  28   ;   ij1 =   28  ;   zcmask( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1), 1:jpk ) =  0.3_wp 
456            !
457            ii0 = 140   ;   ii1 =  140        ! Bouvet Island
458            ij0 =  33   ;   ij1 =   33  ;   zcmask( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1), 1:jpk ) =  0.3_wp 
459            !
460            ii0 = 178   ;   ii1 =  178        ! Prince edwards
461            ij0 =  34   ;   ij1 =   34  ;   zcmask( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1), 1:jpk ) =  0.3_wp 
462            !
463            ii0 =  43   ;   ii1 =   43        ! Balleny islands
464            ij0 =  21   ;   ij1 =   21  ;   zcmask( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1), 1:jpk ) =  0.3_wp 
465         ENDIF
466         CALL lbc_lnk( zcmask , 'T', 1. )      ! lateral boundary conditions on cmask   (sign unchanged)
467         DO jk = 1, jpk
468            DO jj = 1, jpj
469               DO ji = 1, jpi
470                  zexpide   = MIN( 8.,( fsdept(ji,jj,jk) / 500. )**(-1.5) )
471                  zdenitide = -0.9543 + 0.7662 * LOG( zexpide ) - 0.235 * LOG( zexpide )**2
472                  zcmask(ji,jj,jk) = zcmask(ji,jj,jk) * MIN( 1., EXP( zdenitide ) / 0.5 )
473               END DO
474            END DO
475         END DO
476         ! Coastal supply of iron
477         ! -------------------------
478         ironsed(:,:,jpk) = 0._wp
479         DO jk = 1, jpkm1
480            ironsed(:,:,jk) = sedfeinput * zcmask(:,:,jk) / ( fse3t(:,:,jk) * rday )
481         END DO
482         DEALLOCATE( zcmask)
483      ENDIF
484      !
485      ! Iron from Hydrothermal vents
486      ! ------------------------
487      IF( ln_hydrofe ) THEN
488         !
489         IF(lwp) WRITE(numout,*) '    Input of iron from hydrothermal vents '
490         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
491         !
492         ALLOCATE( hydrofe(jpi,jpj,jpk) )    ! allocation
493         !
494         CALL iom_open ( TRIM( sn_hydrofe%clname ), numhydro )
495         CALL iom_get  ( numhydro, jpdom_data, TRIM( sn_hydrofe%clvar ), hydrofe(:,:,:), 1 )
496         CALL iom_close( numhydro )
497         !
498         hydrofe(:,:,:) = ( hydrofe(:,:,:) * hratio ) / ( cvol(:,:,:) * ryyss + rtrn ) / fse3t(:,:,:)
499         !
500      ENDIF
501      !
502      IF( ll_sbc ) CALL p4z_sbc( nit000 ) 
503      !
504      IF(lwp) THEN
505         WRITE(numout,*)
506         WRITE(numout,*) '    Total input of elements from river supply'
507         WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
508         WRITE(numout,*) '    N Supply   : ', rivdininput*rno3*1E3/1E12*14.,' TgN/yr'
509         WRITE(numout,*) '    Si Supply  : ', rivdsiinput*1E3/1E12*28.1,' TgSi/yr'
510         WRITE(numout,*) '    P Supply   : ', rivdipinput*1E3*po4r/1E12*31.,' TgP/yr'
511         WRITE(numout,*) '    Alk Supply : ', rivalkinput*1E3/1E12,' Teq/yr'
512         WRITE(numout,*) '    DIC Supply : ', rivdicinput*1E3*12./1E12,'TgC/yr'
513         WRITE(numout,*) 
514         WRITE(numout,*) '    Total input of elements from atmospheric supply'
515         WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
516         WRITE(numout,*) '    N Supply   : ', nitdepinput*rno3*1E3/1E12*14.,' TgN/yr'
517         WRITE(numout,*) 
518      ENDIF
519      !
520      IF( nn_timing == 1 )  CALL timing_stop('p4z_sbc_init')
521      !
522   END SUBROUTINE p4z_sbc_init
523
524#else
525   !!======================================================================
526   !!  Dummy module :                                   No PISCES bio-model
527   !!======================================================================
528CONTAINS
529   SUBROUTINE p4z_sbc                         ! Empty routine
530   END SUBROUTINE p4z_sbc
531#endif 
532
533   !!======================================================================
534END MODULE  p4zsbc
Note: See TracBrowser for help on using the repository browser.