source: branches/2014/dev_4707_CNRS04_bgc_ice/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zsed.F90 @ 4718

Last change on this file since 4718 was 4718, checked in by vancop, 6 years ago

[sea ice tracer boundary conditions ORCA2_LIM2 PISCES]

File size: 21.0 KB
Line 
1MODULE p4zsed
2   !!======================================================================
3   !!                         ***  MODULE p4sed  ***
4   !! TOP :   PISCES Compute loss of organic matter in the sediments
5   !!======================================================================
6   !! History :   1.0  !  2004-03 (O. Aumont) Original code
7   !!             2.0  !  2007-12 (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06 (C. Ethe) USE of fldread
9   !!             3.5  !  2012-07 (O. Aumont) improvment of river input of nutrients
10   !!----------------------------------------------------------------------
11#if defined key_pisces
12   !!----------------------------------------------------------------------
13   !!   'key_pisces'                                       PISCES bio-model
14   !!----------------------------------------------------------------------
15   !!   p4z_sed        :  Compute loss of organic matter in the sediments
16   !!----------------------------------------------------------------------
17   USE oce_trc         !  shared variables between ocean and passive tracers
18   USE trc             !  passive tracers common variables
19   USE sms_pisces      !  PISCES Source Minus Sink variables
20   USE p4zsink         !  vertical flux of particulate matter due to sinking
21   USE p4zopt          !  optical model
22   USE p4zlim          !  Co-limitations of differents nutrients
23   USE p4zrem          !  Remineralisation of organic matter
24   USE p4zsbc          !  External source of nutrients
25   USE p4zint          !  interpolation and computation of various fields
26   USE iom             !  I/O manager
27   USE prtctl_trc      !  print control for debugging
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   p4z_sed   
33
34   !! * Module variables
35   REAL(wp) :: ryyss                    !: number of seconds per year
36   REAL(wp) :: r1_ryyss                 !: inverse of ryyss
37   REAL(wp) :: rmtss                    !: number of seconds per month
38   REAL(wp) :: r1_rday                  !: inverse of rday
39
40   INTEGER ::  numnit 
41
42
43   !!* Substitution
44#  include "top_substitute.h90"
45   !!----------------------------------------------------------------------
46   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
47   !! $Header:$
48   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE p4z_sed( kt, jnt )
53      !!---------------------------------------------------------------------
54      !!                     ***  ROUTINE p4z_sed  ***
55      !!
56      !! ** Purpose :   Compute loss of organic matter in the sediments. This
57      !!              is by no way a sediment model. The loss is simply
58      !!              computed to balance the inout from rivers and dust
59      !!
60      !! ** Method  : - ???
61      !!---------------------------------------------------------------------
62      !
63      INTEGER, INTENT(in) ::   kt, jnt ! ocean time step
64      INTEGER  ::   ji, jj, jk, ikt
65#if ! defined key_sed
66      REAL(wp) ::   zsumsedsi, zsumsedpo4, zsumsedcal
67      REAL(wp) ::   zrivalk, zrivsil, zrivno3
68#endif
69      REAL(wp) ::  zwflux, zfminus, zfplus
70      REAL(wp) ::  zlim, zfact, zfactcal
71      REAL(wp) ::  zo2, zno3, zflx, zpdenit, z1pdenit, zdenitt, zolimit
72      REAL(wp) ::  zsiloss, zcaloss, zws3, zws4, zwsc, zdep, zwstpoc
73      REAL(wp) ::  ztrfer, ztrpo4, zwdust, zlight
74      REAL(wp) ::  zrdenittot, zsdenittot, znitrpottot
75      !
76      CHARACTER (len=25) :: charout
77      REAL(wp), POINTER, DIMENSION(:,:  ) :: zpdep, zsidep, zwork1, zwork2, zwork3, zwork4
78      REAL(wp), POINTER, DIMENSION(:,:  ) :: zdenit2d, zironice, zbureff
79      REAL(wp), POINTER, DIMENSION(:,:  ) :: zwsbio3, zwsbio4, zwscal
80      REAL(wp), POINTER, DIMENSION(:,:,:) :: znitrpot, zirondep, zsoufer
81      !!---------------------------------------------------------------------
82      !
83      IF( nn_timing == 1 )  CALL timing_start('p4z_sed')
84      !
85      IF( kt == nittrc000 .AND. jnt == 1 )  THEN
86         ryyss    = nyear_len(1) * rday    ! number of seconds per year and per month
87         rmtss    = ryyss / raamo
88         r1_rday  = 1. / rday
89         r1_ryyss = 1. / ryyss
90         IF( ln_check_mass .AND. lwp)  &
91           &  CALL ctl_opn( numnit, 'nitrogen.budget', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
92      ENDIF
93      !
94      ! Allocate temporary workspace
95      CALL wrk_alloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zwork4, zbureff )
96      CALL wrk_alloc( jpi, jpj, zwsbio3, zwsbio4, zwscal )
97      CALL wrk_alloc( jpi, jpj, jpk, znitrpot, zsoufer )
98
99      zdenit2d(:,:) = 0.e0
100      zbureff (:,:) = 0.e0
101
102      ! Iron input/uptake due to sea ice : Crude parameterization based on Lancelot et al.
103      ! ----------------------------------------------------
104      IF( ln_ironice ) THEN 
105         !                                             
106         CALL wrk_alloc( jpi, jpj, zironice )
107         zironice(:,:) = 0.0
108         !                                             
109! MV NOW DONE IN trcsbc
110!        DO jj = 1, jpj
111!           DO ji = 1, jpi
112!              zdep    = rfact2 / fse3t(ji,jj,1)
113!              zwflux  = fmmflx(ji,jj) / 1000._wp
114!              zfminus = MIN( 0._wp, -zwflux ) * trn(ji,jj,1,jpfer) * zdep
115!              zfplus  = MAX( 0._wp, -zwflux ) * icefeinput * zdep
116!              zironice(ji,jj) =  zfplus + zfminus
117!           END DO
118!        END DO
119!        !
120!        trn(:,:,1,jpfer) = trn(:,:,1,jpfer) + zironice(:,:)
121!        !                                             
122         IF( ln_diatrc .AND. lk_iomput .AND. jnt == nrdttrc )   &
123            &   CALL iom_put( "Ironice", zironice(:,:) * 1.e+3 * rfact2r * fse3t(:,:,1) * tmask(:,:,1) ) ! iron flux from ice
124         CALL wrk_dealloc( jpi, jpj, zironice )
125!        !                                             
126!     ENDIF
127! END MV
128
129      ! Add the external input of nutrients from dust deposition
130      ! ----------------------------------------------------------
131      IF( ln_dust ) THEN
132         !                                             
133         CALL wrk_alloc( jpi, jpj,      zpdep, zsidep )
134         CALL wrk_alloc( jpi, jpj, jpk, zirondep      )
135         !                                              ! Iron and Si deposition at the surface
136         IF( ln_solub ) THEN
137            zirondep(:,:,1) = solub(:,:) * dust(:,:) * mfrac * rfact2 / fse3t(:,:,1) / ( 55.85 * rmtss ) + 3.e-10 * r1_ryyss 
138         ELSE
139            zirondep(:,:,1) = dustsolub  * dust(:,:) * mfrac * rfact2 / fse3t(:,:,1) / ( 55.85 * rmtss ) + 3.e-10 * r1_ryyss 
140         ENDIF
141         zsidep(:,:) = 8.8 * 0.075 * dust(:,:) * mfrac * rfact2 / fse3t(:,:,1) / ( 28.1  * rmtss )
142         zpdep (:,:) = 0.1 * 0.021 * dust(:,:) * mfrac * rfact2 / fse3t(:,:,1) / ( 31.   * rmtss ) / po4r 
143         !                                              ! Iron solubilization of particles in the water column
144         !                                              ! dust in kg/m2/s ---> 1/55.85 to put in mol/Fe ;  wdust in m/j
145         zwdust = 0.03 * rday / ( wdust * 55.85 ) / ( 270. * rday )
146         DO jk = 2, jpkm1
147            zirondep(:,:,jk) = dust(:,:) * mfrac * zwdust * rfact2 * EXP( -fsdept(:,:,jk) / 540. )
148         END DO
149         !                                              ! Iron solubilization of particles in the water column
150         trn(:,:,1,jppo4) = trn(:,:,1,jppo4) + zpdep   (:,:)
151         trn(:,:,1,jpsil) = trn(:,:,1,jpsil) + zsidep  (:,:)
152         trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + zirondep(:,:,:) 
153         !                                             
154         IF( ln_diatrc ) THEN
155            zfact = 1.e+3 * rfact2r
156            IF( lk_iomput ) THEN
157               IF( jnt == nrdttrc ) THEN
158                  CALL iom_put( "Irondep", zirondep(:,:,1) * zfact * fse3t(:,:,1) * tmask(:,:,1) ) ! surface downward dust depo of iron
159                  CALL iom_put( "pdust"  , dust(:,:) / ( wdust * rday )  * tmask(:,:,1) ) ! dust concentration at surface
160               ENDIF
161            ELSE
162               trc2d(:,:,jp_pcs0_2d + 11) = zirondep(:,:,1) * zfact * fse3t(:,:,1) * tmask(:,:,1)
163            ENDIF
164         ENDIF
165         CALL wrk_dealloc( jpi, jpj,      zpdep, zsidep )
166         CALL wrk_dealloc( jpi, jpj, jpk, zirondep      )
167         !                                             
168      ENDIF
169     
170      ! Add the external input of nutrients from river
171      ! ----------------------------------------------------------
172      IF( ln_river ) THEN
173         trn(:,:,1,jppo4) = trn(:,:,1,jppo4) + rivdip(:,:) * rfact2
174         trn(:,:,1,jpno3) = trn(:,:,1,jpno3) + rivdin(:,:) * rfact2
175         trn(:,:,1,jpfer) = trn(:,:,1,jpfer) + rivdic(:,:) * 5.e-5 * rfact2
176         trn(:,:,1,jpsil) = trn(:,:,1,jpsil) + rivdsi(:,:) * rfact2
177         trn(:,:,1,jpdic) = trn(:,:,1,jpdic) + rivdic(:,:) * rfact2
178         trn(:,:,1,jptal) = trn(:,:,1,jptal) + ( rivalk(:,:) - rno3 * rivdin(:,:) ) * rfact2
179      ENDIF
180     
181      ! Add the external input of nutrients from nitrogen deposition
182      ! ----------------------------------------------------------
183      IF( ln_ndepo ) THEN
184         trn(:,:,1,jpno3) = trn(:,:,1,jpno3) + nitdep(:,:) * rfact2
185         trn(:,:,1,jptal) = trn(:,:,1,jptal) - rno3 * nitdep(:,:) * rfact2
186      ENDIF
187
188      ! Add the external input of iron from sediment mobilization
189      ! ------------------------------------------------------
190      IF( ln_ironsed ) THEN
191         trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + ironsed(:,:,:) * rfact2
192         !
193         IF( ln_diatrc .AND. lk_iomput .AND. jnt == nrdttrc )   &
194            &   CALL iom_put( "Ironsed", ironsed(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! iron inputs from sediments
195      ENDIF
196
197      ! Add the external input of iron from hydrothermal vents
198      ! ------------------------------------------------------
199      IF( ln_hydrofe ) THEN
200         trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + hydrofe(:,:,:) * rfact2
201         !
202         IF( ln_diatrc .AND. lk_iomput .AND. jnt == nrdttrc )   &
203            &   CALL iom_put( "HYDR", hydrofe(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! hydrothermal iron input
204      ENDIF
205
206
207      ! OA: Warning, the following part is necessary, especially with Kriest
208      ! to avoid CFL problems above the sediments
209      ! --------------------------------------------------------------------
210      DO jj = 1, jpj
211         DO ji = 1, jpi
212            ikt  = mbkt(ji,jj)
213            zdep = fse3t(ji,jj,ikt) / xstep
214            zwsbio4(ji,jj) = MIN( 0.99 * zdep, wsbio4(ji,jj,ikt) )
215            zwscal (ji,jj) = MIN( 0.99 * zdep, wscal (ji,jj,ikt) )
216            zwsbio3(ji,jj) = MIN( 0.99 * zdep, wsbio3(ji,jj,ikt) )
217         END DO
218      END DO
219
220#if ! defined key_sed
221      ! Computation of the sediment denitrification proportion: The metamodel from midlleburg (2006) is being used
222      ! Computation of the fraction of organic matter that is permanently buried from Dunne's model
223      ! -------------------------------------------------------
224      DO jj = 1, jpj
225         DO ji = 1, jpi
226           IF( tmask(ji,jj,1) == 1 ) THEN
227              ikt = mbkt(ji,jj)
228# if defined key_kriest
229              zflx =    trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj)    * 1E3 * 1E6 / 1E4
230# else
231              zflx = (  trn(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
232                &     + trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) )  * 1E3 * 1E6 / 1E4
233#endif
234              zflx  = LOG10( MAX( 1E-3, zflx ) )
235              zo2   = LOG10( MAX( 10. , trn(ji,jj,ikt,jpoxy) * 1E6 ) )
236              zno3  = LOG10( MAX( 1.  , trn(ji,jj,ikt,jpno3) * 1E6 * rno3 ) )
237              zdep  = LOG10( fsdepw(ji,jj,ikt+1) )
238              zdenit2d(ji,jj) = -2.2567 - 1.185 * zflx - 0.221 * zflx**2 - 0.3995 * zno3 * zo2 + 1.25 * zno3    &
239              &                + 0.4721 * zo2 - 0.0996 * zdep + 0.4256 * zflx * zo2
240              zdenit2d(ji,jj) = 10.0**( zdenit2d(ji,jj) )
241              !
242              zflx = (  trn(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
243                &     + trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) ) * 1E6
244              zbureff(ji,jj) = 0.013 + 0.53 * zflx**2 / ( 7.0 + zflx )**2
245           ENDIF
246         END DO
247      END DO 
248
249      ! Loss of biogenic silicon, Caco3 organic carbon in the sediments.
250      ! First, the total loss is computed.
251      ! The factor for calcite comes from the alkalinity effect
252      ! -------------------------------------------------------------
253      DO jj = 1, jpj
254         DO ji = 1, jpi
255            ikt = mbkt(ji,jj) 
256# if defined key_kriest
257            zwork1(ji,jj) = trn(ji,jj,ikt,jpgsi) * zwscal (ji,jj)
258            zwork2(ji,jj) = trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj)
259# else
260            zwork1(ji,jj) = trn(ji,jj,ikt,jpgsi) * zwsbio4(ji,jj)
261            zwork2(ji,jj) = trn(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj) + trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) 
262# endif
263            ! For calcite, burial efficiency is made a function of saturation
264            zfactcal      = MIN( excess(ji,jj,ikt), 0.2 )
265            zfactcal      = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
266            zwork3(ji,jj) = trn(ji,jj,ikt,jpcal) * zwscal(ji,jj) * 2.e0 * zfactcal
267         END DO
268      END DO
269      zsumsedsi  = glob_sum( zwork1(:,:) * e1e2t(:,:) ) * r1_rday
270      zsumsedpo4 = glob_sum( zwork2(:,:) * e1e2t(:,:) ) * r1_rday
271      zsumsedcal = glob_sum( zwork3(:,:) * e1e2t(:,:) ) * r1_rday
272#endif
273
274      ! This loss is scaled at each bottom grid cell for equilibrating the total budget of silica in the ocean.
275      ! Thus, the amount of silica lost in the sediments equal the supply at the surface (dust+rivers)
276      ! ------------------------------------------------------
277#if ! defined key_sed
278      zrivsil =  1._wp - ( sumdepsi + rivdsiinput * r1_ryyss ) / ( zsumsedsi + rtrn )
279#endif
280
281      DO jj = 1, jpj
282         DO ji = 1, jpi
283            ikt  = mbkt(ji,jj)
284            zdep = xstep / fse3t(ji,jj,ikt)
285            zws4 = zwsbio4(ji,jj) * zdep
286            zwsc = zwscal (ji,jj) * zdep
287# if defined key_kriest
288            zsiloss = trn(ji,jj,ikt,jpgsi) * zws4
289# else
290            zsiloss = trn(ji,jj,ikt,jpgsi) * zwsc
291# endif
292            zcaloss = trn(ji,jj,ikt,jpcal) * zwsc
293            !
294            trn(ji,jj,ikt,jpgsi) = trn(ji,jj,ikt,jpgsi) - zsiloss
295            trn(ji,jj,ikt,jpcal) = trn(ji,jj,ikt,jpcal) - zcaloss
296#if ! defined key_sed
297            trn(ji,jj,ikt,jpsil) = trn(ji,jj,ikt,jpsil) + zsiloss * zrivsil 
298            zfactcal = MIN( excess(ji,jj,ikt), 0.2 )
299            zfactcal = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
300            zrivalk  =  1._wp - ( rivalkinput * r1_ryyss ) * zfactcal / ( zsumsedcal + rtrn )
301            trn(ji,jj,ikt,jptal) =  trn(ji,jj,ikt,jptal) + zcaloss * zrivalk * 2.0
302            trn(ji,jj,ikt,jpdic) =  trn(ji,jj,ikt,jpdic) + zcaloss * zrivalk
303#endif
304         END DO
305      END DO
306
307      DO jj = 1, jpj
308         DO ji = 1, jpi
309            ikt     = mbkt(ji,jj)
310            zdep    = xstep / fse3t(ji,jj,ikt)
311            zws4 = zwsbio4(ji,jj) * zdep
312            zws3 = zwsbio3(ji,jj) * zdep
313            zrivno3 = 1. - zbureff(ji,jj)
314# if ! defined key_kriest
315            trn(ji,jj,ikt,jpgoc) = trn(ji,jj,ikt,jpgoc) - trn(ji,jj,ikt,jpgoc) * zws4
316            trn(ji,jj,ikt,jppoc) = trn(ji,jj,ikt,jppoc) - trn(ji,jj,ikt,jppoc) * zws3
317            trn(ji,jj,ikt,jpbfe) = trn(ji,jj,ikt,jpbfe) - trn(ji,jj,ikt,jpbfe) * zws4
318            trn(ji,jj,ikt,jpsfe) = trn(ji,jj,ikt,jpsfe) - trn(ji,jj,ikt,jpsfe) * zws3
319            zwstpoc              =  trn(ji,jj,ikt,jpgoc) * zws4 + trn(ji,jj,ikt,jppoc) * zws3 
320# else
321            trn(ji,jj,ikt,jpnum) = trn(ji,jj,ikt,jpnum) - trn(ji,jj,ikt,jpnum) * zws4
322            trn(ji,jj,ikt,jppoc) = trn(ji,jj,ikt,jppoc) - trn(ji,jj,ikt,jppoc) * zws3
323            trn(ji,jj,ikt,jpsfe) = trn(ji,jj,ikt,jpsfe) - trn(ji,jj,ikt,jpsfe) * zws3
324            zwstpoc = trn(ji,jj,ikt,jppoc) * zws3 
325# endif
326
327#if ! defined key_sed
328            ! The 0.5 factor in zpdenit and zdenitt is to avoid negative NO3 concentration after both denitrification
329            ! in the sediments and just above the sediments. Not very clever, but simpliest option.
330            zpdenit  = MIN( 0.5 * ( trn(ji,jj,ikt,jpno3) - rtrn ) / rdenit, zdenit2d(ji,jj) * zwstpoc * zrivno3 )
331            z1pdenit = zwstpoc * zrivno3 - zpdenit
332            zolimit = MIN( ( trn(ji,jj,ikt,jpoxy) - rtrn ) / o2ut, z1pdenit * ( 1.- nitrfac(ji,jj,ikt) ) )
333            zdenitt = MIN(  0.5 * ( trn(ji,jj,ikt,jpno3) - rtrn ) / rdenit, z1pdenit * nitrfac(ji,jj,ikt) )
334            trn(ji,jj,ikt,jpdoc) = trn(ji,jj,ikt,jpdoc) + z1pdenit - zolimit - zdenitt
335            trn(ji,jj,ikt,jppo4) = trn(ji,jj,ikt,jppo4) + zpdenit + zolimit + zdenitt
336            trn(ji,jj,ikt,jpnh4) = trn(ji,jj,ikt,jpnh4) + zpdenit + zolimit + zdenitt
337            trn(ji,jj,ikt,jpno3) = trn(ji,jj,ikt,jpno3) - rdenit * (zpdenit + zdenitt)
338            trn(ji,jj,ikt,jpoxy) = trn(ji,jj,ikt,jpoxy) - zolimit * o2ut
339            trn(ji,jj,ikt,jptal) = trn(ji,jj,ikt,jptal) + rno3 * (zolimit + (1.+rdenit) * (zpdenit + zdenitt) )
340            trn(ji,jj,ikt,jpdic) = trn(ji,jj,ikt,jpdic) + zpdenit + zolimit + zdenitt
341            zwork4(ji,jj) = rdenit * zpdenit * fse3t(ji,jj,ikt)
342#endif
343         END DO
344      END DO
345
346      ! Nitrogen fixation process
347      ! Small source iron from particulate inorganic iron
348      !-----------------------------------
349      DO jk = 1, jpkm1
350         DO jj = 1, jpj
351            DO ji = 1, jpi
352               !                      ! Potential nitrogen fixation dependant on temperature and iron
353               zlim = ( 1.- xnanono3(ji,jj,jk) - xnanonh4(ji,jj,jk) )
354               IF( zlim <= 0.2 )   zlim = 0.01
355#if defined key_degrad
356               zfact = zlim * rfact2 * facvol(ji,jj,jk)
357#else
358               zfact = zlim * rfact2
359#endif
360               ztrfer = biron(ji,jj,jk)       / ( concfediaz + biron(ji,jj,jk)       )
361               ztrpo4 = trn  (ji,jj,jk,jppo4) / ( concnnh4   + trn  (ji,jj,jk,jppo4) ) 
362               zlight =  ( 1.- EXP( -etot(ji,jj,jk) / diazolight ) ) 
363               znitrpot(ji,jj,jk) =  MAX( 0.e0, ( 0.6 * tgfunc(ji,jj,jk) - 2.15 ) * r1_rday )   &
364                 &         *  zfact * MIN( ztrfer, ztrpo4 ) * zlight
365               zsoufer(ji,jj,jk) = zlight * 2E-11 / (2E-11 + biron(ji,jj,jk))
366            END DO
367         END DO
368      END DO
369
370      ! Nitrogen change due to nitrogen fixation
371      ! ----------------------------------------
372      DO jk = 1, jpkm1
373         DO jj = 1, jpj
374            DO ji = 1, jpi
375               zfact = znitrpot(ji,jj,jk) * nitrfix
376               trn(ji,jj,jk,jpnh4) = trn(ji,jj,jk,jpnh4) +             zfact
377               trn(ji,jj,jk,jptal) = trn(ji,jj,jk,jptal) + rno3      * zfact
378               trn(ji,jj,jk,jpoxy) = trn(ji,jj,jk,jpoxy) + o2nit     * zfact 
379               trn(ji,jj,jk,jppo4) = trn(ji,jj,jk,jppo4) + concdnh4 / ( concdnh4 + trn(ji,jj,jk,jppo4) ) &
380               &                     * 0.002 * trn(ji,jj,jk,jpdoc) * rfact2 / rday
381               trn(ji,jj,jk,jpfer) = trn(ji,jj,jk,jpfer) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * rfact2 / rday
382           END DO
383         END DO
384      END DO
385
386 
387      IF( ln_check_mass ) THEN
388        ! Global budget of N SMS : denitrification in the water column and in the sediment
389         !                          nitrogen fixation by the diazotrophs
390         ! --------------------------------------------------------------------------------
391         zrdenittot   = glob_sum ( denitr(:,:,:) * rdenit * xnegtr(:,:,:) * cvol(:,:,:) )
392         zsdenittot   = glob_sum ( zwork4(:,:)   * e1e2t(:,:) )
393         znitrpottot  = glob_sum ( znitrpot(:,:,:) * nitrfix              * cvol(:,:,:) )
394         IF( kt == nitend .AND. jnt == nrdttrc ) THEN
395            zfact = 1.e+3 * rfact2r * rno3 * ryyss * 14. / 1e12
396            IF(lwp) WRITE(numnit,9100) ndastp, znitrpottot * nitrfix * zfact, zrdenittot * zfact , zsdenittot * zfact
397         ENDIF
398       ENDIF
399      !
400      IF( ln_diatrc ) THEN
401         zfact = 1.e+3 * rfact2r
402         IF( lk_iomput ) THEN
403            IF( jnt == nrdttrc ) THEN
404               CALL iom_put( "Nfix"  , znitrpot(:,:,:) * nitrfix * rno3 * zfact * tmask(:,:,:) )  ! nitrogen fixation
405               CALL iom_put( "Sdenit", zwork4(:,:)               * rno3 * zfact * tmask(:,:,1) )  ! Nitrate reduction in the sediments
406            ENDIF
407         ELSE
408            trc2d(:,:,jp_pcs0_2d + 12) = znitrpot(:,:,1) * nitrfix * zfact * fse3t(:,:,1) * tmask(:,:,1)
409         ENDIF
410      ENDIF
411      !
412      IF(ln_ctl) THEN  ! print mean trends (USEd for debugging)
413         WRITE(charout, fmt="('sed ')")
414         CALL prt_ctl_trc_info(charout)
415         CALL prt_ctl_trc(tab4d=trn, mask=tmask, clinfo=ctrcnm)
416      ENDIF
417      !
418      CALL wrk_dealloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zwork4, zbureff )
419      CALL wrk_dealloc( jpi, jpj, zwsbio3, zwsbio4, zwscal )
420      CALL wrk_dealloc( jpi, jpj, jpk, znitrpot, zsoufer )
421      !
422      IF( nn_timing == 1 )  CALL timing_stop('p4z_sed')
423      !
424 9100  FORMAT(i8,3f10.5)
425      !
426   END SUBROUTINE p4z_sed
427
428#else
429   !!======================================================================
430   !!  Dummy module :                                   No PISCES bio-model
431   !!======================================================================
432CONTAINS
433   SUBROUTINE p4z_sed                         ! Empty routine
434   END SUBROUTINE p4z_sed
435#endif 
436
437   !!======================================================================
438END MODULE  p4zsed
Note: See TracBrowser for help on using the repository browser.