New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
istate.F90 in branches/2013/dev_r3987_UKMO6_C1D/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: branches/2013/dev_r3987_UKMO6_C1D/NEMOGCM/NEMO/OPA_SRC/DOM/istate.F90 @ 4144

Last change on this file since 4144 was 4144, checked in by rfurner, 10 years ago

Commit for 2013 changes; see #1085

  • Property svn:keywords set to Id
File size: 26.0 KB
Line 
1MODULE istate
2   !!======================================================================
3   !!                     ***  MODULE  istate  ***
4   !! Ocean state   :  initial state setting
5   !!=====================================================================
6   !! History :  OPA  !  1989-12  (P. Andrich)  Original code
7   !!            5.0  !  1991-11  (G. Madec)  rewritting
8   !!            6.0  !  1996-01  (G. Madec)  terrain following coordinates
9   !!            8.0  !  2001-09  (M. Levy, M. Ben Jelloul)  istate_eel
10   !!            8.0  !  2001-09  (M. Levy, M. Ben Jelloul)  istate_uvg
11   !!   NEMO     1.0  !  2003-08  (G. Madec, C. Talandier)  F90: Free form, modules + EEL R5
12   !!             -   !  2004-05  (A. Koch-Larrouy)  istate_gyre
13   !!            2.0  !  2006-07  (S. Masson)  distributed restart using iom
14   !!            3.3  !  2010-10  (C. Ethe) merge TRC-TRA
15   !!            3.4  !  2011-04  (G. Madec) Merge of dtatem and dtasal & suppression of tb,tn/sb,sn
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   istate_init   : initial state setting
20   !!   istate_tem    : analytical profile for initial Temperature
21   !!   istate_sal    : analytical profile for initial Salinity
22   !!   istate_eel    : initial state setting of EEL R5 configuration
23   !!   istate_gyre   : initial state setting of GYRE configuration
24   !!   istate_uvg    : initial velocity in geostropic balance
25   !!----------------------------------------------------------------------
26   USE oce             ! ocean dynamics and active tracers
27   USE dom_oce         ! ocean space and time domain
28   USE c1d             ! 1D vertical configuration
29   USE daymod          ! calendar
30   USE eosbn2          ! eq. of state, Brunt Vaisala frequency (eos     routine)
31   USE ldftra_oce      ! ocean active tracers: lateral physics
32   USE zdf_oce         ! ocean vertical physics
33   USE phycst          ! physical constants
34   USE dtatsd          ! data temperature and salinity   (dta_tsd routine)
35   USE dtauvd          ! data: U & V current             (dta_uvd routine)
36   USE in_out_manager  ! I/O manager
37   USE iom             ! I/O library
38   USE zpshde          ! partial step: hor. derivative (zps_hde routine)
39   USE eosbn2          ! equation of state            (eos bn2 routine)
40   USE domvvl          ! varying vertical mesh
41   USE dynspg_oce      ! pressure gradient schemes
42   USE dynspg_flt      ! pressure gradient schemes
43   USE dynspg_exp      ! pressure gradient schemes
44   USE dynspg_ts       ! pressure gradient schemes
45   USE sol_oce         ! ocean solver variables
46   USE lib_mpp         ! MPP library
47   USE restart         ! restart
48   USE wrk_nemo        ! Memory allocation
49   USE timing          ! Timing
50
51   IMPLICIT NONE
52   PRIVATE
53
54   PUBLIC   istate_init   ! routine called by step.F90
55
56   !! * Substitutions
57#  include "domzgr_substitute.h90"
58#  include "vectopt_loop_substitute.h90"
59   !!----------------------------------------------------------------------
60   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
61   !! $Id$
62   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
63   !!----------------------------------------------------------------------
64CONTAINS
65
66   SUBROUTINE istate_init
67      !!----------------------------------------------------------------------
68      !!                   ***  ROUTINE istate_init  ***
69      !!
70      !! ** Purpose :   Initialization of the dynamics and tracer fields.
71      !!----------------------------------------------------------------------
72      ! - ML - needed for initialization of e3t_b
73      INTEGER  ::  jk     ! dummy loop indice
74      REAL(wp), POINTER, DIMENSION(:,:,:,:)  ::  zuvd    ! U & V data workspace
75      !!----------------------------------------------------------------------
76      !
77      IF( nn_timing == 1 )  CALL timing_start('istate_init')
78      !
79
80      IF(lwp) WRITE(numout,*)
81      IF(lwp) WRITE(numout,*) 'istate_ini : Initialization of the dynamics and tracers'
82      IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
83
84      CALL dta_tsd_init                       ! Initialisation of T & S input data
85      IF( lk_c1d ) CALL dta_uvd_init          ! Initialization of U & V input data
86
87      rhd  (:,:,:  ) = 0.e0
88      rhop (:,:,:  ) = 0.e0
89      rn2  (:,:,:  ) = 0.e0 
90      tsa  (:,:,:,:) = 0.e0   
91
92      IF( ln_rstart ) THEN                    ! Restart from a file
93         !                                    ! -------------------
94         neuler = 1                              ! Set time-step indicator at nit000 (leap-frog)
95         CALL rst_read                           ! Read the restart file
96         !                                       ! define e3u_b, e3v_b from e3t_b read in restart file
97         CALL dom_vvl_2( nit000, fse3u_b(:,:,:), fse3v_b(:,:,:) )
98         CALL day_init                           ! model calendar (using both namelist and restart infos)
99      ELSE
100         !                                    ! Start from rest
101         !                                    ! ---------------
102         numror = 0                              ! define numror = 0 -> no restart file to read
103         neuler = 0                              ! Set time-step indicator at nit000 (euler forward)
104         CALL day_init                           ! model calendar (using both namelist and restart infos)
105         !                                       ! Initialization of ocean to zero
106         !   before fields      !       now fields     
107         sshb (:,:)   = 0._wp   ;   sshn (:,:)   = 0._wp
108         ub   (:,:,:) = 0._wp   ;   un   (:,:,:) = 0._wp
109         vb   (:,:,:) = 0._wp   ;   vn   (:,:,:) = 0._wp 
110         rotb (:,:,:) = 0._wp   ;   rotn (:,:,:) = 0._wp
111         hdivb(:,:,:) = 0._wp   ;   hdivn(:,:,:) = 0._wp
112         !
113         IF( cp_cfg == 'eel' ) THEN
114            CALL istate_eel                      ! EEL   configuration : start from pre-defined U,V T-S fields
115         ELSEIF( cp_cfg == 'gyre' ) THEN         
116            CALL istate_gyre                     ! GYRE  configuration : start from pre-defined T-S fields
117         ELSE                                    ! Initial T-S, U-V fields read in files
118            IF ( ln_tsd_init ) THEN              ! read 3D T and S data at nit000
119               CALL dta_tsd( nit000, tsb ) 
120               tsn(:,:,:,:) = tsb(:,:,:,:)
121               !
122            ELSE                                 ! Initial T-S fields defined analytically
123               CALL istate_t_s
124            ENDIF
125            IF ( ln_uvd_init .AND. lk_c1d ) THEN ! read 3D U and V data at nit000
126               CALL wrk_alloc( jpi, jpj, jpk, 2, zuvd )
127               CALL dta_uvd( nit000, zuvd )
128               ub(:,:,:) = zuvd(:,:,:,1) ;  un(:,:,:) = ub(:,:,:)
129               vb(:,:,:) = zuvd(:,:,:,2) ;  vn(:,:,:) = vb(:,:,:)
130               CALL wrk_dealloc( jpi, jpj, jpk, 2, zuvd )
131            ENDIF
132         ENDIF
133         !
134         CALL eos( tsb, rhd, rhop )        ! before potential and in situ densities
135#if ! defined key_c1d
136         IF( ln_zps )   CALL zps_hde( nit000, jpts, tsb, gtsu, gtsv,  & ! zps: before hor. gradient
137            &                                       rhd, gru , grv  )   ! of t,s,rd at ocean bottom
138#endif
139         !   
140         ! - ML - sshn could be modified by istate_eel, so that initialization of fse3t_b is done here
141         IF( lk_vvl ) THEN
142            DO jk = 1, jpk
143               fse3t_b(:,:,jk) = fse3t_n(:,:,jk)
144            ENDDO
145         ENDIF
146         !                                       ! define e3u_b, e3v_b from e3t_b initialized in domzgr
147         CALL dom_vvl_2( nit000, fse3u_b(:,:,:), fse3v_b(:,:,:) )
148         !
149      ENDIF
150      !
151      IF( lk_agrif ) THEN                  ! read free surface arrays in restart file
152         IF( ln_rstart ) THEN
153            IF( lk_dynspg_flt )  THEN      ! read or initialize the following fields
154               !                           ! gcx, gcxb for agrif_opa_init
155               IF( sol_oce_alloc()  > 0 )   CALL ctl_stop('agrif sol_oce_alloc: allocation of arrays failed')
156               CALL flt_rst( nit000, 'READ' )
157            ENDIF
158         ENDIF                             ! explicit case not coded yet with AGRIF
159      ENDIF
160      !
161      IF( nn_timing == 1 )  CALL timing_stop('istate_init')
162      !
163   END SUBROUTINE istate_init
164
165   SUBROUTINE istate_t_s
166      !!---------------------------------------------------------------------
167      !!                  ***  ROUTINE istate_t_s  ***
168      !!   
169      !! ** Purpose :   Intialization of the temperature field with an
170      !!      analytical profile or a file (i.e. in EEL configuration)
171      !!
172      !! ** Method  : - temperature: use Philander analytic profile
173      !!              - salinity   : use to a constant value 35.5
174      !!
175      !! References :  Philander ???
176      !!----------------------------------------------------------------------
177      INTEGER  :: ji, jj, jk
178      REAL(wp) ::   zsal = 35.50
179      !!----------------------------------------------------------------------
180      !
181      IF(lwp) WRITE(numout,*)
182      IF(lwp) WRITE(numout,*) 'istate_t_s : Philander s initial temperature profile'
183      IF(lwp) WRITE(numout,*) '~~~~~~~~~~   and constant salinity (',zsal,' psu)'
184      !
185      DO jk = 1, jpk
186         tsn(:,:,jk,jp_tem) = (  ( ( 7.5 - 0. * ABS( gphit(:,:) )/30. ) * ( 1.-TANH((fsdept(:,:,jk)-80.)/30.) )   &
187            &                + 10. * ( 5000. - fsdept(:,:,jk) ) /5000.)  ) * tmask(:,:,jk)
188         tsb(:,:,jk,jp_tem) = tsn(:,:,jk,jp_tem)
189      END DO
190      tsn(:,:,:,jp_sal) = zsal * tmask(:,:,:)
191      tsb(:,:,:,jp_sal) = tsn(:,:,:,jp_sal)
192      !
193   END SUBROUTINE istate_t_s
194
195
196   SUBROUTINE istate_eel
197      !!----------------------------------------------------------------------
198      !!                   ***  ROUTINE istate_eel  ***
199      !!
200      !! ** Purpose :   Initialization of the dynamics and tracers for EEL R5
201      !!      configuration (channel with or without a topographic bump)
202      !!
203      !! ** Method  : - set temprature field
204      !!              - set salinity field
205      !!              - set velocity field including horizontal divergence
206      !!                and relative vorticity fields
207      !!----------------------------------------------------------------------
208      USE divcur     ! hor. divergence & rel. vorticity      (div_cur routine)
209      USE iom
210 
211      INTEGER  ::   inum              ! temporary logical unit
212      INTEGER  ::   ji, jj, jk        ! dummy loop indices
213      INTEGER  ::   ijloc
214      REAL(wp) ::   zh1, zh2, zslope, zcst, zfcor   ! temporary scalars
215      REAL(wp) ::   zt1  = 15._wp                   ! surface temperature value (EEL R5)
216      REAL(wp) ::   zt2  =  5._wp                   ! bottom  temperature value (EEL R5)
217      REAL(wp) ::   zsal = 35.0_wp                  ! constant salinity (EEL R2, R5 and R6)
218      REAL(wp) ::   zueel = 0.1_wp                  ! constant uniform zonal velocity (EEL R5)
219      REAL(wp), DIMENSION(jpiglo,jpjglo) ::   zssh  ! initial ssh over the global domain
220      !!----------------------------------------------------------------------
221
222      SELECT CASE ( jp_cfg ) 
223         !                                              ! ====================
224         CASE ( 5 )                                     ! EEL R5 configuration
225            !                                           ! ====================
226            !
227            ! set temperature field with a linear profile
228            ! -------------------------------------------
229            IF(lwp) WRITE(numout,*)
230            IF(lwp) WRITE(numout,*) 'istate_eel : EEL R5: linear temperature profile'
231            IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
232            !
233            zh1 = gdept_0(  1  )
234            zh2 = gdept_0(jpkm1)
235            !
236            zslope = ( zt1 - zt2 ) / ( zh1 - zh2 )
237            zcst   = ( zt1 * ( zh1 - zh2) - ( zt1 - zt2 ) * zh1 ) / ( zh1 - zh2 )
238            !
239            DO jk = 1, jpk
240               tsn(:,:,jk,jp_tem) = ( zt2 + zt1 * exp( - fsdept(:,:,jk) / 1000 ) ) * tmask(:,:,jk)
241               tsb(:,:,jk,jp_tem) = tsn(:,:,jk,jp_tem)
242            END DO
243            !
244            IF(lwp) CALL prizre( tsn(:,:,:,jp_tem), jpi   , jpj   , jpk   , jpj/2 ,   &
245               &                             1     , jpi   , 5     , 1     , jpk   ,   &
246               &                             1     , 1.    , numout                  )
247            !
248            ! set salinity field to a constant value
249            ! --------------------------------------
250            IF(lwp) WRITE(numout,*)
251            IF(lwp) WRITE(numout,*) 'istate_eel : EEL R5: constant salinity field, S = ', zsal
252            IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
253            !
254            tsn(:,:,:,jp_sal) = zsal * tmask(:,:,:)
255            tsb(:,:,:,jp_sal) = tsn(:,:,:,jp_sal)
256            !
257            ! set the dynamics: U,V, hdiv, rot (and ssh if necessary)
258            ! ----------------
259            ! Start EEL5 configuration with barotropic geostrophic velocities
260            ! according the sshb and sshn SSH imposed.
261            ! we assume a uniform grid (hence the use of e1t(1,1) for delta_y)
262            ! we use the Coriolis frequency at mid-channel.   
263            ub(:,:,:) = zueel * umask(:,:,:)
264            un(:,:,:) = ub(:,:,:)
265            ijloc = mj0(INT(jpjglo-1)/2)
266            zfcor = ff(1,ijloc)
267            !
268            DO jj = 1, jpjglo
269               zssh(:,jj) = - (FLOAT(jj)- FLOAT(jpjglo-1)/2.)*zueel*e1t(1,1)*zfcor/grav 
270            END DO
271            !
272            IF(lwp) THEN
273               WRITE(numout,*) ' Uniform zonal velocity for EEL R5:',zueel
274               WRITE(numout,*) ' Geostrophic SSH profile as a function of y:'
275               WRITE(numout,'(12(1x,f6.2))') zssh(1,:)
276            ENDIF
277            !
278            DO jj = 1, nlcj
279               DO ji = 1, nlci
280                  sshb(ji,jj) = zssh( mig(ji) , mjg(jj) ) * tmask(ji,jj,1)
281               END DO
282            END DO
283            sshb(nlci+1:jpi,      :   ) = 0.e0      ! set to zero extra mpp columns
284            sshb(      :   ,nlcj+1:jpj) = 0.e0      ! set to zero extra mpp rows
285            !
286            sshn(:,:) = sshb(:,:)                   ! set now ssh to the before value
287            !
288            IF( nn_rstssh /= 0 ) THEN 
289               nn_rstssh = 0                        ! hand-made initilization of ssh
290               CALL ctl_warn( 'istate_eel: force nn_rstssh = 0' )
291            ENDIF
292            !
293            CALL div_cur( nit000 )                  ! horizontal divergence and relative vorticity (curl)
294            ! N.B. the vertical velocity will be computed from the horizontal divergence field
295            ! in istate by a call to wzv routine
296
297
298            !                                     ! ==========================
299         CASE ( 2 , 6 )                           ! EEL R2 or R6 configuration
300            !                                     ! ==========================
301            !
302            ! set temperature field with a NetCDF file
303            ! ----------------------------------------
304            IF(lwp) WRITE(numout,*)
305            IF(lwp) WRITE(numout,*) 'istate_eel : EEL R2 or R6: read initial temperature in a NetCDF file'
306            IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
307            !
308            CALL iom_open ( 'eel.initemp', inum )
309            CALL iom_get ( inum, jpdom_data, 'initemp', tsb(:,:,:,jp_tem) ) ! read before temprature (tb)
310            CALL iom_close( inum )
311            !
312            tsn(:,:,:,jp_tem) = tsb(:,:,:,jp_tem)                            ! set nox temperature to tb
313            !
314            IF(lwp) CALL prizre( tsn(:,:,:,jp_tem), jpi   , jpj   , jpk   , jpj/2 ,   &
315               &                            1     , jpi   , 5     , 1     , jpk   ,   &
316               &                            1     , 1.    , numout                  )
317            !
318            ! set salinity field to a constant value
319            ! --------------------------------------
320            IF(lwp) WRITE(numout,*)
321            IF(lwp) WRITE(numout,*) 'istate_eel : EEL R5: constant salinity field, S = ', zsal
322            IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
323            !
324            tsn(:,:,:,jp_sal) = zsal * tmask(:,:,:)
325            tsb(:,:,:,jp_sal) = tsn(:,:,:,jp_sal)
326            !
327            !                                    ! ===========================
328         CASE DEFAULT                            ! NONE existing configuration
329            !                                    ! ===========================
330            WRITE(ctmp1,*) 'EEL with a ', jp_cfg,' km resolution is not coded'
331            CALL ctl_stop( ctmp1 )
332            !
333      END SELECT
334      !
335   END SUBROUTINE istate_eel
336
337
338   SUBROUTINE istate_gyre
339      !!----------------------------------------------------------------------
340      !!                   ***  ROUTINE istate_gyre  ***
341      !!
342      !! ** Purpose :   Initialization of the dynamics and tracers for GYRE
343      !!      configuration (double gyre with rotated domain)
344      !!
345      !! ** Method  : - set temprature field
346      !!              - set salinity field
347      !!----------------------------------------------------------------------
348      INTEGER :: ji, jj, jk  ! dummy loop indices
349      INTEGER            ::   inum          ! temporary logical unit
350      INTEGER, PARAMETER ::   ntsinit = 0   ! (0/1) (analytical/input data files) T&S initialization
351      !!----------------------------------------------------------------------
352
353      SELECT CASE ( ntsinit)
354
355      CASE ( 0 )                  ! analytical T/S profil deduced from LEVITUS
356         IF(lwp) WRITE(numout,*)
357         IF(lwp) WRITE(numout,*) 'istate_gyre : initial analytical T and S profil deduced from LEVITUS '
358         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
359
360         DO jk = 1, jpk
361            DO jj = 1, jpj
362               DO ji = 1, jpi
363                  tsn(ji,jj,jk,jp_tem) = (  16. - 12. * TANH( (fsdept(ji,jj,jk) - 400) / 700 )         )   &
364                       &           * (-TANH( (500-fsdept(ji,jj,jk)) / 150 ) + 1) / 2               &
365                       &       + (      15. * ( 1. - TANH( (fsdept(ji,jj,jk)-50.) / 1500.) )       &
366                       &                - 1.4 * TANH((fsdept(ji,jj,jk)-100.) / 100.)               &   
367                       &                + 7.  * (1500. - fsdept(ji,jj,jk)) / 1500.             )   & 
368                       &           * (-TANH( (fsdept(ji,jj,jk) - 500) / 150) + 1) / 2
369                  tsn(ji,jj,jk,jp_tem) = tsn(ji,jj,jk,jp_tem) * tmask(ji,jj,jk)
370                  tsb(ji,jj,jk,jp_tem) = tsn(ji,jj,jk,jp_tem)
371
372                  tsn(ji,jj,jk,jp_sal) =  (  36.25 - 1.13 * TANH( (fsdept(ji,jj,jk) - 305) / 460 )  )  &
373                     &              * (-TANH((500 - fsdept(ji,jj,jk)) / 150) + 1) / 2          &
374                     &          + (  35.55 + 1.25 * (5000. - fsdept(ji,jj,jk)) / 5000.         &
375                     &                - 1.62 * TANH( (fsdept(ji,jj,jk) - 60.  ) / 650. )       &
376                     &                + 0.2  * TANH( (fsdept(ji,jj,jk) - 35.  ) / 100. )       &
377                     &                + 0.2  * TANH( (fsdept(ji,jj,jk) - 1000.) / 5000.)    )  &
378                     &              * (-TANH((fsdept(ji,jj,jk) - 500) / 150) + 1) / 2 
379                  tsn(ji,jj,jk,jp_sal) = tsn(ji,jj,jk,jp_sal) * tmask(ji,jj,jk)
380                  tsb(ji,jj,jk,jp_sal) = tsn(ji,jj,jk,jp_sal)
381               END DO
382            END DO
383         END DO
384
385      CASE ( 1 )                  ! T/S data fields read in dta_tem.nc/data_sal.nc files
386         IF(lwp) WRITE(numout,*)
387         IF(lwp) WRITE(numout,*) 'istate_gyre : initial T and S read from dta_tem.nc/data_sal.nc files'
388         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
389         IF(lwp) WRITE(numout,*) '              NetCDF FORMAT'
390
391         ! Read temperature field
392         ! ----------------------
393         CALL iom_open ( 'data_tem', inum )
394         CALL iom_get ( inum, jpdom_data, 'votemper', tsn(:,:,:,jp_tem) ) 
395         CALL iom_close( inum )
396
397         tsn(:,:,:,jp_tem) = tsn(:,:,:,jp_tem) * tmask(:,:,:) 
398         tsb(:,:,:,jp_tem) = tsn(:,:,:,jp_tem)
399
400         ! Read salinity field
401         ! -------------------
402         CALL iom_open ( 'data_sal', inum )
403         CALL iom_get ( inum, jpdom_data, 'vosaline', tsn(:,:,:,jp_sal) ) 
404         CALL iom_close( inum )
405
406         tsn(:,:,:,jp_sal) = tsn(:,:,:,jp_sal) * tmask(:,:,:) 
407         tsb(:,:,:,jp_sal) = tsn(:,:,:,jp_sal)
408
409      END SELECT
410
411      IF(lwp) THEN
412         WRITE(numout,*)
413         WRITE(numout,*) '              Initial temperature and salinity profiles:'
414         WRITE(numout, "(9x,' level   gdept_0   temperature   salinity   ')" )
415         WRITE(numout, "(10x, i4, 3f10.2)" ) ( jk, gdept_0(jk), tsn(2,2,jk,jp_tem), tsn(2,2,jk,jp_sal), jk = 1, jpk )
416      ENDIF
417
418   END SUBROUTINE istate_gyre
419
420
421   SUBROUTINE istate_uvg
422      !!----------------------------------------------------------------------
423      !!                  ***  ROUTINE istate_uvg  ***
424      !!
425      !! ** Purpose :   Compute the geostrophic velocities from (tn,sn) fields
426      !!
427      !! ** Method  :   Using the hydrostatic hypothesis the now hydrostatic
428      !!      pressure is computed by integrating the in-situ density from the
429      !!      surface to the bottom.
430      !!                 p=integral [ rau*g dz ]
431      !!----------------------------------------------------------------------
432      USE dynspg          ! surface pressure gradient             (dyn_spg routine)
433      USE divcur          ! hor. divergence & rel. vorticity      (div_cur routine)
434      USE lbclnk          ! ocean lateral boundary condition (or mpp link)
435
436      INTEGER ::   ji, jj, jk        ! dummy loop indices
437      INTEGER ::   indic             ! ???
438      REAL(wp) ::   zmsv, zphv, zmsu, zphu, zalfg     ! temporary scalars
439      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprn
440      !!----------------------------------------------------------------------
441      !
442      CALL wrk_alloc( jpi, jpj, jpk, zprn)
443      !
444      IF(lwp) WRITE(numout,*) 
445      IF(lwp) WRITE(numout,*) 'istate_uvg : Start from Geostrophy'
446      IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
447
448      ! Compute the now hydrostatic pressure
449      ! ------------------------------------
450
451      zalfg = 0.5 * grav * rau0
452     
453      zprn(:,:,1) = zalfg * fse3w(:,:,1) * ( 1 + rhd(:,:,1) )       ! Surface value
454
455      DO jk = 2, jpkm1                                              ! Vertical integration from the surface
456         zprn(:,:,jk) = zprn(:,:,jk-1)   &
457            &         + zalfg * fse3w(:,:,jk) * ( 2. + rhd(:,:,jk) + rhd(:,:,jk-1) )
458      END DO 
459
460      ! Compute geostrophic balance
461      ! ---------------------------
462      DO jk = 1, jpkm1
463         DO jj = 2, jpjm1
464            DO ji = fs_2, fs_jpim1   ! vertor opt.
465               zmsv = 1. / MAX(  umask(ji-1,jj+1,jk) + umask(ji  ,jj+1,jk)   &
466                               + umask(ji-1,jj  ,jk) + umask(ji  ,jj  ,jk) , 1.  )
467               zphv = ( zprn(ji  ,jj+1,jk) - zprn(ji-1,jj+1,jk) ) * umask(ji-1,jj+1,jk) / e1u(ji-1,jj+1)   &
468                    + ( zprn(ji+1,jj+1,jk) - zprn(ji  ,jj+1,jk) ) * umask(ji  ,jj+1,jk) / e1u(ji  ,jj+1)   &
469                    + ( zprn(ji  ,jj  ,jk) - zprn(ji-1,jj  ,jk) ) * umask(ji-1,jj  ,jk) / e1u(ji-1,jj  )   &
470                    + ( zprn(ji+1,jj  ,jk) - zprn(ji  ,jj  ,jk) ) * umask(ji  ,jj  ,jk) / e1u(ji  ,jj  )
471               zphv = 1. / rau0 * zphv * zmsv * vmask(ji,jj,jk)
472
473               zmsu = 1. / MAX(  vmask(ji+1,jj  ,jk) + vmask(ji  ,jj  ,jk)   &
474                               + vmask(ji+1,jj-1,jk) + vmask(ji  ,jj-1,jk) , 1.  )
475               zphu = ( zprn(ji+1,jj+1,jk) - zprn(ji+1,jj  ,jk) ) * vmask(ji+1,jj  ,jk) / e2v(ji+1,jj  )   &
476                    + ( zprn(ji  ,jj+1,jk) - zprn(ji  ,jj  ,jk) ) * vmask(ji  ,jj  ,jk) / e2v(ji  ,jj  )   &
477                    + ( zprn(ji+1,jj  ,jk) - zprn(ji+1,jj-1,jk) ) * vmask(ji+1,jj-1,jk) / e2v(ji+1,jj-1)   &
478                    + ( zprn(ji  ,jj  ,jk) - zprn(ji  ,jj-1,jk) ) * vmask(ji  ,jj-1,jk) / e2v(ji  ,jj-1)
479               zphu = 1. / rau0 * zphu * zmsu * umask(ji,jj,jk)
480
481               ! Compute the geostrophic velocities
482               un(ji,jj,jk) = -2. * zphu / ( ff(ji,jj) + ff(ji  ,jj-1) )
483               vn(ji,jj,jk) =  2. * zphv / ( ff(ji,jj) + ff(ji-1,jj  ) )
484            END DO
485         END DO
486      END DO
487
488      IF(lwp) WRITE(numout,*) '         we force to zero bottom velocity'
489
490      ! Susbtract the bottom velocity (level jpk-1 for flat bottom case)
491      ! to have a zero bottom velocity
492
493      DO jk = 1, jpkm1
494         un(:,:,jk) = ( un(:,:,jk) - un(:,:,jpkm1) ) * umask(:,:,jk)
495         vn(:,:,jk) = ( vn(:,:,jk) - vn(:,:,jpkm1) ) * vmask(:,:,jk)
496      END DO
497
498      CALL lbc_lnk( un, 'U', -1. )
499      CALL lbc_lnk( vn, 'V', -1. )
500     
501      ub(:,:,:) = un(:,:,:)
502      vb(:,:,:) = vn(:,:,:)
503     
504      ! WARNING !!!!!
505      ! after initializing u and v, we need to calculate the initial streamfunction bsf.
506      ! Otherwise, only the trend will be computed and the model will blow up (inconsistency).
507      ! to do that, we call dyn_spg with a special trick:
508      ! we fill ua and va with the velocities divided by dt, and the streamfunction will be brought to the
509      ! right value assuming the velocities have been set up in one time step.
510      ! we then set bsfd to zero (first guess for next step is d(psi)/dt = 0.)
511      !  sets up s false trend to calculate the barotropic streamfunction.
512
513      ua(:,:,:) = ub(:,:,:) / rdt
514      va(:,:,:) = vb(:,:,:) / rdt
515
516      ! calls dyn_spg. we assume euler time step, starting from rest.
517      indic = 0
518      CALL dyn_spg( nit000, indic )       ! surface pressure gradient
519
520      ! the new velocity is ua*rdt
521
522      CALL lbc_lnk( ua, 'U', -1. )
523      CALL lbc_lnk( va, 'V', -1. )
524
525      ub(:,:,:) = ua(:,:,:) * rdt
526      vb(:,:,:) = va(:,:,:) * rdt
527      ua(:,:,:) = 0.e0
528      va(:,:,:) = 0.e0
529      un(:,:,:) = ub(:,:,:)
530      vn(:,:,:) = vb(:,:,:)
531       
532      ! Compute the divergence and curl
533
534      CALL div_cur( nit000 )            ! now horizontal divergence and curl
535
536      hdivb(:,:,:) = hdivn(:,:,:)       ! set the before to the now value
537      rotb (:,:,:) = rotn (:,:,:)       ! set the before to the now value
538      !
539      CALL wrk_dealloc( jpi, jpj, jpk, zprn)
540      !
541   END SUBROUTINE istate_uvg
542
543   !!=====================================================================
544END MODULE istate
Note: See TracBrowser for help on using the repository browser.