New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zmeso.F90 in branches/2014/dev_r4650_UKMO10_Tidally_Meaned_Diagnostics/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2014/dev_r4650_UKMO10_Tidally_Meaned_Diagnostics/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zmeso.F90 @ 5260

Last change on this file since 5260 was 5260, checked in by deazer, 9 years ago

Merged branch with Trunk at revision 5253.
Checked with SETTE, passes modified iodef.xml for AMM12 experiment

File size: 18.9 KB
Line 
1MODULE p4zmeso
2   !!======================================================================
3   !!                         ***  MODULE p4zmeso  ***
4   !! TOP :   PISCES Compute the sources/sinks for mesozooplankton
5   !!======================================================================
6   !! History :   1.0  !  2002     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_pisces'                                       PISCES bio-model
13   !!----------------------------------------------------------------------
14   !!   p4z_meso       :   Compute the sources/sinks for mesozooplankton
15   !!   p4z_meso_init  :   Initialization of the parameters for mesozooplankton
16   !!----------------------------------------------------------------------
17   USE oce_trc         !  shared variables between ocean and passive tracers
18   USE trc             !  passive tracers common variables
19   USE sms_pisces      !  PISCES Source Minus Sink variables
20   USE p4zsink         !  vertical flux of particulate matter due to sinking
21   USE p4zint          !  interpolation and computation of various fields
22   USE p4zprod         !  production
23   USE prtctl_trc      !  print control for debugging
24   USE iom             !  I/O manager
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_meso              ! called in p4zbio.F90
30   PUBLIC   p4z_meso_init         ! called in trcsms_pisces.F90
31
32   !! * Shared module variables
33   REAL(wp), PUBLIC ::  part2        !: part of calcite not dissolved in mesozoo guts
34   REAL(wp), PUBLIC ::  xprefc       !: mesozoo preference for POC
35   REAL(wp), PUBLIC ::  xprefp       !: mesozoo preference for nanophyto
36   REAL(wp), PUBLIC ::  xprefz       !: mesozoo preference for diatoms
37   REAL(wp), PUBLIC ::  xprefpoc     !: mesozoo preference for POC
38   REAL(wp), PUBLIC ::  xthresh2zoo  !: zoo feeding threshold for mesozooplankton
39   REAL(wp), PUBLIC ::  xthresh2dia  !: diatoms feeding threshold for mesozooplankton
40   REAL(wp), PUBLIC ::  xthresh2phy  !: nanophyto feeding threshold for mesozooplankton
41   REAL(wp), PUBLIC ::  xthresh2poc  !: poc feeding threshold for mesozooplankton
42   REAL(wp), PUBLIC ::  xthresh2     !: feeding threshold for mesozooplankton
43   REAL(wp), PUBLIC ::  resrat2      !: exsudation rate of mesozooplankton
44   REAL(wp), PUBLIC ::  mzrat2       !: microzooplankton mortality rate
45   REAL(wp), PUBLIC ::  grazrat2     !: maximal mesozoo grazing rate
46   REAL(wp), PUBLIC ::  xkgraz2      !: non assimilated fraction of P by mesozoo
47   REAL(wp), PUBLIC ::  unass2       !: Efficicency of mesozoo growth
48   REAL(wp), PUBLIC ::  sigma2       !: Fraction of mesozoo excretion as DOM
49   REAL(wp), PUBLIC ::  epsher2      !: half sturation constant for grazing 2
50   REAL(wp), PUBLIC ::  grazflux     !: mesozoo flux feeding rate
51
52   !!* Substitution
53#  include "top_substitute.h90"
54   !!----------------------------------------------------------------------
55   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
56   !! $Id: p4zmeso.F90 3160 2011-11-20 14:27:18Z cetlod $
57   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
58   !!----------------------------------------------------------------------
59
60CONTAINS
61
62   SUBROUTINE p4z_meso( kt, jnt )
63      !!---------------------------------------------------------------------
64      !!                     ***  ROUTINE p4z_meso  ***
65      !!
66      !! ** Purpose :   Compute the sources/sinks for mesozooplankton
67      !!
68      !! ** Method  : - ???
69      !!---------------------------------------------------------------------
70      INTEGER, INTENT(in) ::   kt, jnt ! ocean time step
71      INTEGER  :: ji, jj, jk
72      REAL(wp) :: zcompadi, zcompaph, zcompapoc, zcompaz, zcompam
73      REAL(wp) :: zgraze2 , zdenom, zdenom2
74      REAL(wp) :: zfact   , zstep, zfood, zfoodlim, zproport
75      REAL(wp) :: zmortzgoc, zfrac, zfracfe, zratio, zratio2
76      REAL(wp) :: zepshert, zepsherv, zgrarsig, zgraztot, zgraztotn, zgraztotf
77      REAL(wp) :: zgrarem2, zgrafer2, zgrapoc2, zprcaca, zmortz2, zgrasrat, zgrasratn
78#if defined key_kriest
79      REAL znumpoc
80#endif
81      REAL(wp) :: zrespz2, ztortz2, zgrazd, zgrazz, zgrazpof
82      REAL(wp) :: zgrazn, zgrazpoc, zgraznf, zgrazf
83      REAL(wp) :: zgrazfffp, zgrazfffg, zgrazffep, zgrazffeg
84      CHARACTER (len=25) :: charout
85      REAL(wp), POINTER, DIMENSION(:,:,:) :: zgrazing, zw3d
86
87      !!---------------------------------------------------------------------
88      !
89      IF( nn_timing == 1 )  CALL timing_start('p4z_meso')
90      !
91      IF( lk_iomput ) THEN
92         CALL wrk_alloc( jpi, jpj, jpk, zgrazing )
93         zgrazing(:,:,:) = 0._wp
94      ENDIF
95
96      DO jk = 1, jpkm1
97         DO jj = 1, jpj
98            DO ji = 1, jpi
99               zcompam   = MAX( ( trn(ji,jj,jk,jpmes) - 1.e-9 ), 0.e0 )
100# if defined key_degrad
101               zstep     = xstep * facvol(ji,jj,jk)
102# else
103               zstep     = xstep
104# endif
105               zfact     = zstep * tgfunc2(ji,jj,jk) * zcompam
106
107               !  Respiration rates of both zooplankton
108               !  -------------------------------------
109               zrespz2   = resrat2 * zfact * trn(ji,jj,jk,jpmes) / ( xkmort + trn(ji,jj,jk,jpmes) )  &
110                  &      + resrat2 * zfact * 3. * nitrfac(ji,jj,jk)
111
112               !  Zooplankton mortality. A square function has been selected with
113               !  no real reason except that it seems to be more stable and may mimic predation
114               !  ---------------------------------------------------------------
115               ztortz2   = mzrat2 * 1.e6 * zfact * trn(ji,jj,jk,jpmes)
116               !
117               zcompadi  = MAX( ( trn(ji,jj,jk,jpdia) - xthresh2dia ), 0.e0 )
118               zcompaz   = MAX( ( trn(ji,jj,jk,jpzoo) - xthresh2zoo ), 0.e0 )
119               ! Size effect of nanophytoplankton on grazing : the smaller it is, the less prone
120               ! it is to predation by mesozooplankton
121               ! -------------------------------------------------------------------------------
122               zcompaph  = MAX( ( trn(ji,jj,jk,jpphy) - xthresh2phy ), 0.e0 ) &
123                  &      * MIN(1., MAX( 0., ( quotan(ji,jj,jk) - 0.2) / 0.3 ) )
124               zcompapoc = MAX( ( trn(ji,jj,jk,jppoc) - xthresh2poc ), 0.e0 )
125
126               zfood     = xprefc * zcompadi + xprefz * zcompaz + xprefp * zcompaph + xprefpoc * zcompapoc 
127               zfoodlim  = MAX( 0., zfood - MIN( 0.5 * zfood, xthresh2 ) )
128               zdenom    = zfoodlim / ( xkgraz2 + zfoodlim )
129               zdenom2   = zdenom / ( zfood + rtrn )
130               zgraze2   = grazrat2 * zstep * tgfunc2(ji,jj,jk) * trn(ji,jj,jk,jpmes) 
131
132               zgrazd    = zgraze2  * xprefc   * zcompadi  * zdenom2 
133               zgrazz    = zgraze2  * xprefz   * zcompaz   * zdenom2 
134               zgrazn    = zgraze2  * xprefp   * zcompaph  * zdenom2 
135               zgrazpoc  = zgraze2  * xprefpoc * zcompapoc * zdenom2 
136
137               zgraznf   = zgrazn   * trn(ji,jj,jk,jpnfe) / ( trn(ji,jj,jk,jpphy) + rtrn)
138               zgrazf    = zgrazd   * trn(ji,jj,jk,jpdfe) / ( trn(ji,jj,jk,jpdia) + rtrn)
139               zgrazpof  = zgrazpoc * trn(ji,jj,jk,jpsfe) / ( trn(ji,jj,jk,jppoc) + rtrn)
140
141               !  Mesozooplankton flux feeding on GOC
142               !  ----------------------------------
143               !  ----------------------------------
144# if ! defined key_kriest
145               zgrazffeg = grazflux  * zstep * wsbio4(ji,jj,jk)      &
146               &           * tgfunc2(ji,jj,jk) * trn(ji,jj,jk,jpgoc) * trn(ji,jj,jk,jpmes)
147               zgrazfffg = zgrazffeg * trn(ji,jj,jk,jpbfe) / (trn(ji,jj,jk,jpgoc) + rtrn)
148# endif
149               zgrazffep = grazflux  * zstep *  wsbio3(ji,jj,jk)     &
150               &           * tgfunc2(ji,jj,jk) * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpmes)
151               zgrazfffp = zgrazffep * trn(ji,jj,jk,jpsfe) / (trn(ji,jj,jk,jppoc) + rtrn)
152              !
153# if ! defined key_kriest
154              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
155              ! Compute the proportion of filter feeders
156              zproport  = (zgrazffep + zgrazffeg)/(rtrn + zgraztot)
157              ! Compute fractionation of aggregates. It is assumed that
158              ! diatoms based aggregates are more prone to fractionation
159              ! since they are more porous (marine snow instead of fecal pellets)
160              zratio    = trn(ji,jj,jk,jpgsi) / ( trn(ji,jj,jk,jpgoc) + rtrn )
161              zratio2   = zratio * zratio
162              zfrac     = zproport * grazflux  * zstep * wsbio4(ji,jj,jk)      &
163               &          * trn(ji,jj,jk,jpgoc) * trn(ji,jj,jk,jpmes)          &
164               &          * ( 0.2 + 3.8 * zratio2 / ( 1.**2 + zratio2 ) )
165              zfracfe   = zfrac * trn(ji,jj,jk,jpbfe) / (trn(ji,jj,jk,jpgoc) + rtrn)
166
167              zgrazffep = zproport * zgrazffep
168              zgrazffeg = zproport * zgrazffeg
169              zgrazfffp = zproport * zgrazfffp
170              zgrazfffg = zproport * zgrazfffg
171              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
172              zgraztotn = zgrazd * quotad(ji,jj,jk) + zgrazz + zgrazn * quotan(ji,jj,jk)   &
173              &   + zgrazpoc + zgrazffep + zgrazffeg
174              zgraztotf = zgrazf + zgraznf + zgrazz * ferat3 + zgrazpof + zgrazfffp + zgrazfffg
175# else
176              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep
177              ! Compute the proportion of filter feeders
178              zproport  = zgrazffep / ( zgraztot + rtrn )
179              zgrazffep = zproport * zgrazffep
180              zgrazfffp = zproport * zgrazfffp
181              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep
182              zgraztotn = zgrazd * quotad(ji,jj,jk) + zgrazz + zgrazn * quotan(ji,jj,jk) + zgrazpoc + zgrazffep
183              zgraztotf = zgrazf + zgraznf + zgrazz * ferat3 + zgrazpof + zgrazfffp
184# endif
185
186              ! Total grazing ( grazing by microzoo is already computed in p4zmicro )
187              IF( lk_iomput )  zgrazing(ji,jj,jk) = zgraztot
188
189              !    Mesozooplankton efficiency
190              !    --------------------------
191               zgrasrat  =  ( zgraztotf +rtrn )/ ( zgraztot + rtrn )
192               zgrasratn =  ( zgraztotn +rtrn )/ ( zgraztot + rtrn )
193               zepshert  = MIN( 1., zgrasratn, zgrasrat / ferat3)
194               zepsherv  = zepshert * MIN( epsher2, (1. - unass2) * zgrasrat / ferat3, (1. - unass2) * zgrasratn )
195               zgrarem2  = zgraztot * ( 1. - zepsherv - unass2 ) &
196                &       + ( 1. - epsher2 - unass2 ) / ( 1. - epsher2 ) * ztortz2
197               zgrafer2  = zgraztot * MAX( 0. , ( 1. - unass2 ) * zgrasrat - ferat3 * zepsherv )    &
198                &       + ferat3 * ( ( 1. - epsher2 - unass2 ) /( 1. - epsher2 ) * ztortz2 )
199               zgrapoc2  = zgraztot * unass2
200
201               !   Update the arrays TRA which contain the biological sources and sinks
202               zgrarsig  = zgrarem2 * sigma2
203               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig
204               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig
205               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem2 - zgrarsig
206               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig
207               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer2
208               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig
209               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig             
210
211               zmortz2 = ztortz2 + zrespz2
212               zmortzgoc = unass2 / ( 1. - epsher2 ) * ztortz2 + zrespz2
213               tra(ji,jj,jk,jpmes) = tra(ji,jj,jk,jpmes) - zmortz2 + zepsherv * zgraztot 
214               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazd
215               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zgrazz
216               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazn
217               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazn * trn(ji,jj,jk,jpnch) / ( trn(ji,jj,jk,jpphy) + rtrn )
218               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazd * trn(ji,jj,jk,jpdch) / ( trn(ji,jj,jk,jpdia) + rtrn )
219               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazd * trn(ji,jj,jk,jpdsi) / ( trn(ji,jj,jk,jpdia) + rtrn )
220               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazd * trn(ji,jj,jk,jpdsi) / ( trn(ji,jj,jk,jpdia) + rtrn )
221               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgraznf
222               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazf
223
224               ! calcite production
225               zprcaca = xfracal(ji,jj,jk) * zgrazn
226               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
227               !
228               zprcaca = part2 * zprcaca
229               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
230               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
231               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
232#if defined key_kriest
233              znumpoc = trn(ji,jj,jk,jpnum) / ( trn(ji,jj,jk,jppoc) + rtrn )
234              tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortzgoc - zgrazpoc - zgrazffep + zgrapoc2
235              tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) - zgrazpoc * znumpoc + zgrapoc2 * xkr_dmeso      &
236                 &   + zmortzgoc * xkr_dmeso - zgrazffep * znumpoc * wsbio4(ji,jj,jk) / ( wsbio3(ji,jj,jk) + rtrn )
237              tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * zmortzgoc - zgrazfffp - zgrazpof    &
238                 &                 + zgraztotf * unass2
239#else
240              tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zgrazpoc - zgrazffep + zfrac
241              tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zmortzgoc - zgrazffeg + zgrapoc2 - zfrac
242              tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zgrazpof - zgrazfffp + zfracfe
243              tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + ferat3 * zmortzgoc - zgrazfffg     &
244                 &                + zgraztotf * unass2 - zfracfe
245#endif
246            END DO
247         END DO
248      END DO
249      !
250      IF( lk_iomput .AND. jnt == nrdttrc ) THEN
251         CALL wrk_alloc( jpi, jpj, jpk, zw3d )
252         IF( iom_use( "GRAZ2" ) ) THEN
253            zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !   Total grazing of phyto by zooplankton
254            CALL iom_put( "GRAZ2", zw3d )
255         ENDIF
256         IF( iom_use( "PCAL" ) ) THEN
257            zw3d(:,:,:) = prodcal(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)   !  Calcite production
258            CALL iom_put( "PCAL", zw3d ) 
259         ENDIF
260         CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
261      ENDIF
262      !
263      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
264        WRITE(charout, FMT="('meso')")
265        CALL prt_ctl_trc_info(charout)
266        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
267      ENDIF
268      !
269      IF( lk_iomput )  CALL wrk_dealloc( jpi, jpj, jpk, zgrazing )
270      !
271      IF( nn_timing == 1 )  CALL timing_stop('p4z_meso')
272      !
273   END SUBROUTINE p4z_meso
274
275   SUBROUTINE p4z_meso_init
276
277      !!----------------------------------------------------------------------
278      !!                  ***  ROUTINE p4z_meso_init  ***
279      !!
280      !! ** Purpose :   Initialization of mesozooplankton parameters
281      !!
282      !! ** Method  :   Read the nampismes namelist and check the parameters
283      !!      called at the first timestep (nittrc000)
284      !!
285      !! ** input   :   Namelist nampismes
286      !!
287      !!----------------------------------------------------------------------
288
289      NAMELIST/nampismes/ part2, grazrat2, resrat2, mzrat2, xprefc, xprefp, xprefz,   &
290         &                xprefpoc, xthresh2dia, xthresh2phy, xthresh2zoo, xthresh2poc, &
291         &                xthresh2, xkgraz2, epsher2, sigma2, unass2, grazflux
292      INTEGER :: ios                 ! Local integer output status for namelist read
293
294      REWIND( numnatp_ref )              ! Namelist nampismes in reference namelist : Pisces mesozooplankton
295      READ  ( numnatp_ref, nampismes, IOSTAT = ios, ERR = 901)
296901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampismes in reference namelist', lwp )
297
298      REWIND( numnatp_cfg )              ! Namelist nampismes in configuration namelist : Pisces mesozooplankton
299      READ  ( numnatp_cfg, nampismes, IOSTAT = ios, ERR = 902 )
300902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampismes in configuration namelist', lwp )
301      IF(lwm) WRITE ( numonp, nampismes )
302
303
304      IF(lwp) THEN                         ! control print
305         WRITE(numout,*) ' ' 
306         WRITE(numout,*) ' Namelist parameters for mesozooplankton, nampismes'
307         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
308         WRITE(numout,*) '    part of calcite not dissolved in mesozoo guts  part2        =', part2
309         WRITE(numout,*) '    mesozoo preference for phyto                   xprefc       =', xprefc
310         WRITE(numout,*) '    mesozoo preference for POC                     xprefp       =', xprefp
311         WRITE(numout,*) '    mesozoo preference for zoo                     xprefz       =', xprefz
312         WRITE(numout,*) '    mesozoo preference for poc                     xprefpoc     =', xprefpoc
313         WRITE(numout,*) '    microzoo feeding threshold  for mesozoo        xthresh2zoo  =', xthresh2zoo
314         WRITE(numout,*) '    diatoms feeding threshold  for mesozoo         xthresh2dia  =', xthresh2dia
315         WRITE(numout,*) '    nanophyto feeding threshold for mesozoo        xthresh2phy  =', xthresh2phy
316         WRITE(numout,*) '    poc feeding threshold for mesozoo              xthresh2poc  =', xthresh2poc
317         WRITE(numout,*) '    feeding threshold for mesozooplankton          xthresh2     =', xthresh2
318         WRITE(numout,*) '    exsudation rate of mesozooplankton             resrat2      =', resrat2
319         WRITE(numout,*) '    mesozooplankton mortality rate                 mzrat2       =', mzrat2
320         WRITE(numout,*) '    maximal mesozoo grazing rate                   grazrat2     =', grazrat2
321         WRITE(numout,*) '    mesozoo flux feeding rate                      grazflux     =', grazflux
322         WRITE(numout,*) '    non assimilated fraction of P by mesozoo       unass2       =', unass2
323         WRITE(numout,*) '    Efficicency of Mesozoo growth                  epsher2      =', epsher2
324         WRITE(numout,*) '    Fraction of mesozoo excretion as DOM           sigma2       =', sigma2
325         WRITE(numout,*) '    half sturation constant for grazing 2          xkgraz2      =', xkgraz2
326      ENDIF
327
328
329   END SUBROUTINE p4z_meso_init
330
331
332#else
333   !!======================================================================
334   !!  Dummy module :                                   No PISCES bio-model
335   !!======================================================================
336CONTAINS
337   SUBROUTINE p4z_meso                    ! Empty routine
338   END SUBROUTINE p4z_meso
339#endif 
340
341   !!======================================================================
342END MODULE  p4zmeso
Note: See TracBrowser for help on using the repository browser.