New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in branches/2014/dev_r4650_UKMO11_restart_functionality/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2014/dev_r4650_UKMO11_restart_functionality/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 5231

Last change on this file since 5231 was 5231, checked in by davestorkey, 9 years ago

Svn keywords deactivated using "svn propdel" in
branch 2014/dev_r4650_UKMO11_restart_functionality.

File size: 64.3 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!----------------------------------------------------------------------
19
20   !!----------------------------------------------------------------------
21   !!   dyn_hpg      : update the momentum trend with the now horizontal
22   !!                  gradient of the hydrostatic pressure
23   !!   dyn_hpg_init : initialisation and control of options
24   !!       hpg_zco  : z-coordinate scheme
25   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
26   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
27   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
28   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
29   !!----------------------------------------------------------------------
30   USE oce             ! ocean dynamics and tracers
31   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
32   USE dom_oce         ! ocean space and time domain
33   USE phycst          ! physical constants
34   USE trd_oce         ! trends: ocean variables
35   USE trddyn          ! trend manager: dynamics
36   !
37   USE in_out_manager  ! I/O manager
38   USE prtctl          ! Print control
39   USE lbclnk          ! lateral boundary condition
40   USE lib_mpp         ! MPP library
41   USE eosbn2          ! compute density
42   USE wrk_nemo        ! Memory Allocation
43   USE timing          ! Timing
44
45   IMPLICIT NONE
46   PRIVATE
47
48   PUBLIC   dyn_hpg        ! routine called by step module
49   PUBLIC   dyn_hpg_init   ! routine called by opa module
50
51   !                                    !!* Namelist namdyn_hpg : hydrostatic pressure gradient
52   LOGICAL , PUBLIC ::   ln_hpg_zco      !: z-coordinate - full steps
53   LOGICAL , PUBLIC ::   ln_hpg_zps      !: z-coordinate - partial steps (interpolation)
54   LOGICAL , PUBLIC ::   ln_hpg_sco      !: s-coordinate (standard jacobian formulation)
55   LOGICAL , PUBLIC ::   ln_hpg_djc      !: s-coordinate (Density Jacobian with Cubic polynomial)
56   LOGICAL , PUBLIC ::   ln_hpg_prj      !: s-coordinate (Pressure Jacobian scheme)
57   LOGICAL , PUBLIC ::   ln_dynhpg_imp   !: semi-implicite hpg flag
58
59   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
60
61   !! * Substitutions
62#  include "domzgr_substitute.h90"
63#  include "vectopt_loop_substitute.h90"
64   !!----------------------------------------------------------------------
65   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
66   !! $Id: dynhpg.F90 5208 2015-04-13 13:08:59Z davestorkey $
67   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
68   !!----------------------------------------------------------------------
69CONTAINS
70
71   SUBROUTINE dyn_hpg( kt )
72      !!---------------------------------------------------------------------
73      !!                  ***  ROUTINE dyn_hpg  ***
74      !!
75      !! ** Method  :   Call the hydrostatic pressure gradient routine
76      !!              using the scheme defined in the namelist
77      !!
78      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
79      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
80      !!----------------------------------------------------------------------
81      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
82      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
83      !!----------------------------------------------------------------------
84      !
85      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
86      !
87      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
88         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
89         ztrdu(:,:,:) = ua(:,:,:)
90         ztrdv(:,:,:) = va(:,:,:)
91      ENDIF
92      !
93      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
94      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
95      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
96      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
97      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
98      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
99      END SELECT
100      !
101      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
102         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
103         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
104         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
105         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
106      ENDIF
107      !
108      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
109         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
110      !
111      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
112      !
113   END SUBROUTINE dyn_hpg
114
115
116   SUBROUTINE dyn_hpg_init
117      !!----------------------------------------------------------------------
118      !!                 ***  ROUTINE dyn_hpg_init  ***
119      !!
120      !! ** Purpose :   initializations for the hydrostatic pressure gradient
121      !!              computation and consistency control
122      !!
123      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
124      !!      with the type of vertical coordinate used (zco, zps, sco)
125      !!----------------------------------------------------------------------
126      INTEGER ::   ioptio = 0      ! temporary integer
127      INTEGER ::   ios             ! Local integer output status for namelist read
128      !!
129      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
130         &                 ln_hpg_djc, ln_hpg_prj, ln_dynhpg_imp
131      !!----------------------------------------------------------------------
132      !
133      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
134      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
135901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
136
137      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
138      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
139902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
140      IF(lwm) WRITE ( numond, namdyn_hpg )
141      !
142      IF(lwp) THEN                   ! Control print
143         WRITE(numout,*)
144         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
145         WRITE(numout,*) '~~~~~~~~~~~~'
146         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
147         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
148         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
149         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
150         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
151         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
152         WRITE(numout,*) '      time stepping: centered (F) or semi-implicit (T)  ln_dynhpg_imp = ', ln_dynhpg_imp
153      ENDIF
154      !
155      IF( ln_hpg_djc )   &
156         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
157                           & currently disabled (bugs under investigation). Please select &
158                           & either  ln_hpg_sco or  ln_hpg_prj instead')
159      !
160      IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj) )   &
161         &   CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
162                           & the standard jacobian formulation hpg_sco or &
163                           & the pressure jacobian formulation hpg_prj')
164      !
165      !                               ! Set nhpg from ln_hpg_... flags
166      IF( ln_hpg_zco )   nhpg = 0
167      IF( ln_hpg_zps )   nhpg = 1
168      IF( ln_hpg_sco )   nhpg = 2
169      IF( ln_hpg_djc )   nhpg = 3
170      IF( ln_hpg_prj )   nhpg = 4
171      !
172      !                               ! Consistency check
173      ioptio = 0
174      IF( ln_hpg_zco )   ioptio = ioptio + 1
175      IF( ln_hpg_zps )   ioptio = ioptio + 1
176      IF( ln_hpg_sco )   ioptio = ioptio + 1
177      IF( ln_hpg_djc )   ioptio = ioptio + 1
178      IF( ln_hpg_prj )   ioptio = ioptio + 1
179      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
180      IF( (ln_hpg_zco .OR. ln_hpg_zps .OR. ln_hpg_djc .OR. ln_hpg_prj ) .AND. nn_isf .NE. 0 )   &
181          &  CALL ctl_stop( 'Only hpg_sco has been corrected to work with ice shelf cavity.' )
182      !
183   END SUBROUTINE dyn_hpg_init
184
185
186   SUBROUTINE hpg_zco( kt )
187      !!---------------------------------------------------------------------
188      !!                  ***  ROUTINE hpg_zco  ***
189      !!
190      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
191      !!      The now hydrostatic pressure gradient at a given level, jk,
192      !!      is computed by taking the vertical integral of the in-situ
193      !!      density gradient along the model level from the suface to that
194      !!      level:    zhpi = grav .....
195      !!                zhpj = grav .....
196      !!      add it to the general momentum trend (ua,va).
197      !!            ua = ua - 1/e1u * zhpi
198      !!            va = va - 1/e2v * zhpj
199      !!
200      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
201      !!----------------------------------------------------------------------
202      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
203      !!
204      INTEGER  ::   ji, jj, jk       ! dummy loop indices
205      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
206      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
207      !!----------------------------------------------------------------------
208      !
209      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
210      !
211      IF( kt == nit000 ) THEN
212         IF(lwp) WRITE(numout,*)
213         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
214         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
215      ENDIF
216
217      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
218
219      ! Surface value
220      DO jj = 2, jpjm1
221         DO ji = fs_2, fs_jpim1   ! vector opt.
222            zcoef1 = zcoef0 * fse3w(ji,jj,1)
223            ! hydrostatic pressure gradient
224            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
225            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
226            ! add to the general momentum trend
227            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
228            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
229         END DO
230      END DO
231
232      !
233      ! interior value (2=<jk=<jpkm1)
234      DO jk = 2, jpkm1
235         DO jj = 2, jpjm1
236            DO ji = fs_2, fs_jpim1   ! vector opt.
237               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
238               ! hydrostatic pressure gradient
239               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
240                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
241                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
242
243               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
244                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
245                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
246               ! add to the general momentum trend
247               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
248               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
249            END DO
250         END DO
251      END DO
252      !
253      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
254      !
255   END SUBROUTINE hpg_zco
256
257
258   SUBROUTINE hpg_zps( kt )
259      !!---------------------------------------------------------------------
260      !!                 ***  ROUTINE hpg_zps  ***
261      !!
262      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
263      !!
264      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
265      !!----------------------------------------------------------------------
266      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
267      !!
268      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
269      INTEGER  ::   iku, ikv                         ! temporary integers
270      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
271      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
272      !!----------------------------------------------------------------------
273      !
274      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
275      !
276      IF( kt == nit000 ) THEN
277         IF(lwp) WRITE(numout,*)
278         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
279         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
280      ENDIF
281
282
283      ! Local constant initialization
284      zcoef0 = - grav * 0.5_wp
285
286      !  Surface value (also valid in partial step case)
287      DO jj = 2, jpjm1
288         DO ji = fs_2, fs_jpim1   ! vector opt.
289            zcoef1 = zcoef0 * fse3w(ji,jj,1)
290            ! hydrostatic pressure gradient
291            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
292            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
293            ! add to the general momentum trend
294            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
295            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
296         END DO
297      END DO
298
299
300      ! interior value (2=<jk=<jpkm1)
301      DO jk = 2, jpkm1
302         DO jj = 2, jpjm1
303            DO ji = fs_2, fs_jpim1   ! vector opt.
304               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
305               ! hydrostatic pressure gradient
306               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
307                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
308                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
309
310               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
311                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
312                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
313               ! add to the general momentum trend
314               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
315               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
316            END DO
317         END DO
318      END DO
319
320
321      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
322      DO jj = 2, jpjm1
323         DO ji = 2, jpim1
324            iku = mbku(ji,jj)
325            ikv = mbkv(ji,jj)
326            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
327            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
328            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
329               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
330               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
331                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
332               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
333            ENDIF
334            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
335               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
336               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
337                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
338               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
339            ENDIF
340         END DO
341      END DO
342      !
343      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
344      !
345   END SUBROUTINE hpg_zps
346
347
348   SUBROUTINE hpg_sco( kt )
349      !!---------------------------------------------------------------------
350      !!                  ***  ROUTINE hpg_sco  ***
351      !!
352      !! ** Method  :   s-coordinate case. Jacobian scheme.
353      !!      The now hydrostatic pressure gradient at a given level, jk,
354      !!      is computed by taking the vertical integral of the in-situ
355      !!      density gradient along the model level from the suface to that
356      !!      level. s-coordinates (ln_sco): a corrective term is added
357      !!      to the horizontal pressure gradient :
358      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
359      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
360      !!      add it to the general momentum trend (ua,va).
361      !!         ua = ua - 1/e1u * zhpi
362      !!         va = va - 1/e2v * zhpj
363      !!
364      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
365      !!----------------------------------------------------------------------
366      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
367      !!
368      INTEGER  ::   ji, jj, jk, iku, ikv, ikt, iktp1i, iktp1j                 ! dummy loop indices
369      REAL(wp) ::   zcoef0, zuap, zvap, znad, ze3wu, ze3wv, zuapint, zvapint, zhpjint, zhpiint, zdzwt, zdzwtjp1, zdzwtip1             ! temporary scalars
370      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  zhpi, zhpj, zrhd
371      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop
372      REAL(wp), POINTER, DIMENSION(:,:)     ::  ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj
373      !!----------------------------------------------------------------------
374      !
375      CALL wrk_alloc( jpi,jpj, 2, ztstop) 
376      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
377      CALL wrk_alloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj) 
378      !
379     IF( kt == nit000 ) THEN
380         IF(lwp) WRITE(numout,*)
381         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
382         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
383      ENDIF
384
385      ! Local constant initialization
386      zcoef0 = - grav * 0.5_wp
387      ! To use density and not density anomaly
388!      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
389!      ELSE                 ;     znad = 0._wp         ! Fixed volume
390!      ENDIF
391      znad=1._wp
392      ! iniitialised to 0. zhpi zhpi
393      zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
394
395!==================================================================================     
396!=====Compute iceload and contribution of the half first wet layer =================
397!===================================================================================
398
399      ! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
400      ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
401
402      ! compute density of the water displaced by the ice shelf
403      zrhd = rhd ! save rhd
404      DO jk = 1, jpk
405           zdept(:,:)=gdept_1d(jk)
406           CALL eos(ztstop(:,:,:),zdept(:,:),rhd(:,:,jk))
407      END DO
408      WHERE ( tmask(:,:,:) == 1._wp)
409        rhd(:,:,:) = zrhd(:,:,:) ! replace wet cell by the saved rhd
410      END WHERE
411     
412      ! compute rhd at the ice/oce interface (ice shelf side)
413      CALL eos(ztstop,risfdep,zrhdtop_isf)
414
415      ! compute rhd at the ice/oce interface (ocean side)
416      DO ji=1,jpi
417        DO jj=1,jpj
418          ikt=mikt(ji,jj)
419          ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
420          ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
421        END DO
422      END DO
423      CALL eos(ztstop,risfdep,zrhdtop_oce)
424      !
425      ! Surface value + ice shelf gradient
426      ! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
427      ziceload = 0._wp
428      DO jj = 1, jpj
429         DO ji = 1, jpi   ! vector opt.
430            ikt=mikt(ji,jj)
431            ziceload(ji,jj) = ziceload(ji,jj) + (znad + rhd(ji,jj,1) ) * fse3w(ji,jj,1) * (1._wp - tmask(ji,jj,1))
432            DO jk=2,ikt-1
433               ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + rhd(ji,jj,jk-1) + rhd(ji,jj,jk)) * fse3w(ji,jj,jk) &
434                  &                              * (1._wp - tmask(ji,jj,jk))
435            END DO
436            IF (ikt .GE. 2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + rhd(ji,jj,ikt-1)) &
437                               &                              * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
438         END DO
439      END DO
440      riceload(:,:) = 0.0_wp ; riceload(:,:)=ziceload(:,:)  ! need to be saved for diaar5
441      ! compute zp from z=0 to first T wet point (correction due to zps not yet applied)
442      DO jj = 2, jpjm1
443         DO ji = fs_2, fs_jpim1   ! vector opt.
444            ikt=mikt(ji,jj) ; iktp1i=mikt(ji+1,jj); iktp1j=mikt(ji,jj+1)
445            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
446            ! we assume ISF is in isostatic equilibrium
447            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * fse3w(ji+1,jj  ,iktp1i)                                    &
448               &                                  * ( 2._wp * znad + rhd(ji+1,jj  ,iktp1i) + zrhdtop_oce(ji+1,jj  ) )   &
449               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    &
450               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
451               &                                  + ( ziceload(ji+1,jj) - ziceload(ji,jj))                              ) 
452            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * fse3w(ji  ,jj+1,iktp1j)                                    &
453               &                                  * ( 2._wp * znad + rhd(ji  ,jj+1,iktp1j) + zrhdtop_oce(ji  ,jj+1) )   &
454               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    & 
455               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
456               &                                  + ( ziceload(ji,jj+1) - ziceload(ji,jj) )                             ) 
457            ! s-coordinate pressure gradient correction (=0 if z coordinate)
458            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
459               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
460            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
461               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
462            ! add to the general momentum trend
463            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
464            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
465         END DO
466      END DO
467!==================================================================================     
468!===== Compute partial cell contribution for the top cell =========================
469!==================================================================================
470      DO jj = 2, jpjm1
471         DO ji = fs_2, fs_jpim1   ! vector opt.
472            iku = miku(ji,jj) ; 
473            zpshpi(ji,jj)=0.0_wp ; zpshpj(ji,jj)=0.0_wp
474            ze3wu  = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku))
475            ! u direction
476            IF ( iku .GT. 1 ) THEN
477               ! case iku
478               zhpi(ji,jj,iku)   =  zcoef0 / e1u(ji,jj) * ze3wu                                            &
479                      &                                 * ( rhd    (ji+1,jj,iku) + rhd   (ji,jj,iku)       &
480                      &                                   + SIGN(1._wp,ze3wu) * grui(ji,jj) + 2._wp * znad )
481               ! corrective term ( = 0 if z coordinate )
482               zuap              = -zcoef0 * ( arui(ji,jj) + 2._wp * znad ) * gzui(ji,jj) / e1u(ji,jj)
483               ! zhpi will be added in interior loop
484               ua(ji,jj,iku)     = ua(ji,jj,iku) + zuap
485               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
486               IF (mbku(ji,jj) == iku + 1) zpshpi(ji,jj)  = zhpi(ji,jj,iku)
487
488               ! case iku + 1 (remove the zphi term added in the interior loop and compute the one corrected for zps)
489               zhpiint        =  zcoef0 / e1u(ji,jj)                                                               &   
490                  &           * (  fse3w(ji+1,jj  ,iku+1) * ( (rhd(ji+1,jj,iku+1) + znad)                          &
491                  &                                         + (rhd(ji+1,jj,iku  ) + znad) ) * tmask(ji+1,jj,iku)   &
492                  &              - fse3w(ji  ,jj  ,iku+1) * ( (rhd(ji  ,jj,iku+1) + znad)                          &
493                  &                                         + (rhd(ji  ,jj,iku  ) + znad) ) * tmask(ji  ,jj,iku)   )
494               zhpi(ji,jj,iku+1) =  zcoef0 / e1u(ji,jj) * ge3rui(ji,jj) - zhpiint 
495            END IF
496               
497            ! v direction
498            ikv = mikv(ji,jj)
499            ze3wv  = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
500            IF ( ikv .GT. 1 ) THEN
501               ! case ikv
502               zhpj(ji,jj,ikv)   =  zcoef0 / e2v(ji,jj) * ze3wv                                            &
503                     &                                  * ( rhd(ji,jj+1,ikv) + rhd   (ji,jj,ikv)           &
504                     &                                    + SIGN(1._wp,ze3wv) * grvi(ji,jj) + 2._wp * znad )
505               ! corrective term ( = 0 if z coordinate )
506               zvap              = -zcoef0 * ( arvi(ji,jj) + 2._wp * znad ) * gzvi(ji,jj) / e2v(ji,jj)
507               ! zhpi will be added in interior loop
508               va(ji,jj,ikv)      = va(ji,jj,ikv) + zvap
509               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
510               IF (mbkv(ji,jj) == ikv + 1)  zpshpj(ji,jj)  =  zhpj(ji,jj,ikv) 
511               
512               ! case ikv + 1 (remove the zphj term added in the interior loop and compute the one corrected for zps)
513               zhpjint        =  zcoef0 / e2v(ji,jj)                                                              &
514                  &           * (  fse3w(ji  ,jj+1,ikv+1) * ( (rhd(ji,jj+1,ikv+1) + znad)                         &
515                  &                                       + (rhd(ji,jj+1,ikv  ) + znad) ) * tmask(ji,jj+1,ikv)    &
516                  &              - fse3w(ji  ,jj  ,ikv+1) * ( (rhd(ji,jj  ,ikv+1) + znad)                         &
517                  &                                       + (rhd(ji,jj  ,ikv  ) + znad) ) * tmask(ji,jj  ,ikv)  )
518               zhpj(ji,jj,ikv+1) =  zcoef0 / e2v(ji,jj) * ge3rvi(ji,jj) - zhpjint
519            END IF
520         END DO
521      END DO
522
523!==================================================================================     
524!===== Compute interior value =====================================================
525!==================================================================================
526
527      DO jj = 2, jpjm1
528         DO ji = fs_2, fs_jpim1   ! vector opt.
529            iku=miku(ji,jj); ikv=mikv(ji,jj)
530            DO jk = 2, jpkm1
531               ! hydrostatic pressure gradient along s-surfaces
532               ! zhpi is masked for the first wet cell  (contribution already done in the upper bloc)
533               zhpi(ji,jj,jk) = zhpi(ji,jj,jk) + zhpi(ji,jj,jk-1)                                                              &
534                  &                            + zcoef0 / e1u(ji,jj)                                                           &
535                  &                                     * ( fse3w(ji+1,jj  ,jk) * ( (rhd(ji+1,jj,jk  ) + znad)                 &
536                  &                                                     + (rhd(ji+1,jj,jk-1) + znad) ) * tmask(ji+1,jj,jk-1)   &
537                  &                                       - fse3w(ji  ,jj  ,jk) * ( (rhd(ji  ,jj,jk  ) + znad)                 &
538                  &                                                     + (rhd(ji  ,jj,jk-1) + znad) ) * tmask(ji  ,jj,jk-1)   ) 
539               ! s-coordinate pressure gradient correction
540               ! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
541               zuap = - zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )                    &
542                  &            * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj) * umask(ji,jj,jk-1)
543               ua(ji,jj,jk) = ua(ji,jj,jk) + ( zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
544
545               ! hydrostatic pressure gradient along s-surfaces
546               ! zhpi is masked for the first wet cell  (contribution already done in the upper bloc)
547               zhpj(ji,jj,jk) = zhpj(ji,jj,jk) + zhpj(ji,jj,jk-1)                                                              &
548                  &                            + zcoef0 / e2v(ji,jj)                                                           &
549                  &                                     * ( fse3w(ji  ,jj+1,jk) * ( (rhd(ji,jj+1,jk  ) + znad)                 &
550                  &                                                     + (rhd(ji,jj+1,jk-1) + znad) ) * tmask(ji,jj+1,jk-1)   &
551                  &                                       - fse3w(ji  ,jj  ,jk) * ( (rhd(ji,jj  ,jk  ) + znad)                 &
552                  &                                                     + (rhd(ji,jj  ,jk-1) + znad) ) * tmask(ji,jj  ,jk-1)   )
553               ! s-coordinate pressure gradient correction
554               ! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
555               zvap = - zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )                     &
556                  &            * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj) * vmask(ji,jj,jk-1)
557               ! add to the general momentum trend
558               va(ji,jj,jk) = va(ji,jj,jk) + ( zhpj(ji,jj,jk) + zvap ) * vmask(ji,jj,jk)
559            END DO
560         END DO
561      END DO
562
563!==================================================================================     
564!===== Compute bottom cell contribution (partial cell) ============================
565!==================================================================================
566
567# if defined key_vectopt_loop
568         jj = 1
569         DO ji = jpi+2, jpij-jpi-1   ! vector opt. (forced unrolling)
570# else
571      DO jj = 2, jpjm1
572         DO ji = 2, jpim1
573# endif
574            iku = mbku(ji,jj)
575            ikv = mbkv(ji,jj)
576
577            IF (iku .GT. 1) THEN
578               ! remove old value (interior case)
579               zuap            = -zcoef0 * ( rhd   (ji+1,jj  ,iku) + rhd   (ji,jj,iku) + 2._wp * znad )   &
580                     &                   * ( fsde3w(ji+1,jj  ,iku) - fsde3w(ji,jj,iku) ) / e1u(ji,jj)
581               ua(ji,jj,iku)   = ua(ji,jj,iku) - zhpi(ji,jj,iku) - zuap
582               ! put new value
583               ! -zpshpi to avoid double contribution of the partial step in the top layer
584               zuap            = -zcoef0 * ( aru(ji,jj) + 2._wp * znad ) * gzu(ji,jj)  / e1u(ji,jj)
585               zhpi(ji,jj,iku) =  zhpi(ji,jj,iku-1) + zcoef0 / e1u(ji,jj) * ge3ru(ji,jj) - zpshpi(ji,jj) 
586               ua(ji,jj,iku)   =  ua(ji,jj,iku) + zhpi(ji,jj,iku) + zuap
587            END IF
588            ! v direction
589            IF (ikv .GT. 1) THEN
590               ! remove old value (interior case)
591               zvap            = -zcoef0 * ( rhd   (ji  ,jj+1,ikv) + rhd   (ji,jj,ikv) + 2._wp * znad )   &
592                     &                   * ( fsde3w(ji  ,jj+1,ikv) - fsde3w(ji,jj,ikv) )   / e2v(ji,jj)
593               va(ji,jj,ikv)   = va(ji,jj,ikv) - zhpj(ji,jj,ikv) - zvap
594               ! put new value
595               ! -zpshpj to avoid double contribution of the partial step in the top layer
596               zvap            = -zcoef0 * ( arv(ji,jj) + 2._wp * znad ) * gzv(ji,jj)     / e2v(ji,jj)
597               zhpj(ji,jj,ikv) =  zhpj(ji,jj,ikv-1) + zcoef0 / e2v(ji,jj) * ge3rv(ji,jj) - zpshpj(ji,jj)   
598               va(ji,jj,ikv)   =  va(ji,jj,ikv) + zhpj(ji,jj,ikv) + zvap
599            END IF
600# if ! defined key_vectopt_loop
601         END DO
602# endif
603      END DO
604     
605      ! set back to original density value into the ice shelf cell (maybe useless because it is masked)
606      rhd = zrhd
607      !
608      CALL wrk_dealloc( jpi,jpj,2, ztstop)
609      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
610      CALL wrk_dealloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
611      !
612   END SUBROUTINE hpg_sco
613
614
615   SUBROUTINE hpg_djc( kt )
616      !!---------------------------------------------------------------------
617      !!                  ***  ROUTINE hpg_djc  ***
618      !!
619      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
620      !!
621      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
622      !!----------------------------------------------------------------------
623      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
624      !!
625      INTEGER  ::   ji, jj, jk          ! dummy loop indices
626      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
627      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
628      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
629      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
630      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
631      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
632      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
633      !!----------------------------------------------------------------------
634      !
635      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
636      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
637      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
638      !
639
640      IF( kt == nit000 ) THEN
641         IF(lwp) WRITE(numout,*)
642         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
643         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
644      ENDIF
645
646      ! Local constant initialization
647      zcoef0 = - grav * 0.5_wp
648      z1_10  = 1._wp / 10._wp
649      z1_12  = 1._wp / 12._wp
650
651      !----------------------------------------------------------------------------------------
652      !  compute and store in provisional arrays elementary vertical and horizontal differences
653      !----------------------------------------------------------------------------------------
654
655!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
656
657      DO jk = 2, jpkm1
658         DO jj = 2, jpjm1
659            DO ji = fs_2, fs_jpim1   ! vector opt.
660               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
661               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
662               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
663               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
664               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
665               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
666            END DO
667         END DO
668      END DO
669
670      !-------------------------------------------------------------------------
671      ! compute harmonic averages using eq. 5.18
672      !-------------------------------------------------------------------------
673      zep = 1.e-15
674
675!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
676!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
677
678      DO jk = 2, jpkm1
679         DO jj = 2, jpjm1
680            DO ji = fs_2, fs_jpim1   ! vector opt.
681               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
682
683               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
684               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
685
686               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
687               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
688
689               IF( cffw > zep) THEN
690                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
691                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
692               ELSE
693                  drhow(ji,jj,jk) = 0._wp
694               ENDIF
695
696               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
697                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
698
699               IF( cffu > zep ) THEN
700                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
701                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
702               ELSE
703                  drhou(ji,jj,jk ) = 0._wp
704               ENDIF
705
706               IF( cffx > zep ) THEN
707                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
708                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
709               ELSE
710                  dzu(ji,jj,jk) = 0._wp
711               ENDIF
712
713               IF( cffv > zep ) THEN
714                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
715                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
716               ELSE
717                  drhov(ji,jj,jk) = 0._wp
718               ENDIF
719
720               IF( cffy > zep ) THEN
721                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
722                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
723               ELSE
724                  dzv(ji,jj,jk) = 0._wp
725               ENDIF
726
727            END DO
728         END DO
729      END DO
730
731      !----------------------------------------------------------------------------------
732      ! apply boundary conditions at top and bottom using 5.36-5.37
733      !----------------------------------------------------------------------------------
734      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
735      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
736      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
737
738      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
739      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
740      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
741
742
743      !--------------------------------------------------------------
744      ! Upper half of top-most grid box, compute and store
745      !-------------------------------------------------------------
746
747!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
748!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
749
750      DO jj = 2, jpjm1
751         DO ji = fs_2, fs_jpim1   ! vector opt.
752            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )               &
753               &                   * (  rhd(ji,jj,1)                                    &
754               &                     + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
755               &                              * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
756               &                              / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  )
757         END DO
758      END DO
759
760!!bug gm    : here also, simplification is possible
761!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
762
763      DO jk = 2, jpkm1
764         DO jj = 2, jpjm1
765            DO ji = fs_2, fs_jpim1   ! vector opt.
766
767               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
768                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
769                  &            - grav * z1_10 * (                                                                     &
770                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
771                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
772                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
773                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
774                  &                             )
775
776               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
777                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
778                  &            - grav* z1_10 * (                                                                      &
779                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
780                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
781                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
782                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
783                  &                            )
784
785               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
786                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
787                  &            - grav* z1_10 * (                                                                      &
788                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
789                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
790                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
791                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
792                  &                            )
793
794            END DO
795         END DO
796      END DO
797      CALL lbc_lnk(rho_k,'W',1.)
798      CALL lbc_lnk(rho_i,'U',1.)
799      CALL lbc_lnk(rho_j,'V',1.)
800
801
802      ! ---------------
803      !  Surface value
804      ! ---------------
805      DO jj = 2, jpjm1
806         DO ji = fs_2, fs_jpim1   ! vector opt.
807            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
808            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
809            ! add to the general momentum trend
810            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
811            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
812         END DO
813      END DO
814
815      ! ----------------
816      !  interior value   (2=<jk=<jpkm1)
817      ! ----------------
818      DO jk = 2, jpkm1
819         DO jj = 2, jpjm1
820            DO ji = fs_2, fs_jpim1   ! vector opt.
821               ! hydrostatic pressure gradient along s-surfaces
822               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
823                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
824                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
825               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
826                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
827                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
828               ! add to the general momentum trend
829               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
830               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
831            END DO
832         END DO
833      END DO
834      !
835      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
836      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
837      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
838      !
839   END SUBROUTINE hpg_djc
840
841
842   SUBROUTINE hpg_prj( kt )
843      !!---------------------------------------------------------------------
844      !!                  ***  ROUTINE hpg_prj  ***
845      !!
846      !! ** Method  :   s-coordinate case.
847      !!      A Pressure-Jacobian horizontal pressure gradient method
848      !!      based on the constrained cubic-spline interpolation for
849      !!      all vertical coordinate systems
850      !!
851      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
852      !!----------------------------------------------------------------------
853      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
854      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
855      !!
856      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
857      REAL(wp) ::   zcoef0, znad                    ! temporary scalars
858      !!
859      !! The local variables for the correction term
860      INTEGER  :: jk1, jis, jid, jjs, jjd
861      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
862      REAL(wp) :: zrhdt1
863      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
864      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh
865      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
866      !!----------------------------------------------------------------------
867      !
868      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
869      CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
870      !
871      IF( kt == nit000 ) THEN
872         IF(lwp) WRITE(numout,*)
873         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
874         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
875      ENDIF
876
877      !!----------------------------------------------------------------------
878      ! Local constant initialization
879      zcoef0 = - grav
880      znad = 0.0_wp
881      IF( lk_vvl ) znad = 1._wp
882
883      ! Clean 3-D work arrays
884      zhpi(:,:,:) = 0._wp
885      zrhh(:,:,:) = rhd(:,:,:)
886
887      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
888      DO jj = 1, jpj
889        DO ji = 1, jpi
890          jk = mbathy(ji,jj)
891          IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
892          ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
893          ELSE IF(jk < jpkm1) THEN
894             DO jkk = jk+1, jpk
895                zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk),   fsde3w(ji,jj,jkk-1), &
896                                         fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
897             END DO
898          ENDIF
899        END DO
900      END DO
901
902      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
903      DO jj = 1, jpj
904         DO ji = 1, jpi
905            zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
906         END DO
907      END DO
908
909      DO jk = 2, jpk
910         DO jj = 1, jpj
911            DO ji = 1, jpi
912               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
913            END DO
914         END DO
915      END DO
916
917      fsp(:,:,:) = zrhh (:,:,:)
918      xsp(:,:,:) = zdept(:,:,:)
919
920      ! Construct the vertical density profile with the
921      ! constrained cubic spline interpolation
922      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
923      CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
924
925      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
926      DO jj = 2, jpj
927        DO ji = 2, jpi
928          zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
929                                         bsp(ji,jj,1),   csp(ji,jj,1), &
930                                         dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
931
932          ! assuming linear profile across the top half surface layer
933          zhpi(ji,jj,1) =  0.5_wp * fse3w(ji,jj,1) * zrhdt1
934        END DO
935      END DO
936
937      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
938      DO jk = 2, jpkm1
939        DO jj = 2, jpj
940          DO ji = 2, jpi
941            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                          &
942                             integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
943                                    asp(ji,jj,jk-1),    bsp(ji,jj,jk-1), &
944                                    csp(ji,jj,jk-1),    dsp(ji,jj,jk-1))
945          END DO
946        END DO
947      END DO
948
949      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
950      DO jj = 2, jpjm1
951        DO ji = 2, jpim1
952          zu(ji,jj,1) = - ( fse3u(ji,jj,1) - sshn(ji,jj) * znad)    ! probable bug: changed from sshu_n for ztilde compilation
953          zv(ji,jj,1) = - ( fse3v(ji,jj,1) - sshn(ji,jj) * znad)    ! probable bug: changed from sshv_n for ztilde compilation
954        END DO
955      END DO
956
957      DO jk = 2, jpkm1
958        DO jj = 2, jpjm1
959          DO ji = 2, jpim1
960            zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
961            zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
962          END DO
963        END DO
964      END DO
965
966      DO jk = 1, jpkm1
967        DO jj = 2, jpjm1
968          DO ji = 2, jpim1
969            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
970            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
971          END DO
972        END DO
973      END DO
974
975      DO jk = 1, jpkm1
976        DO jj = 2, jpjm1
977          DO ji = 2, jpim1
978            zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
979            zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
980            zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
981            zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
982          END DO
983        END DO
984      END DO
985
986
987      DO jk = 1, jpkm1
988        DO jj = 2, jpjm1
989          DO ji = 2, jpim1
990            zpwes = 0._wp; zpwed = 0._wp
991            zpnss = 0._wp; zpnsd = 0._wp
992            zuijk = zu(ji,jj,jk)
993            zvijk = zv(ji,jj,jk)
994
995            !!!!!     for u equation
996            IF( jk <= mbku(ji,jj) ) THEN
997               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
998                 jis = ji + 1; jid = ji
999               ELSE
1000                 jis = ji;     jid = ji +1
1001               ENDIF
1002
1003               ! integrate the pressure on the shallow side
1004               jk1 = jk
1005               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1006                 IF( jk1 == mbku(ji,jj) ) THEN
1007                   zuijk = -zdept(jis,jj,jk1)
1008                   EXIT
1009                 ENDIF
1010                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1011                 zpwes = zpwes +                                    &
1012                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1013                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1014                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1015                 jk1 = jk1 + 1
1016               END DO
1017
1018               ! integrate the pressure on the deep side
1019               jk1 = jk
1020               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1021                 IF( jk1 == 1 ) THEN
1022                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1023                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1024                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1025                                                     dsp(jid,jj,1)) * zdeps
1026                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1027                   EXIT
1028                 ENDIF
1029                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1030                 zpwed = zpwed +                                        &
1031                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1032                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1033                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1034                 jk1 = jk1 - 1
1035               END DO
1036
1037               ! update the momentum trends in u direction
1038
1039               zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
1040               IF( lk_vvl ) THEN
1041                 zdpdx2 = zcoef0 / e1u(ji,jj) * &
1042                         ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1043                ELSE
1044                 zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1045               ENDIF
1046
1047               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
1048               &           umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
1049            ENDIF
1050
1051            !!!!!     for v equation
1052            IF( jk <= mbkv(ji,jj) ) THEN
1053               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1054                 jjs = jj + 1; jjd = jj
1055               ELSE
1056                 jjs = jj    ; jjd = jj + 1
1057               ENDIF
1058
1059               ! integrate the pressure on the shallow side
1060               jk1 = jk
1061               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1062                 IF( jk1 == mbkv(ji,jj) ) THEN
1063                   zvijk = -zdept(ji,jjs,jk1)
1064                   EXIT
1065                 ENDIF
1066                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1067                 zpnss = zpnss +                                      &
1068                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1069                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1070                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1071                 jk1 = jk1 + 1
1072               END DO
1073
1074               ! integrate the pressure on the deep side
1075               jk1 = jk
1076               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1077                 IF( jk1 == 1 ) THEN
1078                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1079                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1080                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1081                                                     dsp(ji,jjd,1) ) * zdeps
1082                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1083                   EXIT
1084                 ENDIF
1085                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1086                 zpnsd = zpnsd +                                        &
1087                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1088                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1089                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1090                 jk1 = jk1 - 1
1091               END DO
1092
1093
1094               ! update the momentum trends in v direction
1095
1096               zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
1097               IF( lk_vvl ) THEN
1098                   zdpdy2 = zcoef0 / e2v(ji,jj) * &
1099                           ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1100               ELSE
1101                   zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1102               ENDIF
1103
1104               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
1105               &              vmask(ji,jj,jk)*tmask(ji,jj,jk)*tmask(ji,jj+1,jk)
1106            ENDIF
1107
1108
1109           END DO
1110        END DO
1111      END DO
1112      !
1113      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1114      CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
1115      !
1116   END SUBROUTINE hpg_prj
1117
1118
1119   SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
1120      !!----------------------------------------------------------------------
1121      !!                 ***  ROUTINE cspline  ***
1122      !!
1123      !! ** Purpose :   constrained cubic spline interpolation
1124      !!
1125      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1126      !!
1127      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1128      !!----------------------------------------------------------------------
1129      IMPLICIT NONE
1130      REAL(wp), DIMENSION(:,:,:), INTENT(in)  :: fsp, xsp           ! value and coordinate
1131      REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
1132                                                                    ! the interpoated function
1133      INTEGER, INTENT(in) :: polynomial_type                        ! 1: cubic spline
1134                                                                    ! 2: Linear
1135      !
1136      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1137      INTEGER  ::   jpi, jpj, jpkm1
1138      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1139      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1140      REAL(wp) ::   zdf(size(fsp,3))
1141      !!----------------------------------------------------------------------
1142
1143      jpi   = size(fsp,1)
1144      jpj   = size(fsp,2)
1145      jpkm1 = size(fsp,3) - 1
1146
1147
1148      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1149         DO ji = 1, jpi
1150            DO jj = 1, jpj
1151           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1152           !    DO jk = 2, jpkm1-1
1153           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1154           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1155           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1156           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1157           !
1158           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1159           !
1160           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1161           !           zdf(jk) = 0._wp
1162           !       ELSE
1163           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1164           !       ENDIF
1165           !    END DO
1166
1167           !!Simply geometric average
1168               DO jk = 2, jpkm1-1
1169                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1170                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1171
1172                  IF(zdf1 * zdf2 <= 0._wp) THEN
1173                     zdf(jk) = 0._wp
1174                  ELSE
1175                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1176                  ENDIF
1177               END DO
1178
1179               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1180                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) ) -  0.5_wp * zdf(2)
1181               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1182                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1183                          & 0.5_wp * zdf(jpkm1 - 1)
1184
1185               DO jk = 1, jpkm1 - 1
1186                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1187                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1188                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1189                 zddf1  = -2._wp * ztmp1 + ztmp2
1190                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1191                 zddf2  =  2._wp * ztmp1 - ztmp2
1192
1193                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1194                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1195                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1196                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1197                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1198                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1199                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1200                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1201                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1202               END DO
1203            END DO
1204         END DO
1205
1206      ELSE IF (polynomial_type == 2) THEN     ! Linear
1207         DO ji = 1, jpi
1208            DO jj = 1, jpj
1209               DO jk = 1, jpkm1-1
1210                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1211                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1212
1213                  dsp(ji,jj,jk) = 0._wp
1214                  csp(ji,jj,jk) = 0._wp
1215                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1216                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1217               END DO
1218            END DO
1219         END DO
1220
1221      ELSE
1222           CALL ctl_stop( 'invalid polynomial type in cspline' )
1223      ENDIF
1224
1225   END SUBROUTINE cspline
1226
1227
1228   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1229      !!----------------------------------------------------------------------
1230      !!                 ***  ROUTINE interp1  ***
1231      !!
1232      !! ** Purpose :   1-d linear interpolation
1233      !!
1234      !! ** Method  :   interpolation is straight forward
1235      !!                extrapolation is also permitted (no value limit)
1236      !!----------------------------------------------------------------------
1237      IMPLICIT NONE
1238      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1239      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1240      REAL(wp)             ::  zdeltx
1241      !!----------------------------------------------------------------------
1242
1243      zdeltx = xr - xl
1244      IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1245        f = 0.5_wp * (fl + fr)
1246      ELSE
1247        f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1248      ENDIF
1249
1250   END FUNCTION interp1
1251
1252
1253   FUNCTION interp2(x, a, b, c, d)  RESULT(f)
1254      !!----------------------------------------------------------------------
1255      !!                 ***  ROUTINE interp1  ***
1256      !!
1257      !! ** Purpose :   1-d constrained cubic spline interpolation
1258      !!
1259      !! ** Method  :  cubic spline interpolation
1260      !!
1261      !!----------------------------------------------------------------------
1262      IMPLICIT NONE
1263      REAL(wp), INTENT(in) ::  x, a, b, c, d
1264      REAL(wp)             ::  f ! value from the interpolation
1265      !!----------------------------------------------------------------------
1266
1267      f = a + x* ( b + x * ( c + d * x ) )
1268
1269   END FUNCTION interp2
1270
1271
1272   FUNCTION interp3(x, a, b, c, d)  RESULT(f)
1273      !!----------------------------------------------------------------------
1274      !!                 ***  ROUTINE interp1  ***
1275      !!
1276      !! ** Purpose :   Calculate the first order of deriavtive of
1277      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1278      !!
1279      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1280      !!
1281      !!----------------------------------------------------------------------
1282      IMPLICIT NONE
1283      REAL(wp), INTENT(in) ::  x, a, b, c, d
1284      REAL(wp)             ::  f ! value from the interpolation
1285      !!----------------------------------------------------------------------
1286
1287      f = b + x * ( 2._wp * c + 3._wp * d * x)
1288
1289   END FUNCTION interp3
1290
1291
1292   FUNCTION integ_spline(xl, xr, a, b, c, d)  RESULT(f)
1293      !!----------------------------------------------------------------------
1294      !!                 ***  ROUTINE interp1  ***
1295      !!
1296      !! ** Purpose :   1-d constrained cubic spline integration
1297      !!
1298      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1299      !!
1300      !!----------------------------------------------------------------------
1301      IMPLICIT NONE
1302      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1303      REAL(wp)             ::  za1, za2, za3
1304      REAL(wp)             ::  f                   ! integration result
1305      !!----------------------------------------------------------------------
1306
1307      za1 = 0.5_wp * b
1308      za2 = c / 3.0_wp
1309      za3 = 0.25_wp * d
1310
1311      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1312         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1313
1314   END FUNCTION integ_spline
1315
1316   !!======================================================================
1317END MODULE dynhpg
1318
Note: See TracBrowser for help on using the repository browser.