!----------------------------------------------------------------------
! NEMO system team, System and Interface for oceanic RElocable Nesting
!----------------------------------------------------------------------
!
! MODULE: date
!
! DESCRIPTION:
!> @brief This module provide the calculation of Julian dates, and
!> do many manipulations with dates.<br/>
!> Actually we use Modified Julian Dates, with origin the 
!> 17 Nov 1858 at 00:00:00
!
!> @details
!>   define type TDATE:<br/>
!>   TYPE(TDATE) :: tl_date1<br/>
!>   default date is 17 Nov 1858 at 00:00:00<br/>
!>
!>   to intialise date : <br/>
!>   - from date of the day at 12:00:00 : tl_date1=date_today()<br/>
!>   - from date and time of the day    : tl_date1=date_now()<br/>
!>   - from julian day                  : tl_date1=date_init(1.)<br/>  
!>   - from year month day              : tl_date1=date_init(2012,12,10)<br/>
!>
!>   to print date in format YYYY-MM-DD hh:mm:ss<br/>
!>   CHARACTER(LEN=lc) :: cl_date<br/>
!>   cl_date=date_print(tl_date1)<br/>
!>   PRINT *, TRIM(cl_date)<br/>
!>
!>   to print day if the week:<br/>
!>   PRINT *,"dow ", tl_date1\%i_dow<br/>
!>   to print last day of the month:<br/>
!>   PRINT *,"last day ", tl_date1\%i_lday<br/>
!>   to know if year is a leap year:<br/>
!>   LOGICAL :: ll_isleap<br/>
!>   ll_isleap=date_leapyear(tl_date1)<br/>
!>
!>   to compute difference between to dates:<br/>
!>   tl_date2=date_init(2010,12,10)<br/>
!>   print *,"diff ",tl_date1-tl_date2<br/>
!>
!>   to add or substract nday to a date:<br/>
!>   tl_date2=tl_date1+2.<br/>
!>   print *,"add ",trim(date_print(tl_date2))<br/>
!>   tl_date2=tl_date1-2.6<br/>
!>   print *,"sub ",trim(date_print(tl_date2))<br/>
!>
!>   to print julian day:<br/>
!>   print *," julian day",tl_date1\%r_jd<br/>
!>
!>   to print CNES julian day (origin 1950-01-01 00:00:00)<br/>
!>   print *," CNES julian day",tl_date1\%r_jc<br/>
!>
!>   to create pseudo julian day with origin date_now:<br/>
!>   tl_date1=date_init(2012,12,10,td_dateo=date_now())<br/>
!>   print *," new julian day",tl_date1\%r_jc<br/>
!>   Note that you erase CNES julian day when doing so<br/> 
!>
!>   to print julian day in seconds:<br/>
!>   print *, tl_date1\%k_jdsec<br/>
!>   to print CNES or new julian day in seconds:<br/>
!>   print *, tl_date1\%k_jcsec<br/>
!>
!> @author
!> J.Paul
! REVISION HISTORY:
!> @date Nov, 2013 - Initial Version
!
!> @note This module is based on Perderabo's date calculator (ksh)
!> @note Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
!> @todo
!> - check if real(sp), integer(i8) is enough
!> - see calendar.f90 and select Gregorian, NoLeap, or D360 calendar
!> - add suffix to number
!> - add log message
!----------------------------------------------------------------------
MODULE date
   USE global                          ! global variable
   USE kind                            ! F90 kind parameter
   USE fct                             ! basic useful function
   USE logger                             ! log file manager
   IMPLICIT NONE
   PRIVATE
   ! NOTE_avoid_public_variables_if_possible

   ! type and variable
   PUBLIC :: TDATE              ! date structure

   ! function and subroutine
   PUBLIC :: OPERATOR(-)        ! substract two dates or n days to a date
   PUBLIC :: OPERATOR(+)        ! add n days to a date
   PUBLIC :: date_init          ! initiazed date structure form julian day or year month day
   PUBLIC :: date_now           ! return the date and time
   PUBLIC :: date_today         ! return the date of the day at 12:00:00
   PUBLIC :: date_print         ! print the date with format YYYY-MM-DD hh:mm:ss
   PUBLIC :: date_leapyear      ! check if year is a leap year

   PRIVATE :: date__init_fmtdate ! initiazed date structure from character YYYY-MM-DD hh:mm:ss
   PRIVATE :: date__init_jd      ! initiazed date structure from julian day
   PRIVATE :: date__init_nsec    ! initiazed date structure from number of second since origin of julian day
   PRIVATE :: date__init_ymd     ! initiazed date structure from year month day
   PRIVATE :: date__addnday      ! add nday to a date
   PRIVATE :: date__subnday      ! substract nday to a date
   PRIVATE :: date__diffdate     ! compute number of day between two dates 
   PRIVATE :: date__lastday      ! compute last day of the month
   PRIVATE :: date__ymd2jd       ! compute julian day from year month day
   PRIVATE :: date__jd2ymd       ! compute year month day from julian day 
   PRIVATE :: date__jc2jd        ! compute julian day from pseudo julian day
   PRIVATE :: date__jd2jc        ! compute pseudo julian day with new date origin
   PRIVATE :: date__jd2dow       ! compute the day of week from julian day
   PRIVATE :: date__hms2jd       ! compute fraction of a day from hour, minute, second
   PRIVATE :: date__jd2hms       ! compute hour, minute, second from julian fraction
   PRIVATE :: date__check        ! check date in date structure
   PRIVATE :: date__adjust       ! adjust date
   PRIVATE :: date__jd2sec       ! convert julian day in seconds since julian day origin 
   PRIVATE :: date__sec2jd       ! convert seconds since julian day origin in julian day

   !> @struct TDATE
   TYPE TDATE
      INTEGER(i4) :: i_year  = 1858   !< year
      INTEGER(i4) :: i_month = 11     !< month
      INTEGER(i4) :: i_day   = 17     !< day
      INTEGER(i4) :: i_hms   = 0      !< fraction of the day
      INTEGER(i4) :: i_hour  = 0      !< hour
      INTEGER(i4) :: i_min   = 0      !< min
      INTEGER(i4) :: i_sec   = 0      !< sec
      INTEGER(i4) :: i_dow   = 0      !< day of week
      INTEGER(i4) :: i_lday  = 0      !< last day of the month
      REAL(sp)    :: r_jd = 0         !< julian day (origin : 1858/11/17 00:00:00)
      REAL(sp)    :: r_jc = 0         !< CNES julian day or pseudo julian day with new date origin    
      INTEGER(i8) :: k_jdsec  = 0     !< number of seconds since julian day origin
      INTEGER(i8) :: k_jcsec  = 0     !< number of seconds since CNES or pseudo julian day origin
   END TYPE TDATE   

   !  module variable   
   CHARACTER(LEN=lc), PARAMETER :: cm_fmtdate = &  !< date format
   &  "(i0.4,'-',i0.2,'-',i0.2,1x,i0.2,':',i0.2,':',i0.2)"

   INTEGER(i4), PARAMETER :: im_secbyday = 86400    !< number of second by day   

   INTERFACE date_init
      MODULE PROCEDURE date__init_jd    ! initiazed date structure from julian day
      MODULE PROCEDURE date__init_nsec  ! initiazed date structure from number of second since origin of julian day
      MODULE PROCEDURE date__init_ymd   ! initiazed date structure from year month day
      MODULE PROCEDURE date__init_fmtdate   ! initiazed date structure from character YYYY-MM-DD hh:mm:ss
   END INTERFACE date_init

   INTERFACE OPERATOR(+)
      MODULE PROCEDURE date__addnday   ! add nday to a date
   END INTERFACE

   INTERFACE OPERATOR(-)
      MODULE PROCEDURE date__subnday   ! substract nday to a date
      MODULE PROCEDURE date__diffdate  ! compute number of day between two dates
   END INTERFACE

