New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd.F90 in branches/2014/dev_4728_CNRS04_coupled_interface/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2014/dev_4728_CNRS04_coupled_interface/NEMOGCM/NEMO/LIM_SRC_3/limthd.F90 @ 4734

Last change on this file since 4734 was 4734, checked in by vancop, 10 years ago

compilation bug
  • Property svn:keywords set to Id
File size: 34.4 KB
Line 
1MODULE limthd
2   !!======================================================================
3   !!                  ***  MODULE limthd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add lim_thd_glohec, lim_thd_con_dh and lim_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in wfx_snw
11   !!            3.3  ! 2010-11 (G. Madec) corrected snow melting heat (due to factor betas)
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3'                                      LIM3 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   lim_thd       : thermodynamic of sea ice
20   !!   lim_thd_init  : initialisation of sea-ice thermodynamic
21   !!----------------------------------------------------------------------
22   USE phycst         ! physical constants
23   USE dom_oce        ! ocean space and time domain variables
24   USE oce     , ONLY :  iatte, oatte
25   USE ice            ! LIM: sea-ice variables
26   USE par_ice        ! LIM: sea-ice parameters
27   USE sbc_oce        ! Surface boundary condition: ocean fields
28   USE sbc_ice        ! Surface boundary condition: ice fields
29   USE thd_ice        ! LIM thermodynamic sea-ice variables
30   USE dom_ice        ! LIM sea-ice domain
31   USE domvvl         ! domain: variable volume level
32   USE limthd_dif     ! LIM: thermodynamics, vertical diffusion
33   USE limthd_dh      ! LIM: thermodynamics, ice and snow thickness variation
34   USE limthd_sal     ! LIM: thermodynamics, ice salinity
35   USE limthd_ent     ! LIM: thermodynamics, ice enthalpy redistribution
36   USE limtab         ! LIM: 1D <==> 2D transformation
37   USE limvar         ! LIM: sea-ice variables
38   USE lbclnk         ! lateral boundary condition - MPP links
39   USE lib_mpp        ! MPP library
40   USE wrk_nemo       ! work arrays
41   USE in_out_manager ! I/O manager
42   USE prtctl         ! Print control
43   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
44   USE timing         ! Timing
45   USE cpl_oasis3, ONLY : lk_cpl
46   USE limcons        ! conservation tests
47
48   IMPLICIT NONE
49   PRIVATE
50
51   PUBLIC   lim_thd        ! called by limstp module
52   PUBLIC   lim_thd_init   ! called by iceini module
53
54   REAL(wp) ::   epsi10 = 1.e-10_wp   !
55
56   !! * Substitutions
57#  include "domzgr_substitute.h90"
58#  include "vectopt_loop_substitute.h90"
59   !!----------------------------------------------------------------------
60   !! NEMO/LIM3 3.3 , UCL - NEMO Consortium (2010)
61   !! $Id$
62   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
63   !!----------------------------------------------------------------------
64CONTAINS
65
66   SUBROUTINE lim_thd( kt )
67      !!-------------------------------------------------------------------
68      !!                ***  ROUTINE lim_thd  ***       
69      !! 
70      !! ** Purpose : This routine manages ice thermodynamics
71      !!         
72      !! ** Action : - Initialisation of some variables
73      !!             - Some preliminary computation (oceanic heat flux
74      !!               at the ice base, snow acc.,heat budget of the leads)
75      !!             - selection of the icy points and put them in an array
76      !!             - call lim_thd_dif  for vertical heat diffusion
77      !!             - call lim_thd_dh   for vertical ice growth and melt
78      !!             - call lim_thd_ent  for enthalpy remapping
79      !!             - call lim_thd_sal  for ice desalination
80      !!             - call lim_thd_temp to  retrieve temperature from ice enthalpy
81      !!             - back to the geographic grid
82      !!     
83      !! ** References :
84      !!---------------------------------------------------------------------
85      INTEGER, INTENT(in) ::   kt    ! number of iteration
86      !!
87      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
88      INTEGER  :: nbpb             ! nb of icy pts for thermo. cal.
89      INTEGER  :: ii, ij           ! temporary dummy loop index
90      REAL(wp) :: zfric_umin = 0._wp        ! lower bound for the friction velocity (cice value=5.e-04)
91      REAL(wp) :: zch        = 0.0057_wp    ! heat transfer coefficient
92      REAL(wp) :: zinda, zindb, zareamin 
93      REAL(wp) :: zfric_u, zqld, zqfr
94      !
95      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
96      !
97      REAL(wp), POINTER, DIMENSION(:,:) ::  zqsr, zqns
98      !!-------------------------------------------------------------------
99      CALL wrk_alloc( jpi, jpj, zqsr, zqns )
100
101      IF( nn_timing == 1 )  CALL timing_start('limthd')
102
103      ! conservation test
104      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
105
106      !------------------------------------------------------------------------------!
107      ! 1) Initialization of diagnostic variables                                    !
108      !------------------------------------------------------------------------------!
109
110      !--------------------
111      ! 1.2) Heat content   
112      !--------------------
113      ! Change the units of heat content; from global units to J.m3
114      DO jl = 1, jpl
115         DO jk = 1, nlay_i
116            DO jj = 1, jpj
117               DO ji = 1, jpi
118                  !0 if no ice and 1 if yes
119                  zindb = 1.0 - MAX(  0.0 , SIGN( 1.0 , - v_i(ji,jj,jl) + epsi10 )  )
120                  !Energy of melting q(S,T) [J.m-3]
121                  e_i(ji,jj,jk,jl) = zindb * e_i(ji,jj,jk,jl) / ( area(ji,jj) * MAX( v_i(ji,jj,jl) , epsi10 ) ) * REAL( nlay_i )
122                  !convert units ! very important that this line is here       
123                  e_i(ji,jj,jk,jl) = e_i(ji,jj,jk,jl) * unit_fac 
124               END DO
125            END DO
126         END DO
127         DO jk = 1, nlay_s
128            DO jj = 1, jpj
129               DO ji = 1, jpi
130                  !0 if no ice and 1 if yes
131                  zindb = 1.0 - MAX(  0.0 , SIGN( 1.0 , - v_s(ji,jj,jl) + epsi10 )  )
132                  !Energy of melting q(S,T) [J.m-3]
133                  e_s(ji,jj,jk,jl) = zindb * e_s(ji,jj,jk,jl) / ( area(ji,jj) * MAX( v_s(ji,jj,jl) , epsi10 ) ) * REAL( nlay_s )
134                  !convert units ! very important that this line is here
135                  e_s(ji,jj,jk,jl) = e_s(ji,jj,jk,jl) * unit_fac 
136               END DO
137            END DO
138         END DO
139      END DO
140
141      ! 2) Partial computation of forcing for the thermodynamic sea ice model.      !
142      !-----------------------------------------------------------------------------!
143
144      !--- Ocean solar and non solar fluxes to be used in zqld
145      IF ( .NOT. lk_cpl ) THEN   ! --- forced case, fluxes to the lead are the same as over the ocean
146         !
147         zqsr(:,:) = qsr(:,:)      ; zqns(:,:) = qns(:,:)
148         !
149      ELSE                       ! --- coupled case, fluxes to the lead are total - intercepted
150         !
151         zqsr(:,:) = qsr_tot(:,:)  ; zqns(:,:) = qns_tot(:,:)
152         !
153         DO jl = 1, jpl
154            DO jj = 1, jpj
155               DO ji = 1, jpi
156                  zqsr(ji,jj) = zqsr(ji,jj) - qsr_ice(ji,jj,jl) * old_a_i(ji,jj,jl)
157                  zqns(ji,jj) = zqns(ji,jj) - qns_ice(ji,jj,jl) * old_a_i(ji,jj,jl)
158               END DO
159            END DO
160         END DO
161         !
162      ENDIF
163
164!CDIR NOVERRCHK
165      DO jj = 1, jpj
166!CDIR NOVERRCHK
167         DO ji = 1, jpi
168            zinda          = tms(ji,jj) * ( 1._wp - MAX( 0._wp , SIGN( 1._wp , - at_i(ji,jj) + epsi10 ) ) ) ! 0 if no ice
169            !
170            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
171            !           !  practically no "direct lateral ablation"
172            !           
173            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
174            !           !  temperature and turbulent mixing (McPhee, 1992)
175            !
176
177            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
178            zqld =  tms(ji,jj) * rdt_ice *                                          &
179               &  ( pfrld(ji,jj)         * ( zqsr(ji,jj) * oatte(ji,jj) + zqns(ji,jj) ) &
180               &    + ( pfrld(ji,jj)**betas - pfrld(ji,jj) ) * sprecip(ji,jj) *     & ! heat content of precip
181               &      ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rtt ) - lfus )  &
182               &    + ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rtt ) )
183               ! REMARK valid at least in forced mode from clem
184               ! precip is included in qns but not in qns_ice
185
186            !-- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
187            zqfr = tms(ji,jj) * rau0 * rcp * fse3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
188
189            !-- Energy Budget of the leads (J.m-2). Must be < 0 to form ice
190            qlead(ji,jj) = MIN( 0._wp , zqld - zqfr ) 
191
192            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
193            IF( at_i(ji,jj) > epsi10 .AND. zqld > 0._wp ) THEN
194               fhld (ji,jj) = zqld * r1_rdtice / at_i(ji,jj) ! divided by at_i since this is (re)multiplied by a_i in limthd_dh.F90
195               qlead(ji,jj) = 0._wp
196            ENDIF
197            !
198            !-- Energy from the turbulent oceanic heat flux --- !
199            !clem zfric_u        = MAX ( MIN( SQRT( ust2s(ji,jj) ) , zfric_umax ) , zfric_umin )
200            zfric_u      = MAX( SQRT( ust2s(ji,jj) ), zfric_umin ) 
201            fhtur(ji,jj) = MAX( 0._wp, zinda * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ) ! W.m-2
202            ! upper bound for fhtur: we do not want SST to drop below Tfreeze.
203            ! So we say that the heat retrieved from the ocean (fhtur+fhld) must be < to the heat necessary to reach Tfreeze (zqfr)   
204            ! This is not a clean budget, so that should be corrected at some point
205            fhtur(ji,jj) = zinda * MIN( fhtur(ji,jj), - fhld(ji,jj) - zqfr * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
206
207            ! -----------------------------------------
208            ! Net heat flux on top of ice-ocean [W.m-2]
209            ! -----------------------------------------
210            !     First  step here      : heat flux at the ocean surface + precip
211            !     Second step below     : heat flux at the ice   surface (after limthd_dif)
212            hfx_in(ji,jj) = hfx_in(ji,jj)                                                                                         & 
213               ! heat flux above the ocean
214               &    +             pfrld(ji,jj)   * ( qns(ji,jj) + qsr(ji,jj) )                                                    &
215               ! latent heat of precip (note that precip is included in qns but not in qns_ice)
216               &    +   ( 1._wp - pfrld(ji,jj) ) * sprecip(ji,jj) * ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rtt ) - lfus )  &
217               &    +   ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rtt )
218
219            ! -----------------------------------------------------------------------------
220            ! Net heat flux that is retroceded to the ocean or taken from the ocean [W.m-2]
221            ! -----------------------------------------------------------------------------
222            !     First  step here              :  non solar + precip - qlead - qturb
223            !     Second step in limthd_dh      :  heat remaining if total melt (zq_rema)
224            !     Third  step in limsbc         :  heat from ice-ocean mass exchange (zf_mass) + solar
225            hfx_out(ji,jj) = hfx_out(ji,jj)                                                                                                        & 
226               ! Non solar heat flux received by the ocean
227               &    +        pfrld(ji,jj) * qns(ji,jj)                                                                                             &
228               ! latent heat of precip (note that precip is included in qns but not in qns_ice)
229               &    +      ( pfrld(ji,jj)**betas - pfrld(ji,jj) ) * sprecip(ji,jj) * ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rtt ) - lfus )  &
230               &    +      ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rtt )                        &
231               ! heat flux taken from the ocean where there is open water ice formation
232               &    -      qlead(ji,jj) * r1_rdtice                                                                                                &
233               ! heat flux taken from the ocean during bottom growth/melt (fhld should be 0 while bott growth)
234               &    -      at_i(ji,jj) * fhtur(ji,jj)                                                                                              &
235               &    -      at_i(ji,jj) *  fhld(ji,jj)
236
237         END DO
238      END DO
239
240      !------------------------------------------------------------------------------!
241      ! 3) Select icy points and fulfill arrays for the vectorial grid.           
242      !------------------------------------------------------------------------------!
243
244      DO jl = 1, jpl      !loop over ice categories
245
246         IF( kt == nit000 .AND. lwp ) THEN
247            WRITE(numout,*) ' lim_thd : transfer to 1D vectors. Category no : ', jl 
248            WRITE(numout,*) ' ~~~~~~~~'
249         ENDIF
250
251         zareamin = epsi10
252         nbpb = 0
253         DO jj = 1, jpj
254            DO ji = 1, jpi
255               IF ( a_i(ji,jj,jl) .gt. zareamin ) THEN     
256                  nbpb      = nbpb  + 1
257                  npb(nbpb) = (jj - 1) * jpi + ji
258               ENDIF
259            END DO
260         END DO
261
262         ! debug point to follow
263         jiindex_1d = 0
264         IF( ln_nicep ) THEN
265            DO ji = mi0(jiindx), mi1(jiindx)
266               DO jj = mj0(jjindx), mj1(jjindx)
267                  jiindex_1d = (jj - 1) * jpi + ji
268                  WRITE(numout,*) ' lim_thd : Category no : ', jl 
269               END DO
270            END DO
271         ENDIF
272
273         !------------------------------------------------------------------------------!
274         ! 4) Thermodynamic computation
275         !------------------------------------------------------------------------------!
276
277         IF( lk_mpp )   CALL mpp_ini_ice( nbpb , numout )
278
279         IF( nbpb > 0 ) THEN  ! If there is no ice, do nothing.
280
281            !-------------------------
282            ! 4.1 Move to 1D arrays
283            !-------------------------
284
285            CALL tab_2d_1d( nbpb, at_i_b     (1:nbpb), at_i            , jpi, jpj, npb(1:nbpb) )
286            CALL tab_2d_1d( nbpb, a_i_b      (1:nbpb), a_i(:,:,jl)     , jpi, jpj, npb(1:nbpb) )
287            CALL tab_2d_1d( nbpb, ht_i_b     (1:nbpb), ht_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
288            CALL tab_2d_1d( nbpb, ht_s_b     (1:nbpb), ht_s(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
289
290            CALL tab_2d_1d( nbpb, t_su_b     (1:nbpb), t_su(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
291            CALL tab_2d_1d( nbpb, sm_i_b     (1:nbpb), sm_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
292            DO jk = 1, nlay_s
293               CALL tab_2d_1d( nbpb, t_s_b(1:nbpb,jk), t_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
294               CALL tab_2d_1d( nbpb, q_s_b(1:nbpb,jk), e_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
295            END DO
296            DO jk = 1, nlay_i
297               CALL tab_2d_1d( nbpb, t_i_b(1:nbpb,jk), t_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
298               CALL tab_2d_1d( nbpb, q_i_b(1:nbpb,jk), e_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
299               CALL tab_2d_1d( nbpb, s_i_b(1:nbpb,jk), s_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
300            END DO
301
302            CALL tab_2d_1d( nbpb, tatm_ice_1d(1:nbpb), tatm_ice(:,:)   , jpi, jpj, npb(1:nbpb) )
303            CALL tab_2d_1d( nbpb, qsr_ice_1d (1:nbpb), qsr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
304            CALL tab_2d_1d( nbpb, fr1_i0_1d  (1:nbpb), fr1_i0          , jpi, jpj, npb(1:nbpb) )
305            CALL tab_2d_1d( nbpb, fr2_i0_1d  (1:nbpb), fr2_i0          , jpi, jpj, npb(1:nbpb) )
306            CALL tab_2d_1d( nbpb, qns_ice_1d (1:nbpb), qns_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
307            CALL tab_2d_1d( nbpb, ftr_ice_1d (1:nbpb), ftr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
308            IF( .NOT. lk_cpl ) THEN
309               CALL tab_2d_1d( nbpb, qla_ice_1d (1:nbpb), qla_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
310               CALL tab_2d_1d( nbpb, dqla_ice_1d(1:nbpb), dqla_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
311            ENDIF
312            CALL tab_2d_1d( nbpb, dqns_ice_1d(1:nbpb), dqns_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
313            CALL tab_2d_1d( nbpb, t_bo_b     (1:nbpb), t_bo            , jpi, jpj, npb(1:nbpb) )
314            CALL tab_2d_1d( nbpb, sprecip_1d (1:nbpb), sprecip         , jpi, jpj, npb(1:nbpb) ) 
315            CALL tab_2d_1d( nbpb, fhtur_1d   (1:nbpb), fhtur           , jpi, jpj, npb(1:nbpb) )
316            CALL tab_2d_1d( nbpb, qlead_1d   (1:nbpb), qlead           , jpi, jpj, npb(1:nbpb) )
317            CALL tab_2d_1d( nbpb, fhld_1d    (1:nbpb), fhld            , jpi, jpj, npb(1:nbpb) )
318
319            CALL tab_2d_1d( nbpb, wfx_snw_1d (1:nbpb), wfx_snw         , jpi, jpj, npb(1:nbpb) )
320            CALL tab_2d_1d( nbpb, wfx_sub_1d (1:nbpb), wfx_sub         , jpi, jpj, npb(1:nbpb) )
321
322            CALL tab_2d_1d( nbpb, wfx_bog_1d (1:nbpb), wfx_bog         , jpi, jpj, npb(1:nbpb) )
323            CALL tab_2d_1d( nbpb, wfx_bom_1d (1:nbpb), wfx_bom         , jpi, jpj, npb(1:nbpb) )
324            CALL tab_2d_1d( nbpb, wfx_sum_1d (1:nbpb), wfx_sum         , jpi, jpj, npb(1:nbpb) )
325            CALL tab_2d_1d( nbpb, wfx_sni_1d (1:nbpb), wfx_sni         , jpi, jpj, npb(1:nbpb) )
326            CALL tab_2d_1d( nbpb, wfx_res_1d (1:nbpb), wfx_res         , jpi, jpj, npb(1:nbpb) )
327            CALL tab_2d_1d( nbpb, wfx_spr_1d (1:nbpb), wfx_spr         , jpi, jpj, npb(1:nbpb) )
328
329            CALL tab_2d_1d( nbpb, sfx_bog_1d (1:nbpb), sfx_bog         , jpi, jpj, npb(1:nbpb) )
330            CALL tab_2d_1d( nbpb, sfx_bom_1d (1:nbpb), sfx_bom         , jpi, jpj, npb(1:nbpb) )
331            CALL tab_2d_1d( nbpb, sfx_sum_1d (1:nbpb), sfx_sum         , jpi, jpj, npb(1:nbpb) )
332            CALL tab_2d_1d( nbpb, sfx_sni_1d (1:nbpb), sfx_sni         , jpi, jpj, npb(1:nbpb) )
333            CALL tab_2d_1d( nbpb, sfx_bri_1d (1:nbpb), sfx_bri         , jpi, jpj, npb(1:nbpb) )
334            CALL tab_2d_1d( nbpb, sfx_res_1d (1:nbpb), sfx_res         , jpi, jpj, npb(1:nbpb) )
335
336            CALL tab_2d_1d( nbpb, iatte_1d   (1:nbpb), iatte           , jpi, jpj, npb(1:nbpb) ) 
337            CALL tab_2d_1d( nbpb, oatte_1d   (1:nbpb), oatte           , jpi, jpj, npb(1:nbpb) ) 
338
339            CALL tab_2d_1d( nbpb, hfx_thd_1d (1:nbpb), hfx_thd         , jpi, jpj, npb(1:nbpb) )
340            CALL tab_2d_1d( nbpb, hfx_spr_1d (1:nbpb), hfx_spr         , jpi, jpj, npb(1:nbpb) )
341            CALL tab_2d_1d( nbpb, hfx_sum_1d (1:nbpb), hfx_sum         , jpi, jpj, npb(1:nbpb) )
342            CALL tab_2d_1d( nbpb, hfx_bom_1d (1:nbpb), hfx_bom         , jpi, jpj, npb(1:nbpb) )
343            CALL tab_2d_1d( nbpb, hfx_bog_1d (1:nbpb), hfx_bog         , jpi, jpj, npb(1:nbpb) )
344            CALL tab_2d_1d( nbpb, hfx_dif_1d (1:nbpb), hfx_dif         , jpi, jpj, npb(1:nbpb) )
345            CALL tab_2d_1d( nbpb, hfx_opw_1d (1:nbpb), hfx_opw         , jpi, jpj, npb(1:nbpb) )
346            CALL tab_2d_1d( nbpb, hfx_snw_1d (1:nbpb), hfx_snw         , jpi, jpj, npb(1:nbpb) )
347            CALL tab_2d_1d( nbpb, hfx_sub_1d (1:nbpb), hfx_sub         , jpi, jpj, npb(1:nbpb) )
348            CALL tab_2d_1d( nbpb, hfx_err_1d (1:nbpb), hfx_err         , jpi, jpj, npb(1:nbpb) )
349            CALL tab_2d_1d( nbpb, hfx_res_1d (1:nbpb), hfx_res         , jpi, jpj, npb(1:nbpb) )
350            CALL tab_2d_1d( nbpb, hfx_err_rem_1d (1:nbpb), hfx_err_rem , jpi, jpj, npb(1:nbpb) )
351
352            !--------------------------------
353            ! 4.3) Thermodynamic processes
354            !--------------------------------
355
356            !---------------------------------!
357            ! Ice/Snow Temperature profile    !
358            !---------------------------------!
359            CALL lim_thd_dif( 1, nbpb )
360
361            !---------------------------------!
362            ! Ice/Snow thicnkess              !
363            !---------------------------------!
364            CALL lim_thd_dh( 1, nbpb )   
365
366            ! --- Ice enthalpy remapping --- !
367            CALL lim_thd_ent( 1, nbpb, q_i_b(1:nbpb,:) ) 
368                                           
369            !---------------------------------!
370            ! --- Ice salinity --- !
371            !---------------------------------!
372            CALL lim_thd_sal( 1, nbpb )   
373
374            !---------------------------------!
375            ! --- temperature update --- !
376            !---------------------------------!
377            CALL lim_thd_temp( 1, nbpb )
378
379            !--------------------------------
380            ! 4.4) Move 1D to 2D vectors
381            !--------------------------------
382
383               CALL tab_1d_2d( nbpb, at_i          , npb, at_i_b    (1:nbpb)   , jpi, jpj )
384               CALL tab_1d_2d( nbpb, ht_i(:,:,jl)  , npb, ht_i_b    (1:nbpb)   , jpi, jpj )
385               CALL tab_1d_2d( nbpb, ht_s(:,:,jl)  , npb, ht_s_b    (1:nbpb)   , jpi, jpj )
386               CALL tab_1d_2d( nbpb, a_i (:,:,jl)  , npb, a_i_b     (1:nbpb)   , jpi, jpj )
387               CALL tab_1d_2d( nbpb, t_su(:,:,jl)  , npb, t_su_b    (1:nbpb)   , jpi, jpj )
388               CALL tab_1d_2d( nbpb, sm_i(:,:,jl)  , npb, sm_i_b    (1:nbpb)   , jpi, jpj )
389            DO jk = 1, nlay_s
390               CALL tab_1d_2d( nbpb, t_s(:,:,jk,jl), npb, t_s_b     (1:nbpb,jk), jpi, jpj)
391               CALL tab_1d_2d( nbpb, e_s(:,:,jk,jl), npb, q_s_b     (1:nbpb,jk), jpi, jpj)
392            END DO
393            DO jk = 1, nlay_i
394               CALL tab_1d_2d( nbpb, t_i(:,:,jk,jl), npb, t_i_b     (1:nbpb,jk), jpi, jpj)
395               CALL tab_1d_2d( nbpb, e_i(:,:,jk,jl), npb, q_i_b     (1:nbpb,jk), jpi, jpj)
396               CALL tab_1d_2d( nbpb, s_i(:,:,jk,jl), npb, s_i_b     (1:nbpb,jk), jpi, jpj)
397            END DO
398               CALL tab_1d_2d( nbpb, qlead         , npb, qlead_1d  (1:nbpb)   , jpi, jpj )
399
400               CALL tab_1d_2d( nbpb, wfx_snw       , npb, wfx_snw_1d(1:nbpb)   , jpi, jpj )
401               CALL tab_1d_2d( nbpb, wfx_sub       , npb, wfx_sub_1d(1:nbpb)   , jpi, jpj )
402
403               CALL tab_1d_2d( nbpb, wfx_bog       , npb, wfx_bog_1d(1:nbpb)   , jpi, jpj )
404               CALL tab_1d_2d( nbpb, wfx_bom       , npb, wfx_bom_1d(1:nbpb)   , jpi, jpj )
405               CALL tab_1d_2d( nbpb, wfx_sum       , npb, wfx_sum_1d(1:nbpb)   , jpi, jpj )
406               CALL tab_1d_2d( nbpb, wfx_sni       , npb, wfx_sni_1d(1:nbpb)   , jpi, jpj )
407               CALL tab_1d_2d( nbpb, wfx_res       , npb, wfx_res_1d(1:nbpb)   , jpi, jpj )
408               CALL tab_1d_2d( nbpb, wfx_spr       , npb, wfx_spr_1d(1:nbpb)   , jpi, jpj )
409
410               CALL tab_1d_2d( nbpb, sfx_bog       , npb, sfx_bog_1d(1:nbpb)   , jpi, jpj )
411               CALL tab_1d_2d( nbpb, sfx_bom       , npb, sfx_bom_1d(1:nbpb)   , jpi, jpj )
412               CALL tab_1d_2d( nbpb, sfx_sum       , npb, sfx_sum_1d(1:nbpb)   , jpi, jpj )
413               CALL tab_1d_2d( nbpb, sfx_sni       , npb, sfx_sni_1d(1:nbpb)   , jpi, jpj )
414               CALL tab_1d_2d( nbpb, sfx_res       , npb, sfx_res_1d(1:nbpb)   , jpi, jpj )
415            !
416            IF( num_sal == 2 ) THEN
417               CALL tab_1d_2d( nbpb, sfx_bri       , npb, sfx_bri_1d(1:nbpb)   , jpi, jpj )
418            ENDIF
419
420              CALL tab_1d_2d( nbpb, hfx_thd       , npb, hfx_thd_1d(1:nbpb)   , jpi, jpj )
421              CALL tab_1d_2d( nbpb, hfx_spr       , npb, hfx_spr_1d(1:nbpb)   , jpi, jpj )
422              CALL tab_1d_2d( nbpb, hfx_sum       , npb, hfx_sum_1d(1:nbpb)   , jpi, jpj )
423              CALL tab_1d_2d( nbpb, hfx_bom       , npb, hfx_bom_1d(1:nbpb)   , jpi, jpj )
424              CALL tab_1d_2d( nbpb, hfx_bog       , npb, hfx_bog_1d(1:nbpb)   , jpi, jpj )
425              CALL tab_1d_2d( nbpb, hfx_dif       , npb, hfx_dif_1d(1:nbpb)   , jpi, jpj )
426              CALL tab_1d_2d( nbpb, hfx_opw       , npb, hfx_opw_1d(1:nbpb)   , jpi, jpj )
427              CALL tab_1d_2d( nbpb, hfx_snw       , npb, hfx_snw_1d(1:nbpb)   , jpi, jpj )
428              CALL tab_1d_2d( nbpb, hfx_sub       , npb, hfx_sub_1d(1:nbpb)   , jpi, jpj )
429              CALL tab_1d_2d( nbpb, hfx_err       , npb, hfx_err_1d(1:nbpb)   , jpi, jpj )
430              CALL tab_1d_2d( nbpb, hfx_res       , npb, hfx_res_1d(1:nbpb)   , jpi, jpj )
431              CALL tab_1d_2d( nbpb, hfx_err_rem   , npb, hfx_err_rem_1d(1:nbpb)   , jpi, jpj )
432            !
433            !+++++       temporary stuff for a dummy version
434              CALL tab_1d_2d( nbpb, dh_i_surf2D, npb, dh_i_surf(1:nbpb)      , jpi, jpj )
435              CALL tab_1d_2d( nbpb, dh_i_bott2D, npb, dh_i_bott(1:nbpb)      , jpi, jpj )
436              CALL tab_1d_2d( nbpb, s_i_newice , npb, s_i_new  (1:nbpb)      , jpi, jpj )
437              CALL tab_1d_2d( nbpb, izero(:,:,jl) , npb, i0    (1:nbpb)      , jpi, jpj )
438            !+++++
439              CALL tab_1d_2d( nbpb, qns_ice(:,:,jl), npb, qns_ice_1d(1:nbpb) , jpi, jpj)
440              CALL tab_1d_2d( nbpb, ftr_ice(:,:,jl), npb, ftr_ice_1d(1:nbpb) , jpi, jpj )
441            !
442            IF( lk_mpp )   CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
443         ENDIF
444         !
445      END DO
446
447      !------------------------------------------------------------------------------!
448      ! 5) Global variables, diagnostics
449      !------------------------------------------------------------------------------!
450
451      !------------------------
452      ! 5.1) Ice heat content             
453      !------------------------
454      ! Enthalpies are global variables we have to readjust the units (heat content in Joules)
455      DO jl = 1, jpl
456         DO jk = 1, nlay_i
457            e_i(:,:,jk,jl) = e_i(:,:,jk,jl) * area(:,:) * a_i(:,:,jl) * ht_i(:,:,jl) / ( unit_fac * REAL( nlay_i ) )
458         END DO
459      END DO
460
461      !------------------------
462      ! 5.2) Snow heat content             
463      !------------------------
464      ! Enthalpies are global variables we have to readjust the units (heat content in Joules)
465      DO jl = 1, jpl
466         DO jk = 1, nlay_s
467            e_s(:,:,jk,jl) = e_s(:,:,jk,jl) * area(:,:) * a_i(:,:,jl) * ht_s(:,:,jl) / ( unit_fac * REAL( nlay_s ) )
468         END DO
469      END DO
470
471      !----------------------------------
472      ! 5.3) Change thickness to volume
473      !----------------------------------
474      CALL lim_var_eqv2glo
475
476      !--------------------------------------------
477      ! 5.4) Diagnostic thermodynamic growth rates
478      !--------------------------------------------
479      IF(ln_ctl) THEN            ! Control print
480         CALL prt_ctl_info(' ')
481         CALL prt_ctl_info(' - Cell values : ')
482         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
483         CALL prt_ctl(tab2d_1=area , clinfo1=' lim_thd  : cell area :')
484         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_thd  : at_i      :')
485         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_thd  : vt_i      :')
486         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_thd  : vt_s      :')
487         DO jl = 1, jpl
488            CALL prt_ctl_info(' ')
489            CALL prt_ctl_info(' - Category : ', ivar1=jl)
490            CALL prt_ctl_info('   ~~~~~~~~~~')
491            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_thd  : a_i      : ')
492            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_thd  : ht_i     : ')
493            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_thd  : ht_s     : ')
494            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_thd  : v_i      : ')
495            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_thd  : v_s      : ')
496            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_thd  : e_s      : ')
497            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_thd  : t_su     : ')
498            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_thd  : t_snow   : ')
499            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_thd  : sm_i     : ')
500            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_thd  : smv_i    : ')
501            DO jk = 1, nlay_i
502               CALL prt_ctl_info(' ')
503               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
504               CALL prt_ctl_info('   ~~~~~~~')
505               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_thd  : t_i      : ')
506               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_thd  : e_i      : ')
507            END DO
508         END DO
509      ENDIF
510      !
511      !
512      CALL wrk_dealloc( jpi, jpj, zqsr, zqns )
513
514      !
515      ! conservation test
516      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
517      !
518      IF( nn_timing == 1 )  CALL timing_stop('limthd')
519
520   END SUBROUTINE lim_thd 
521
522   SUBROUTINE lim_thd_temp( kideb, kiut )
523      !!-----------------------------------------------------------------------
524      !!                   ***  ROUTINE lim_thd_temp ***
525      !!                 
526      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
527      !!
528      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
529      !!-------------------------------------------------------------------
530      INTEGER, INTENT(in) ::   kideb, kiut   ! bounds for the spatial loop
531      !!
532      INTEGER  ::   ji, jk   ! dummy loop indices
533      REAL(wp) ::   ztmelts, zswitch, zaaa, zbbb, zccc, zdiscrim  ! local scalar
534      !!-------------------------------------------------------------------
535      ! Recover ice temperature
536      DO jk = 1, nlay_i
537         DO ji = kideb, kiut
538            ztmelts       =  -tmut * s_i_b(ji,jk) + rtt
539            ! Conversion q(S,T) -> T (second order equation)
540            zaaa          =  cpic
541            zbbb          =  ( rcp - cpic ) * ( ztmelts - rtt ) + q_i_b(ji,jk) / rhoic - lfus
542            zccc          =  lfus * ( ztmelts - rtt )
543            zdiscrim      =  SQRT( MAX( zbbb * zbbb - 4._wp * zaaa * zccc, 0._wp ) )
544            t_i_b(ji,jk)  =  rtt - ( zbbb + zdiscrim ) / ( 2._wp * zaaa )
545           
546            ! mask temperature
547            zswitch      =  1._wp - MAX( 0._wp , SIGN( 1._wp , - ht_i_b(ji) ) ) 
548            t_i_b(ji,jk) =  zswitch * t_i_b(ji,jk) + ( 1._wp - zswitch ) * rtt
549         END DO
550      END DO
551
552   END SUBROUTINE lim_thd_temp
553
554   SUBROUTINE lim_thd_init
555      !!-----------------------------------------------------------------------
556      !!                   ***  ROUTINE lim_thd_init ***
557      !!                 
558      !! ** Purpose :   Physical constants and parameters linked to the ice
559      !!              thermodynamics
560      !!
561      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
562      !!              parameter values called at the first timestep (nit000)
563      !!
564      !! ** input   :   Namelist namicether
565      !!-------------------------------------------------------------------
566      INTEGER  ::   ios                 ! Local integer output status for namelist read
567      NAMELIST/namicethd/ hmelt , hiccrit, fraz_swi, maxfrazb, vfrazb, Cfrazb,   &
568         &                hiclim, hnzst, parsub, betas,                          & 
569         &                kappa_i, nconv_i_thd, maxer_i_thd, thcon_i_swi
570      !!-------------------------------------------------------------------
571      !
572      IF(lwp) THEN
573         WRITE(numout,*)
574         WRITE(numout,*) 'lim_thd : Ice Thermodynamics'
575         WRITE(numout,*) '~~~~~~~'
576      ENDIF
577      !
578      REWIND( numnam_ice_ref )              ! Namelist namicethd in reference namelist : Ice thermodynamics
579      READ  ( numnam_ice_ref, namicethd, IOSTAT = ios, ERR = 901)
580901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in reference namelist', lwp )
581
582      REWIND( numnam_ice_cfg )              ! Namelist namicethd in configuration namelist : Ice thermodynamics
583      READ  ( numnam_ice_cfg, namicethd, IOSTAT = ios, ERR = 902 )
584902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in configuration namelist', lwp )
585      IF(lwm) WRITE ( numoni, namicethd )
586      !
587      IF(lwp) THEN                          ! control print
588         WRITE(numout,*)
589         WRITE(numout,*)'   Namelist of ice parameters for ice thermodynamic computation '
590         WRITE(numout,*)'      maximum melting at the bottom                           hmelt        = ', hmelt
591         WRITE(numout,*)'      ice thick. for lateral accretion                        hiccrit      = ', hiccrit
592         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       fraz_swi     = ', fraz_swi
593         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   maxfrazb     = ', maxfrazb
594         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  vfrazb       = ', vfrazb
595         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          Cfrazb       = ', Cfrazb
596         WRITE(numout,*)'      minimum ice thickness                                   hiclim       = ', hiclim 
597         WRITE(numout,*)'      numerical carac. of the scheme for diffusion in ice '
598         WRITE(numout,*)'      thickness of the surf. layer in temp. computation       hnzst        = ', hnzst
599         WRITE(numout,*)'      switch for snow sublimation  (=1) or not (=0)           parsub       = ', parsub 
600         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          betas        = ', betas
601         WRITE(numout,*)'      extinction radiation parameter in sea ice (1.0)         kappa_i      = ', kappa_i
602         WRITE(numout,*)'      maximal n. of iter. for heat diffusion computation      nconv_i_thd  = ', nconv_i_thd
603         WRITE(numout,*)'      maximal err. on T for heat diffusion computation        maxer_i_thd  = ', maxer_i_thd
604         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     thcon_i_swi  = ', thcon_i_swi
605         WRITE(numout,*)'      check heat conservation in the ice/snow                 con_i        = ', con_i
606      ENDIF
607      !
608   END SUBROUTINE lim_thd_init
609
610#else
611   !!----------------------------------------------------------------------
612   !!   Default option         Dummy module          NO  LIM3 sea-ice model
613   !!----------------------------------------------------------------------
614#endif
615
616   !!======================================================================
617END MODULE limthd
Note: See TracBrowser for help on using the repository browser.