New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcmod.F90 in branches/2013/dev_r4028_CNRS_LIM3/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2013/dev_r4028_CNRS_LIM3/NEMOGCM/NEMO/OPA_SRC/SBC/sbcmod.F90 @ 4649

Last change on this file since 4649 was 4649, checked in by clem, 10 years ago

finalizing LIM3 heat budget conservation + multiple minor bugs corrections

  • Property svn:keywords set to Id
File size: 25.7 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!            3.4  ! 2011-11  (C. Harris) CICE added as an option
14   !!            3.5  ! 2012-11  (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!   sbc_init       : read namsbc namelist
19   !!   sbc            : surface ocean momentum, heat and freshwater boundary conditions
20   !!----------------------------------------------------------------------
21   USE oce              ! ocean dynamics and tracers
22   USE dom_oce          ! ocean space and time domain
23   USE phycst           ! physical constants
24   USE sbc_oce          ! Surface boundary condition: ocean fields
25   USE sbc_ice          ! Surface boundary condition: ice fields
26   USE sbcdcy           ! surface boundary condition: diurnal cycle
27   USE sbcssm           ! surface boundary condition: sea-surface mean variables
28   USE sbcapr           ! surface boundary condition: atmospheric pressure
29   USE sbcana           ! surface boundary condition: analytical formulation
30   USE sbcflx           ! surface boundary condition: flux formulation
31   USE sbcblk_clio      ! surface boundary condition: bulk formulation : CLIO
32   USE sbcblk_core      ! surface boundary condition: bulk formulation : CORE
33   USE sbcblk_mfs       ! surface boundary condition: bulk formulation : MFS
34   USE sbcice_if        ! surface boundary condition: ice-if sea-ice model
35   USE sbcice_lim       ! surface boundary condition: LIM 3.0 sea-ice model
36   USE sbcice_lim_2     ! surface boundary condition: LIM 2.0 sea-ice model
37   USE sbcice_cice      ! surface boundary condition: CICE    sea-ice model
38   USE sbccpl           ! surface boundary condition: coupled florulation
39   USE cpl_oasis3, ONLY:lk_cpl      ! are we in coupled mode?
40   USE sbcssr           ! surface boundary condition: sea surface restoring
41   USE sbcrnf           ! surface boundary condition: runoffs
42   USE sbcfwb           ! surface boundary condition: freshwater budget
43   USE closea           ! closed sea
44   USE icbstp           ! Icebergs!
45
46   USE prtctl           ! Print control                    (prt_ctl routine)
47   USE iom              ! IOM library
48   USE in_out_manager   ! I/O manager
49   USE lib_mpp          ! MPP library
50   USE timing           ! Timing
51   USE sbcwave          ! Wave module
52
53   IMPLICIT NONE
54   PRIVATE
55
56   PUBLIC   sbc        ! routine called by step.F90
57   PUBLIC   sbc_init   ! routine called by opa.F90
58   
59   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
60     
61   !! * Substitutions
62#  include "domzgr_substitute.h90"
63   !!----------------------------------------------------------------------
64   !! NEMO/OPA 4.0 , NEMO-consortium (2011)
65   !! $Id$
66   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
67   !!----------------------------------------------------------------------
68CONTAINS
69
70   SUBROUTINE sbc_init
71      !!---------------------------------------------------------------------
72      !!                    ***  ROUTINE sbc_init ***
73      !!
74      !! ** Purpose :   Initialisation of the ocean surface boundary computation
75      !!
76      !! ** Method  :   Read the namsbc namelist and set derived parameters
77      !!                Call init routines for all other SBC modules that have one
78      !!
79      !! ** Action  : - read namsbc parameters
80      !!              - nsbc: type of sbc
81      !!----------------------------------------------------------------------
82      INTEGER ::   icpt   ! local integer
83      !!
84      NAMELIST/namsbc/ nn_fsbc   , ln_ana    , ln_flx,  ln_blk_clio, ln_blk_core, ln_cpl,   &
85         &             ln_blk_mfs, ln_apr_dyn, nn_ice,  nn_ice_embd, ln_dm2dc   , ln_rnf,   &
86         &             ln_ssr    , nn_fwb    , ln_cdgw , ln_wave , ln_sdw, cn_iceflx
87      !!----------------------------------------------------------------------
88
89      IF(lwp) THEN
90         WRITE(numout,*)
91         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
92         WRITE(numout,*) '~~~~~~~~ '
93      ENDIF
94
95      REWIND( numnam )           ! Read Namelist namsbc
96      READ  ( numnam, namsbc )
97
98      !                          ! overwrite namelist parameter using CPP key information
99      IF( Agrif_Root() ) THEN                ! AGRIF zoom
100        IF( lk_lim2 )   nn_ice      = 2
101        IF( lk_lim3 )   nn_ice      = 3
102        IF( lk_cice )   nn_ice      = 4
103      ENDIF
104      IF( cp_cfg == 'gyre' ) THEN            ! GYRE configuration
105          ln_ana      = .TRUE.   
106          nn_ice      =   0
107      ENDIF
108     
109      IF(lwp) THEN               ! Control print
110         WRITE(numout,*) '        Namelist namsbc (partly overwritten with CPP key setting)'
111         WRITE(numout,*) '           frequency update of sbc (and ice)             nn_fsbc     = ', nn_fsbc
112         WRITE(numout,*) '           Type of sbc : '
113         WRITE(numout,*) '              analytical formulation                     ln_ana      = ', ln_ana
114         WRITE(numout,*) '              flux       formulation                     ln_flx      = ', ln_flx
115         WRITE(numout,*) '              CLIO bulk  formulation                     ln_blk_clio = ', ln_blk_clio
116         WRITE(numout,*) '              CORE bulk  formulation                     ln_blk_core = ', ln_blk_core
117         WRITE(numout,*) '              MFS  bulk  formulation                     ln_blk_mfs  = ', ln_blk_mfs
118         WRITE(numout,*) '              coupled    formulation (T if key_sbc_cpl)  ln_cpl      = ', ln_cpl
119         WRITE(numout,*) '              Flux handling over ice categories          cn_iceflx   = ', TRIM (cn_iceflx)
120         WRITE(numout,*) '           Misc. options of sbc : '
121         WRITE(numout,*) '              Patm gradient added in ocean & ice Eqs.    ln_apr_dyn  = ', ln_apr_dyn
122         WRITE(numout,*) '              ice management in the sbc (=0/1/2/3)       nn_ice      = ', nn_ice 
123         WRITE(numout,*) '              ice-ocean embedded/levitating (=0/1/2)     nn_ice_embd = ', nn_ice_embd
124         WRITE(numout,*) '              daily mean to diurnal cycle qsr            ln_dm2dc    = ', ln_dm2dc 
125         WRITE(numout,*) '              runoff / runoff mouths                     ln_rnf      = ', ln_rnf
126         WRITE(numout,*) '              Sea Surface Restoring on SST and/or SSS    ln_ssr      = ', ln_ssr
127         WRITE(numout,*) '              FreshWater Budget control  (=0/1/2)        nn_fwb      = ', nn_fwb
128         WRITE(numout,*) '              closed sea (=0/1) (set in namdom)          nn_closea   = ', nn_closea
129      ENDIF
130
131      !   Flux handling over ice categories
132#if defined key_coupled 
133      SELECT CASE ( TRIM (cn_iceflx))
134      CASE ('ave')
135         ln_iceflx_ave    = .TRUE.
136         ln_iceflx_linear = .FALSE.
137      CASE ('linear')
138         ln_iceflx_ave    = .FALSE.
139         ln_iceflx_linear = .TRUE.
140      CASE default
141         ln_iceflx_ave    = .FALSE.
142         ln_iceflx_linear = .FALSE.
143      END SELECT
144      IF(lwp) WRITE(numout,*) '              Fluxes averaged over all ice categories         ln_iceflx_ave    = ', ln_iceflx_ave
145      IF(lwp) WRITE(numout,*) '              Fluxes distributed linearly over ice categories ln_iceflx_linear = ', ln_iceflx_linear
146#endif
147      !
148      !                              ! allocate sbc arrays
149      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_oce arrays' )
150
151      !                          ! Checks:
152      IF( .NOT. ln_rnf ) THEN                      ! no specific treatment in vicinity of river mouths
153         ln_rnf_mouth  = .false.                     
154         IF( sbc_rnf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_rnf arrays' )
155         nkrnf         = 0
156         rnf     (:,:) = 0.0_wp
157         rnf_b   (:,:) = 0.0_wp
158         rnfmsk  (:,:) = 0.0_wp
159         rnfmsk_z(:)   = 0.0_wp
160      ENDIF
161      IF( nn_ice == 0  )   fr_i(:,:) = 0.e0        ! no ice in the domain, ice fraction is always zero
162
163      sfx(:,:) = 0.0_wp                            ! the salt flux due to freezing/melting will be computed (i.e. will be non-zero)
164                                                   ! only if sea-ice is present
165 
166      fmmflx(:,:) = 0.0_wp                        ! freezing-melting array initialisation
167
168      !                                            ! restartability   
169      IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR.   &
170          MOD( nstock             , nn_fsbc) /= 0 ) THEN
171         WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock,   &
172            &           ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
173         CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
174      ENDIF
175      !
176      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
177         &  CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' )
178      !
179      IF( ( nn_ice == 2 .OR. nn_ice ==3 ) .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. lk_cpl ) )   &
180         &   CALL ctl_stop( 'LIM sea-ice model requires a bulk formulation or coupled configuration' )
181      IF( nn_ice == 4 .AND. .NOT.( ln_blk_core .OR. lk_cpl ) )   &
182         &   CALL ctl_stop( 'CICE sea-ice model requires ln_blk_core or lk_cpl' )
183      IF( nn_ice == 4 .AND. lk_agrif )   &
184         &   CALL ctl_stop( 'CICE sea-ice model not currently available with AGRIF' )
185      IF( ( nn_ice == 3 .OR. nn_ice == 4 ) .AND. nn_ice_embd == 0 )   &
186         &   CALL ctl_stop( 'LIM3 and CICE sea-ice models require nn_ice_embd = 1 or 2' )
187#if defined key_coupled
188      IF( ln_iceflx_ave .AND. ln_iceflx_linear ) &
189         &   CALL ctl_stop( ' ln_iceflx_ave and ln_iceflx_linear options are not compatible' )
190      IF( ( nn_ice ==3 .AND. lk_cpl) .AND. .NOT. ( ln_iceflx_ave .OR. ln_iceflx_linear ) ) &
191         &   CALL ctl_stop( ' With lim3 coupled, either ln_iceflx_ave or ln_iceflx_linear must be set to .TRUE.' )
192#endif     
193      IF( ln_dm2dc )   nday_qsr = -1   ! initialisation flag
194
195      IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk_core ) )   &
196         &   CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or core-bulk formulation' )
197     
198      IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) )  < 8 ) )   &
199         &   CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
200
201      IF ( ln_wave ) THEN
202      !Activated wave module but neither drag nor stokes drift activated
203         IF ( .NOT.(ln_cdgw .OR. ln_sdw) )   THEN
204            CALL ctl_warn( 'Ask for wave coupling but nor drag coefficient (ln_cdgw=F) neither stokes drift activated (ln_sdw=F)' )
205      !drag coefficient read from wave model definable only with mfs bulk formulae and core
206         ELSEIF (ln_cdgw .AND. .NOT.(ln_blk_mfs .OR. ln_blk_core) )       THEN       
207             CALL ctl_stop( 'drag coefficient read from wave model definable only with mfs bulk formulae and core')
208         ENDIF
209      ELSE
210      IF ( ln_cdgw .OR. ln_sdw  )                                         & 
211         &   CALL ctl_stop('Not Activated Wave Module (ln_wave=F) but     &
212         & asked coupling with drag coefficient (ln_cdgw =T) or Stokes drift (ln_sdw=T) ')
213      ENDIF 
214     
215      !                          ! Choice of the Surface Boudary Condition (set nsbc)
216      icpt = 0
217      IF( ln_ana          ) THEN   ;   nsbc =  1   ; icpt = icpt + 1   ;   ENDIF       ! analytical      formulation
218      IF( ln_flx          ) THEN   ;   nsbc =  2   ; icpt = icpt + 1   ;   ENDIF       ! flux            formulation
219      IF( ln_blk_clio     ) THEN   ;   nsbc =  3   ; icpt = icpt + 1   ;   ENDIF       ! CLIO bulk       formulation
220      IF( ln_blk_core     ) THEN   ;   nsbc =  4   ; icpt = icpt + 1   ;   ENDIF       ! CORE bulk       formulation
221      IF( ln_blk_mfs      ) THEN   ;   nsbc =  6   ; icpt = icpt + 1   ;   ENDIF       ! MFS  bulk       formulation
222      IF( ln_cpl          ) THEN   ;   nsbc =  5   ; icpt = icpt + 1   ;   ENDIF       ! Coupled         formulation
223      IF( cp_cfg == 'gyre') THEN   ;   nsbc =  0                       ;   ENDIF       ! GYRE analytical formulation
224      IF( lk_esopa        )            nsbc = -1                                       ! esopa test, ALL formulations
225      !
226      IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN
227         WRITE(numout,*)
228         WRITE(numout,*) '           E R R O R in setting the sbc, one and only one namelist/CPP key option '
229         WRITE(numout,*) '                     must be choosen. You choose ', icpt, ' option(s)'
230         WRITE(numout,*) '                     We stop'
231         nstop = nstop + 1
232      ENDIF
233      IF(lwp) THEN
234         WRITE(numout,*)
235         IF( nsbc == -1 )   WRITE(numout,*) '              ESOPA test All surface boundary conditions'
236         IF( nsbc ==  0 )   WRITE(numout,*) '              GYRE analytical formulation'
237         IF( nsbc ==  1 )   WRITE(numout,*) '              analytical formulation'
238         IF( nsbc ==  2 )   WRITE(numout,*) '              flux formulation'
239         IF( nsbc ==  3 )   WRITE(numout,*) '              CLIO bulk formulation'
240         IF( nsbc ==  4 )   WRITE(numout,*) '              CORE bulk formulation'
241         IF( nsbc ==  5 )   WRITE(numout,*) '              coupled formulation'
242         IF( nsbc ==  6 )   WRITE(numout,*) '              MFS Bulk formulation'
243      ENDIF
244      !
245                          CALL sbc_ssm_init               ! Sea-surface mean fields initialisation
246      !
247      IF( ln_ssr      )   CALL sbc_ssr_init               ! Sea-Surface Restoring initialisation
248      !
249      IF( nn_ice == 4 )   CALL cice_sbc_init( nsbc )      ! CICE initialisation
250      !
251   END SUBROUTINE sbc_init
252
253
254   SUBROUTINE sbc( kt )
255      !!---------------------------------------------------------------------
256      !!                    ***  ROUTINE sbc  ***
257      !!             
258      !! ** Purpose :   provide at each time-step the ocean surface boundary
259      !!                condition (momentum, heat and freshwater fluxes)
260      !!
261      !! ** Method  :   blah blah  to be written ?????????
262      !!                CAUTION : never mask the surface stress field (tke sbc)
263      !!
264      !! ** Action  : - set the ocean surface boundary condition at before and now
265      !!                time step, i.e. 
266      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b
267      !!                utau  , vtau  , qns  , qsr  , emp  , sfx  , qrp  , erp
268      !!              - updte the ice fraction : fr_i
269      !!----------------------------------------------------------------------
270      INTEGER, INTENT(in) ::   kt       ! ocean time step
271      !!---------------------------------------------------------------------
272      !
273      IF( nn_timing == 1 )  CALL timing_start('sbc')
274      !
275      !                                            ! ---------------------------------------- !
276      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
277         !                                         ! ---------------------------------------- !
278         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
279         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
280         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
281         ! The 3D heat content due to qsr forcing is treated in traqsr
282         ! qsr_b (:,:) = qsr (:,:)
283         emp_b(:,:) = emp(:,:)
284         sfx_b(:,:) = sfx(:,:)
285      ENDIF
286      !                                            ! ---------------------------------------- !
287      !                                            !        forcing field computation         !
288      !                                            ! ---------------------------------------- !
289      !
290      IF( ln_apr_dyn ) CALL sbc_apr( kt )                ! atmospheric pressure provided at kt+0.5*nn_fsbc
291                                                         ! (caution called before sbc_ssm)
292      !
293      CALL sbc_ssm( kt )                                 ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
294      !                                                  ! averaged over nf_sbc time-step
295
296      IF (ln_wave) CALL sbc_wave( kt )
297                                                   !==  sbc formulation  ==!
298                                                           
299      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
300      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, sfx)
301      CASE(  0 )   ;   CALL sbc_gyre    ( kt )                    ! analytical formulation : GYRE configuration
302      CASE(  1 )   ;   CALL sbc_ana     ( kt )                    ! analytical formulation : uniform sbc
303      CASE(  2 )   ;   CALL sbc_flx     ( kt )                    ! flux formulation
304      CASE(  3 )   ;   CALL sbc_blk_clio( kt )                    ! bulk formulation : CLIO for the ocean
305      CASE(  4 )   ;   CALL sbc_blk_core( kt )                    ! bulk formulation : CORE for the ocean
306      CASE(  5 )   ;   CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! coupled formulation
307      CASE(  6 )   ;   CALL sbc_blk_mfs ( kt )                    ! bulk formulation : MFS for the ocean
308      CASE( -1 )                               
309                       CALL sbc_ana     ( kt )                    ! ESOPA, test ALL the formulations
310                       CALL sbc_gyre    ( kt )                    !
311                       CALL sbc_flx     ( kt )                    !
312                       CALL sbc_blk_clio( kt )                    !
313                       CALL sbc_blk_core( kt )                    !
314                       CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   !
315      END SELECT
316
317      !                                            !==  Misc. Options  ==!
318     
319      SELECT CASE( nn_ice )                                       ! Update heat and freshwater fluxes over sea-ice areas
320      CASE(  1 )   ;         CALL sbc_ice_if   ( kt )                ! Ice-cover climatology ("Ice-if" model)
321      CASE(  2 )   ;         CALL sbc_ice_lim_2( kt, nsbc )          ! LIM-2 ice model
322      CASE(  3 )   ;         CALL sbc_ice_lim  ( kt, nsbc )          ! LIM-3 ice model
323      !is it useful?
324      CASE(  4 )   ;         CALL sbc_ice_cice ( kt, nsbc )          ! CICE ice model
325      END SELECT                                             
326
327      IF( ln_icebergs    )   CALL icb_stp( kt )                   ! compute icebergs
328
329      IF( ln_rnf         )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
330 
331      IF( ln_ssr         )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
332
333      IF( nn_fwb    /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
334
335      IF( nn_closea == 1 )   CALL sbc_clo( kt )                   ! treatment of closed sea in the model domain
336      !                                                           ! (update freshwater fluxes)
337!RBbug do not understand why see ticket 667
338      !clem-bugsal CALL lbc_lnk( emp, 'T', 1. )
339      !
340      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
341         !                                             ! ---------------------------------------- !
342         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
343            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
344            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
345            CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b )   ! before i-stress  (U-point)
346            CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b )   ! before j-stress  (V-point)
347            CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b  )   ! before non solar heat flux (T-point)
348            ! The 3D heat content due to qsr forcing is treated in traqsr
349            ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b  ) ! before     solar heat flux (T-point)
350            CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b  )    ! before     freshwater flux (T-point)
351            ! To ensure restart capability with 3.3x/3.4 restart files    !! to be removed in v3.6
352            IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN
353               CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b )  ! before salt flux (T-point)
354            ELSE
355               sfx_b (:,:) = sfx(:,:)
356            ENDIF
357         ELSE                                                   !* no restart: set from nit000 values
358            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
359            utau_b(:,:) = utau(:,:) 
360            vtau_b(:,:) = vtau(:,:)
361            qns_b (:,:) = qns (:,:)
362            emp_b (:,:) = emp(:,:)
363            sfx_b (:,:) = sfx(:,:)
364         ENDIF
365      ENDIF
366      !                                                ! ---------------------------------------- !
367      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
368         !                                             ! ---------------------------------------- !
369         IF(lwp) WRITE(numout,*)
370         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
371            &                    'at it= ', kt,' date= ', ndastp
372         IF(lwp) WRITE(numout,*) '~~~~'
373         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau )
374         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau )
375         CALL iom_rstput( kt, nitrst, numrow, 'qns_b'  , qns  )
376         ! The 3D heat content due to qsr forcing is treated in traqsr
377         ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr  )
378         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp  )
379         CALL iom_rstput( kt, nitrst, numrow, 'sfx_b' , sfx )
380      ENDIF
381
382      !                                                ! ---------------------------------------- !
383      !                                                !        Outputs and control print         !
384      !                                                ! ---------------------------------------- !
385      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
386         CALL iom_put( "empmr" , emp  - rnf )                   ! upward water flux
387         CALL iom_put( "saltflx", sfx  )                        ! downward salt flux 
388                                                                ! (includes virtual salt flux beneath ice
389                                                                ! in linear free surface case)
390         CALL iom_put( "fmmflx", fmmflx  )                      ! Freezing-melting water flux
391         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
392         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
393         CALL iom_put( "qsr"   ,        qsr )                   ! solar heat flux
394         IF( nn_ice > 0 )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
395      ENDIF
396      !
397      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at
398      CALL iom_put( "vtau", vtau )   ! j-wind stress    each time step in sea-ice)
399      CALL iom_put( "taum", taum )   ! wind stress module
400      CALL iom_put( "wspd", wndm )   ! wind speed  module
401      !
402      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
403         CALL prt_ctl(tab2d_1=fr_i             , clinfo1=' fr_i     - : ', mask1=tmask, ovlap=1 )
404         CALL prt_ctl(tab2d_1=(emp-rnf)        , clinfo1=' emp-rnf  - : ', mask1=tmask, ovlap=1 )
405         CALL prt_ctl(tab2d_1=(sfx-rnf)        , clinfo1=' sfx-rnf  - : ', mask1=tmask, ovlap=1 )
406         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask, ovlap=1 )
407         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask, ovlap=1 )
408         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, ovlap=1, kdim=jpk )
409         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst      - : ', mask1=tmask, ovlap=1, kdim=1   )
410         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss      - : ', mask1=tmask, ovlap=1, kdim=1   )
411         CALL prt_ctl(tab2d_1=utau             , clinfo1=' utau     - : ', mask1=umask,                      &
412            &         tab2d_2=vtau             , clinfo2=' vtau     - : ', mask2=vmask, ovlap=1 )
413      ENDIF
414
415      IF( kt == nitend )   CALL sbc_final         ! Close down surface module if necessary
416      !
417      IF( nn_timing == 1 )  CALL timing_stop('sbc')
418      !
419   END SUBROUTINE sbc
420
421
422   SUBROUTINE sbc_final
423      !!---------------------------------------------------------------------
424      !!                    ***  ROUTINE sbc_final  ***
425      !!
426      !! ** Purpose :   Finalize CICE (if used)
427      !!---------------------------------------------------------------------
428      !
429      IF( nn_ice == 4 )   CALL cice_sbc_final
430      !
431   END SUBROUTINE sbc_final
432
433   !!======================================================================
434END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.