CONTAINS
   !-------------------------------------------------------------------
   !> @brief This function print the date with 
   !> format YYYY/MM/DD hh:mm:ss
   !>
   !> @author J.Paul
   !> - Nov, 2013- Initial Version
   !
   !> @param[in] td_date : date strutcutre
   !> @return date in format YYYY-MM-DD hh:mm:ss
   !-------------------------------------------------------------------
   ! @code
   CHARACTER(LEN=lc) FUNCTION date_print(td_date)
      IMPLICIT NONE
      ! Argument   
      TYPE(TDATE), INTENT(IN) :: td_date
      !----------------------------------------------------------------

      WRITE(date_print,cm_fmtdate) &
      &    td_date%i_year,td_date%i_month,td_date%i_day, &
      &    td_date%i_hour,td_date%i_min,td_date%i_sec

   END FUNCTION date_print
   ! @endcode
   !-------------------------------------------------------------------
   !> @brief This function check if year is a leap year.
   !>
   !> @author J.Paul
   !> - Nov, 2013- Initial Version
   !
   !> @param[in] td_date : date strutcutre
   !> @return true if year is leap year
   !-------------------------------------------------------------------
   ! @code
   LOGICAL FUNCTION date_leapyear(td_date)
      IMPLICIT NONE
      ! Argument   
      TYPE(TDATE), INTENT(IN) :: td_date
      !----------------------------------------------------------------

      date_leapyear=.false.
      IF( (MOD(td_date%i_year,100_i4)==0) )THEN
         IF( (MOD(td_date%i_year,400_i4)==0) )THEN
            date_leapyear=.true.
         ENDIF
      ELSE
         IF( (MOD(td_date%i_year,4_i4)==0) )THEN
            date_leapyear=.true.
         ENDIF
      ENDIF      

   END FUNCTION date_leapyear
   ! @endcode
   !-------------------------------------------------------------------
   !> @brief This function return the date and time 
   !>
   !> @author J.Paul
   !> - Nov, 2013- Initial Version
   !
   !> @return date and time of the day in a date structure
   !-------------------------------------------------------------------
   ! @code
   TYPE(TDATE) FUNCTION date_now()
      IMPLICIT NONE
      ! local variable
      INTEGER(sp), DIMENSION(8) :: il_values
      !----------------------------------------------------------------

      CALL DATE_AND_TIME( values= il_values)

      date_now=date_init( il_values(1), il_values(2), il_values(3), &
      &                   il_values(5), il_values(6), il_values(7) )

   END FUNCTION date_now
   ! @endcode
   !-------------------------------------------------------------------
   !> @brief This function return the date of the day at 12:00:00 
   !>
   !> @author J.Paul
   !> - Nov, 2013- Initial Version
   !
   !> @return date of the day at 12:00:00 in a date structure
   !-------------------------------------------------------------------
   ! @code
   TYPE(TDATE) FUNCTION date_today()
      IMPLICIT NONE
      ! local variable
      INTEGER(sp), DIMENSION(8) :: il_values
      !----------------------------------------------------------------

      CALL DATE_AND_TIME( values= il_values)

      date_today=date_init( il_values(1), il_values(2), il_values(3), 12_i4 )

   END FUNCTION date_today
   ! @endcode
   !-------------------------------------------------------------------
   !> @brief This function initiazed date structure from a character 
   !> date with format YYYY-MM-DD hh:mm:ss
   !>
   !> @author J.Paul
   !> - Nov, 2013- Initial Version
   !
   !> @param[in] cd_date : date in format YYYY-MM-DD hh:mm:ss
   !> @param[in] td_dateo : new date origin for pseudo julian day
   !> @return date structure
   !-------------------------------------------------------------------
   ! @code
   TYPE(TDATE) FUNCTION date__init_fmtdate(cd_date, td_dateo)
      IMPLICIT NONE
      ! Argument   
      CHARACTER(LEN=*), INTENT(IN)  :: cd_date
      TYPE(TDATE),      INTENT(IN), OPTIONAL :: td_dateo

      ! local variable
      CHARACTER(LEN=lc) :: cl_date
      CHARACTER(LEN=lc) :: cl_year
      CHARACTER(LEN=lc) :: cl_month
      CHARACTER(LEN=lc) :: cl_day
      CHARACTER(LEN=lc) :: cl_hour
      CHARACTER(LEN=lc) :: cl_min
      CHARACTER(LEN=lc) :: cl_sec

      INTEGER(i4) :: il_year
      INTEGER(i4) :: il_month
      INTEGER(i4) :: il_day
      INTEGER(i4) :: il_hour
      INTEGER(i4) :: il_min
      INTEGER(i4) :: il_sec
      !----------------------------------------------------------------

      cl_date=TRIM(ADJUSTL(cd_date))

      cl_year=cl_date(1:4)
      READ(cl_year,*) il_year
      cl_month=cl_date(6:7)
      READ(cl_month, *) il_month
      cl_day=cl_date(9:10)
      READ(cl_day, *) il_day
      cl_hour=cl_date(12:13)
      READ(cl_hour, *) il_hour
      cl_min=cl_date(15:16)
      READ(cl_min, *) il_min
      cl_sec=cl_date(18:19)
      READ(cl_sec, *) il_sec

      date__init_fmtdate = date_init( il_year, il_month, il_day, il_hour, &
      &                               il_min, il_sec, td_dateo=td_dateo )

   END FUNCTION date__init_fmtdate
   ! @endcode   
   !-------------------------------------------------------------------
   !> @brief This function initiazed date structure from julian day<br/>
   !> optionaly create pseudo julian day with new origin<br/>
   !> julian day origin is 17 Nov 1858 at 00:00:00
   !>
   !> @author J.Paul
   !> - Nov, 2013- Initial Version
   !
   !> @param[in] rd_jd : julian day
   !> @param[in] td_dateo : new date origin for pseudo julian day
   !
   !> @return date structure of julian day
   !-------------------------------------------------------------------
   ! @code
   TYPE(TDATE) FUNCTION date__init_jd(rd_jd, td_dateo)
      IMPLICIT NONE
      !Argument
      REAL(sp),    INTENT(IN)  :: rd_jd
      TYPE(TDATE), INTENT(IN), OPTIONAL :: td_dateo
      !----------------------------------------------------------------
      IF( PRESENT(td_dateo) )THEN
         CALL date__check(td_dateo)

         ! pseudo julian day with origin dateo
         date__init_jd%r_jc=rd_jd
         date__init_jd%k_jcsec=date__jd2sec(rd_jd)

         ! convert to truly julian day
         CALL date__jc2jd(date__init_jd, td_dateo)
      ELSE
         date__init_jd%r_jd=rd_jd
         date__init_jd%k_jdsec=date__jd2sec(rd_jd)

         ! compute CNES julian day
         CALL date__jd2jc(date__init_jd)
      ENDIF

      ! check input data
      CALL date__check(date__init_jd)

      ! compute year month day hour min sec 
      CALL date__jd2ymd(date__init_jd)

      ! compute day of the wekk
      CALL date__jd2dow(date__init_jd)

      !compute last day of the month
      date__init_jd%i_lday=date__lastday(date__init_jd)

   END FUNCTION date__init_jd
   ! @endcode
   !-------------------------------------------------------------------
   !> @brief This function initiazed date structure from number of 
   !> second since julian day origin<br/>
   !> optionaly create pseudo julian day with new origin
   !>
   !> @author J.Paul
   !> - Nov, 2013- Initial Version
   !
   !> @param[in] rd_jd : julian day
   !> @param[in] td_dateo : new date origin for pseudo julian day
   !
   !> @return date structure of julian day
   !-------------------------------------------------------------------
   ! @code
   TYPE(TDATE) FUNCTION date__init_nsec(kd_nsec, td_dateo)
      IMPLICIT NONE
      !Argument
      INTEGER(i8), INTENT(IN)  :: kd_nsec
      TYPE(TDATE), INTENT(IN), OPTIONAL :: td_dateo
      !----------------------------------------------------------------
      IF( PRESENT(td_dateo) )THEN
         date__init_nsec=date_init( date__sec2jd(kd_nsec), td_dateo )
      ELSE
         date__init_nsec=date_init( date__sec2jd(kd_nsec) )
      ENDIF

   END FUNCTION date__init_nsec
   ! @endcode   
   !-------------------------------------------------------------------
   !> @brief This function initiazed date structure form year month day
   !> and optionnaly hour min sec<br/>
   !> optionaly create pseudo julian day with new origin
   !
   !> @author J.Paul
   !> - Nov, 2013- Initial Version
   !
   !> @param[in] id_year
   !> @param[in] id_month
   !> @param[in] id_day
   !> @param[in] id_hour
   !> @param[in] id_min
   !> @param[in] id_sec
   !> @param[in] td_dateo : new date origin for pseudo julian day
   !
   !> @return date structure of year month day
   !-------------------------------------------------------------------
   ! @code
   TYPE(TDATE) FUNCTION date__init_ymd(id_year, id_month, id_day,  &
   &                                   id_hour, id_min, id_sec, &
   &                                   td_dateo)
      IMPLICIT NONE
      !Argument
      INTEGER(i4), INTENT(IN) :: id_year
      INTEGER(i4), INTENT(IN) :: id_month
      INTEGER(i4), INTENT(IN) :: id_day
      INTEGER(i4), INTENT(IN), OPTIONAL :: id_hour
      INTEGER(i4), INTENT(IN), OPTIONAL :: id_min
      INTEGER(i4), INTENT(IN), OPTIONAL :: id_sec
      TYPE(TDATE), INTENT(IN), OPTIONAL :: td_dateo
      !----------------------------------------------------------------
      date__init_ymd%i_year=id_year
      date__init_ymd%i_month=id_month
      date__init_ymd%i_day=id_day
      IF( PRESENT(id_hour) )THEN
         date__init_ymd%i_hour=id_hour
      ENDIF
      IF( PRESENT(id_min) )THEN
         date__init_ymd%i_min=id_min
      ENDIF   
      IF( PRESENT(id_sec) )THEN   
         date__init_ymd%i_sec=id_sec
      ENDIF   
      ! check input data
      CALL date__check(date__init_ymd)

      ! compute julian day
      CALL date__ymd2jd(date__init_ymd)

      IF( PRESENT(td_dateo) )THEN
         CALL date__check(td_dateo)
         ! compute julian day with origin dateo
         CALL date__jd2jc(date__init_ymd, td_dateo)         
      ELSE
         ! compute CNES julian day
         CALL date__jd2jc(date__init_ymd)
      ENDIF      

      ! compute day of the week
      CALL date__jd2dow(date__init_ymd)

      !compute last day of the month
      date__init_ymd%i_lday=date__lastday(date__init_ymd)

   END FUNCTION date__init_ymd
   ! @endcode
   !-------------------------------------------------------------------
   !> @brief This function compute number of day between two dates<br/> 
   !> nday= date1 - date2
   !
   !> @author J.Paul
   !> - Nov, 2013- Initial Version
   !
   !> @param[in] td_date1 : first date strutcutre
   !> @param[in] td_date2 : second date strutcutre
   !> @return nday
   !-------------------------------------------------------------------
   ! @code
   REAL(sp) FUNCTION date__diffdate(td_date1, td_date2)
      IMPLICIT NONE
       
      !Argument
      TYPE(TDATE), INTENT(IN) :: td_date1
      TYPE(TDATE), INTENT(IN) :: td_date2
      !----------------------------------------------------------------

      ! check year month day hour min sec
      CALL date__check(td_date1)   
      CALL date__check(td_date2)   

      date__diffdate = td_date1%r_jd - td_date2%r_jd

   END FUNCTION date__diffdate
   ! @endcode
   !-------------------------------------------------------------------
   !> @brief This function substract nday to a date 
   !> date2 = date1 - nday
   !>
   !> @author J.Paul
   !> - Nov, 2013- Initial Version
   !
   !> @param[in] td_date : date strutcutre
   !> @param[in] rd_nday : number of day
   !> @return date strutcutre of date - nday
   !-------------------------------------------------------------------
   ! @code
   TYPE(TDATE) FUNCTION date__subnday(td_date, rd_nday)
      IMPLICIT NONE
      !Argument
      TYPE(TDATE), INTENT(IN) :: td_date
      REAL(sp),    INTENT(IN) :: rd_nday
      !----------------------------------------------------------------

      ! check year month day hour min sec
      CALL date__check(td_date)   

      date__subnday=date__init_jd(td_date%r_jd-rd_nday)

   END FUNCTION date__subnday
   ! @endcode
   !-------------------------------------------------------------------
   !> @brief This function add nday to a date  
   !> date2 = date1 + nday
   !>
   !> @author J.Paul
   !> - Nov, 2013- Initial Version
   !
   !> @param[in] td_date : date strutcutre
   !> @param[in] rd_nday : number of day
   !> @return date strutcutre of date + nday
   !-------------------------------------------------------------------
   ! @code
   TYPE(TDATE) FUNCTION date__addnday(td_date, rd_nday)
      IMPLICIT NONE
      !Argument
      TYPE(TDATE), INTENT(IN) :: td_date
      REAL(sp),    INTENT(IN) :: rd_nday
      !----------------------------------------------------------------

      ! check year month day hour min sec
      CALL date__check(td_date)   

      date__addnday=date__init_jd(td_date%r_jd+rd_nday)

   END FUNCTION date__addnday
   ! @endcode
   !-------------------------------------------------------------------
   !> @brief This subroutine compute last day of the month
   !
   !> @author J.Paul
   !> - Nov, 2013- Initial Version
   !
   !> @param[inout] td_date : date strutcutre
   !-------------------------------------------------------------------
   ! @code
   INTEGER(i4) FUNCTION date__lastday(td_date)
      IMPLICIT NONE
      ! Argument   
      TYPE(TDATE), INTENT(IN) :: td_date

      ! local variable
      INTEGER, DIMENSION(12), PARAMETER :: il_lastdaytab = &
      &        (/31,28,31,30,31,30,31,31,30,31,30,31/)
      !----------------------------------------------------------------

      ! general case
      IF( td_date%i_month /= 2 )THEN
         date__lastday=il_lastdaytab(td_date%i_month)
      ELSE
         IF( date_leapyear(td_date) )THEN
            date__lastday=29
         ELSE
            date__lastday=il_lastdaytab(td_date%i_month)
         ENDIF
      ENDIF

   END FUNCTION date__lastday
   ! @endcode   
   !-------------------------------------------------------------------
   !> @brief This subroutine compute julian day from year month day
   !>
   !> @author J.Paul
   !> - Nov, 2013- Initial Version
   !
   !> @param[inout] td_date : date strutcutre
   !> @return julian day in the date strutcutre
   !-------------------------------------------------------------------
   ! @code
   SUBROUTINE date__ymd2jd(td_date)
      IMPLICIT NONE
      ! Argument   
      TYPE(TDATE), INTENT(INOUT) :: td_date

      ! local variable
      REAL(sp) :: rl_standard_jd
      REAL(sp) :: rl_frac
      !----------------------------------------------------------------

      rl_standard_jd= td_date%i_day - 32075                               & 
          & + 1461 * (td_date%i_year + 4800 - (14 - td_date%i_month)/12)/4  &
          & + 367 * (td_date%i_month - 2 + (14 - td_date%i_month)/12*12)/12 &
          & - 3 * ((td_date%i_year + 4900 - (14 - td_date%i_month)/12)/100)/4
      
      td_date%r_jd = rl_standard_jd-2400001 ! origin : 17 nov 1858 h00m00s00

      ! compute fraction of day
      rl_frac=date__hms2jd(td_date)

      td_date%r_jd = td_date%r_jd + rl_frac

      td_date%k_jdsec = date__jd2sec( td_date%r_jd ) 

   END SUBROUTINE date__ymd2jd
   ! @endcode   
   !-------------------------------------------------------------------
   !> @brief This subroutine compute year month day from julian day
   !>
   !> @author J.Paul
   !> - Nov, 2013- Initial Version
   !
   !> @param[inout] td_date : date strutcutre
   !> @return year month day in the date strutcutre
   !-------------------------------------------------------------------
   ! @code
   SUBROUTINE date__jd2ymd(td_date)
      IMPLICIT NONE
      ! Argument   
      TYPE(TDATE), INTENT(INOUT) :: td_date

      ! local variable
      REAL(sp) :: rl_frac
      INTEGER(i4) :: il_standard_jd
      INTEGER(i4) :: il_temp1
      INTEGER(i4) :: il_temp2
      !----------------------------------------------------------------

      ! check year month day hour min sec
      CALL date__check(td_date)   

      il_standard_jd=INT( td_date%r_jd+2400001, i4 )
      rl_frac=(td_date%r_jd+2400001)-il_standard_jd

      il_temp1=il_standard_jd + 68569
      il_temp2=4*il_temp1/146097
      il_temp1=il_temp1 - (146097 * il_temp2 + 3) / 4
      td_date%i_year  = 4000 * (il_temp1 + 1) / 1461001
      il_temp1 = il_temp1 - 1461 * td_date%i_year/4 + 31
      td_date%i_month = 80 * il_temp1 / 2447
      td_date%i_day   = il_temp1 - 2447 * td_date%i_month / 80
      il_temp1 = td_date%i_month / 11
      td_date%i_month = td_date%i_month + 2 - 12 * il_temp1
      td_date%i_year  = 100 * (il_temp2 - 49) + td_date%i_year + il_temp1

      ! compute hour, minute, second from julian fraction
      CALL date__jd2hms(td_date)

      ! adjust date
      CALL date__adjust(td_date)

   END SUBROUTINE date__jd2ymd
   ! @endcode
   !-------------------------------------------------------------------
   !> @brief This subroutine compute julian day from pseudo julian day 
   !> with new date origin<br/>
   !>
   !> @author J.Paul
   !> - Nov, 2013- Initial Version
   !
   !> @param[inout] td_date : date
   !> @return julian day inside input date structure
   !-------------------------------------------------------------------
   ! @code
   SUBROUTINE date__jc2jd(td_date, td_dateo)
      IMPLICIT NONE
      ! Argument   
      TYPE(TDATE), INTENT(INOUT) :: td_date
      TYPE(TDATE), INTENT(IN) :: td_dateo

      ! local variable
      TYPE(TDATE) :: tl_date
      REAL(sp)    :: rl_nday
      !----------------------------------------------------------------
      ! origin julian day
      tl_date=date_init(1858,11,17)

      rl_nday=td_dateo-tl_date

      ! compute julian day
      td_date%r_jd = td_date%r_jc + rl_nday
      ! compute number of second since julian day origin
      td_date%k_jdsec = date__jd2sec(td_date%r_jd)

   END SUBROUTINE date__jc2jd
   ! @endcode   
   !-------------------------------------------------------------------
   !> @brief This subroutine compute pseudo julian day with new date origin<br/>
   !>  default new origin is CNES julian day origin: 1950/01/01
   !>
   !> @author J.Paul
   !> - Nov, 2013- Initial Version
   !
   !> @param[inout] td_date : date
   !> @param[in] td_dateo : new origin date
   !> @return pseudo julian day inside input date structure
   !-------------------------------------------------------------------
   ! @code
   SUBROUTINE date__jd2jc(td_date, td_dateo)
      IMPLICIT NONE
      ! Argument   
      TYPE(TDATE), INTENT(INOUT) :: td_date
      TYPE(TDATE), INTENT(IN),   OPTIONAL :: td_dateo

      ! local variable
      TYPE(TDATE) :: tl_dateo
      !----------------------------------------------------------------
      IF( PRESENT(td_dateo) )THEN
         td_date%r_jc=td_date%r_jd-td_dateo%r_jd
      ELSE
         ! CNES julian day origin
         tl_dateo%i_year = 1950
         tl_dateo%i_month = 1
         tl_dateo%i_day = 1

         CALL date__ymd2jd(tl_dateo)

         td_date%r_jc = td_date%r_jd-tl_dateo%r_jd
      ENDIF

      td_date%k_jcsec = date__jd2sec(td_date%r_jc)

   END SUBROUTINE date__jd2jc
   ! @endcode   
   !-------------------------------------------------------------------
   !> @brief This subroutine compute the day of week from julian day<br/>
   !>  days   : Sunday Monday Tuesday Wednesday Thursday Friday Saturday<br/>
   !>  numday : 0      1      2       3         4        5      6<br/>
   !>
   !> @author J.Paul
   !> - Nov, 2013- Initial Version
   !
   !> @param[inout] td_date : date strutcutre
   !> @return day of week inside input date structure 
   !-------------------------------------------------------------------
   ! @code
   SUBROUTINE date__jd2dow(td_date)
      IMPLICIT NONE
      ! Argument   
      TYPE(TDATE), INTENT(INOUT) :: td_date
      !----------------------------------------------------------------

      td_date%i_dow=MOD((INT(AINT(td_date%r_jd))+3),7)

   END SUBROUTINE date__jd2dow
   ! @endcode   
   !-------------------------------------------------------------------
   !> @brief This function compute fraction of a day from 
   !> hour, minute, second 
   !>
   !> @author J.Paul
   !> - Nov, 2013- Initial Version
   !
   !> @param[in] td_date : date strutcutre
   !> @return fraction of the day
   !-------------------------------------------------------------------
   ! @code
   REAL(sp) FUNCTION date__hms2jd(td_date)
      IMPLICIT NONE
      ! Argument   
      TYPE(TDATE), INTENT(IN) :: td_date
      !----------------------------------------------------------------

      !  compute real seconds
      date__hms2jd = REAL( td_date%i_sec, sp )   
      !  compute real minutes
      date__hms2jd = REAL( td_date%i_min, sp ) + date__hms2jd/60.0
      !  compute real hours
      date__hms2jd = REAL( td_date%i_hour, sp ) + date__hms2jd/60.0
      !  julian fraction of a day
      date__hms2jd = date__hms2jd/24.0

   END FUNCTION date__hms2jd
   ! @endcode 
   !-------------------------------------------------------------------
   !> @brief This function compute hour, minute, second from julian 
   !> fraction
   !>
   !> @author J.Paul
   !> - Nov, 2013- Initial Version
   !
   !> @param[in] td_date : date strutcutre
   !> @return date strutcutre
   !-------------------------------------------------------------------
   ! @code
   SUBROUTINE date__jd2hms(td_date)
      IMPLICIT NONE
      ! Argument   
      TYPE(TDATE), INTENT(INOUT) :: td_date

      !local variable
      REAL(sp) :: rl_fract
      !----------------------------------------------------------------

      rl_fract=(td_date%r_jd)-AINT(td_date%r_jd)
      !  compute hour
      td_date%i_hour = INT( rl_fract * 24.0, i4 )
      rl_fract = ( rl_fract - REAL( td_date%i_hour, sp ) / 24.0) * 24.0
      !  compute minute
      td_date%i_min = INT( rl_fract * 60.0, i4 )
      rl_fract = ( rl_fract - REAL( td_date%i_min, sp ) / 60.0) * 60.0
      !  compute second
      td_date%i_sec = NINT( rl_fract * 60.0, i4 )

   END SUBROUTINE date__jd2hms
   ! @endcode   
   !-------------------------------------------------------------------
   !> @brief This subroutine check date express in date structure
   !>
   !> @author J.Paul
   !> - Nov, 2013- Initial Version
   !
   !> @param[in] td_date : date strutcutre
   !-------------------------------------------------------------------
   ! @code
   SUBROUTINE date__check(td_date)
      IMPLICIT NONE
      ! Argument   
      TYPE(TDATE), INTENT(IN) :: td_date

      ! local variable
      INTEGER(i4)       :: il_lastday
      INTEGER(i4)       :: il_status
      CHARACTER(LEN=lc) :: cl_msg
      !----------------------------------------------------------------

      ! check year
      IF( td_date%i_year < 1858_i4 .OR. td_date%i_year > 39999_i4 )THEN
         WRITE(cl_msg,*) "year ",td_date%i_year," out of range"
         CALL logger_error(cl_msg)
         CALL fct_err(il_status)
      ENDIF
      ! check month
      IF( td_date%i_month < 1_i4 .OR. td_date%i_month > 12_i4 )THEN
         WRITE(cl_msg,*) "month ",td_date%i_month," out of range"
         CALL logger_error(cl_msg)
         CALL fct_err(il_status)
      ENDIF
      ! check day
      il_lastday=date__lastday(td_date)
      IF( td_date%i_day < 1_i4 .OR. td_date%i_day > il_lastday )THEN
         WRITE(cl_msg,*) "day ",td_date%i_day," out of range"
         CALL logger_error(cl_msg)
         CALL fct_err(il_status)
      ENDIF
      ! check hour
      IF( td_date%i_hour < 0_i4 .OR. td_date%i_hour > 23_i4 )THEN
         WRITE(cl_msg,*) "hour ",td_date%i_hour," out of range"
         CALL logger_error(cl_msg)
         CALL fct_err(il_status)
      ENDIF
      ! check minutes
      IF( td_date%i_min < 0_i4 .OR. td_date%i_min > 59_i4 )THEN
         WRITE(cl_msg,*) "minutes ",td_date%i_min," out of range"
         CALL logger_error(cl_msg)
         CALL fct_err(il_status)
      ENDIF   
      ! check seconds
      IF( td_date%i_sec < 0_i4 .OR. td_date%i_sec > 59_i4 )THEN
         WRITE(cl_msg,*) "seconds ",td_date%i_sec," out of range"
         CALL logger_error(cl_msg)
         CALL fct_err(il_status)
      ENDIF

      ! check julian day
      IF( td_date%r_jd < 0_sp .OR. td_date%r_jd > 782028_sp )THEN
         WRITE(cl_msg,*) "julian day ",td_date%r_jd," out of range"
         CALL logger_error(cl_msg)
         CALL fct_err(il_status)
      ENDIF

   END SUBROUTINE date__check
   ! @endcode   
   !-------------------------------------------------------------------
   !> @brief This subroutine adjust date
   !>
   !> @author J.Paul
   !> - Nov, 2013- Initial Version
   !
   !> @param[inout] td_date : date strutcutre
   !-------------------------------------------------------------------
   ! @code
   SUBROUTINE date__adjust(td_date)
      IMPLICIT NONE
      ! Argument   
      TYPE(TDATE), INTENT(INOUT) :: td_date
      !----------------------------------------------------------------

      IF( td_date%i_sec == 60 )THEN
         td_date%i_sec=0
         td_date%i_min=td_date%i_min+1
      ENDIF
      
      IF( td_date%i_min == 60 )THEN
         td_date%i_min=0
         td_date%i_hour=td_date%i_hour+1
      ENDIF

      IF( td_date%i_hour == 24 )THEN
         td_date%i_hour=0
         td_date=date__addnday(td_date,1._sp)
      ENDIF

   END SUBROUTINE date__adjust
   ! @endcode   
   !-------------------------------------------------------------------
   !> @brief This function convert julian day in seconds
   !> since julian day origin
   !> @author J.Paul
   !> - Nov, 2013- Initial Version
   !
   !> @param[in] td_date : date strutcutre
   !> @return number of seconds since julian day origin
   !-------------------------------------------------------------------
   ! @code
   INTEGER(i8) FUNCTION date__jd2sec(rd_jul)
      IMPLICIT NONE
      ! Argument   
      REAL(sp), INTENT(IN) :: rd_jul
      !----------------------------------------------------------------

      date__jd2sec = NINT( rd_jul * im_secbyday, i8 )

   END FUNCTION date__jd2sec
   ! @endcode   
   !-------------------------------------------------------------------
   !> @brief This function convert seconds since julian day origin in 
   !> julian day
   !> @author J.Paul
   !> - Nov, 2013- Initial Version
   !
   !> @param[in] td_date : date strutcutre
   !> @return number of seconds since julian day origin
   !-------------------------------------------------------------------
   ! @code
   REAL(sp) FUNCTION date__sec2jd(kd_nsec)
      IMPLICIT NONE
      ! Argument   
      INTEGER(i8), INTENT(IN) :: kd_nsec
      !----------------------------------------------------------------

      date__sec2jd = REAL( REAL( kd_nsec , sp ) / im_secbyday, sp )

   END FUNCTION date__sec2jd
   ! @endcode   
END MODULE date