New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_mus.F90 in branches/2014/dev_r4650_UKMO14.12_STAND_ALONE_OBSOPER/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2014/dev_r4650_UKMO14.12_STAND_ALONE_OBSOPER/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_mus.F90 @ 6043

Last change on this file since 6043 was 6043, checked in by timgraham, 8 years ago

Merged head of trunk into branch
  • Property svn:keywords set to Id
File size: 15.6 KB
Line 
1MODULE traadv_mus
2   !!======================================================================
3   !!                       ***  MODULE  traadv_mus  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
10   !!            3.4  !  2012-06  (P. Oddo, M. Vichi) include the upstream where needed
11   !!            3.7  !  2015-09  (G. Madec) add the ice-shelf cavities boundary condition
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv_mus   : update the tracer trend with the horizontal
16   !!                   and vertical advection trends using MUSCL scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE trc_oce        ! share passive tracers/Ocean variables
20   USE dom_oce        ! ocean space and time domain
21   USE trd_oce        ! trends: ocean variables
22   USE trdtra         ! tracers trends manager
23   USE sbcrnf         ! river runoffs
24   USE diaptr         ! poleward transport diagnostics
25   !
26   USE wrk_nemo       ! Memory Allocation
27   USE timing         ! Timing
28   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
29   USE in_out_manager ! I/O manager
30   USE lib_mpp        ! distribued memory computing
31   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   tra_adv_mus   ! routine called by traadv.F90
37   
38   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   upsmsk   !: mixed upstream/centered scheme near some straits
39   !                                                           !  and in closed seas (orca 2 and 4 configurations)
40   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   xind     !: mixed upstream/centered index
41   
42   !! * Substitutions
43#  include "domzgr_substitute.h90"
44#  include "vectopt_loop_substitute.h90"
45   !!----------------------------------------------------------------------
46   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
47   !! $Id$
48   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE tra_adv_mus( kt, kit000, cdtype, p2dt, pun, pvn, pwn,             &
53      &                                              ptb, pta, kjpt, ld_msc_ups )
54      !!----------------------------------------------------------------------
55      !!                    ***  ROUTINE tra_adv_mus  ***
56      !!
57      !! ** Purpose :   Compute the now trend due to total advection of tracers
58      !!              using a MUSCL scheme (Monotone Upstream-centered Scheme for
59      !!              Conservation Laws) and add it to the general tracer trend.
60      !!
61      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
62      !!              ld_msc_ups=T :
63      !!
64      !! ** Action  : - update (ta,sa) with the now advective tracer trends
65      !!              - send trends to trdtra module for further diagnostcs
66      !!
67      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
68      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
69      !!----------------------------------------------------------------------
70      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
71      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
72      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
73      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
74      LOGICAL                              , INTENT(in   ) ::   ld_msc_ups      ! use upstream scheme within muscl
75      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
76      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
77      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb             ! before tracer field
78      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
79      !
80      INTEGER  ::   ji, jj, jk, jn       ! dummy loop indices
81      INTEGER  ::   ierr                 ! local integer
82      REAL(wp) ::   zu, z0u, zzwx, zw    ! local scalars
83      REAL(wp) ::   zv, z0v, zzwy, z0w   !   -      -
84      REAL(wp) ::   zdt, zalpha          !   -      -
85      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zslpx, zslpy   ! 3D workspace
86      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwx  , zwy     ! -      -
87      !!----------------------------------------------------------------------
88      !
89      IF( nn_timing == 1 )  CALL timing_start('tra_adv_mus')
90      !
91      CALL wrk_alloc( jpi,jpj,jpk,   zslpx, zslpy, zwx, zwy )
92      !
93      IF( kt == kit000 )  THEN
94         IF(lwp) WRITE(numout,*)
95         IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype
96         IF(lwp) WRITE(numout,*) '        : mixed up-stream           ', ld_msc_ups
97         IF(lwp) WRITE(numout,*) '~~~~~~~'
98         IF(lwp) WRITE(numout,*)
99         !
100         ! Upstream / MUSCL scheme indicator
101         !
102         ALLOCATE( xind(jpi,jpj,jpk), STAT=ierr )
103         xind(:,:,:) = 1._wp              ! set equal to 1 where up-stream is not needed
104         !
105         IF( ld_msc_ups ) THEN            ! define the upstream indicator (if asked)
106            ALLOCATE( upsmsk(jpi,jpj), STAT=ierr )
107            upsmsk(:,:) = 0._wp                             ! not upstream by default
108            !
109            DO jk = 1, jpkm1
110               xind(:,:,jk) = 1._wp                              &                 ! =>1 where up-stream is not needed
111                  &         - MAX ( rnfmsk(:,:) * rnfmsk_z(jk),  &                 ! =>0 near runoff mouths (& closed sea outflows)
112                  &                 upsmsk(:,:)                ) * tmask(:,:,jk)   ! =>0 in some user defined area
113            END DO
114         ENDIF 
115         !
116      ENDIF 
117      !     
118      !                                                     ! ===========
119      DO jn = 1, kjpt                                       ! tracer loop
120         !                                                  ! ===========
121         ! I. Horizontal advective fluxes
122         ! ------------------------------
123         ! first guess of the slopes
124         zwx(:,:,jpk) = 0.e0   ;   zwy(:,:,jpk) = 0.e0        ! bottom values
125         ! interior values
126         DO jk = 1, jpkm1
127            DO jj = 1, jpjm1     
128               DO ji = 1, fs_jpim1   ! vector opt.
129                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
130                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
131               END DO
132           END DO
133         END DO
134         !
135         CALL lbc_lnk( zwx, 'U', -1. )                        ! lateral boundary conditions on zwx, zwy   (changed sign)
136         CALL lbc_lnk( zwy, 'V', -1. )
137         !                                             !-- Slopes of tracer
138         zslpx(:,:,jpk) = 0.e0   ;   zslpy(:,:,jpk) = 0.e0    ! bottom values
139         DO jk = 1, jpkm1                                     ! interior values
140            DO jj = 2, jpj
141               DO ji = fs_2, jpi   ! vector opt.
142                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
143                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
144                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
145                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
146               END DO
147            END DO
148         END DO
149         !
150         DO jk = 1, jpkm1                                     ! Slopes limitation
151            DO jj = 2, jpj
152               DO ji = fs_2, jpi   ! vector opt.
153                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
154                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
155                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
156                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
157                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
158                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
159               END DO
160           END DO
161         END DO
162         !
163         !                                             !-- MUSCL horizontal advective fluxes
164         DO jk = 1, jpkm1                                     ! interior values
165            zdt  = p2dt(jk)
166            DO jj = 2, jpjm1
167               DO ji = fs_2, fs_jpim1   ! vector opt.
168                  ! MUSCL fluxes
169                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
170                  zalpha = 0.5 - z0u
171                  zu  = z0u - 0.5 * pun(ji,jj,jk) * zdt / ( e1e2u(ji,jj) * fse3u(ji,jj,jk) )
172                  zzwx = ptb(ji+1,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji+1,jj,jk)
173                  zzwy = ptb(ji  ,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji  ,jj,jk)
174                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
175                  !
176                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
177                  zalpha = 0.5 - z0v
178                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * zdt / ( e1e2v(ji,jj) * fse3v(ji,jj,jk) )
179                  zzwx = ptb(ji,jj+1,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj+1,jk)
180                  zzwy = ptb(ji,jj  ,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj  ,jk)
181                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
182               END DO
183            END DO
184         END DO
185         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )   ! lateral boundary conditions   (changed sign)
186         !
187         DO jk = 1, jpkm1         ! Tracer flux divergence at t-point added to the general trend
188            DO jj = 2, jpjm1     
189               DO ji = fs_2, fs_jpim1   ! vector opt.
190                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )       &
191                  &                                     + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )     &
192                  &                                   / ( e1e2t(ji,jj) * fse3t(ji,jj,jk) )
193               END DO
194           END DO
195         END DO       
196         !                                 ! trend diagnostics (contribution of upstream fluxes)
197         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR.   &
198            &( cdtype == 'TRC' .AND. l_trdtrc )      )  THEN
199            CALL trd_tra( kt, cdtype, jn, jptra_xad, zwx, pun, ptb(:,:,:,jn) )
200            CALL trd_tra( kt, cdtype, jn, jptra_yad, zwy, pvn, ptb(:,:,:,jn) )
201         END IF
202         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
203         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
204            IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
205            IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
206         ENDIF
207
208         ! II. Vertical advective fluxes
209         ! -----------------------------
210         !                                !-- first guess of the slopes
211         zwx(:,:, 1 ) = 0._wp                   ! surface & bottom boundary conditions
212         zwx(:,:,jpk) = 0._wp                   ! surface & bottom boundary conditions
213         DO jk = 2, jpkm1                                     ! interior values
214            zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) )
215         END DO
216
217         !                                !-- Slopes of tracer
218         zslpx(:,:,1) = 0._wp                   ! surface values
219         DO jk = 2, jpkm1                       ! interior value
220            DO jj = 1, jpj
221               DO ji = 1, jpi
222                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )   &
223                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) ) )
224               END DO
225            END DO
226         END DO
227         !                                !-- Slopes limitation
228         DO jk = 2, jpkm1                       ! interior values
229            DO jj = 1, jpj
230               DO ji = 1, jpi
231                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
232                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
233                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
234               END DO
235            END DO
236         END DO
237         !                                !-- vertical advective flux
238         DO jk = 1, jpkm1                       ! interior values
239            zdt  = p2dt(jk)
240            DO jj = 2, jpjm1     
241               DO ji = fs_2, fs_jpim1   ! vector opt.
242                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
243                  zalpha = 0.5 + z0w
244                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * zdt  / ( e1e2t(ji,jj) * fse3w(ji,jj,jk+1) )
245                  zzwx = ptb(ji,jj,jk+1,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk+1)
246                  zzwy = ptb(ji,jj,jk  ,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk  )
247                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy ) * wmask(ji,jj,jk)
248               END DO
249            END DO
250         END DO
251         !                                      ! top values  (bottom already set to zero)
252         IF( lk_vvl ) THEN                            !  variable volume
253            zwx(:,:, 1 ) = 0._wp                            ! k=1 only as zwx has been multiplied by wmask
254         ELSE                                         ! linear free surface
255            IF( ln_isfcav ) THEN                            ! ice-shelf cavities (top of the ocean)
256               DO jj = 1, jpj
257                  DO ji = 1, jpi
258                     zwx(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)
259                  END DO
260               END DO   
261            ELSE                                             ! no cavities: only at the ocean surface
262               zwx(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
263            ENDIF
264         ENDIF
265         !
266         DO jk = 1, jpkm1                    ! Compute & add the vertical advective trend
267            DO jj = 2, jpjm1     
268               DO ji = fs_2, fs_jpim1   ! vector opt.
269                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) ) / ( e1e2t(ji,jj) * fse3t(ji,jj,jk) )
270               END DO
271            END DO
272         END DO
273         !                                 ! Save the vertical advective trends for diagnostic
274         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR.     &
275            &( cdtype == 'TRC' .AND. l_trdtrc )      )   &
276            CALL trd_tra( kt, cdtype, jn, jptra_zad, zwx, pwn, ptb(:,:,:,jn) )
277         !
278      END DO
279      !
280      CALL wrk_dealloc( jpi,jpj,jpk,   zslpx, zslpy, zwx, zwy )
281      !
282      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_mus')
283      !
284   END SUBROUTINE tra_adv_mus
285
286   !!======================================================================
287END MODULE traadv_mus
Note: See TracBrowser for help on using the repository browser.