source: branches/2014/dev_r4650_UKMO14.12_STAND_ALONE_OBSOPER/NEMOGCM/NEMO/OPA_SRC/TRA/trabbc.F90 @ 5600

Last change on this file since 5600 was 5600, checked in by andrewryan, 5 years ago

merged in latest version of trunk alongside changes to SAO_SRC to be compatible with latest OBS

  • Property svn:keywords set to Id
File size: 9.5 KB
Line 
1MODULE trabbc
2   !!==============================================================================
3   !!                       ***  MODULE  trabbc  ***
4   !! Ocean active tracers:  bottom boundary condition (geothermal heat flux)
5   !!==============================================================================
6   !! History :  OPA  ! 1999-10 (G. Madec)  original code
7   !!   NEMO     1.0  ! 2002-08 (G. Madec)  free form + modules
8   !!             -   ! 2002-11 (A. Bozec)  tra_bbc_init: original code
9   !!            3.3  ! 2010-10 (G. Madec)  dynamical allocation + suppression of key_trabbc
10   !!             -   ! 2010-11 (G. Madec)  use mbkt array (deepest ocean t-level)
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   tra_bbc      : update the tracer trend at ocean bottom
15   !!   tra_bbc_init : initialization of geothermal heat flux trend
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean variables
18   USE dom_oce         ! domain: ocean
19   USE phycst          ! physical constants
20   USE trd_oce         ! trends: ocean variables
21   USE trdtra          ! trends manager: tracers
22   USE in_out_manager  ! I/O manager
23   USE iom             ! I/O manager
24   USE fldread         ! read input fields
25   USE lbclnk            ! ocean lateral boundary conditions (or mpp link)
26   USE lib_mpp           ! distributed memory computing library
27   USE prtctl          ! Print control
28   USE wrk_nemo        ! Memory Allocation
29   USE timing          ! Timing
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC tra_bbc          ! routine called by step.F90
35   PUBLIC tra_bbc_init     ! routine called by opa.F90
36
37   !                                 !!* Namelist nambbc: bottom boundary condition *
38   LOGICAL, PUBLIC ::   ln_trabbc     !: Geothermal heat flux flag
39   INTEGER         ::   nn_geoflx     !  Geothermal flux (=1:constant flux, =2:read in file )
40   REAL(wp)        ::   rn_geoflx_cst !  Constant value of geothermal heat flux
41
42   REAL(wp), PUBLIC, DIMENSION(:,:), ALLOCATABLE ::   qgh_trd0   ! geothermal heating trend
43   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_qgh              ! structure of input qgh (file informations, fields read)
44 
45   !! * Substitutions
46#  include "domzgr_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
49   !! $Id$
50   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE tra_bbc( kt )
55      !!----------------------------------------------------------------------
56      !!                  ***  ROUTINE tra_bbc  ***
57      !!
58      !! ** Purpose :   Compute the bottom boundary contition on temperature
59      !!              associated with geothermal heating and add it to the
60      !!              general trend of temperature equations.
61      !!
62      !! ** Method  :   The geothermal heat flux set to its constant value of
63      !!              86.4 mW/m2 (Stein and Stein 1992, Huang 1999).
64      !!       The temperature trend associated to this heat flux through the
65      !!       ocean bottom can be computed once and is added to the temperature
66      !!       trend juste above the bottom at each time step:
67      !!            ta = ta + Qsf / (rau0 rcp e3T) for k= mbkt
68      !!       Where Qsf is the geothermal heat flux.
69      !!
70      !! ** Action  : - update the temperature trends (ta) with the trend of
71      !!                the ocean bottom boundary condition
72      !!
73      !! References : Stein, C. A., and S. Stein, 1992, Nature, 359, 123-129.
74      !!              Emile-Geay and Madec, 2009, Ocean Science.
75      !!----------------------------------------------------------------------
76      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
77      !!
78      INTEGER  ::   ji, jj, ik    ! dummy loop indices
79      REAL(wp) ::   zqgh_trd      ! geothermal heat flux trend
80      REAL(wp), POINTER, DIMENSION(:,:,:) ::   ztrdt
81      !!----------------------------------------------------------------------
82      !
83      IF( nn_timing == 1 )  CALL timing_start('tra_bbc')
84      !
85      IF( l_trdtra )   THEN         ! Save ta and sa trends
86         CALL wrk_alloc( jpi, jpj, jpk, ztrdt )
87         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
88      ENDIF
89      !
90      !                             !  Add the geothermal heat flux trend on temperature
91      DO jj = 2, jpjm1
92         DO ji = 2, jpim1
93            ik = mbkt(ji,jj)
94            zqgh_trd = qgh_trd0(ji,jj) / fse3t(ji,jj,ik)
95            tsa(ji,jj,ik,jp_tem) = tsa(ji,jj,ik,jp_tem) + zqgh_trd
96         END DO
97      END DO
98      !
99      CALL lbc_lnk( tsa(:,:,:,jp_tem) , 'T', 1. )
100      !
101      IF( l_trdtra ) THEN        ! Save the geothermal heat flux trend for diagnostics
102         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:)
103         CALL trd_tra( kt, 'TRA', jp_tem, jptra_bbc, ztrdt )
104         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt )
105      ENDIF
106      !
107      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' bbc  - Ta: ', mask1=tmask, clinfo3='tra-ta' )
108      !
109      IF( nn_timing == 1 )  CALL timing_stop('tra_bbc')
110      !
111   END SUBROUTINE tra_bbc
112
113
114   SUBROUTINE tra_bbc_init
115      !!----------------------------------------------------------------------
116      !!                  ***  ROUTINE tra_bbc_init  ***
117      !!
118      !! ** Purpose :   Compute once for all the trend associated with geothermal
119      !!              heating that will be applied at each time step at the
120      !!              last ocean level
121      !!
122      !! ** Method  :   Read the nambbc namelist and check the parameters.
123      !!
124      !! ** Input   : - Namlist nambbc
125      !!              - NetCDF file  : geothermal_heating.nc ( if necessary )
126      !!
127      !! ** Action  : - read/fix the geothermal heat qgh_trd0
128      !!----------------------------------------------------------------------
129      USE iom
130      !!
131      INTEGER  ::   ji, jj              ! dummy loop indices
132      INTEGER  ::   inum                ! temporary logical unit
133      INTEGER  ::   ios                 ! Local integer output status for namelist read
134      INTEGER  ::   ierror              ! local integer
135      !
136      TYPE(FLD_N)        ::   sn_qgh    ! informations about the geotherm. field to be read
137      CHARACTER(len=256) ::   cn_dir    ! Root directory for location of ssr files
138      !
139      NAMELIST/nambbc/ln_trabbc, nn_geoflx, rn_geoflx_cst, sn_qgh, cn_dir 
140      !!----------------------------------------------------------------------
141
142      REWIND( numnam_ref )              ! Namelist nambbc in reference namelist : Bottom momentum boundary condition
143      READ  ( numnam_ref, nambbc, IOSTAT = ios, ERR = 901)
144901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nambbc in reference namelist', lwp )
145
146      REWIND( numnam_cfg )              ! Namelist nambbc in configuration namelist : Bottom momentum boundary condition
147      READ  ( numnam_cfg, nambbc, IOSTAT = ios, ERR = 902 )
148902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nambbc in configuration namelist', lwp )
149      IF(lwm) WRITE ( numond, nambbc )
150
151      IF(lwp) THEN                     ! Control print
152         WRITE(numout,*)
153         WRITE(numout,*) 'tra_bbc : Bottom Boundary Condition (bbc), apply a Geothermal heating'
154         WRITE(numout,*) '~~~~~~~   '
155         WRITE(numout,*) '   Namelist nambbc : set bbc parameters'
156         WRITE(numout,*) '      Apply a geothermal heating at ocean bottom   ln_trabbc     = ', ln_trabbc
157         WRITE(numout,*) '      type of geothermal flux                      nn_geoflx     = ', nn_geoflx
158         WRITE(numout,*) '      Constant geothermal flux value               rn_geoflx_cst = ', rn_geoflx_cst
159         WRITE(numout,*)
160      ENDIF
161
162      IF( ln_trabbc ) THEN             !==  geothermal heating  ==!
163         !
164         ALLOCATE( qgh_trd0(jpi,jpj) )    ! allocation
165         !
166         SELECT CASE ( nn_geoflx )        ! geothermal heat flux / (rauO * Cp)
167         !
168         CASE ( 1 )                          !* constant flux
169            IF(lwp) WRITE(numout,*) '      *** constant heat flux  =   ', rn_geoflx_cst
170            qgh_trd0(:,:) = r1_rau0_rcp * rn_geoflx_cst
171            !
172         CASE ( 2 )                          !* variable geothermal heat flux : read the geothermal fluxes in mW/m2
173            IF(lwp) WRITE(numout,*) '      *** variable geothermal heat flux'
174            !
175            ALLOCATE( sf_qgh(1), STAT=ierror )
176            IF( ierror > 0 ) THEN
177               CALL ctl_stop( 'tra_bbc_init: unable to allocate sf_qgh structure' )   ;
178               RETURN
179            ENDIF
180            ALLOCATE( sf_qgh(1)%fnow(jpi,jpj,1)   )
181            IF( sn_qgh%ln_tint )ALLOCATE( sf_qgh(1)%fdta(jpi,jpj,1,2) )
182            ! fill sf_chl with sn_chl and control print
183            CALL fld_fill( sf_qgh, (/ sn_qgh /), cn_dir, 'tra_bbc_init',   &
184               &          'bottom temperature boundary condition', 'nambbc' )
185
186            CALL fld_read( nit000, 1, sf_qgh )                         ! Read qgh data
187            qgh_trd0(:,:) = r1_rau0_rcp * sf_qgh(1)%fnow(:,:,1) * 1.e-3 ! conversion in W/m2
188            !
189         CASE DEFAULT
190            WRITE(ctmp1,*) '     bad flag value for nn_geoflx = ', nn_geoflx
191            CALL ctl_stop( ctmp1 )
192            !
193         END SELECT
194         !
195      ELSE
196         IF(lwp) WRITE(numout,*) '      *** no geothermal heat flux'
197      ENDIF
198      !
199   END SUBROUTINE tra_bbc_init
200
201   !!======================================================================
202END MODULE trabbc
Note: See TracBrowser for help on using the repository browser.