New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso.F90 in branches/2014/dev_r4650_UKMO11_restart_functionality/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2014/dev_r4650_UKMO11_restart_functionality/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_iso.F90 @ 5208

Last change on this file since 5208 was 5208, checked in by davestorkey, 9 years ago

Merge in changes from trunk up to 5021.

  • Property svn:keywords set to Id
File size: 16.9 KB
Line 
1MODULE traldf_iso
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :  OPA  !  1994-08  (G. Madec, M. Imbard)
7   !!            8.0  !  1997-05  (G. Madec)  split into traldf and trazdf
8   !!            NEMO !  2002-08  (G. Madec)  Free form, F90
9   !!            1.0  !  2005-11  (G. Madec)  merge traldf and trazdf :-)
10   !!            3.3  !  2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!----------------------------------------------------------------------
12#if   defined key_ldfslp   ||   defined key_esopa
13   !!----------------------------------------------------------------------
14   !!   'key_ldfslp'               slope of the lateral diffusive direction
15   !!----------------------------------------------------------------------
16   !!   tra_ldf_iso  : update the tracer trend with the horizontal
17   !!                  component of a iso-neutral laplacian operator
18   !!                  and with the vertical part of
19   !!                  the isopycnal or geopotential s-coord. operator
20   !!----------------------------------------------------------------------
21   USE oce             ! ocean dynamics and active tracers
22   USE dom_oce         ! ocean space and time domain
23   USE trc_oce         ! share passive tracers/Ocean variables
24   USE zdf_oce         ! ocean vertical physics
25   USE ldftra_oce      ! ocean active tracers: lateral physics
26   USE ldfslp          ! iso-neutral slopes
27   USE diaptr          ! poleward transport diagnostics
28   USE in_out_manager  ! I/O manager
29   USE iom             ! I/O library
30#if defined key_diaar5
31   USE phycst          ! physical constants
32   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
33#endif
34   USE wrk_nemo        ! Memory Allocation
35   USE timing          ! Timing
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   tra_ldf_iso   ! routine called by step.F90
41
42   !! * Substitutions
43#  include "domzgr_substitute.h90"
44#  include "ldftra_substitute.h90"
45#  include "vectopt_loop_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
48   !! $Id$
49   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE tra_ldf_iso( kt, kit000, cdtype, pgu, pgv,              &
54      &                                pgui, pgvi,                    &
55      &                                ptb, pta, kjpt, pahtb0 )
56      !!----------------------------------------------------------------------
57      !!                  ***  ROUTINE tra_ldf_iso  ***
58      !!
59      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
60      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
61      !!      add it to the general trend of tracer equation.
62      !!
63      !! ** Method  :   The horizontal component of the lateral diffusive trends
64      !!      is provided by a 2nd order operator rotated along neural or geopo-
65      !!      tential surfaces to which an eddy induced advection can be added
66      !!      It is computed using before fields (forward in time) and isopyc-
67      !!      nal or geopotential slopes computed in routine ldfslp.
68      !!
69      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
70      !!      ========    with partial cell update if ln_zps=T.
71      !!
72      !!      2nd part :  horizontal fluxes of the lateral mixing operator
73      !!      ========   
74      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
75      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
76      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
77      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
78      !!      take the horizontal divergence of the fluxes:
79      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
80      !!      Add this trend to the general trend (ta,sa):
81      !!         ta = ta + difft
82      !!
83      !!      3rd part: vertical trends of the lateral mixing operator
84      !!      ========  (excluding the vertical flux proportional to dk[t] )
85      !!      vertical fluxes associated with the rotated lateral mixing:
86      !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
87      !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
88      !!      take the horizontal divergence of the fluxes:
89      !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
90      !!      Add this trend to the general trend (ta,sa):
91      !!         pta = pta + difft
92      !!
93      !! ** Action :   Update pta arrays with the before rotated diffusion
94      !!----------------------------------------------------------------------
95      USE oce     , ONLY:   zftu => ua       , zftv  => va         ! (ua,va) used as workspace
96      !
97      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
98      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
99      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
100      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
101      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu , pgv    ! tracer gradient at pstep levels
102      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgui, pgvi   ! tracer gradient at pstep levels
103      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
104      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
105      REAL(wp)                             , INTENT(in   ) ::   pahtb0     ! background diffusion coef
106      !
107      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
108      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3   ! local scalars
109      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4   !   -      -
110      REAL(wp) ::  zcoef0, zbtr, ztra            !   -      -
111#if defined key_diaar5
112      REAL(wp)                         ::   zztmp               ! local scalar
113#endif
114      REAL(wp), POINTER, DIMENSION(:,:  ) ::  z2d
115      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zdkt, zdk1t, zdit, zdjt, ztfw 
116      !!----------------------------------------------------------------------
117      !
118      IF( nn_timing == 1 )  CALL timing_start('tra_ldf_iso')
119      !
120      CALL wrk_alloc( jpi, jpj,      z2d ) 
121      CALL wrk_alloc( jpi, jpj, jpk, zdit, zdjt, ztfw, zdkt, zdk1t ) 
122      !
123
124      IF( kt == kit000 )  THEN
125         IF(lwp) WRITE(numout,*)
126         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator on ', cdtype
127         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
128      ENDIF
129      !
130      !                                                          ! ===========
131      DO jn = 1, kjpt                                            ! tracer loop
132         !                                                       ! ===========
133         !                                               
134         !!----------------------------------------------------------------------
135         !!   I - masked horizontal derivative
136         !!----------------------------------------------------------------------
137         !!bug ajout.... why?   ( 1,jpj,:) and (jpi,1,:) should be sufficient....
138         zdit (1,:,:) = 0.e0     ;     zdit (jpi,:,:) = 0.e0
139         zdjt (1,:,:) = 0.e0     ;     zdjt (jpi,:,:) = 0.e0
140         !!end
141
142         ! Horizontal tracer gradient
143         DO jk = 1, jpkm1
144            DO jj = 1, jpjm1
145               DO ji = 1, fs_jpim1   ! vector opt.
146                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
147                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
148               END DO
149            END DO
150         END DO
151         IF( ln_zps ) THEN      ! partial steps correction at the last ocean level
152            DO jj = 1, jpjm1
153               DO ji = 1, fs_jpim1   ! vector opt.
154! IF useless if zpshde defines pgu everywhere
155                  IF (mbku(ji,jj) > 1) zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)         
156                  IF (mbkv(ji,jj) > 1) zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)
157                  ! (ISF)
158                  IF (miku(ji,jj) > 1) zdit(ji,jj,miku(ji,jj)) = pgui(ji,jj,jn)         
159                  IF (mikv(ji,jj) > 1) zdjt(ji,jj,mikv(ji,jj)) = pgvi(ji,jj,jn)     
160               END DO
161            END DO
162         ENDIF
163
164         !!----------------------------------------------------------------------
165         !!   II - horizontal trend  (full)
166         !!----------------------------------------------------------------------
167!CDIR PARALLEL DO PRIVATE( zdk1t )
168         !                                                ! ===============
169         DO jj = 1, jpj                                 ! Horizontal slab
170            !                                             ! ===============
171            DO ji = 1, jpi   ! vector opt.
172               DO jk = mikt(ji,jj), jpkm1
173               ! 1. Vertical tracer gradient at level jk and jk+1
174               ! ------------------------------------------------
175               ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
176                  zdk1t(ji,jj,jk) = ( ptb(ji,jj,jk,jn) - ptb(ji,jj,jk+1,jn) ) * tmask(ji,jj,jk+1)
177               !
178                  IF( jk == mikt(ji,jj) ) THEN  ;   zdkt(ji,jj,jk) = zdk1t(ji,jj,jk)
179                  ELSE                          ;   zdkt(ji,jj,jk) = ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) ) * tmask(ji,jj,jk)
180                  ENDIF
181               END DO
182            END DO
183         END DO
184
185            ! 2. Horizontal fluxes
186            ! --------------------   
187         DO jj = 1 , jpjm1
188            DO ji = 1, fs_jpim1   ! vector opt.
189               DO jk = mikt(ji,jj), jpkm1
190                  zabe1 = ( fsahtu(ji,jj,jk) + pahtb0 ) * re2u_e1u(ji,jj) * fse3u_n(ji,jj,jk)
191                  zabe2 = ( fsahtv(ji,jj,jk) + pahtb0 ) * re1v_e2v(ji,jj) * fse3v_n(ji,jj,jk)
192                  !
193                  zmsku = 1. / MAX(  tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
194                     &             + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
195                  !
196                  zmskv = 1. / MAX(  tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
197                     &             + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
198                  !
199                  zcof1 = - fsahtu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
200                  zcof2 = - fsahtv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
201                  !
202                  zftu(ji,jj,jk ) = (  zabe1 * zdit(ji,jj,jk)   &
203                     &              + zcof1 * (  zdkt (ji+1,jj,jk) + zdk1t(ji,jj,jk)      &
204                     &                         + zdk1t(ji+1,jj,jk) + zdkt (ji,jj,jk)  )  ) * umask(ji,jj,jk)
205                  zftv(ji,jj,jk) = (  zabe2 * zdjt(ji,jj,jk)   &
206                     &              + zcof2 * (  zdkt (ji,jj+1,jk) + zdk1t(ji,jj,jk)      &
207                     &                         + zdk1t(ji,jj+1,jk) + zdkt (ji,jj,jk)  )  ) * vmask(ji,jj,jk)                 
208               END DO
209            END DO
210         END DO
211
212            ! II.4 Second derivative (divergence) and add to the general trend
213            ! ----------------------------------------------------------------
214         DO jj = 2 , jpjm1
215            DO ji = fs_2, fs_jpim1   ! vector opt.
216               DO jk = mikt(ji,jj), jpkm1
217                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
218                  ztra = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )
219                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
220               END DO
221            END DO
222            !                                          ! ===============
223         END DO                                        !   End of slab 
224         !                                             ! ===============
225         !
226         ! "Poleward" diffusive heat or salt transports (T-S case only)
227         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN
228            ! note sign is reversed to give down-gradient diffusive transports (#1043)
229            IF( jn == jp_tem)   htr_ldf(:) = ptr_vj( -zftv(:,:,:) )
230            IF( jn == jp_sal)   str_ldf(:) = ptr_vj( -zftv(:,:,:) )
231         ENDIF
232 
233#if defined key_diaar5
234         IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
235            z2d(:,:) = 0._wp 
236            ! note sign is reversed to give down-gradient diffusive transports (#1043)
237            zztmp = -1.0_wp * rau0 * rcp
238            DO jk = 1, jpkm1
239               DO jj = 2, jpjm1
240                  DO ji = fs_2, fs_jpim1   ! vector opt.
241                     z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) 
242                  END DO
243               END DO
244            END DO
245            z2d(:,:) = zztmp * z2d(:,:)
246            CALL lbc_lnk( z2d, 'U', -1. )
247            CALL iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
248            z2d(:,:) = 0._wp 
249            DO jk = 1, jpkm1
250               DO jj = 2, jpjm1
251                  DO ji = fs_2, fs_jpim1   ! vector opt.
252                     z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) 
253                  END DO
254               END DO
255            END DO
256            z2d(:,:) = zztmp * z2d(:,:)
257            CALL lbc_lnk( z2d, 'V', -1. )
258            CALL iom_put( "vdiff_heattr", z2d )                  !  heat transport in i-direction
259         END IF
260#endif
261
262         !!----------------------------------------------------------------------
263         !!   III - vertical trend of T & S (extra diagonal terms only)
264         !!----------------------------------------------------------------------
265         
266         ! Local constant initialization
267         ! -----------------------------
268         ztfw(1,:,:) = 0.e0     ;     ztfw(jpi,:,:) = 0.e0
269         
270         ! Vertical fluxes
271         ! ---------------
272         
273         ! Surface and bottom vertical fluxes set to zero
274         ztfw(:,:, 1 ) = 0.e0      ;      ztfw(:,:,jpk) = 0.e0
275         
276         ! interior (2=<jk=<jpk-1)
277         DO jk = 2, jpkm1
278            DO jj = 2, jpjm1
279               DO ji = fs_2, fs_jpim1   ! vector opt.
280                  zcoef0 = - fsahtw(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji,jj,jk-1)
281                  !
282                  zmsku = 1./MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)      &
283                     &            + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk), 1.  )
284                  zmskv = 1./MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)      &
285                     &            + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk), 1.  )
286                  !
287                  zcoef3 = zcoef0 * e2t(ji,jj) * zmsku * wslpi (ji,jj,jk)
288                  zcoef4 = zcoef0 * e1t(ji,jj) * zmskv * wslpj (ji,jj,jk)
289                  !
290                  ztfw(ji,jj,jk) = zcoef3 * (   zdit(ji  ,jj  ,jk-1) + zdit(ji-1,jj  ,jk)      &
291                     &                        + zdit(ji-1,jj  ,jk-1) + zdit(ji  ,jj  ,jk)  )   &
292                     &           + zcoef4 * (   zdjt(ji  ,jj  ,jk-1) + zdjt(ji  ,jj-1,jk)      &
293                     &                        + zdjt(ji  ,jj-1,jk-1) + zdjt(ji  ,jj  ,jk)  )
294               END DO
295            END DO
296         END DO
297         
298         
299         ! I.5 Divergence of vertical fluxes added to the general tracer trend
300         ! -------------------------------------------------------------------
301         DO jk = 1, jpkm1
302            DO jj = 2, jpjm1
303               DO ji = fs_2, fs_jpim1   ! vector opt.
304                  zbtr = 1.0 / ( e12t(ji,jj) * fse3t_n(ji,jj,jk) )
305                  ztra = (  ztfw(ji,jj,jk) - ztfw(ji,jj,jk+1)  ) * zbtr
306                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
307               END DO
308            END DO
309         END DO
310         !
311      END DO
312      !
313      CALL wrk_dealloc( jpi, jpj, z2d ) 
314      CALL wrk_dealloc( jpi, jpj, jpk, zdit, zdjt, ztfw, zdkt, zdk1t ) 
315      !
316      IF( nn_timing == 1 )  CALL timing_stop('tra_ldf_iso')
317      !
318   END SUBROUTINE tra_ldf_iso
319
320#else
321   !!----------------------------------------------------------------------
322   !!   default option :   Dummy code   NO rotation of the diffusive tensor
323   !!----------------------------------------------------------------------
324CONTAINS
325   SUBROUTINE tra_ldf_iso( kt, kit000,cdtype, pgu, pgv, pgui, pgvi, ptb, pta, kjpt, pahtb0 )      ! Empty routine
326      INTEGER:: kt, kit000
327      CHARACTER(len=3) ::   cdtype
328      REAL, DIMENSION(:,:,:) ::   pgu, pgv, pgui, pgvi    ! tracer gradient at pstep levels
329      REAL, DIMENSION(:,:,:,:) ::   ptb, pta
330      WRITE(*,*) 'tra_ldf_iso: You should not have seen this print! error?', kt, kit000, cdtype,   &
331         &                       pgu(1,1,1), pgv(1,1,1), ptb(1,1,1,1), pta(1,1,1,1), kjpt, pahtb0
332   END SUBROUTINE tra_ldf_iso
333#endif
334
335   !!==============================================================================
336END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.