New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd_sal.F90 in branches/2013/dev_r4028_CNRS_LIM3/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2013/dev_r4028_CNRS_LIM3/NEMOGCM/NEMO/LIM_SRC_3/limthd_sal.F90 @ 4634

Last change on this file since 4634 was 4634, checked in by clem, 10 years ago

major changes in heat budget
  • Property svn:keywords set to Id
File size: 8.4 KB
Line 
1MODULE limthd_sal
2   !!======================================================================
3   !!                       ***  MODULE limthd_sal ***
4   !! LIM-3 sea-ice :  computation of salinity variations in the ice
5   !!======================================================================
6   !! History :   -   ! 2003-05 (M. Vancoppenolle) UCL-ASTR first coding for LIM3-1D
7   !!            3.0  ! 2005-12 (M. Vancoppenolle) adapted to the 3-D version
8   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
9   !!---------------------------------------------------------------------
10#if defined key_lim3
11   !!----------------------------------------------------------------------
12   !!   'key_lim3'                                      LIM-3 sea-ice model
13   !!----------------------------------------------------------------------
14   !!   lim_thd_sal   : salinity variations in the ice
15   !!----------------------------------------------------------------------
16   USE par_oce        ! ocean parameters
17   USE phycst         ! physical constants (ocean directory)
18   USE sbc_oce        ! Surface boundary condition: ocean fields
19   USE ice            ! LIM variables
20   USE par_ice        ! LIM parameters
21   USE thd_ice        ! LIM thermodynamics
22   USE limvar         ! LIM variables
23   USE in_out_manager ! I/O manager
24   USE lib_mpp        ! MPP library
25   USE wrk_nemo       ! work arrays
26   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   lim_thd_sal        ! called by limthd module
32   PUBLIC   lim_thd_sal_init   ! called by iceini module
33
34   !!----------------------------------------------------------------------
35   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
36   !! $Id$
37   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
38   !!----------------------------------------------------------------------
39CONTAINS
40
41   SUBROUTINE lim_thd_sal( kideb, kiut )
42      !!-------------------------------------------------------------------
43      !!                ***  ROUTINE lim_thd_sal  ***   
44      !!   
45      !! ** Purpose :   computes new salinities in the ice
46      !!
47      !! ** Method  :  3 possibilities
48      !!               -> num_sal = 1 -> Sice = cst    [ice salinity constant in both time & space]
49      !!               -> num_sal = 2 -> Sice = S(z,t) [Vancoppenolle et al. 2005]
50      !!               -> num_sal = 3 -> Sice = S(z)   [multiyear ice]
51      !!---------------------------------------------------------------------
52      INTEGER, INTENT(in) ::   kideb, kiut   ! thickness category index
53      !
54      INTEGER  ::   ji, jk     ! dummy loop indices
55      REAL(wp) ::   iflush, igravdr, ztmelts   ! local scalars
56      REAL(wp) ::   zaaa, zbbb, zccc, zdiscrim   ! local scalars
57      !!---------------------------------------------------------------------
58
59      !------------------------------------------------------------------------------|
60      ! 1) Constant salinity, constant in time                                       |
61      !------------------------------------------------------------------------------|
62!!gm comment: if num_sal = 1 s_i_new, s_i_b and sm_i_b can be set to bulk_sal one for all in the initialisation phase !!
63!!gm           ===>>>   simplification of almost all test on num_sal value
64      IF(  num_sal == 1  ) THEN
65            s_i_b  (kideb:kiut,1:nlay_i) =  bulk_sal
66            sm_i_b (kideb:kiut)          =  bulk_sal 
67            s_i_new(kideb:kiut)          =  bulk_sal
68      ENDIF
69
70      !------------------------------------------------------------------------------|
71      !  Module 2 : Constant salinity varying in time                                |
72      !------------------------------------------------------------------------------|
73
74      IF(  num_sal == 2  ) THEN
75
76         DO ji = kideb, kiut
77            !
78            ! Switches
79            !----------
80            iflush       =         MAX( 0._wp , SIGN( 1._wp , t_su_b(ji) - rtt )        )    ! =1 if summer
81            igravdr      =         MAX( 0._wp , SIGN( 1._wp , t_bo_b(ji) - t_su_b(ji) ) )    ! =1 if t_su < t_bo
82
83            !---------------------
84            ! Salinity tendencies
85            !---------------------
86            !                               
87            dsm_i_gd_1d(ji) = - igravdr * MAX( sm_i_b(ji) - sal_G , 0._wp ) / time_G * rdt_ice  ! drainage by gravity
88            dsm_i_fl_1d(ji) = - iflush  * MAX( sm_i_b(ji) - sal_F , 0._wp ) / time_F * rdt_ice  ! drainage by flushing
89            !
90            !-----------------
91            ! Update salinity   
92            !-----------------
93            ! only drainage terms ( gravity drainage and flushing )
94            ! snow ice / bottom sources are added in lim_thd_ent to conserve energy
95            sm_i_b(ji) = sm_i_b(ji) + dsm_i_fl_1d(ji) + dsm_i_gd_1d(ji)
96
97            !----------------------------
98            ! Salt flux - brine drainage
99            !----------------------------
100            sfx_bri_1d(ji) = sfx_bri_1d(ji) - rhoic * a_i_b(ji) * ht_i_b(ji) * ( dsm_i_fl_1d(ji) + dsm_i_gd_1d(ji) ) * r1_rdtice
101
102         END DO
103
104         ! Salinity profile
105         CALL lim_var_salprof1d( kideb, kiut )
106
107
108         ! Only necessary for conservation check since salinity is modified
109         !--------------------
110         ! Temperature update
111         !--------------------
112         DO jk = 1, nlay_i
113            DO ji = kideb, kiut
114               ztmelts    =  -tmut*s_i_b(ji,jk) + rtt
115               !Conversion q(S,T) -> T (second order equation)
116               zaaa         =  cpic
117               zbbb         =  ( rcp - cpic ) * ( ztmelts - rtt ) + q_i_b(ji,jk) / rhoic - lfus
118               zccc         =  lfus * ( ztmelts - rtt )
119               zdiscrim     =  SQRT(  MAX( zbbb*zbbb - 4.0*zaaa*zccc, 0._wp )  )
120               t_i_b(ji,jk) =  rtt - ( zbbb + zdiscrim ) / ( 2.0 *zaaa )
121            END DO
122         END DO
123         !
124      ENDIF 
125
126      !------------------------------------------------------------------------------|
127      !  Module 3 : Profile of salinity, constant in time                            |
128      !------------------------------------------------------------------------------|
129
130      IF(  num_sal == 3  )   CALL lim_var_salprof1d( kideb, kiut )
131
132      !
133   END SUBROUTINE lim_thd_sal
134
135
136   SUBROUTINE lim_thd_sal_init
137      !!-------------------------------------------------------------------
138      !!                  ***  ROUTINE lim_thd_sal_init  ***
139      !!
140      !! ** Purpose :   initialization of ice salinity parameters
141      !!
142      !! ** Method  :   Read the namicesal namelist and check the parameter
143      !!              values called at the first timestep (nit000)
144      !!
145      !! ** input   :   Namelist namicesal
146      !!-------------------------------------------------------------------
147      NAMELIST/namicesal/ num_sal, bulk_sal, sal_G, time_G, sal_F, time_F,   &
148         &                s_i_max, s_i_min, s_i_0, s_i_1
149      !!-------------------------------------------------------------------
150      !
151      REWIND( numnam_ice )                   ! Read Namelist namicesal
152      READ  ( numnam_ice  , namicesal )
153      !
154      IF(lwp) THEN                           ! control print
155         WRITE(numout,*)
156         WRITE(numout,*) 'lim_thd_sal_init : Ice parameters for salinity '
157         WRITE(numout,*) '~~~~~~~~~~~~~~~~'
158         WRITE(numout,*) ' switch for salinity num_sal        : ', num_sal
159         WRITE(numout,*) ' bulk salinity value if num_sal = 1 : ', bulk_sal
160         WRITE(numout,*) ' restoring salinity for GD          : ', sal_G
161         WRITE(numout,*) ' restoring time for GD              : ', time_G
162         WRITE(numout,*) ' restoring salinity for flushing    : ', sal_F
163         WRITE(numout,*) ' restoring time for flushing        : ', time_F
164         WRITE(numout,*) ' Maximum tolerated ice salinity     : ', s_i_max
165         WRITE(numout,*) ' Minimum tolerated ice salinity     : ', s_i_min
166         WRITE(numout,*) ' 1st salinity for salinity profile  : ', s_i_0
167         WRITE(numout,*) ' 2nd salinity for salinity profile  : ', s_i_1
168      ENDIF
169      !
170   END SUBROUTINE lim_thd_sal_init
171
172#else
173   !!----------------------------------------------------------------------
174   !!   Default option         Dummy Module          No LIM-3 sea-ice model
175   !!----------------------------------------------------------------------
176#endif
177   !!======================================================================
178END MODULE limthd_sal
Note: See TracBrowser for help on using the repository browser.