| 1 | MODULE sbcmod |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcmod *** |
|---|
| 4 | !! Surface module : provide to the ocean its surface boundary condition |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.0 ! 2006-07 (G. Madec) Original code |
|---|
| 7 | !! 3.1 ! 2008-08 (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface |
|---|
| 8 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 9 | !! 3.3 ! 2010-10 (S. Masson) add diurnal cycle |
|---|
| 10 | !! 3.3 ! 2010-09 (D. Storkey) add ice boundary conditions (BDY) |
|---|
| 11 | !! - ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step |
|---|
| 12 | !! - ! 2010-10 (J. Chanut, C. Bricaud, G. Madec) add the surface pressure forcing |
|---|
| 13 | !! 3.4 ! 2011-11 (C. Harris) CICE added as an option |
|---|
| 14 | !! 3.5 ! 2012-11 (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | !! sbc_init : read namsbc namelist |
|---|
| 19 | !! sbc : surface ocean momentum, heat and freshwater boundary conditions |
|---|
| 20 | !!---------------------------------------------------------------------- |
|---|
| 21 | USE oce ! ocean dynamics and tracers |
|---|
| 22 | USE dom_oce ! ocean space and time domain |
|---|
| 23 | USE phycst ! physical constants |
|---|
| 24 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 25 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 26 | USE sbcdcy ! surface boundary condition: diurnal cycle |
|---|
| 27 | USE sbcssm ! surface boundary condition: sea-surface mean variables |
|---|
| 28 | USE sbcapr ! surface boundary condition: atmospheric pressure |
|---|
| 29 | USE sbcana ! surface boundary condition: analytical formulation |
|---|
| 30 | USE sbcflx ! surface boundary condition: flux formulation |
|---|
| 31 | USE sbcblk_clio ! surface boundary condition: bulk formulation : CLIO |
|---|
| 32 | USE sbcblk_core ! surface boundary condition: bulk formulation : CORE |
|---|
| 33 | USE sbcblk_mfs ! surface boundary condition: bulk formulation : MFS |
|---|
| 34 | USE sbcice_if ! surface boundary condition: ice-if sea-ice model |
|---|
| 35 | USE sbcice_lim ! surface boundary condition: LIM 3.0 sea-ice model |
|---|
| 36 | USE sbcice_lim_2 ! surface boundary condition: LIM 2.0 sea-ice model |
|---|
| 37 | USE sbcice_cice ! surface boundary condition: CICE sea-ice model |
|---|
| 38 | USE sbccpl ! surface boundary condition: coupled florulation |
|---|
| 39 | USE cpl_oasis3, ONLY:lk_cpl ! are we in coupled mode? |
|---|
| 40 | USE sbcssr ! surface boundary condition: sea surface restoring |
|---|
| 41 | USE sbcrnf ! surface boundary condition: runoffs |
|---|
| 42 | USE sbcfwb ! surface boundary condition: freshwater budget |
|---|
| 43 | USE closea ! closed sea |
|---|
| 44 | USE icbstp ! Icebergs! |
|---|
| 45 | |
|---|
| 46 | USE prtctl ! Print control (prt_ctl routine) |
|---|
| 47 | USE iom ! IOM library |
|---|
| 48 | USE in_out_manager ! I/O manager |
|---|
| 49 | USE lib_mpp ! MPP library |
|---|
| 50 | USE timing ! Timing |
|---|
| 51 | USE sbcwave ! Wave module |
|---|
| 52 | |
|---|
| 53 | IMPLICIT NONE |
|---|
| 54 | PRIVATE |
|---|
| 55 | |
|---|
| 56 | PUBLIC sbc ! routine called by step.F90 |
|---|
| 57 | PUBLIC sbc_init ! routine called by opa.F90 |
|---|
| 58 | |
|---|
| 59 | INTEGER :: nsbc ! type of surface boundary condition (deduced from namsbc informations) |
|---|
| 60 | |
|---|
| 61 | !! * Substitutions |
|---|
| 62 | # include "domzgr_substitute.h90" |
|---|
| 63 | !!---------------------------------------------------------------------- |
|---|
| 64 | !! NEMO/OPA 4.0 , NEMO-consortium (2011) |
|---|
| 65 | !! $Id$ |
|---|
| 66 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 67 | !!---------------------------------------------------------------------- |
|---|
| 68 | CONTAINS |
|---|
| 69 | |
|---|
| 70 | SUBROUTINE sbc_init |
|---|
| 71 | !!--------------------------------------------------------------------- |
|---|
| 72 | !! *** ROUTINE sbc_init *** |
|---|
| 73 | !! |
|---|
| 74 | !! ** Purpose : Initialisation of the ocean surface boundary computation |
|---|
| 75 | !! |
|---|
| 76 | !! ** Method : Read the namsbc namelist and set derived parameters |
|---|
| 77 | !! Call init routines for all other SBC modules that have one |
|---|
| 78 | !! |
|---|
| 79 | !! ** Action : - read namsbc parameters |
|---|
| 80 | !! - nsbc: type of sbc |
|---|
| 81 | !!---------------------------------------------------------------------- |
|---|
| 82 | INTEGER :: icpt ! local integer |
|---|
| 83 | !! |
|---|
| 84 | NAMELIST/namsbc/ nn_fsbc , ln_ana , ln_flx, ln_blk_clio, ln_blk_core, ln_cpl, & |
|---|
| 85 | & ln_blk_mfs, ln_apr_dyn, nn_ice, nn_ice_embd, ln_dm2dc , ln_rnf, & |
|---|
| 86 | & ln_ssr , nn_fwb , ln_cdgw , ln_wave , ln_sdw, nn_lsm, nn_limflx |
|---|
| 87 | INTEGER :: ios |
|---|
| 88 | !!---------------------------------------------------------------------- |
|---|
| 89 | |
|---|
| 90 | IF(lwp) THEN |
|---|
| 91 | WRITE(numout,*) |
|---|
| 92 | WRITE(numout,*) 'sbc_init : surface boundary condition setting' |
|---|
| 93 | WRITE(numout,*) '~~~~~~~~ ' |
|---|
| 94 | ENDIF |
|---|
| 95 | |
|---|
| 96 | REWIND( numnam_ref ) ! Namelist namsbc in reference namelist : Surface boundary |
|---|
| 97 | READ ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901) |
|---|
| 98 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in reference namelist', lwp ) |
|---|
| 99 | |
|---|
| 100 | REWIND( numnam_cfg ) ! Namelist namsbc in configuration namelist : Parameters of the run |
|---|
| 101 | READ ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 ) |
|---|
| 102 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in configuration namelist', lwp ) |
|---|
| 103 | IF(lwm) WRITE ( numond, namsbc ) |
|---|
| 104 | |
|---|
| 105 | ! ! overwrite namelist parameter using CPP key information |
|---|
| 106 | IF( Agrif_Root() ) THEN ! AGRIF zoom |
|---|
| 107 | IF( lk_lim2 ) nn_ice = 2 |
|---|
| 108 | IF( lk_lim3 ) nn_ice = 3 |
|---|
| 109 | IF( lk_cice ) nn_ice = 4 |
|---|
| 110 | ENDIF |
|---|
| 111 | IF( cp_cfg == 'gyre' ) THEN ! GYRE configuration |
|---|
| 112 | ln_ana = .TRUE. |
|---|
| 113 | nn_ice = 0 |
|---|
| 114 | ENDIF |
|---|
| 115 | |
|---|
| 116 | IF(lwp) THEN ! Control print |
|---|
| 117 | WRITE(numout,*) ' Namelist namsbc (partly overwritten with CPP key setting)' |
|---|
| 118 | WRITE(numout,*) ' frequency update of sbc (and ice) nn_fsbc = ', nn_fsbc |
|---|
| 119 | WRITE(numout,*) ' Type of sbc : ' |
|---|
| 120 | WRITE(numout,*) ' analytical formulation ln_ana = ', ln_ana |
|---|
| 121 | WRITE(numout,*) ' flux formulation ln_flx = ', ln_flx |
|---|
| 122 | WRITE(numout,*) ' CLIO bulk formulation ln_blk_clio = ', ln_blk_clio |
|---|
| 123 | WRITE(numout,*) ' CORE bulk formulation ln_blk_core = ', ln_blk_core |
|---|
| 124 | WRITE(numout,*) ' MFS bulk formulation ln_blk_mfs = ', ln_blk_mfs |
|---|
| 125 | WRITE(numout,*) ' coupled formulation (T if key_sbc_cpl) ln_cpl = ', ln_cpl |
|---|
| 126 | WRITE(numout,*) ' Multicategory heat flux formulation (LIM3) nn_limflx = ', nn_limflx |
|---|
| 127 | WRITE(numout,*) ' Misc. options of sbc : ' |
|---|
| 128 | WRITE(numout,*) ' Patm gradient added in ocean & ice Eqs. ln_apr_dyn = ', ln_apr_dyn |
|---|
| 129 | WRITE(numout,*) ' ice management in the sbc (=0/1/2/3) nn_ice = ', nn_ice |
|---|
| 130 | WRITE(numout,*) ' ice-ocean embedded/levitating (=0/1/2) nn_ice_embd = ', nn_ice_embd |
|---|
| 131 | WRITE(numout,*) ' daily mean to diurnal cycle qsr ln_dm2dc = ', ln_dm2dc |
|---|
| 132 | WRITE(numout,*) ' runoff / runoff mouths ln_rnf = ', ln_rnf |
|---|
| 133 | WRITE(numout,*) ' Sea Surface Restoring on SST and/or SSS ln_ssr = ', ln_ssr |
|---|
| 134 | WRITE(numout,*) ' FreshWater Budget control (=0/1/2) nn_fwb = ', nn_fwb |
|---|
| 135 | WRITE(numout,*) ' closed sea (=0/1) (set in namdom) nn_closea = ', nn_closea |
|---|
| 136 | WRITE(numout,*) ' n. of iterations if land-sea-mask applied nn_lsm = ', nn_lsm |
|---|
| 137 | ENDIF |
|---|
| 138 | |
|---|
| 139 | ! LIM3 Multi-category heat flux formulation |
|---|
| 140 | SELECT CASE ( nn_limflx) |
|---|
| 141 | CASE ( -1 ) |
|---|
| 142 | IF(lwp) WRITE(numout,*) ' Use of per-category fluxes (nn_limflx = -1) ' |
|---|
| 143 | CASE ( 0 ) |
|---|
| 144 | IF(lwp) WRITE(numout,*) ' Average per-category fluxes (nn_limflx = 0) ' |
|---|
| 145 | CASE ( 1 ) |
|---|
| 146 | IF(lwp) WRITE(numout,*) ' Average then redistribute per-category fluxes (nn_limflx = 1) ' |
|---|
| 147 | CASE ( 2 ) |
|---|
| 148 | IF(lwp) WRITE(numout,*) ' Redistribute a single flux over categories (nn_limflx = 2) ' |
|---|
| 149 | END SELECT |
|---|
| 150 | ! |
|---|
| 151 | #if defined key_top && ! defined key_offline |
|---|
| 152 | ltrcdm2dc = (ln_dm2dc .AND. ln_blk_core .AND. nn_ice==2) |
|---|
| 153 | IF( ltrcdm2dc )THEN |
|---|
| 154 | IF(lwp)THEN |
|---|
| 155 | WRITE(numout,*)"analytical diurnal cycle, core bulk formulation and LIM2 use: " |
|---|
| 156 | WRITE(numout,*)"Diurnal cycle on physics but not in passive tracers" |
|---|
| 157 | ENDIF |
|---|
| 158 | ENDIF |
|---|
| 159 | #else |
|---|
| 160 | ltrcdm2dc = .FALSE. |
|---|
| 161 | #endif |
|---|
| 162 | |
|---|
| 163 | ! |
|---|
| 164 | ! ! allocate sbc arrays |
|---|
| 165 | IF( sbc_oce_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_oce arrays' ) |
|---|
| 166 | |
|---|
| 167 | ! ! Checks: |
|---|
| 168 | IF( .NOT. ln_rnf ) THEN ! no specific treatment in vicinity of river mouths |
|---|
| 169 | ln_rnf_mouth = .false. |
|---|
| 170 | IF( sbc_rnf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_rnf arrays' ) |
|---|
| 171 | nkrnf = 0 |
|---|
| 172 | rnf (:,:) = 0.0_wp |
|---|
| 173 | rnf_b (:,:) = 0.0_wp |
|---|
| 174 | rnfmsk (:,:) = 0.0_wp |
|---|
| 175 | rnfmsk_z(:) = 0.0_wp |
|---|
| 176 | ENDIF |
|---|
| 177 | IF( nn_ice == 0 ) fr_i(:,:) = 0.e0 ! no ice in the domain, ice fraction is always zero |
|---|
| 178 | |
|---|
| 179 | sfx(:,:) = 0.0_wp ! the salt flux due to freezing/melting will be computed (i.e. will be non-zero) |
|---|
| 180 | ! only if sea-ice is present |
|---|
| 181 | |
|---|
| 182 | fmmflx(:,:) = 0.0_wp ! freezing-melting array initialisation |
|---|
| 183 | |
|---|
| 184 | ! ! restartability |
|---|
| 185 | IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR. & |
|---|
| 186 | MOD( nstock , nn_fsbc) /= 0 ) THEN |
|---|
| 187 | WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock, & |
|---|
| 188 | & ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')' |
|---|
| 189 | CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' ) |
|---|
| 190 | ENDIF |
|---|
| 191 | ! |
|---|
| 192 | IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 ) & |
|---|
| 193 | & CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' ) |
|---|
| 194 | ! |
|---|
| 195 | IF( ( nn_ice == 2 .OR. nn_ice ==3 ) .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. lk_cpl ) ) & |
|---|
| 196 | & CALL ctl_stop( 'LIM sea-ice model requires a bulk formulation or coupled configuration' ) |
|---|
| 197 | IF( nn_ice == 4 .AND. .NOT.( ln_blk_core .OR. lk_cpl ) ) & |
|---|
| 198 | & CALL ctl_stop( 'CICE sea-ice model requires ln_blk_core or lk_cpl' ) |
|---|
| 199 | IF( nn_ice == 4 .AND. lk_agrif ) & |
|---|
| 200 | & CALL ctl_stop( 'CICE sea-ice model not currently available with AGRIF' ) |
|---|
| 201 | IF( ( nn_ice == 3 .OR. nn_ice == 4 ) .AND. nn_ice_embd == 0 ) & |
|---|
| 202 | & CALL ctl_stop( 'LIM3 and CICE sea-ice models require nn_ice_embd = 1 or 2' ) |
|---|
| 203 | IF( ( nn_ice /= 3 ) .AND. ( nn_limflx >= 0 ) ) & |
|---|
| 204 | & WRITE(numout,*) 'The nn_limflx>=0 option has no effect if sea ice model is not LIM3' |
|---|
| 205 | IF( ( nn_ice == 3 ) .AND. ( lk_cpl ) .AND. ( ( nn_limflx == -1 ) .OR. ( nn_limflx == 1 ) ) ) & |
|---|
| 206 | & CALL ctl_stop( 'The chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' ) |
|---|
| 207 | IF( ( nn_ice == 3 ) .AND. ( .NOT. lk_cpl ) .AND. ( nn_limflx == 2 ) ) & |
|---|
| 208 | & CALL ctl_stop( 'The chosen nn_limflx for LIM3 in forced mode cannot be 2' ) |
|---|
| 209 | |
|---|
| 210 | IF( ln_dm2dc ) nday_qsr = -1 ! initialisation flag |
|---|
| 211 | |
|---|
| 212 | IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk_core ) ) & |
|---|
| 213 | & CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or core-bulk formulation' ) |
|---|
| 214 | |
|---|
| 215 | IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) ) < 8 ) ) & |
|---|
| 216 | & CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' ) |
|---|
| 217 | |
|---|
| 218 | IF ( ln_wave ) THEN |
|---|
| 219 | !Activated wave module but neither drag nor stokes drift activated |
|---|
| 220 | IF ( .NOT.(ln_cdgw .OR. ln_sdw) ) THEN |
|---|
| 221 | CALL ctl_warn( 'Ask for wave coupling but nor drag coefficient (ln_cdgw=F) neither stokes drift activated (ln_sdw=F)' ) |
|---|
| 222 | !drag coefficient read from wave model definable only with mfs bulk formulae and core |
|---|
| 223 | ELSEIF (ln_cdgw .AND. .NOT.(ln_blk_mfs .OR. ln_blk_core) ) THEN |
|---|
| 224 | CALL ctl_stop( 'drag coefficient read from wave model definable only with mfs bulk formulae and core') |
|---|
| 225 | ENDIF |
|---|
| 226 | ELSE |
|---|
| 227 | IF ( ln_cdgw .OR. ln_sdw ) & |
|---|
| 228 | & CALL ctl_stop('Not Activated Wave Module (ln_wave=F) but & |
|---|
| 229 | & asked coupling with drag coefficient (ln_cdgw =T) or Stokes drift (ln_sdw=T) ') |
|---|
| 230 | ENDIF |
|---|
| 231 | |
|---|
| 232 | ! ! Choice of the Surface Boudary Condition (set nsbc) |
|---|
| 233 | icpt = 0 |
|---|
| 234 | IF( ln_ana ) THEN ; nsbc = 1 ; icpt = icpt + 1 ; ENDIF ! analytical formulation |
|---|
| 235 | IF( ln_flx ) THEN ; nsbc = 2 ; icpt = icpt + 1 ; ENDIF ! flux formulation |
|---|
| 236 | IF( ln_blk_clio ) THEN ; nsbc = 3 ; icpt = icpt + 1 ; ENDIF ! CLIO bulk formulation |
|---|
| 237 | IF( ln_blk_core ) THEN ; nsbc = 4 ; icpt = icpt + 1 ; ENDIF ! CORE bulk formulation |
|---|
| 238 | IF( ln_blk_mfs ) THEN ; nsbc = 6 ; icpt = icpt + 1 ; ENDIF ! MFS bulk formulation |
|---|
| 239 | IF( ln_cpl ) THEN ; nsbc = 5 ; icpt = icpt + 1 ; ENDIF ! Coupled formulation |
|---|
| 240 | IF( cp_cfg == 'gyre') THEN ; nsbc = 0 ; ENDIF ! GYRE analytical formulation |
|---|
| 241 | IF( lk_esopa ) nsbc = -1 ! esopa test, ALL formulations |
|---|
| 242 | ! |
|---|
| 243 | IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN |
|---|
| 244 | WRITE(numout,*) |
|---|
| 245 | WRITE(numout,*) ' E R R O R in setting the sbc, one and only one namelist/CPP key option ' |
|---|
| 246 | WRITE(numout,*) ' must be choosen. You choose ', icpt, ' option(s)' |
|---|
| 247 | WRITE(numout,*) ' We stop' |
|---|
| 248 | nstop = nstop + 1 |
|---|
| 249 | ENDIF |
|---|
| 250 | IF(lwp) THEN |
|---|
| 251 | WRITE(numout,*) |
|---|
| 252 | IF( nsbc == -1 ) WRITE(numout,*) ' ESOPA test All surface boundary conditions' |
|---|
| 253 | IF( nsbc == 0 ) WRITE(numout,*) ' GYRE analytical formulation' |
|---|
| 254 | IF( nsbc == 1 ) WRITE(numout,*) ' analytical formulation' |
|---|
| 255 | IF( nsbc == 2 ) WRITE(numout,*) ' flux formulation' |
|---|
| 256 | IF( nsbc == 3 ) WRITE(numout,*) ' CLIO bulk formulation' |
|---|
| 257 | IF( nsbc == 4 ) WRITE(numout,*) ' CORE bulk formulation' |
|---|
| 258 | IF( nsbc == 5 ) WRITE(numout,*) ' coupled formulation' |
|---|
| 259 | IF( nsbc == 6 ) WRITE(numout,*) ' MFS Bulk formulation' |
|---|
| 260 | ENDIF |
|---|
| 261 | ! |
|---|
| 262 | CALL sbc_ssm_init ! Sea-surface mean fields initialisation |
|---|
| 263 | ! |
|---|
| 264 | IF( ln_ssr ) CALL sbc_ssr_init ! Sea-Surface Restoring initialisation |
|---|
| 265 | ! |
|---|
| 266 | IF( nn_ice == 4 ) CALL cice_sbc_init( nsbc ) ! CICE initialisation |
|---|
| 267 | ! |
|---|
| 268 | END SUBROUTINE sbc_init |
|---|
| 269 | |
|---|
| 270 | |
|---|
| 271 | SUBROUTINE sbc( kt ) |
|---|
| 272 | !!--------------------------------------------------------------------- |
|---|
| 273 | !! *** ROUTINE sbc *** |
|---|
| 274 | !! |
|---|
| 275 | !! ** Purpose : provide at each time-step the ocean surface boundary |
|---|
| 276 | !! condition (momentum, heat and freshwater fluxes) |
|---|
| 277 | !! |
|---|
| 278 | !! ** Method : blah blah to be written ????????? |
|---|
| 279 | !! CAUTION : never mask the surface stress field (tke sbc) |
|---|
| 280 | !! |
|---|
| 281 | !! ** Action : - set the ocean surface boundary condition at before and now |
|---|
| 282 | !! time step, i.e. |
|---|
| 283 | !! utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b |
|---|
| 284 | !! utau , vtau , qns , qsr , emp , sfx , qrp , erp |
|---|
| 285 | !! - updte the ice fraction : fr_i |
|---|
| 286 | !!---------------------------------------------------------------------- |
|---|
| 287 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 288 | !!--------------------------------------------------------------------- |
|---|
| 289 | ! |
|---|
| 290 | IF( nn_timing == 1 ) CALL timing_start('sbc') |
|---|
| 291 | ! |
|---|
| 292 | ! ! ---------------------------------------- ! |
|---|
| 293 | IF( kt /= nit000 ) THEN ! Swap of forcing fields ! |
|---|
| 294 | ! ! ---------------------------------------- ! |
|---|
| 295 | utau_b(:,:) = utau(:,:) ! Swap the ocean forcing fields |
|---|
| 296 | vtau_b(:,:) = vtau(:,:) ! (except at nit000 where before fields |
|---|
| 297 | qns_b (:,:) = qns (:,:) ! are set at the end of the routine) |
|---|
| 298 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 299 | ! qsr_b (:,:) = qsr (:,:) |
|---|
| 300 | emp_b(:,:) = emp(:,:) |
|---|
| 301 | sfx_b(:,:) = sfx(:,:) |
|---|
| 302 | ENDIF |
|---|
| 303 | ! ! ---------------------------------------- ! |
|---|
| 304 | ! ! forcing field computation ! |
|---|
| 305 | ! ! ---------------------------------------- ! |
|---|
| 306 | ! |
|---|
| 307 | IF( ln_apr_dyn ) CALL sbc_apr( kt ) ! atmospheric pressure provided at kt+0.5*nn_fsbc |
|---|
| 308 | ! (caution called before sbc_ssm) |
|---|
| 309 | ! |
|---|
| 310 | CALL sbc_ssm( kt ) ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m) |
|---|
| 311 | ! ! averaged over nf_sbc time-step |
|---|
| 312 | |
|---|
| 313 | IF (ln_wave) CALL sbc_wave( kt ) |
|---|
| 314 | !== sbc formulation ==! |
|---|
| 315 | |
|---|
| 316 | SELECT CASE( nsbc ) ! Compute ocean surface boundary condition |
|---|
| 317 | ! ! (i.e. utau,vtau, qns, qsr, emp, sfx) |
|---|
| 318 | CASE( 0 ) ; CALL sbc_gyre ( kt ) ! analytical formulation : GYRE configuration |
|---|
| 319 | CASE( 1 ) ; CALL sbc_ana ( kt ) ! analytical formulation : uniform sbc |
|---|
| 320 | CASE( 2 ) ; CALL sbc_flx ( kt ) ! flux formulation |
|---|
| 321 | CASE( 3 ) ; CALL sbc_blk_clio( kt ) ! bulk formulation : CLIO for the ocean |
|---|
| 322 | CASE( 4 ) ; CALL sbc_blk_core( kt ) ! bulk formulation : CORE for the ocean |
|---|
| 323 | CASE( 5 ) ; CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! coupled formulation |
|---|
| 324 | CASE( 6 ) ; CALL sbc_blk_mfs ( kt ) ! bulk formulation : MFS for the ocean |
|---|
| 325 | CASE( -1 ) |
|---|
| 326 | CALL sbc_ana ( kt ) ! ESOPA, test ALL the formulations |
|---|
| 327 | CALL sbc_gyre ( kt ) ! |
|---|
| 328 | CALL sbc_flx ( kt ) ! |
|---|
| 329 | CALL sbc_blk_clio( kt ) ! |
|---|
| 330 | CALL sbc_blk_core( kt ) ! |
|---|
| 331 | CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! |
|---|
| 332 | END SELECT |
|---|
| 333 | |
|---|
| 334 | ! !== Misc. Options ==! |
|---|
| 335 | |
|---|
| 336 | SELECT CASE( nn_ice ) ! Update heat and freshwater fluxes over sea-ice areas |
|---|
| 337 | CASE( 1 ) ; CALL sbc_ice_if ( kt ) ! Ice-cover climatology ("Ice-if" model) |
|---|
| 338 | CASE( 2 ) ; CALL sbc_ice_lim_2( kt, nsbc ) ! LIM-2 ice model |
|---|
| 339 | CASE( 3 ) ; CALL sbc_ice_lim ( kt, nsbc ) ! LIM-3 ice model |
|---|
| 340 | !is it useful? |
|---|
| 341 | CASE( 4 ) ; CALL sbc_ice_cice ( kt, nsbc ) ! CICE ice model |
|---|
| 342 | END SELECT |
|---|
| 343 | |
|---|
| 344 | IF( ln_icebergs ) CALL icb_stp( kt ) ! compute icebergs |
|---|
| 345 | |
|---|
| 346 | IF( ln_rnf ) CALL sbc_rnf( kt ) ! add runoffs to fresh water fluxes |
|---|
| 347 | |
|---|
| 348 | IF( ln_ssr ) CALL sbc_ssr( kt ) ! add SST/SSS damping term |
|---|
| 349 | |
|---|
| 350 | IF( nn_fwb /= 0 ) CALL sbc_fwb( kt, nn_fwb, nn_fsbc ) ! control the freshwater budget |
|---|
| 351 | |
|---|
| 352 | IF( nn_closea == 1 ) CALL sbc_clo( kt ) ! treatment of closed sea in the model domain |
|---|
| 353 | ! ! (update freshwater fluxes) |
|---|
| 354 | !RBbug do not understand why see ticket 667 |
|---|
| 355 | !clem-bugsal CALL lbc_lnk( emp, 'T', 1. ) |
|---|
| 356 | ! |
|---|
| 357 | IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 ! |
|---|
| 358 | ! ! ---------------------------------------- ! |
|---|
| 359 | IF( ln_rstart .AND. & !* Restart: read in restart file |
|---|
| 360 | & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 361 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields red in the restart file' |
|---|
| 362 | CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b ) ! before i-stress (U-point) |
|---|
| 363 | CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b ) ! before j-stress (V-point) |
|---|
| 364 | CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b ) ! before non solar heat flux (T-point) |
|---|
| 365 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 366 | ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b ) ! before solar heat flux (T-point) |
|---|
| 367 | CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b ) ! before freshwater flux (T-point) |
|---|
| 368 | ! To ensure restart capability with 3.3x/3.4 restart files !! to be removed in v3.6 |
|---|
| 369 | IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 370 | CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b ) ! before salt flux (T-point) |
|---|
| 371 | ELSE |
|---|
| 372 | sfx_b (:,:) = sfx(:,:) |
|---|
| 373 | ENDIF |
|---|
| 374 | ELSE !* no restart: set from nit000 values |
|---|
| 375 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields set to nit000' |
|---|
| 376 | utau_b(:,:) = utau(:,:) |
|---|
| 377 | vtau_b(:,:) = vtau(:,:) |
|---|
| 378 | qns_b (:,:) = qns (:,:) |
|---|
| 379 | emp_b (:,:) = emp(:,:) |
|---|
| 380 | sfx_b (:,:) = sfx(:,:) |
|---|
| 381 | ENDIF |
|---|
| 382 | ENDIF |
|---|
| 383 | ! ! ---------------------------------------- ! |
|---|
| 384 | IF( lrst_oce ) THEN ! Write in the ocean restart file ! |
|---|
| 385 | ! ! ---------------------------------------- ! |
|---|
| 386 | IF(lwp) WRITE(numout,*) |
|---|
| 387 | IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ', & |
|---|
| 388 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 389 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 390 | CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau ) |
|---|
| 391 | CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau ) |
|---|
| 392 | CALL iom_rstput( kt, nitrst, numrow, 'qns_b' , qns ) |
|---|
| 393 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 394 | ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b' , qsr ) |
|---|
| 395 | CALL iom_rstput( kt, nitrst, numrow, 'emp_b' , emp ) |
|---|
| 396 | CALL iom_rstput( kt, nitrst, numrow, 'sfx_b' , sfx ) |
|---|
| 397 | ENDIF |
|---|
| 398 | |
|---|
| 399 | ! ! ---------------------------------------- ! |
|---|
| 400 | ! ! Outputs and control print ! |
|---|
| 401 | ! ! ---------------------------------------- ! |
|---|
| 402 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN |
|---|
| 403 | CALL iom_put( "empmr" , emp - rnf ) ! upward water flux |
|---|
| 404 | CALL iom_put( "saltflx", sfx ) ! downward salt flux |
|---|
| 405 | ! (includes virtual salt flux beneath ice |
|---|
| 406 | ! in linear free surface case) |
|---|
| 407 | CALL iom_put( "fmmflx", fmmflx ) ! Freezing-melting water flux |
|---|
| 408 | CALL iom_put( "qt" , qns + qsr ) ! total heat flux |
|---|
| 409 | CALL iom_put( "qns" , qns ) ! solar heat flux |
|---|
| 410 | CALL iom_put( "qsr" , qsr ) ! solar heat flux |
|---|
| 411 | IF( nn_ice > 0 ) CALL iom_put( "ice_cover", fr_i ) ! ice fraction |
|---|
| 412 | ENDIF |
|---|
| 413 | ! |
|---|
| 414 | CALL iom_put( "utau", utau ) ! i-wind stress (stress can be updated at |
|---|
| 415 | CALL iom_put( "vtau", vtau ) ! j-wind stress each time step in sea-ice) |
|---|
| 416 | CALL iom_put( "taum", taum ) ! wind stress module |
|---|
| 417 | CALL iom_put( "wspd", wndm ) ! wind speed module |
|---|
| 418 | ! |
|---|
| 419 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 420 | CALL prt_ctl(tab2d_1=fr_i , clinfo1=' fr_i - : ', mask1=tmask, ovlap=1 ) |
|---|
| 421 | CALL prt_ctl(tab2d_1=(emp-rnf) , clinfo1=' emp-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 422 | CALL prt_ctl(tab2d_1=(sfx-rnf) , clinfo1=' sfx-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 423 | CALL prt_ctl(tab2d_1=qns , clinfo1=' qns - : ', mask1=tmask, ovlap=1 ) |
|---|
| 424 | CALL prt_ctl(tab2d_1=qsr , clinfo1=' qsr - : ', mask1=tmask, ovlap=1 ) |
|---|
| 425 | CALL prt_ctl(tab3d_1=tmask , clinfo1=' tmask - : ', mask1=tmask, ovlap=1, kdim=jpk ) |
|---|
| 426 | CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 427 | CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 428 | CALL prt_ctl(tab2d_1=utau , clinfo1=' utau - : ', mask1=umask, & |
|---|
| 429 | & tab2d_2=vtau , clinfo2=' vtau - : ', mask2=vmask, ovlap=1 ) |
|---|
| 430 | ENDIF |
|---|
| 431 | |
|---|
| 432 | IF( kt == nitend ) CALL sbc_final ! Close down surface module if necessary |
|---|
| 433 | ! |
|---|
| 434 | IF( nn_timing == 1 ) CALL timing_stop('sbc') |
|---|
| 435 | ! |
|---|
| 436 | END SUBROUTINE sbc |
|---|
| 437 | |
|---|
| 438 | |
|---|
| 439 | SUBROUTINE sbc_final |
|---|
| 440 | !!--------------------------------------------------------------------- |
|---|
| 441 | !! *** ROUTINE sbc_final *** |
|---|
| 442 | !! |
|---|
| 443 | !! ** Purpose : Finalize CICE (if used) |
|---|
| 444 | !!--------------------------------------------------------------------- |
|---|
| 445 | ! |
|---|
| 446 | IF( nn_ice == 4 ) CALL cice_sbc_final |
|---|
| 447 | ! |
|---|
| 448 | END SUBROUTINE sbc_final |
|---|
| 449 | |
|---|
| 450 | !!====================================================================== |
|---|
| 451 | END MODULE sbcmod |
|---|
