New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcini.F90 in branches/2014/dev_r4650_UKMO11_restart_functionality/NEMOGCM/NEMO/TOP_SRC – NEMO

source: branches/2014/dev_r4650_UKMO11_restart_functionality/NEMOGCM/NEMO/TOP_SRC/trcini.F90 @ 5313

Last change on this file since 5313 was 5313, checked in by timgraham, 9 years ago

Merged head of trunk (r5302) into branch

  • Property svn:keywords set to Id
File size: 9.8 KB
Line 
1MODULE trcini
2   !!======================================================================
3   !!                         ***  MODULE trcini  ***
4   !! TOP :   Manage the passive tracer initialization
5   !!======================================================================
6   !! History :   -   ! 1991-03 (O. Marti)  original code
7   !!            1.0  ! 2005-03 (O. Aumont, A. El Moussaoui) F90
8   !!            2.0  ! 2005-10 (C. Ethe, G. Madec) revised architecture
9   !!            4.0  ! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
10   !!----------------------------------------------------------------------
11#if defined key_top
12   !!----------------------------------------------------------------------
13   !!   'key_top'                                                TOP models
14   !!----------------------------------------------------------------------
15   !!   trc_init  :   Initialization for passive tracer
16   !!   top_alloc :   allocate the TOP arrays
17   !!----------------------------------------------------------------------
18   USE oce_trc         ! shared variables between ocean and passive tracers
19   USE trc             ! passive tracers common variables
20   USE trcrst          ! passive tracers restart
21   USE trcnam          ! Namelist read
22   USE trcini_cfc      ! CFC      initialisation
23   USE trcini_pisces   ! PISCES   initialisation
24   USE trcini_c14b     ! C14 bomb initialisation
25   USE trcini_my_trc   ! MY_TRC   initialisation
26   USE trcdta          ! initialisation from files
27   USE daymod          ! calendar manager
28   USE zpshde          ! partial step: hor. derivative   (zps_hde routine)
29   USE prtctl_trc      ! Print control passive tracers (prt_ctl_trc_init routine)
30   USE trcsub          ! variables to substep passive tracers
31   USE lib_mpp         ! distribued memory computing library
32   USE sbc_oce
33 
34   IMPLICIT NONE
35   PRIVATE
36   
37   PUBLIC   trc_init   ! called by opa
38
39    !! * Substitutions
40#  include "domzgr_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/TOP 4.0 , NEMO Consortium (2011)
43   !! $Id$
44   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47   
48   SUBROUTINE trc_init
49      !!---------------------------------------------------------------------
50      !!                     ***  ROUTINE trc_init  ***
51      !!
52      !! ** Purpose :   Initialization of the passive tracer fields
53      !!
54      !! ** Method  : - read namelist
55      !!              - control the consistancy
56      !!              - compute specific initialisations
57      !!              - set initial tracer fields (either read restart
58      !!                or read data or analytical formulation
59      !!---------------------------------------------------------------------
60      INTEGER ::   jk, jn, jl    ! dummy loop indices
61      CHARACTER (len=25) :: charout
62      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrcdta   ! 4D  workspace
63      !!---------------------------------------------------------------------
64      !
65      IF( nn_timing == 1 )   CALL timing_start('trc_init')
66      !
67      IF(lwp) WRITE(numout,*)
68      IF(lwp) WRITE(numout,*) 'trc_init : initial set up of the passive tracers'
69      IF(lwp) WRITE(numout,*) '~~~~~~~'
70
71      CALL top_alloc()              ! allocate TOP arrays
72
73#if defined key_offline
74      ltrcdm2dc = .FALSE.
75#endif
76
77      IF( ltrcdm2dc )CALL ctl_warn( ' Diurnal cycle on physics but not in PISCES or LOBSTER ' )
78
79      IF( nn_cla == 1 )   &
80         &  CALL ctl_stop( ' Cross Land Advection not yet implemented with passive tracer ; nn_cla must be 0' )
81
82      CALL trc_nam      ! read passive tracers namelists
83      !
84      IF(lwp) WRITE(numout,*)
85      !
86      IF( ln_rsttr .AND. .NOT. lk_offline ) CALL trc_rst_cal( nit000, 'READ' )   ! calendar
87      !
88      IF(lwp) WRITE(numout,*)
89                                                              ! masked grid volume
90      !                                                              ! masked grid volume
91      DO jk = 1, jpk
92         cvol(:,:,jk) = e1e2t(:,:) * fse3t(:,:,jk) * tmask(:,:,jk)
93      END DO
94      IF( lk_degrad ) cvol(:,:,:) = cvol(:,:,:) * facvol(:,:,:)      ! degrad option: reduction by facvol
95      !                                                              ! total volume of the ocean
96      areatot = glob_sum( cvol(:,:,:) )
97
98      IF( lk_pisces  )       CALL trc_ini_pisces       ! PISCES  bio-model
99      IF( lk_cfc     )       CALL trc_ini_cfc          ! CFC     tracers
100      IF( lk_c14b    )       CALL trc_ini_c14b         ! C14 bomb  tracer
101      IF( lk_my_trc  )       CALL trc_ini_my_trc       ! MY_TRC  tracers
102
103      IF( lwp ) THEN
104         !
105         CALL ctl_opn( numstr, 'tracer.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp , narea )
106         !
107      ENDIF
108
109      IF( ln_trcdta )      CALL trc_dta_init(jptra)
110
111
112      IF( ln_rsttr ) THEN
113        !
114        CALL trc_rst_read              ! restart from a file
115        !
116      ELSE
117        !
118        IF( ln_trcdta .AND. nb_trcdta > 0 ) THEN  ! Initialisation of tracer from a file that may also be used for damping
119            !
120            CALL wrk_alloc( jpi, jpj, jpk, ztrcdta )    ! Memory allocation
121            !
122            DO jn = 1, jptra
123               IF( ln_trc_ini(jn) ) THEN      ! update passive tracers arrays with input data read from file
124                  jl = n_trc_index(jn) 
125                  CALL trc_dta( nit000, sf_trcdta(jl),rf_trfac(jl) )   ! read tracer data at nit000
126                  ztrcdta(:,:,:) = sf_trcdta(jl)%fnow(:,:,:)
127                  trn(:,:,:,jn) = ztrcdta(:,:,:) * tmask(:,:,:) 
128                  IF( .NOT.ln_trcdmp .AND. .NOT.ln_trcdmp_clo ) THEN      !== deallocate data structure   ==!
129                     !                                                    (data used only for initialisation)
130                     IF(lwp) WRITE(numout,*) 'trc_dta: deallocate data arrays as they are only used to initialize the run'
131                                                  DEALLOCATE( sf_trcdta(jl)%fnow )     !  arrays in the structure
132                     IF( sf_trcdta(jl)%ln_tint )  DEALLOCATE( sf_trcdta(jl)%fdta )
133                     !
134                  ENDIF
135               ENDIF
136            ENDDO
137            CALL wrk_dealloc( jpi, jpj, jpk, ztrcdta )
138        ENDIF
139        !
140        trb(:,:,:,:) = trn(:,:,:,:)
141        !
142      ENDIF
143 
144      tra(:,:,:,:) = 0._wp
145      IF( ln_zps .AND. .NOT. lk_c1d .AND. .NOT. ln_isfcav )   &              ! Partial steps: before horizontal gradient of passive
146        &    CALL zps_hde    ( nit000, jptra, trn, gtru, gtrv  )  ! Partial steps: before horizontal gradient
147      IF( ln_zps .AND. .NOT. lk_c1d .AND.       ln_isfcav )   &
148        &    CALL zps_hde_isf( nit000, jptra, trn, pgtu=gtru, pgtv=gtrv, pgtui=gtrui, pgtvi=gtrvi )       ! tracers at the bottom ocean level
149
150
151      !
152      IF( nn_dttrc /= 1 )        CALL trc_sub_ini      ! Initialize variables for substepping passive tracers
153      !
154
155      trai(:) = 0._wp                                                   ! initial content of all tracers
156      DO jn = 1, jptra
157         trai(jn) = trai(jn) + glob_sum( trn(:,:,:,jn) * cvol(:,:,:)   )
158      END DO
159
160      IF(lwp) THEN               ! control print
161         WRITE(numout,*)
162         WRITE(numout,*)
163         WRITE(numout,*) '          *** Total number of passive tracer jptra = ', jptra
164         WRITE(numout,*) '          *** Total volume of ocean                = ', areatot
165         WRITE(numout,*) '          *** Total inital content of all tracers '
166         WRITE(numout,*)
167         DO jn = 1, jptra
168            WRITE(numout,9000) jn, TRIM( ctrcnm(jn) ), trai(jn)
169         ENDDO
170         WRITE(numout,*)
171      ENDIF
172      IF(lwp) WRITE(numout,*)
173      IF(ln_ctl) THEN            ! print mean trends (used for debugging)
174         CALL prt_ctl_trc_init
175         WRITE(charout, FMT="('ini ')")
176         CALL prt_ctl_trc_info( charout )
177         CALL prt_ctl_trc( tab4d=trn, mask=tmask, clinfo=ctrcnm )
178      ENDIF
1799000  FORMAT(' tracer nb : ',i2,'      name :',a10,'      initial content :',e18.10)
180      !
181      IF( nn_timing == 1 )   CALL timing_stop('trc_init')
182      !
183   END SUBROUTINE trc_init
184
185
186   SUBROUTINE top_alloc
187      !!----------------------------------------------------------------------
188      !!                     ***  ROUTINE top_alloc  ***
189      !!
190      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
191      !!----------------------------------------------------------------------
192      USE trcadv        , ONLY:   trc_adv_alloc          ! TOP-related alloc routines...
193      USE trc           , ONLY:   trc_alloc
194      USE trcnxt        , ONLY:   trc_nxt_alloc
195      USE trczdf        , ONLY:   trc_zdf_alloc
196      USE trdtrc_oce    , ONLY:   trd_trc_oce_alloc
197#if defined key_trdmxl_trc 
198      USE trdmxl_trc    , ONLY:   trd_mxl_trc_alloc
199#endif
200      !
201      INTEGER :: ierr
202      !!----------------------------------------------------------------------
203      !
204      ierr =        trc_adv_alloc()          ! Start of TOP-related alloc routines...
205      ierr = ierr + trc_alloc    ()
206      ierr = ierr + trc_nxt_alloc()
207      ierr = ierr + trc_zdf_alloc()
208      ierr = ierr + trd_trc_oce_alloc()
209#if defined key_trdmxl_trc 
210      ierr = ierr + trd_mxl_trc_alloc()
211#endif
212      !
213      IF( lk_mpp    )   CALL mpp_sum( ierr )
214      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'top_alloc : unable to allocate standard ocean arrays' )
215      !
216   END SUBROUTINE top_alloc
217
218#else
219   !!----------------------------------------------------------------------
220   !!  Empty module :                                     No passive tracer
221   !!----------------------------------------------------------------------
222CONTAINS
223   SUBROUTINE trc_init                      ! Dummy routine   
224   END SUBROUTINE trc_init
225#endif
226
227   !!======================================================================
228END MODULE trcini
Note: See TracBrowser for help on using the repository browser.