New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in branches/2014/dev_r4621_NOC4_BDY_VERT_INTERP/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/2014/dev_r4621_NOC4_BDY_VERT_INTERP/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 4694

Last change on this file since 4694 was 4354, checked in by jchanut, 10 years ago

Restore AGRIF and BDY compatibility, see ticket #1133

  • Property svn:keywords set to Id
File size: 38.5 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!                 ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!----------------------------------------------------------------------
33
34   !!----------------------------------------------------------------------
35   !!   nemo_gcm       : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
36   !!   nemo_init      : initialization of the NEMO system
37   !!   nemo_ctl       : initialisation of the contol print
38   !!   nemo_closefile : close remaining open files
39   !!   nemo_alloc     : dynamical allocation
40   !!   nemo_partition : calculate MPP domain decomposition
41   !!   factorise      : calculate the factors of the no. of MPI processes
42   !!----------------------------------------------------------------------
43   USE step_oce        ! module used in the ocean time stepping module
44   USE sbc_oce         ! surface boundary condition: ocean
45   USE cla             ! cross land advection               (tra_cla routine)
46   USE domcfg          ! domain configuration               (dom_cfg routine)
47   USE mppini          ! shared/distributed memory setting (mpp_init routine)
48   USE domain          ! domain initialization             (dom_init routine)
49#if defined key_nemocice_decomp
50   USE ice_domain_size, only: nx_global, ny_global
51#endif
52   USE tideini         ! tidal components initialization   (tide_ini routine)
53   USE bdyini          ! open boundary cond. initialization (bdy_init routine)
54   USE bdydta          ! open boundary cond. initialization (bdy_dta_init routine)
55   USE bdytides        ! open boundary cond. initialization (bdytide_init routine)
56   USE istate          ! initial state setting          (istate_init routine)
57   USE ldfdyn          ! lateral viscosity setting      (ldfdyn_init routine)
58   USE ldftra          ! lateral diffusivity setting    (ldftra_init routine)
59   USE zdfini          ! vertical physics setting          (zdf_init routine)
60   USE phycst          ! physical constant                  (par_cst routine)
61   USE trdmod          ! momentum/tracers trends       (trd_mod_init routine)
62   USE asminc          ! assimilation increments     
63   USE asmbkg          ! writing out state trajectory
64   USE diaptr          ! poleward transports           (dia_ptr_init routine)
65   USE diadct          ! sections transports           (dia_dct_init routine)
66   USE diaobs          ! Observation diagnostics       (dia_obs_init routine)
67   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
68   USE step            ! NEMO time-stepping                 (stp     routine)
69   USE icbini          ! handle bergs, initialisation
70   USE icbstp          ! handle bergs, calving, themodynamics and transport
71#if defined key_oasis3
72   USE cpl_oasis3      ! OASIS3 coupling
73#elif defined key_oasis4
74   USE cpl_oasis4      ! OASIS4 coupling (not working)
75#endif
76   USE c1d             ! 1D configuration
77   USE step_c1d        ! Time stepping loop for the 1D configuration
78   USE dyndmp          ! Momentum damping
79#if defined key_top
80   USE trcini          ! passive tracer initialisation
81#endif
82   USE lib_mpp         ! distributed memory computing
83#if defined key_iomput
84   USE xios
85#endif
86   USE sbctide, ONLY: lk_tide
87   USE crsini          ! initialise grid coarsening utility
88   USE lbcnfd, ONLY: isendto, nsndto ! Setup of north fold exchanges
89
90   IMPLICIT NONE
91   PRIVATE
92
93   PUBLIC   nemo_gcm    ! called by model.F90
94   PUBLIC   nemo_init   ! needed by AGRIF
95   PUBLIC   nemo_alloc  ! needed by TAM
96
97   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
98
99   !!----------------------------------------------------------------------
100   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
101   !! $Id$
102   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
103   !!----------------------------------------------------------------------
104CONTAINS
105
106   SUBROUTINE nemo_gcm
107      !!----------------------------------------------------------------------
108      !!                     ***  ROUTINE nemo_gcm  ***
109      !!
110      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
111      !!              curvilinear mesh on the sphere.
112      !!
113      !! ** Method  : - model general initialization
114      !!              - launch the time-stepping (stp routine)
115      !!              - finalize the run by closing files and communications
116      !!
117      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
118      !!              Madec, 2008, internal report, IPSL.
119      !!----------------------------------------------------------------------
120      INTEGER ::   istp       ! time step index
121      !!----------------------------------------------------------------------
122      !
123
124#if defined key_agrif
125      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
126#endif
127
128      !                            !-----------------------!
129      CALL nemo_init               !==  Initialisations  ==!
130      !                            !-----------------------!
131#if defined key_agrif
132      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
133      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
134# if defined key_top
135      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
136# endif
137# if defined key_lim2
138      CALL Agrif_Declare_Var_lim2  !  "      "   "   "      "  LIM
139# endif
140#endif
141
142      ! check that all process are still there... If some process have an error,
143      ! they will never enter in step and other processes will wait until the end of the cpu time!
144      IF( lk_mpp )   CALL mpp_max( nstop )
145
146      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
147
148      !                            !-----------------------!
149      !                            !==   time stepping   ==!
150      !                            !-----------------------!
151      istp = nit000
152#if defined key_c1d
153         DO WHILE ( istp <= nitend .AND. nstop == 0 )
154            CALL stp_c1d( istp )
155            istp = istp + 1
156         END DO
157#else
158          IF( lk_asminc ) THEN
159             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
160             IF( ln_asmdin ) THEN                        ! Direct initialization
161                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
162                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
163                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
164             ENDIF
165          ENDIF
166
167         DO WHILE ( istp <= nitend .AND. nstop == 0 )
168
169#if defined key_agrif
170            CALL Agrif_Step( stp )           ! AGRIF: time stepping
171#else
172            CALL stp( istp )                 ! standard time stepping
173#endif
174
175            istp = istp + 1
176            IF( lk_mpp )   CALL mpp_max( nstop )
177         END DO
178#endif
179
180      IF( lk_diaobs   )   CALL dia_obs_wri
181      !
182      IF( ln_icebergs )   CALL icb_end( nitend )
183
184      !                            !------------------------!
185      !                            !==  finalize the run  ==!
186      !                            !------------------------!
187      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
188      !
189      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
190         WRITE(numout,cform_err)
191         WRITE(numout,*) nstop, ' error have been found'
192      ENDIF
193      !
194#if defined key_agrif
195      CALL Agrif_ParentGrid_To_ChildGrid()
196      IF( lk_diaobs ) CALL dia_obs_wri
197      IF( nn_timing == 1 )   CALL timing_finalize
198      CALL Agrif_ChildGrid_To_ParentGrid()
199#endif
200      IF( nn_timing == 1 )   CALL timing_finalize
201      !
202      CALL nemo_closefile
203#if defined key_iomput
204      CALL xios_finalize                ! end mpp communications with xios
205# if defined key_oasis3 || defined key_oasis4
206      CALL cpl_prism_finalize           ! end coupling and mpp communications with OASIS
207# endif
208#else
209# if defined key_oasis3 || defined key_oasis4
210      CALL cpl_prism_finalize           ! end coupling and mpp communications with OASIS
211# else
212      IF( lk_mpp )   CALL mppstop       ! end mpp communications
213# endif
214#endif
215      !
216   END SUBROUTINE nemo_gcm
217
218
219   SUBROUTINE nemo_init
220      !!----------------------------------------------------------------------
221      !!                     ***  ROUTINE nemo_init  ***
222      !!
223      !! ** Purpose :   initialization of the NEMO GCM
224      !!----------------------------------------------------------------------
225      INTEGER ::   ji            ! dummy loop indices
226      INTEGER ::   ilocal_comm   ! local integer
227      INTEGER ::   ios
228      CHARACTER(len=80), DIMENSION(16) ::   cltxt
229      !!
230      NAMELIST/namctl/ ln_ctl, nn_print, nn_ictls, nn_ictle,   &
231         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
232         &             nn_bench, nn_timing
233      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
234         &             jpizoom, jpjzoom, jperio
235      !!----------------------------------------------------------------------
236      !
237      cltxt = ''
238      !
239      !                             ! Open reference namelist and configuration namelist files
240      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
241      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
242      CALL ctl_opn( numond, 'output.namelist.dyn', 'UNKNOWN', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. , 1 )
243      !
244      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
245      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
246901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
247
248      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
249      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
250902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
251      WRITE( numond, namctl )
252
253      !
254      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
255      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
256903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
257
258      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
259      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
260904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
261      WRITE( numond, namcfg )
262
263! Force values for AGRIF zoom (cf. agrif_user.F90)
264#if defined key_agrif
265   IF( .NOT. Agrif_Root() ) THEN
266      jpiglo  = nbcellsx + 2 + 2*nbghostcells
267      jpjglo  = nbcellsy + 2 + 2*nbghostcells
268      jpi     = ( jpiglo-2*jpreci + (jpni-1+0) ) / jpni + 2*jpreci
269      jpj     = ( jpjglo-2*jprecj + (jpnj-1+0) ) / jpnj + 2*jprecj
270      jpidta  = jpiglo
271      jpjdta  = jpjglo
272      jpizoom = 1
273      jpjzoom = 1
274      nperio  = 0
275      jperio  = 0
276   ENDIF
277#endif
278      !
279      !                             !--------------------------------------------!
280      !                             !  set communicator & select the local node  !
281      !                             !--------------------------------------------!
282#if defined key_iomput
283      IF( Agrif_Root() ) THEN
284# if defined key_oasis3 || defined key_oasis4
285         CALL cpl_prism_init( ilocal_comm )      ! nemo local communicator given by oasis
286         CALL xios_initialize( "oceanx",local_comm=ilocal_comm )
287# else
288         CALL  xios_initialize( "nemo",return_comm=ilocal_comm )
289# endif
290      ENDIF
291      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection
292#else
293# if defined key_oasis3 || defined key_oasis4
294      IF( Agrif_Root() ) THEN
295         CALL cpl_prism_init( ilocal_comm )                 ! nemo local communicator given by oasis
296      ENDIF
297      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection (control print return in cltxt)
298# else
299      ilocal_comm = 0
300      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop )                 ! Nodes selection (control print return in cltxt)
301# endif
302#endif
303      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
304
305      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
306
307      ! If dimensions of processor grid weren't specified in the namelist file
308      ! then we calculate them here now that we have our communicator size
309      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
310#if   defined key_mpp_mpi
311         IF( Agrif_Root() ) CALL nemo_partition(mppsize)
312#else
313         jpni  = 1
314         jpnj  = 1
315         jpnij = jpni*jpnj
316#endif
317      END IF
318
319      ! Calculate domain dimensions given calculated jpni and jpnj
320      ! This used to be done in par_oce.F90 when they were parameters rather
321      ! than variables
322      IF( Agrif_Root() ) THEN
323#if defined key_nemocice_decomp
324         jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci ! first  dim.
325         jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim.
326#else
327         jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
328         jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
329#endif
330      ENDIF
331         jpk = jpkdta                                             ! third dim
332         jpim1 = jpi-1                                            ! inner domain indices
333         jpjm1 = jpj-1                                            !   "           "
334         jpkm1 = jpk-1                                            !   "           "
335         jpij  = jpi*jpj                                          !  jpi x j
336
337      IF(lwp) THEN                            ! open listing units
338         !
339         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
340         !
341         WRITE(numout,*)
342         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
343         WRITE(numout,*) '                       NEMO team'
344         WRITE(numout,*) '            Ocean General Circulation Model'
345         WRITE(numout,*) '                  version 3.4  (2011) '
346         WRITE(numout,*)
347         WRITE(numout,*)
348         DO ji = 1, SIZE(cltxt)
349            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
350         END DO
351         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
352         !
353      ENDIF
354
355      ! Now we know the dimensions of the grid and numout has been set we can
356      ! allocate arrays
357      CALL nemo_alloc()
358
359      !                             !-------------------------------!
360      !                             !  NEMO general initialization  !
361      !                             !-------------------------------!
362
363      CALL nemo_ctl                          ! Control prints & Benchmark
364
365      !                                      ! Domain decomposition
366      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
367      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
368      ENDIF
369      !
370      IF( nn_timing == 1 )  CALL timing_init
371      !
372      !                                      ! General initialization
373                            CALL     phy_cst    ! Physical constants
374                            CALL     eos_init   ! Equation of state
375      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
376                            CALL     dom_cfg    ! Domain configuration
377                            CALL     dom_init   ! Domain
378
379      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
380
381      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
382
383                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
384
385      IF( lk_tide       )   CALL    tide_init( nit000 )    ! Initialisation of the tidal harmonics
386
387      IF( lk_bdy        )   CALL      bdy_init  ! Open boundaries initialisation
388      IF( lk_bdy        )   CALL  bdy_dta_init  ! Open boundaries initialisation of external data arrays
389      IF( lk_bdy .AND. lk_tide )   &
390         &                  CALL  bdytide_init  ! Open boundaries initialisation of tidal harmonic forcing
391
392                            CALL dyn_nept_init  ! simplified form of Neptune effect
393
394      !     
395      IF( ln_crs        )   CALL     crs_init   ! Domain initialization of coarsened grid
396      !
397                                ! Ocean physics
398                            CALL     sbc_init   ! Forcings : surface module
399      !                                         ! Vertical physics
400
401                            CALL     zdf_init      ! namelist read
402
403                            CALL zdf_bfr_init      ! bottom friction
404
405      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
406      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
407      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
408      IF( lk_zdfkpp     )   CALL zdf_kpp_init      ! KPP closure scheme
409      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
410      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
411         &                  CALL zdf_ddm_init      ! double diffusive mixing
412      !                                         ! Lateral physics
413                            CALL ldf_tra_init      ! Lateral ocean tracer physics
414                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
415      IF( lk_ldfslp     )   CALL ldf_slp_init      ! slope of lateral mixing
416
417      !                                     ! Active tracers
418                            CALL tra_qsr_init   ! penetrative solar radiation qsr
419                            CALL tra_bbc_init   ! bottom heat flux
420      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
421                            CALL tra_dmp_init   ! internal damping trends- tracers
422                            CALL tra_adv_init   ! horizontal & vertical advection
423                            CALL tra_ldf_init   ! lateral mixing
424                            CALL tra_zdf_init   ! vertical mixing and after tracer fields
425
426      !                                     ! Dynamics
427      IF( lk_c1d        )   CALL dyn_dmp_init   ! internal damping trends- momentum
428                            CALL dyn_adv_init   ! advection (vector or flux form)
429                            CALL dyn_vor_init   ! vorticity term including Coriolis
430                            CALL dyn_ldf_init   ! lateral mixing
431                            CALL dyn_hpg_init   ! horizontal gradient of Hydrostatic pressure
432                            CALL dyn_zdf_init   ! vertical diffusion
433                            CALL dyn_spg_init   ! surface pressure gradient
434
435      !                                     ! Misc. options
436      IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 )   CALL cla_init       ! Cross Land Advection
437                            CALL icb_init( rdt, nit000)   ! initialise icebergs instance
438     
439#if defined key_top
440      !                                     ! Passive tracers
441                            CALL     trc_init
442#endif
443      !
444 
445                                            ! Diagnostics
446      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
447      IF( lk_diaar5     )   CALL dia_ar5_init   ! ar5 diag
448                            CALL dia_ptr_init   ! Poleward TRansports initialization
449      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
450                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
451                            CALL trd_mod_init   ! Mixed-layer/Vorticity/Integral constraints trends
452      IF( lk_diaobs     ) THEN                  ! Observation & model comparison
453                            CALL dia_obs_init            ! Initialize observational data
454                            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
455      ENDIF
456      !                                     ! Assimilation increments
457      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
458      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
459      !
460   END SUBROUTINE nemo_init
461
462
463   SUBROUTINE nemo_ctl
464      !!----------------------------------------------------------------------
465      !!                     ***  ROUTINE nemo_ctl  ***
466      !!
467      !! ** Purpose :   control print setting
468      !!
469      !! ** Method  : - print namctl information and check some consistencies
470      !!----------------------------------------------------------------------
471      !
472      IF(lwp) THEN                  ! control print
473         WRITE(numout,*)
474         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
475         WRITE(numout,*) '~~~~~~~ '
476         WRITE(numout,*) '   Namelist namctl'
477         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
478         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
479         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
480         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
481         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
482         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
483         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
484         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
485         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
486         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
487      ENDIF
488      !
489      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
490      nictls    = nn_ictls
491      nictle    = nn_ictle
492      njctls    = nn_jctls
493      njctle    = nn_jctle
494      isplt     = nn_isplt
495      jsplt     = nn_jsplt
496      nbench    = nn_bench
497
498      IF(lwp) THEN                  ! control print
499         WRITE(numout,*)
500         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
501         WRITE(numout,*) '~~~~~~~ '
502         WRITE(numout,*) '   Namelist namcfg'
503         WRITE(numout,*) '      configuration name              cp_cfg      = ', TRIM(cp_cfg)
504         WRITE(numout,*) '      configuration zoom name         cp_cfz      = ', TRIM(cp_cfz)
505         WRITE(numout,*) '      configuration resolution        jp_cfg      = ', jp_cfg
506         WRITE(numout,*) '      1st lateral dimension ( >= jpi ) jpidta     = ', jpidta
507         WRITE(numout,*) '      2nd    "         "    ( >= jpj ) jpjdta     = ', jpjdta
508         WRITE(numout,*) '      3nd    "         "               jpkdta     = ', jpkdta
509         WRITE(numout,*) '      1st dimension of global domain in i jpiglo  = ', jpiglo
510         WRITE(numout,*) '      2nd    -                  -    in j jpjglo  = ', jpjglo
511         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
512         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
513         WRITE(numout,*) '      lateral cond. type (between 0 and 6) jperio = ', jperio   
514      ENDIF
515      !                             ! Parameter control
516      !
517      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
518         IF( lk_mpp .AND. jpnij > 1 ) THEN
519            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
520         ELSE
521            IF( isplt == 1 .AND. jsplt == 1  ) THEN
522               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
523                  &           ' - the print control will be done over the whole domain' )
524            ENDIF
525            ijsplt = isplt * jsplt            ! total number of processors ijsplt
526         ENDIF
527         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
528         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
529         !
530         !                              ! indices used for the SUM control
531         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
532            lsp_area = .FALSE.
533         ELSE                                             ! print control done over a specific  area
534            lsp_area = .TRUE.
535            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
536               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
537               nictls = 1
538            ENDIF
539            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
540               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
541               nictle = jpiglo
542            ENDIF
543            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
544               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
545               njctls = 1
546            ENDIF
547            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
548               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
549               njctle = jpjglo
550            ENDIF
551         ENDIF
552      ENDIF
553      !
554      IF( nbench == 1 ) THEN              ! Benchmark
555         SELECT CASE ( cp_cfg )
556         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
557         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
558            &                                 ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
559         END SELECT
560      ENDIF
561      !
562      IF( lk_c1d .AND. .NOT.lk_iomput )   CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ',   &
563         &                                               'with the IOM Input/Output manager. '         ,   &
564         &                                               'Compile with key_iomput enabled' )
565      !
566      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
567         &                                               'f2003 standard. '                              ,  &
568         &                                               'Compile with key_nosignedzero enabled' )
569      !
570   END SUBROUTINE nemo_ctl
571
572
573   SUBROUTINE nemo_closefile
574      !!----------------------------------------------------------------------
575      !!                     ***  ROUTINE nemo_closefile  ***
576      !!
577      !! ** Purpose :   Close the files
578      !!----------------------------------------------------------------------
579      !
580      IF( lk_mpp )   CALL mppsync
581      !
582      CALL iom_close                                 ! close all input/output files managed by iom_*
583      !
584      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
585      IF( numsol          /= -1 )   CLOSE( numsol          )   ! solver file
586      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
587      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
588      IF( numond          /= -1 )   CLOSE( numond          )   ! oce output namelist
589      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
590      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
591      IF( numoni          /= -1 )   CLOSE( numoni          )   ! ice output namelist
592      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
593      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
594      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
595      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
596      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
597
598      !
599      numout = 6                                     ! redefine numout in case it is used after this point...
600      !
601   END SUBROUTINE nemo_closefile
602
603
604   SUBROUTINE nemo_alloc
605      !!----------------------------------------------------------------------
606      !!                     ***  ROUTINE nemo_alloc  ***
607      !!
608      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
609      !!
610      !! ** Method  :
611      !!----------------------------------------------------------------------
612      USE diawri    , ONLY: dia_wri_alloc
613      USE dom_oce   , ONLY: dom_oce_alloc
614      USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
615      USE ldftra_oce, ONLY: ldftra_oce_alloc
616      USE trc_oce   , ONLY: trc_oce_alloc
617#if defined key_diadct 
618      USE diadct    , ONLY: diadct_alloc 
619#endif 
620#if defined key_bdy
621      USE bdy_oce   , ONLY: bdy_oce_alloc
622#endif
623      !
624      INTEGER :: ierr
625      !!----------------------------------------------------------------------
626      !
627      ierr =        oce_alloc       ()          ! ocean
628      ierr = ierr + dia_wri_alloc   ()
629      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
630      ierr = ierr + ldfdyn_oce_alloc()          ! ocean lateral  physics : dynamics
631      ierr = ierr + ldftra_oce_alloc()          ! ocean lateral  physics : tracers
632      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
633      !
634      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
635      !
636#if defined key_diadct 
637      ierr = ierr + diadct_alloc    ()          !
638#endif 
639#if defined key_bdy
640      ierr = ierr + bdy_oce_alloc   ()          ! bdy masks (incl. initialization)
641#endif
642      !
643      IF( lk_mpp    )   CALL mpp_sum( ierr )
644      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
645      !
646   END SUBROUTINE nemo_alloc
647
648
649   SUBROUTINE nemo_partition( num_pes )
650      !!----------------------------------------------------------------------
651      !!                 ***  ROUTINE nemo_partition  ***
652      !!
653      !! ** Purpose :
654      !!
655      !! ** Method  :
656      !!----------------------------------------------------------------------
657      INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
658      !
659      INTEGER, PARAMETER :: nfactmax = 20
660      INTEGER :: nfact ! The no. of factors returned
661      INTEGER :: ierr  ! Error flag
662      INTEGER :: ji
663      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
664      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
665      !!----------------------------------------------------------------------
666
667      ierr = 0
668
669      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
670
671      IF( nfact <= 1 ) THEN
672         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
673         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
674         jpnj = 1
675         jpni = num_pes
676      ELSE
677         ! Search through factors for the pair that are closest in value
678         mindiff = 1000000
679         imin    = 1
680         DO ji = 1, nfact-1, 2
681            idiff = ABS( ifact(ji) - ifact(ji+1) )
682            IF( idiff < mindiff ) THEN
683               mindiff = idiff
684               imin = ji
685            ENDIF
686         END DO
687         jpnj = ifact(imin)
688         jpni = ifact(imin + 1)
689      ENDIF
690      !
691      jpnij = jpni*jpnj
692      !
693   END SUBROUTINE nemo_partition
694
695
696   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
697      !!----------------------------------------------------------------------
698      !!                     ***  ROUTINE factorise  ***
699      !!
700      !! ** Purpose :   return the prime factors of n.
701      !!                knfax factors are returned in array kfax which is of
702      !!                maximum dimension kmaxfax.
703      !! ** Method  :
704      !!----------------------------------------------------------------------
705      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
706      INTEGER                    , INTENT(  out) ::   kerr, knfax
707      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
708      !
709      INTEGER :: ifac, jl, inu
710      INTEGER, PARAMETER :: ntest = 14
711      INTEGER :: ilfax(ntest)
712
713      ! lfax contains the set of allowed factors.
714      data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256,  &
715         &                            128,   64,   32,   16,    8,   4,   2  /
716      !!----------------------------------------------------------------------
717
718      ! Clear the error flag and initialise output vars
719      kerr = 0
720      kfax = 1
721      knfax = 0
722
723      ! Find the factors of n.
724      IF( kn == 1 )   GOTO 20
725
726      ! nu holds the unfactorised part of the number.
727      ! knfax holds the number of factors found.
728      ! l points to the allowed factor list.
729      ! ifac holds the current factor.
730
731      inu   = kn
732      knfax = 0
733
734      DO jl = ntest, 1, -1
735         !
736         ifac = ilfax(jl)
737         IF( ifac > inu )   CYCLE
738
739         ! Test whether the factor will divide.
740
741         IF( MOD(inu,ifac) == 0 ) THEN
742            !
743            knfax = knfax + 1            ! Add the factor to the list
744            IF( knfax > kmaxfax ) THEN
745               kerr = 6
746               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
747               return
748            ENDIF
749            kfax(knfax) = ifac
750            ! Store the other factor that goes with this one
751            knfax = knfax + 1
752            kfax(knfax) = inu / ifac
753            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
754         ENDIF
755         !
756      END DO
757
758   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
759      !
760   END SUBROUTINE factorise
761
762#if defined key_mpp_mpi
763   SUBROUTINE nemo_northcomms
764      !!======================================================================
765      !!                     ***  ROUTINE  nemo_northcomms  ***
766      !! nemo_northcomms    :  Setup for north fold exchanges with explicit
767      !!                       point-to-point messaging
768      !!=====================================================================
769      !!----------------------------------------------------------------------
770      !!
771      !! ** Purpose :   Initialization of the northern neighbours lists.
772      !!----------------------------------------------------------------------
773      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
774      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
775      !!----------------------------------------------------------------------
776
777      INTEGER  ::   sxM, dxM, sxT, dxT, jn
778      INTEGER  ::   njmppmax
779
780      njmppmax = MAXVAL( njmppt )
781   
782      !initializes the north-fold communication variables
783      isendto(:) = 0
784      nsndto = 0
785
786      !if I am a process in the north
787      IF ( njmpp == njmppmax ) THEN
788          !sxM is the first point (in the global domain) needed to compute the
789          !north-fold for the current process
790          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
791          !dxM is the last point (in the global domain) needed to compute the
792          !north-fold for the current process
793          dxM = jpiglo - nimppt(narea) + 2
794
795          !loop over the other north-fold processes to find the processes
796          !managing the points belonging to the sxT-dxT range
797          DO jn = jpnij - jpni +1, jpnij
798             IF ( njmppt(jn) == njmppmax ) THEN
799                !sxT is the first point (in the global domain) of the jn
800                !process
801                sxT = nimppt(jn)
802                !dxT is the last point (in the global domain) of the jn
803                !process
804                dxT = nimppt(jn) + nlcit(jn) - 1
805                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
806                   nsndto = nsndto + 1
807                   isendto(nsndto) = jn
808                ELSEIF ((sxM .le. sxT) .AND. (dxM .gt. dxT)) THEN
809                   nsndto = nsndto + 1
810                   isendto(nsndto) = jn
811                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
812                   nsndto = nsndto + 1
813                   isendto(nsndto) = jn
814                END IF
815             END IF
816          END DO
817      ENDIF
818      l_north_nogather = .TRUE.
819   END SUBROUTINE nemo_northcomms
820#else
821   SUBROUTINE nemo_northcomms      ! Dummy routine
822      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
823   END SUBROUTINE nemo_northcomms
824#endif
825   !!======================================================================
826END MODULE nemogcm
827
828
Note: See TracBrowser for help on using the repository browser.