New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
step.F90 in branches/2014/dev_r4650_UKMO10_Tidally_Meaned_Diagnostics/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/2014/dev_r4650_UKMO10_Tidally_Meaned_Diagnostics/NEMOGCM/NEMO/OPA_SRC/step.F90 @ 5989

Last change on this file since 5989 was 5989, checked in by deazer, 8 years ago

Merging TMB and 25h diagnostics to head of trunk
added brief documentation

  • Property svn:keywords set to Id
File size: 20.7 KB
Line 
1MODULE step
2   !!======================================================================
3   !!                       ***  MODULE step  ***
4   !! Time-stepping    : manager of the ocean, tracer and ice time stepping
5   !!======================================================================
6   !! History :  OPA  !  1991-03  (G. Madec)  Original code
7   !!             -   !  1991-11  (G. Madec)
8   !!             -   !  1992-06  (M. Imbard)  add a first output record
9   !!             -   !  1996-04  (G. Madec)  introduction of dynspg
10   !!             -   !  1996-04  (M.A. Foujols)  introduction of passive tracer
11   !!            8.0  !  1997-06  (G. Madec)  new architecture of call
12   !!            8.2  !  1997-06  (G. Madec, M. Imbard, G. Roullet)  free surface
13   !!             -   !  1999-02  (G. Madec, N. Grima)  hpg implicit
14   !!             -   !  2000-07  (J-M Molines, M. Imbard)  Open Bondary Conditions
15   !!   NEMO     1.0  !  2002-06  (G. Madec)  free form, suppress macro-tasking
16   !!             -   !  2004-08  (C. Talandier) New trends organization
17   !!             -   !  2005-01  (C. Ethe) Add the KPP closure scheme
18   !!             -   !  2005-11  (G. Madec)  Reorganisation of tra and dyn calls
19   !!             -   !  2006-01  (L. Debreu, C. Mazauric)  Agrif implementation
20   !!             -   !  2006-07  (S. Masson)  restart using iom
21   !!            3.2  !  2009-02  (G. Madec, R. Benshila)  reintroduicing z*-coordinate
22   !!             -   !  2009-06  (S. Masson, G. Madec)  TKE restart compatible with key_cpl
23   !!            3.3  !  2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
24   !!             -   !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
25   !!            3.4  !  2011-04  (G. Madec, C. Ethe) Merge of dtatem and dtasal
26   !!            3.6  !  2012-07  (J. Simeon, G. Madec. C. Ethe)  Online coarsening of outputs
27   !!            3.6  !  2014-04  (F. Roquet, G. Madec) New equations of state
28   !!            3.7  !  2014-10  (G. Madec)  LDF simplication
29   !!             -   !  2014-12  (G. Madec) remove KPP scheme
30   !!             -   !  2015-11  (J. Chanut) free surface simplification
31   !!----------------------------------------------------------------------
32
33   !!----------------------------------------------------------------------
34   !!   stp             : OPA system time-stepping
35   !!----------------------------------------------------------------------
36   USE step_oce         ! time stepping definition modules
37   USE iom
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   stp   ! called by nemogcm.F90
43
44   !! * Substitutions
45#  include "domzgr_substitute.h90"
46!!gm   #  include "zdfddm_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/OPA 3.7 , NEMO Consortium (2015)
49   !! $Id$
50   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54#if defined key_agrif
55   RECURSIVE SUBROUTINE stp( )
56      INTEGER             ::   kstp   ! ocean time-step index
57#else
58   SUBROUTINE stp( kstp )
59      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
60#endif
61      !!----------------------------------------------------------------------
62      !!                     ***  ROUTINE stp  ***
63      !!
64      !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.)
65      !!              - Time stepping of LIM (dynamic and thermodynamic eqs.)
66      !!              - Tme stepping  of TRC (passive tracer eqs.)
67      !!
68      !! ** Method  : -1- Update forcings and data
69      !!              -2- Update ocean physics
70      !!              -3- Compute the t and s trends
71      !!              -4- Update t and s
72      !!              -5- Compute the momentum trends
73      !!              -6- Update the horizontal velocity
74      !!              -7- Compute the diagnostics variables (rd,N2, hdiv,w)
75      !!              -8- Outputs and diagnostics
76      !!----------------------------------------------------------------------
77      INTEGER ::   jk       ! dummy loop indice
78      INTEGER ::   indic    ! error indicator if < 0
79      INTEGER ::   kcall    ! optional integer argument (dom_vvl_sf_nxt)
80      !! ---------------------------------------------------------------------
81#if defined key_agrif
82      kstp = nit000 + Agrif_Nb_Step()
83      IF( lk_agrif_debug ) THEN
84         IF( Agrif_Root() .and. lwp)   WRITE(*,*) '---'
85         IF(lwp)   WRITE(*,*) 'Grid Number', Agrif_Fixed(),' time step ', kstp, 'int tstep', Agrif_NbStepint()
86      ENDIF
87      IF( kstp == nit000 + 1 )   lk_agrif_fstep = .FALSE.
88# if defined key_iomput
89      IF( Agrif_Nbstepint() == 0 )   CALL iom_swap( cxios_context )
90# endif
91#endif
92      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
93      ! update I/O and calendar
94      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
95                             indic = 0                ! reset to no error condition
96                             
97      IF( kstp == nit000 ) THEN                       ! initialize IOM context (must be done after nemo_init for AGRIF+XIOS+OASIS)
98                             CALL iom_init(      cxios_context          )  ! for model grid (including passible AGRIF zoom)
99         IF( ln_crs      )   CALL iom_init( TRIM(cxios_context)//"_crs" )  ! for coarse grid
100      ENDIF
101      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
102                             CALL iom_setkt( kstp - nit000 + 1,      cxios_context          )   ! tell IOM we are at time step kstp
103      IF( ln_crs         )   CALL iom_setkt( kstp - nit000 + 1, TRIM(cxios_context)//"_crs" )   ! tell IOM we are at time step kstp
104
105      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
106      ! Update external forcing (tides, open boundaries, and surface boundary condition (including sea-ice)
107      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
108      IF( lk_tide    )   CALL sbc_tide( kstp )                   ! update tide potential
109      IF( ln_apr_dyn )   CALL sbc_apr ( kstp )                   ! atmospheric pressure (NB: call before bdy_dta which needs ssh_ib)
110      IF( lk_bdy     )   CALL bdy_dta ( kstp, time_offset=+1 )   ! update dynamic & tracer data at open boundaries
111                         CALL sbc     ( kstp )                   ! Sea Boundary Condition (including sea-ice)
112
113      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
114      ! Update stochastic parameters and random T/S fluctuations
115      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
116                         CALL sto_par( kstp )          ! Stochastic parameters
117
118      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
119      ! Ocean physics update                (ua, va, tsa used as workspace)
120      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
121      !  THERMODYNAMICS
122                         CALL eos_rab( tsb, rab_b )       ! before local thermal/haline expension ratio at T-points
123                         CALL eos_rab( tsn, rab_n )       ! now    local thermal/haline expension ratio at T-points
124                         CALL bn2    ( tsb, rab_b, rn2b ) ! before Brunt-Vaisala frequency
125                         CALL bn2    ( tsn, rab_n, rn2  ) ! now    Brunt-Vaisala frequency
126
127      !
128      !  VERTICAL PHYSICS
129                         CALL zdf_bfr( kstp )         ! bottom friction (if quadratic)
130      !                                               ! Vertical eddy viscosity and diffusivity coefficients
131      IF( lk_zdfric  )   CALL zdf_ric( kstp )            ! Richardson number dependent Kz
132      IF( lk_zdftke  )   CALL zdf_tke( kstp )            ! TKE closure scheme for Kz
133      IF( lk_zdfgls  )   CALL zdf_gls( kstp )            ! GLS closure scheme for Kz
134      IF( lk_zdfcst  ) THEN                              ! Constant Kz (reset avt, avm[uv] to the background value)
135         avt (:,:,:) = rn_avt0 * wmask (:,:,:)
136         avmu(:,:,:) = rn_avm0 * wumask(:,:,:)
137         avmv(:,:,:) = rn_avm0 * wvmask(:,:,:)
138      ENDIF
139
140      IF( ln_rnf_mouth ) THEN                         ! increase diffusivity at rivers mouths
141         DO jk = 2, nkrnf   ;   avt(:,:,jk) = avt(:,:,jk) + 2._wp * rn_avt_rnf * rnfmsk(:,:) * tmask(:,:,jk)   ;   END DO
142      ENDIF
143      IF( ln_zdfevd  )   CALL zdf_evd( kstp )         ! enhanced vertical eddy diffusivity
144
145      IF( lk_zdftmx  )   CALL zdf_tmx( kstp )         ! tidal vertical mixing
146
147      IF( lk_zdfddm  )   CALL zdf_ddm( kstp )         ! double diffusive mixing
148
149                         CALL zdf_mxl( kstp )         ! mixed layer depth
150
151                                                      ! write TKE or GLS information in the restart file
152      IF( lrst_oce .AND. lk_zdftke )   CALL tke_rst( kstp, 'WRITE' )
153      IF( lrst_oce .AND. lk_zdfgls )   CALL gls_rst( kstp, 'WRITE' )
154      !
155      !  LATERAL  PHYSICS
156      !
157      IF( l_ldfslp ) THEN                             ! slope of lateral mixing
158!!gm : why this here ????
159         IF(ln_sto_eos ) CALL sto_pts( tsn )          ! Random T/S fluctuations
160!!gm
161                         CALL eos( tsb, rhd, gdept_0(:,:,:) )               ! before in situ density
162
163         IF( ln_zps .AND. .NOT. ln_isfcav)                               &
164            &            CALL zps_hde    ( kstp, jpts, tsb, gtsu, gtsv,  &  ! Partial steps: before horizontal gradient
165            &                                          rhd, gru , grv    )  ! of t, s, rd at the last ocean level
166
167         IF( ln_zps .AND.       ln_isfcav)                               &
168            &            CALL zps_hde_isf( kstp, jpts, tsb, gtsu, gtsv, gtui, gtvi,   &    ! Partial steps for top cell (ISF)
169            &                                          rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv ,   &
170            &                                   grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi    ) ! of t, s, rd at the first ocean level
171
172         IF( ln_traldf_triad ) THEN
173                         CALL ldf_slp_triad( kstp )                       ! before slope for triad operator
174         ELSE     
175                         CALL ldf_slp     ( kstp, rhd, rn2b )             ! before slope for standard operator
176         ENDIF
177      ENDIF
178      !                                               ! eddy diffusivity coeff. and/or eiv coeff.
179      IF( l_ldftra_time .OR. l_ldfeiv_time )   CALL ldf_tra( kstp ) 
180
181      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
182      !  Ocean dynamics : hdiv, ssh, e3, u, v, w
183      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
184
185                         CALL ssh_nxt       ( kstp )  ! after ssh (includes call to div_hor)
186      IF( lk_vvl     )   CALL dom_vvl_sf_nxt( kstp )  ! after vertical scale factors
187                         CALL wzv           ( kstp )  ! now cross-level velocity
188
189!!gm : why also here ????
190      IF(ln_sto_eos  )   CALL sto_pts( tsn )                             ! Random T/S fluctuations
191!!gm
192                         CALL eos    ( tsn, rhd, rhop, fsdept_n(:,:,:) ) ! now in situ density for hpg computation
193
194!!jc: fs simplification
195!!jc: lines below are useless if lk_vvl=T. Keep them here (which maintains a bug if lk_vvl=F and ln_zps=T, cf ticket #1636)
196!!                                         but ensures reproductible results
197!!                                         with previous versions using split-explicit free surface         
198            IF( ln_zps .AND. .NOT. ln_isfcav)   &                           ! Partial steps: bottom before horizontal gradient
199               &            CALL zps_hde    ( kstp, jpts, tsn, gtsu, gtsv,  &  ! of t, s, rd at the last ocean level
200               &                                          rhd, gru , grv    )
201            IF( ln_zps .AND.       ln_isfcav)   &                           ! Partial steps: top & bottom before horizontal gradient
202               &            CALL zps_hde_isf( kstp, jpts, tsn, gtsu, gtsv, gtui, gtvi,   & 
203               &                                          rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv ,   &
204               &                                               grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi    )
205!!jc: fs simplification
206                           
207                         ua(:,:,:) = 0._wp            ! set dynamics trends to zero
208                         va(:,:,:) = 0._wp
209
210      IF(  lk_asminc .AND. ln_asmiau .AND. ln_dyninc )   &
211                         CALL dyn_asm_inc   ( kstp )  ! apply dynamics assimilation increment
212      IF( lk_bdy     )   CALL bdy_dyn3d_dmp ( kstp )  ! bdy damping trends
213#if defined key_agrif
214      IF(.NOT. Agrif_Root())  & 
215               &         CALL Agrif_Sponge_dyn        ! momentum sponge
216#endif
217                         CALL dyn_adv       ( kstp )  ! advection (vector or flux form)
218                         CALL dyn_vor       ( kstp )  ! vorticity term including Coriolis
219                         CALL dyn_ldf       ( kstp )  ! lateral mixing
220                         CALL dyn_hpg       ( kstp )  ! horizontal gradient of Hydrostatic pressure
221                         CALL dyn_spg       ( kstp )  ! surface pressure gradient
222
223                                                      ! With split-explicit free surface, since now transports have been updated and ssha as well
224      IF( ln_dynspg_ts ) THEN                         ! vertical scale factors and vertical velocity need to be updated
225                            CALL div_hor    ( kstp )              ! Horizontal divergence  (2nd call in time-split case)
226         IF( lk_vvl )       CALL dom_vvl_sf_nxt( kstp, kcall=2 )  ! after vertical scale factors (update depth average component)
227                            CALL wzv        ( kstp )              ! now cross-level velocity
228      ENDIF
229
230                         CALL dyn_bfr       ( kstp )  ! bottom friction
231                         CALL dyn_zdf       ( kstp )  ! vertical diffusion
232
233      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
234      ! diagnostics and outputs             
235      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
236      IF( lk_floats  )   CALL flo_stp       ( kstp )  ! drifting Floats
237      IF( lk_diahth  )   CALL dia_hth       ( kstp )  ! Thermocline depth (20 degres isotherm depth)
238      IF(.NOT.ln_cpl )   CALL dia_fwb       ( kstp )  ! Fresh water budget diagnostics
239      IF( lk_diadct  )   CALL dia_dct       ( kstp )  ! Transports
240      IF( lk_diaar5  )   CALL dia_ar5       ( kstp )  ! ar5 diag
241      IF( lk_diaharm )   CALL dia_harm      ( kstp )  ! Tidal harmonic analysis
242                         CALL dia_wri       ( kstp )  ! ocean model: outputs
243      !
244      IF( ln_crs     )   CALL crs_fld       ( kstp )  ! ocean model: online field coarsening & output
245
246#if defined key_top
247      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
248      ! Passive Tracer Model
249      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
250                         CALL trc_stp       ( kstp )  ! time-stepping
251#endif
252
253      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
254      ! Active tracers                             
255      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
256                         tsa(:,:,:,:) = 0._wp         ! set tracer trends to zero
257
258      IF(  lk_asminc .AND. ln_asmiau .AND. &
259         & ln_trainc )   CALL tra_asm_inc   ( kstp )  ! apply tracer assimilation increment
260                         CALL tra_sbc       ( kstp )  ! surface boundary condition
261      IF( ln_traqsr  )   CALL tra_qsr       ( kstp )  ! penetrative solar radiation qsr
262      IF( ln_trabbc  )   CALL tra_bbc       ( kstp )  ! bottom heat flux
263      IF( lk_trabbl  )   CALL tra_bbl       ( kstp )  ! advective (and/or diffusive) bottom boundary layer scheme
264      IF( ln_tradmp  )   CALL tra_dmp       ( kstp )  ! internal damping trends
265      IF( lk_bdy     )   CALL bdy_tra_dmp   ( kstp )  ! bdy damping trends
266#if defined key_agrif
267      IF(.NOT. Agrif_Root())  & 
268               &         CALL Agrif_Sponge_tra        ! tracers sponge
269#endif
270                         CALL tra_adv       ( kstp )  ! horizontal & vertical advection
271                         CALL tra_ldf       ( kstp )  ! lateral mixing
272
273!!gm : why CALL to dia_ptr has been moved here??? (use trends info?)
274      IF( ln_diaptr  )   CALL dia_ptr                 ! Poleward adv/ldf TRansports diagnostics
275!!gm
276                         CALL tra_zdf       ( kstp )  ! vertical mixing and after tracer fields
277      IF( ln_zdfnpc  )   CALL tra_npc       ( kstp )  ! update after fields by non-penetrative convection
278
279      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
280      ! Set boundary conditions and Swap
281      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
282!!jc1: For agrif, it would be much better to finalize tracers/momentum here (e.g. bdy conditions) and move the swap
283!!    (and time filtering) after Agrif update. Then restart would be done after and would contain updated fields.
284!!    If so:
285!!    (i) no need to call agrif update at initialization time
286!!    (ii) no need to update "before" fields
287!!
288!!    Apart from creating new tra_swp/dyn_swp routines, this however:
289!!    (i) makes boundary conditions at initialization time computed from updated fields which is not the case between
290!!    two restarts => restartability issue. One can circumvent this, maybe, by assuming "interface separation",
291!!    e.g. a shift of the feedback interface inside child domain.
292!!    (ii) requires that all restart outputs of updated variables by agrif (e.g. passive tracers/tke/barotropic arrays) are done at the same
293!!    place.
294!!
295!!jc2: dynnxt must be the latest call. fse3t_b are indeed updated in that routine
296                         CALL tra_nxt       ( kstp )  ! finalize (bcs) tracer fields at next time step and swap
297                         CALL dyn_nxt       ( kstp )  ! finalize (bcs) velocities at next time step and swap
298                         CALL ssh_swp       ( kstp )  ! swap of sea surface height
299      IF( lk_vvl     )   CALL dom_vvl_sf_swp( kstp )  ! swap of vertical scale factors
300      !
301
302!!gm : This does not only concern the dynamics ==>>> add a new title
303!!gm2: why ouput restart before AGRIF update?
304!!
305!!jc: That would be better, but see comment above
306!!
307      IF( lrst_oce   )   CALL rst_write     ( kstp )  ! write output ocean restart file
308
309#if defined key_agrif
310      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
311      ! AGRIF
312      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<     
313                         CALL Agrif_Integrate_ChildGrids( stp ) 
314
315      IF ( Agrif_NbStepint().EQ.0 ) THEN              ! AGRIF Update
316!!jc in fact update i useless at last time step, but do it for global diagnostics
317                         CALL Agrif_Update_Tra()      ! Update active tracers
318                         CALL Agrif_Update_Dyn()      ! Update momentum
319      ENDIF
320#endif
321      IF( ln_diahsb  )   CALL dia_hsb       ( kstp )  ! - ML - global conservation diagnostics
322      IF( lk_diaobs  )   CALL dia_obs       ( kstp )  ! obs-minus-model (assimilation) diagnostics (call after dynamics update)
323
324      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
325      ! Control
326      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
327                         CALL stp_ctl       ( kstp, indic )
328      IF( indic < 0  )   THEN
329                         CALL ctl_stop( 'step: indic < 0' )
330                         CALL dia_wri_state( 'output.abort', kstp )
331      ENDIF
332      IF( kstp == nit000 )   THEN
333                 CALL iom_close( numror )     ! close input  ocean restart file
334         IF(lwm) CALL FLUSH    ( numond )     ! flush output namelist oce
335         IF(lwm.AND.numoni /= -1 )   &
336            &    CALL FLUSH    ( numoni )     ! flush output namelist ice (if exist)
337      ENDIF
338
339      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
340      ! Coupled mode
341      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
342!!gm why lk_oasis and not lk_cpl ????
343      IF( lk_oasis   )   CALL sbc_cpl_snd( kstp )     ! coupled mode : field exchanges
344      !
345#if defined key_iomput
346      IF( kstp == nitend .OR. indic < 0 ) THEN
347                      CALL iom_context_finalize(      cxios_context          ) ! needed for XIOS+AGRIF
348         IF( ln_crs ) CALL iom_context_finalize( trim(cxios_context)//"_crs" ) !
349      ENDIF
350#endif
351      !
352      IF( nn_timing == 1 .AND.  kstp == nit000  )   CALL timing_reset
353      !
354   END SUBROUTINE stp
355
356   !!======================================================================
357END MODULE step
Note: See TracBrowser for help on using the repository browser.