New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traqsr.F90 in branches/2014/dev_r4650_UKMO14.12_STAND_ALONE_OBSOPER/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2014/dev_r4650_UKMO14.12_STAND_ALONE_OBSOPER/NEMOGCM/NEMO/OPA_SRC/TRA/traqsr.F90 @ 5034

Last change on this file since 5034 was 5034, checked in by andrewryan, 9 years ago

merge with trunk

  • Property svn:keywords set to Id
File size: 29.9 KB
Line 
1MODULE traqsr
2   !!======================================================================
3   !!                       ***  MODULE  traqsr  ***
4   !! Ocean physics: solar radiation penetration in the top ocean levels
5   !!======================================================================
6   !! History :  OPA  !  1990-10  (B. Blanke)  Original code
7   !!            7.0  !  1991-11  (G. Madec)
8   !!                 !  1996-01  (G. Madec)  s-coordinates
9   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
10   !!             -   !  2005-11  (G. Madec) zco, zps, sco coordinate
11   !!            3.2  !  2009-04  (G. Madec & NEMO team)
12   !!            4.0  !  2012-05  (C. Rousset) store attenuation coef for use in ice model
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   tra_qsr      : trend due to the solar radiation penetration
17   !!   tra_qsr_init : solar radiation penetration initialization
18   !!----------------------------------------------------------------------
19   USE oce             ! ocean dynamics and active tracers
20   USE dom_oce         ! ocean space and time domain
21   USE sbc_oce         ! surface boundary condition: ocean
22   USE trc_oce         ! share SMS/Ocean variables
23   USE trd_oce        ! trends: ocean variables
24   USE trdtra         ! trends manager: tracers
25   USE in_out_manager  ! I/O manager
26   USE phycst          ! physical constants
27   USE prtctl          ! Print control
28   USE iom             ! I/O manager
29   USE fldread         ! read input fields
30   USE restart         ! ocean restart
31   USE lib_mpp         ! MPP library
32   USE wrk_nemo       ! Memory Allocation
33   USE timing         ! Timing
34   USE sbc_ice, ONLY : lk_lim3
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   tra_qsr       ! routine called by step.F90 (ln_traqsr=T)
40   PUBLIC   tra_qsr_init  ! routine called by opa.F90
41
42   !                                 !!* Namelist namtra_qsr: penetrative solar radiation
43   LOGICAL , PUBLIC ::   ln_traqsr    !: light absorption (qsr) flag
44   LOGICAL , PUBLIC ::   ln_qsr_rgb   !: Red-Green-Blue light absorption flag 
45   LOGICAL , PUBLIC ::   ln_qsr_2bd   !: 2 band         light absorption flag
46   LOGICAL , PUBLIC ::   ln_qsr_bio   !: bio-model      light absorption flag
47   LOGICAL , PUBLIC ::   ln_qsr_ice   !: light penetration for ice-model LIM3 (clem)
48   INTEGER , PUBLIC ::   nn_chldta    !: use Chlorophyll data (=1) or not (=0)
49   REAL(wp), PUBLIC ::   rn_abs       !: fraction absorbed in the very near surface (RGB & 2 bands)
50   REAL(wp), PUBLIC ::   rn_si0       !: very near surface depth of extinction      (RGB & 2 bands)
51   REAL(wp), PUBLIC ::   rn_si1       !: deepest depth of extinction (water type I)       (2 bands)
52   
53   ! Module variables
54   REAL(wp) ::   xsi0r                           !: inverse of rn_si0
55   REAL(wp) ::   xsi1r                           !: inverse of rn_si1
56   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_chl   ! structure of input Chl (file informations, fields read)
57   INTEGER, PUBLIC ::   nksr              ! levels below which the light cannot penetrate ( depth larger than 391 m)
58   REAL(wp), DIMENSION(3,61) ::   rkrgb   !: tabulated attenuation coefficients for RGB absorption
59
60   !! * Substitutions
61#  include "domzgr_substitute.h90"
62#  include "vectopt_loop_substitute.h90"
63   !!----------------------------------------------------------------------
64   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
65   !! $Id$
66   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
67   !!----------------------------------------------------------------------
68CONTAINS
69
70   SUBROUTINE tra_qsr( kt )
71      !!----------------------------------------------------------------------
72      !!                  ***  ROUTINE tra_qsr  ***
73      !!
74      !! ** Purpose :   Compute the temperature trend due to the solar radiation
75      !!      penetration and add it to the general temperature trend.
76      !!
77      !! ** Method  : The profile of the solar radiation within the ocean is defined
78      !!      through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs
79      !!      Considering the 2 wavebands case:
80      !!         I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) )
81      !!         The temperature trend associated with the solar radiation penetration
82      !!         is given by : zta = 1/e3t dk[ I ] / (rau0*Cp)
83      !!         At the bottom, boudary condition for the radiation is no flux :
84      !!      all heat which has not been absorbed in the above levels is put
85      !!      in the last ocean level.
86      !!         In z-coordinate case, the computation is only done down to the
87      !!      level where I(k) < 1.e-15 W/m2. In addition, the coefficients
88      !!      used for the computation are calculated one for once as they
89      !!      depends on k only.
90      !!
91      !! ** Action  : - update ta with the penetrative solar radiation trend
92      !!              - save the trend in ttrd ('key_trdtra')
93      !!
94      !! Reference  : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
95      !!              Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516.
96      !!----------------------------------------------------------------------
97      !
98      INTEGER, INTENT(in) ::   kt     ! ocean time-step
99      !
100      INTEGER  ::   ji, jj, jk           ! dummy loop indices
101      INTEGER  ::   irgb                 ! local integers
102      REAL(wp) ::   zchl, zcoef, zfact   ! local scalars
103      REAL(wp) ::   zc0, zc1, zc2, zc3   !    -         -
104      REAL(wp) ::   zzc0, zzc1, zzc2, zzc3   !    -         -
105      REAL(wp) ::   zz0, zz1, z1_e3t     !    -         -
106      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
107      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea, ztrdt
108      !!----------------------------------------------------------------------
109      !
110      IF( nn_timing == 1 )  CALL timing_start('tra_qsr')
111      !
112      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        ) 
113      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
114      !
115      IF( kt == nit000 ) THEN
116         IF(lwp) WRITE(numout,*)
117         IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation'
118         IF(lwp) WRITE(numout,*) '~~~~~~~'
119         IF( .NOT.ln_traqsr )   RETURN
120      ENDIF
121
122      IF( l_trdtra ) THEN      ! Save ta and sa trends
123         CALL wrk_alloc( jpi, jpj, jpk, ztrdt ) 
124         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
125      ENDIF
126
127      !                                        Set before qsr tracer content field
128      !                                        ***********************************
129      IF( kt == nit000 ) THEN                     ! Set the forcing field at nit000 - 1
130         !                                        ! -----------------------------------
131         qsr_hc(:,:,:) = 0.e0
132         !
133         IF( ln_rstart .AND.    &                    ! Restart: read in restart file
134              & iom_varid( numror, 'qsr_hc_b', ldstop = .FALSE. ) > 0 ) THEN
135            IF(lwp) WRITE(numout,*) '          nit000-1 qsr tracer content forcing field red in the restart file'
136            zfact = 0.5e0
137            CALL iom_get( numror, jpdom_autoglo, 'qsr_hc_b', qsr_hc_b )   ! before heat content trend due to Qsr flux
138         ELSE                                           ! No restart or restart not found: Euler forward time stepping
139            zfact = 1.e0
140            qsr_hc_b(:,:,:) = 0.e0
141         ENDIF
142      ELSE                                        ! Swap of forcing field
143         !                                        ! ---------------------
144         zfact = 0.5e0
145         qsr_hc_b(:,:,:) = qsr_hc(:,:,:)
146      ENDIF
147      !                                        Compute now qsr tracer content field
148      !                                        ************************************
149     
150      !                                           ! ============================================== !
151      IF( lk_qsr_bio .AND. ln_qsr_bio ) THEN      !  bio-model fluxes  : all vertical coordinates  !
152         !                                        ! ============================================== !
153         DO jk = 1, jpkm1
154            qsr_hc(:,:,jk) = r1_rau0_rcp * ( etot3(:,:,jk) - etot3(:,:,jk+1) )
155         END DO
156         !                                        Add to the general trend
157         DO jk = 1, jpkm1
158            DO jj = 2, jpjm1 
159               DO ji = fs_2, fs_jpim1   ! vector opt.
160                  z1_e3t = zfact / fse3t(ji,jj,jk)
161                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
162               END DO
163            END DO
164         END DO
165         CALL iom_put( 'qsr3d', etot3 )   ! Shortwave Radiation 3D distribution
166         ! clem: store attenuation coefficient of the first ocean level
167         IF ( lk_lim3 .AND. ln_qsr_ice ) THEN
168            DO jj = 1, jpj
169               DO ji = 1, jpi
170                  IF ( qsr(ji,jj) /= 0._wp ) THEN
171                     fraqsr_1lev(ji,jj) = ( qsr_hc(ji,jj,1) / ( r1_rau0_rcp * qsr(ji,jj) ) )
172                  ENDIF
173               END DO
174            END DO
175         ENDIF
176         !                                        ! ============================================== !
177      ELSE                                        !  Ocean alone :
178         !                                        ! ============================================== !
179         !
180         !                                                ! ------------------------- !
181         IF( ln_qsr_rgb) THEN                             !  R-G-B  light penetration !
182            !                                             ! ------------------------- !
183            ! Set chlorophyl concentration
184            IF( nn_chldta == 1 .OR. lk_vvl ) THEN            !*  Variable Chlorophyll or ocean volume
185               !
186               IF( nn_chldta == 1 ) THEN                             !*  Variable Chlorophyll
187                  !
188                  CALL fld_read( kt, 1, sf_chl )                         ! Read Chl data and provides it at the current time step
189                  !         
190!CDIR COLLAPSE
191!CDIR NOVERRCHK
192                  DO jj = 1, jpj                                         ! Separation in R-G-B depending of the surface Chl
193!CDIR NOVERRCHK
194                     DO ji = 1, jpi
195                        zchl = MIN( 10. , MAX( 0.03, sf_chl(1)%fnow(ji,jj,1) ) )
196                        irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
197                        zekb(ji,jj) = rkrgb(1,irgb)
198                        zekg(ji,jj) = rkrgb(2,irgb)
199                        zekr(ji,jj) = rkrgb(3,irgb)
200                     END DO
201                  END DO
202               ELSE                                            ! Variable ocean volume but constant chrlorophyll
203                  zchl = 0.05                                     ! constant chlorophyll
204                  irgb = NINT( 41 + 20.*LOG10( zchl ) + 1.e-15 )
205                  zekb(:,:) = rkrgb(1,irgb)                       ! Separation in R-G-B depending of the chlorophyll
206                  zekg(:,:) = rkrgb(2,irgb)
207                  zekr(:,:) = rkrgb(3,irgb)
208               ENDIF
209               !
210               zcoef  = ( 1. - rn_abs ) / 3.e0                        ! equi-partition in R-G-B
211               ze0(:,:,1) = rn_abs  * qsr(:,:)
212               ze1(:,:,1) = zcoef * qsr(:,:)
213               ze2(:,:,1) = zcoef * qsr(:,:)
214               ze3(:,:,1) = zcoef * qsr(:,:)
215               zea(:,:,1) =         qsr(:,:)
216               !
217               DO jk = 2, nksr+1
218!CDIR NOVERRCHK
219                  DO jj = 1, jpj
220!CDIR NOVERRCHK   
221                     DO ji = 1, jpi
222                        zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r     )
223                        zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) )
224                        zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) )
225                        zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) )
226                        ze0(ji,jj,jk) = zc0
227                        ze1(ji,jj,jk) = zc1
228                        ze2(ji,jj,jk) = zc2
229                        ze3(ji,jj,jk) = zc3
230                        zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
231                     END DO
232                  END DO
233               END DO
234               ! clem: store attenuation coefficient of the first ocean level
235               IF ( lk_lim3 .AND. ln_qsr_ice ) THEN
236                  DO jj = 1, jpj
237                     DO ji = 1, jpi
238                        zzc0 = rn_abs * EXP( - fse3t(ji,jj,1) * xsi0r     )
239                        zzc1 = zcoef  * EXP( - fse3t(ji,jj,1) * zekb(ji,jj) )
240                        zzc2 = zcoef  * EXP( - fse3t(ji,jj,1) * zekg(ji,jj) )
241                        zzc3 = zcoef  * EXP( - fse3t(ji,jj,1) * zekr(ji,jj) )
242                        fraqsr_1lev(ji,jj) = 1.0 - ( zzc0 + zzc1 + zzc2  + zzc3  ) * tmask(ji,jj,2) 
243                     END DO
244                  END DO
245               ENDIF
246               !
247               DO jk = 1, nksr                                        ! compute and add qsr trend to ta
248                  qsr_hc(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) )
249               END DO
250               zea(:,:,nksr+1:jpk) = 0.e0     ! below 400m set to zero
251               CALL iom_put( 'qsr3d', zea )   ! Shortwave Radiation 3D distribution
252               !
253            ELSE                                                 !*  Constant Chlorophyll
254               DO jk = 1, nksr
255                  qsr_hc(:,:,jk) =  etot3(:,:,jk) * qsr(:,:)
256               END DO
257               ! clem: store attenuation coefficient of the first ocean level
258               IF ( lk_lim3 .AND. ln_qsr_ice ) THEN
259                  fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp
260               ENDIF
261           ENDIF
262
263         ENDIF
264         !                                                ! ------------------------- !
265         IF( ln_qsr_2bd ) THEN                            !  2 band light penetration !
266            !                                             ! ------------------------- !
267            !
268            IF( lk_vvl ) THEN                                  !* variable volume
269               zz0   =        rn_abs   * r1_rau0_rcp
270               zz1   = ( 1. - rn_abs ) * r1_rau0_rcp
271               DO jk = 1, nksr                    ! solar heat absorbed at T-point in the top 400m
272                  DO jj = 1, jpj
273                     DO ji = 1, jpi
274                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
275                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
276                        qsr_hc(ji,jj,jk) = qsr(ji,jj) * ( zc0*tmask(ji,jj,jk) - zc1*tmask(ji,jj,jk+1) ) 
277                     END DO
278                  END DO
279               END DO
280               ! clem: store attenuation coefficient of the first ocean level
281               IF ( lk_lim3 .AND. ln_qsr_ice ) THEN
282                  DO jj = 1, jpj
283                     DO ji = 1, jpi
284                        zc0 = zz0 * EXP( -fsdepw(ji,jj,1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,1)*xsi1r )
285                        zc1 = zz0 * EXP( -fsdepw(ji,jj,2)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,2)*xsi1r )
286                        fraqsr_1lev(ji,jj) = ( zc0*tmask(ji,jj,1) - zc1*tmask(ji,jj,2) ) / r1_rau0_rcp
287                     END DO
288                  END DO
289               ENDIF
290            ELSE                                               !* constant volume: coef. computed one for all
291               DO jk = 1, nksr
292                  DO jj = 2, jpjm1
293                     DO ji = fs_2, fs_jpim1   ! vector opt.
294                        ! (ISF) no light penetration below the ice shelves         
295                        qsr_hc(ji,jj,jk) =  etot3(ji,jj,jk) * qsr(ji,jj) * tmask(ji,jj,1)
296                     END DO
297                  END DO
298               END DO
299               ! clem: store attenuation coefficient of the first ocean level
300               IF ( lk_lim3 .AND. ln_qsr_ice ) THEN
301                  fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp
302               ENDIF
303               !
304            ENDIF
305            !
306         ENDIF
307         !
308         !                                        Add to the general trend
309         DO jk = 1, nksr
310            DO jj = 2, jpjm1 
311               DO ji = fs_2, fs_jpim1   ! vector opt.
312                  z1_e3t = zfact / fse3t(ji,jj,jk)
313                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
314               END DO
315            END DO
316         END DO
317         !
318      ENDIF
319      !
320      IF( lrst_oce ) THEN   !                  Write in the ocean restart file
321         !                                     *******************************
322         IF(lwp) WRITE(numout,*)
323         IF(lwp) WRITE(numout,*) 'qsr tracer content forcing field written in ocean restart file ',   &
324            &                    'at it= ', kt,' date= ', ndastp
325         IF(lwp) WRITE(numout,*) '~~~~'
326         CALL iom_rstput( kt, nitrst, numrow, 'qsr_hc_b', qsr_hc )
327         !
328      ENDIF
329
330      IF( l_trdtra ) THEN     ! qsr tracers trends saved for diagnostics
331         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:)
332         CALL trd_tra( kt, 'TRA', jp_tem, jptra_qsr, ztrdt )
333         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt ) 
334      ENDIF
335      !                       ! print mean trends (used for debugging)
336      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' qsr  - Ta: ', mask1=tmask, clinfo3='tra-ta' )
337      !
338      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        ) 
339      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
340      !
341      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr')
342      !
343   END SUBROUTINE tra_qsr
344
345
346   SUBROUTINE tra_qsr_init
347      !!----------------------------------------------------------------------
348      !!                  ***  ROUTINE tra_qsr_init  ***
349      !!
350      !! ** Purpose :   Initialization for the penetrative solar radiation
351      !!
352      !! ** Method  :   The profile of solar radiation within the ocean is set
353      !!      from two length scale of penetration (rn_si0,rn_si1) and a ratio
354      !!      (rn_abs). These parameters are read in the namtra_qsr namelist. The
355      !!      default values correspond to clear water (type I in Jerlov'
356      !!      (1968) classification.
357      !!         called by tra_qsr at the first timestep (nit000)
358      !!
359      !! ** Action  : - initialize rn_si0, rn_si1 and rn_abs
360      !!
361      !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
362      !!----------------------------------------------------------------------
363      !
364      INTEGER  ::   ji, jj, jk                   ! dummy loop indices
365      INTEGER  ::   irgb, ierror, ioptio, nqsr   ! local integer
366      INTEGER  ::   ios                          ! Local integer output status for namelist read
367      REAL(wp) ::   zz0, zc0  , zc1, zcoef       ! local scalars
368      REAL(wp) ::   zz1, zc2  , zc3, zchl        !   -      -
369      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
370      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea
371      !
372      CHARACTER(len=100) ::   cn_dir   ! Root directory for location of ssr files
373      TYPE(FLD_N)        ::   sn_chl   ! informations about the chlorofyl field to be read
374      !!
375      NAMELIST/namtra_qsr/  sn_chl, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio, ln_qsr_ice,  &
376         &                  nn_chldta, rn_abs, rn_si0, rn_si1
377      !!----------------------------------------------------------------------
378
379      !
380      IF( nn_timing == 1 )  CALL timing_start('tra_qsr_init')
381      !
382      ! Default value for fraqsr_1lev
383      IF( .NOT. ln_rstart ) THEN
384         fraqsr_1lev(:,:) = 1._wp
385      ENDIF
386      !
387      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        ) 
388      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
389      !
390
391      REWIND( numnam_ref )              ! Namelist namtra_qsr in reference namelist : Ratio and length of penetration
392      READ  ( numnam_ref, namtra_qsr, IOSTAT = ios, ERR = 901)
393901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in reference namelist', lwp )
394
395      REWIND( numnam_cfg )              !  Namelist namtra_qsr in configuration namelist : Ratio and length of penetration
396      READ  ( numnam_cfg, namtra_qsr, IOSTAT = ios, ERR = 902 )
397902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in configuration namelist', lwp )
398      IF(lwm) WRITE ( numond, namtra_qsr )
399      !
400      IF(lwp) THEN                ! control print
401         WRITE(numout,*)
402         WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation'
403         WRITE(numout,*) '~~~~~~~~~~~~'
404         WRITE(numout,*) '   Namelist namtra_qsr : set the parameter of penetration'
405         WRITE(numout,*) '      Light penetration (T) or not (F)         ln_traqsr  = ', ln_traqsr
406         WRITE(numout,*) '      RGB (Red-Green-Blue) light penetration   ln_qsr_rgb = ', ln_qsr_rgb
407         WRITE(numout,*) '      2 band               light penetration   ln_qsr_2bd = ', ln_qsr_2bd
408         WRITE(numout,*) '      bio-model            light penetration   ln_qsr_bio = ', ln_qsr_bio
409         WRITE(numout,*) '      light penetration for ice-model LIM3     ln_qsr_ice = ', ln_qsr_ice
410         WRITE(numout,*) '      RGB : Chl data (=1) or cst value (=0)    nn_chldta  = ', nn_chldta
411         WRITE(numout,*) '      RGB & 2 bands: fraction of light (rn_si1)    rn_abs = ', rn_abs
412         WRITE(numout,*) '      RGB & 2 bands: shortess depth of extinction  rn_si0 = ', rn_si0
413         WRITE(numout,*) '      2 bands: longest depth of extinction         rn_si1 = ', rn_si1
414         WRITE(numout,*) '      light penetration for ice-model LIM3     ln_qsr_ice = ', ln_qsr_ice   
415      ENDIF
416
417      IF( ln_traqsr ) THEN     ! control consistency
418         !                     
419         IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio )   THEN
420            CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' )
421            ln_qsr_bio = .FALSE.
422         ENDIF
423         !
424         ioptio = 0                      ! Parameter control
425         IF( ln_qsr_rgb  )   ioptio = ioptio + 1
426         IF( ln_qsr_2bd  )   ioptio = ioptio + 1
427         IF( ln_qsr_bio  )   ioptio = ioptio + 1
428         !
429         IF( ioptio /= 1 ) &
430            CALL ctl_stop( '          Choose ONE type of light penetration in namelist namtra_qsr',  &
431            &              ' 2 bands, 3 RGB bands or bio-model light penetration' )
432         !
433         IF( ln_qsr_rgb .AND. nn_chldta == 0 )   nqsr =  1 
434         IF( ln_qsr_rgb .AND. nn_chldta == 1 )   nqsr =  2
435         IF( ln_qsr_2bd                      )   nqsr =  3
436         IF( ln_qsr_bio                      )   nqsr =  4
437         !
438         IF(lwp) THEN                   ! Print the choice
439            WRITE(numout,*)
440            IF( nqsr ==  1 )   WRITE(numout,*) '         R-G-B   light penetration - Constant Chlorophyll'
441            IF( nqsr ==  2 )   WRITE(numout,*) '         R-G-B   light penetration - Chl data '
442            IF( nqsr ==  3 )   WRITE(numout,*) '         2 bands light penetration'
443            IF( nqsr ==  4 )   WRITE(numout,*) '         bio-model light penetration'
444         ENDIF
445         !
446      ENDIF
447      !                          ! ===================================== !
448      IF( ln_traqsr  ) THEN      !  Initialisation of Light Penetration  ! 
449         !                       ! ===================================== !
450         !
451         xsi0r = 1.e0 / rn_si0
452         xsi1r = 1.e0 / rn_si1
453         !                                ! ---------------------------------- !
454         IF( ln_qsr_rgb ) THEN            !  Red-Green-Blue light penetration  !
455            !                             ! ---------------------------------- !
456            !
457            CALL trc_oce_rgb( rkrgb )           !* tabulated attenuation coef.
458            !
459            !                                   !* level of light extinction
460            IF(  ln_sco ) THEN   ;   nksr = jpkm1
461            ELSE                 ;   nksr = trc_oce_ext_lev( r_si2, 0.33e2 )
462            ENDIF
463
464            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m'
465            !
466            IF( nn_chldta == 1 ) THEN           !* Chl data : set sf_chl structure
467               IF(lwp) WRITE(numout,*)
468               IF(lwp) WRITE(numout,*) '        Chlorophyll read in a file'
469               ALLOCATE( sf_chl(1), STAT=ierror )
470               IF( ierror > 0 ) THEN
471                  CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' )   ;   RETURN
472               ENDIF
473               ALLOCATE( sf_chl(1)%fnow(jpi,jpj,1)   )
474               IF( sn_chl%ln_tint )ALLOCATE( sf_chl(1)%fdta(jpi,jpj,1,2) )
475               !                                        ! fill sf_chl with sn_chl and control print
476               CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init',   &
477                  &                                         'Solar penetration function of read chlorophyll', 'namtra_qsr' )
478               !
479            ELSE                                !* constant Chl : compute once for all the distribution of light (etot3)
480               IF(lwp) WRITE(numout,*)
481               IF(lwp) WRITE(numout,*) '        Constant Chlorophyll concentration = 0.05'
482               IF( lk_vvl ) THEN                   ! variable volume
483                  IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
484               ELSE                                ! constant volume: computes one for all
485                  IF(lwp) WRITE(numout,*) '        fixed volume: light distribution computed one for all'
486                  !
487                  zchl = 0.05                                 ! constant chlorophyll
488                  irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
489                  zekb(:,:) = rkrgb(1,irgb)                   ! Separation in R-G-B depending of the chlorophyll
490                  zekg(:,:) = rkrgb(2,irgb)
491                  zekr(:,:) = rkrgb(3,irgb)
492                  !
493                  zcoef = ( 1. - rn_abs ) / 3.e0              ! equi-partition in R-G-B
494                  ze0(:,:,1) = rn_abs
495                  ze1(:,:,1) = zcoef
496                  ze2(:,:,1) = zcoef 
497                  ze3(:,:,1) = zcoef
498                  zea(:,:,1) = tmask(:,:,1)                   ! = ( ze0+ze1+z2+ze3 ) * tmask
499               
500                  DO jk = 2, nksr+1
501!CDIR NOVERRCHK
502                     DO jj = 1, jpj
503!CDIR NOVERRCHK   
504                        DO ji = 1, jpi
505                           zc0 = ze0(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * xsi0r     )
506                           zc1 = ze1(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekb(ji,jj) )
507                           zc2 = ze2(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekg(ji,jj) )
508                           zc3 = ze3(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekr(ji,jj) )
509                           ze0(ji,jj,jk) = zc0
510                           ze1(ji,jj,jk) = zc1
511                           ze2(ji,jj,jk) = zc2
512                           ze3(ji,jj,jk) = zc3
513                           zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
514                        END DO
515                     END DO
516                  END DO 
517                  !
518                  DO jk = 1, nksr
519                     ! (ISF) no light penetration below the ice shelves
520                     etot3(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) ) * tmask(:,:,1)
521                  END DO
522                  etot3(:,:,nksr+1:jpk) = 0.e0                ! below 400m set to zero
523               ENDIF
524            ENDIF
525            !
526         ENDIF
527            !                             ! ---------------------------------- !
528         IF( ln_qsr_2bd ) THEN            !    2 bands    light penetration    !
529            !                             ! ---------------------------------- !
530            !
531            !                                ! level of light extinction
532            nksr = trc_oce_ext_lev( rn_si1, 1.e2 )
533            IF(lwp) THEN
534               WRITE(numout,*)
535            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m'
536            ENDIF
537            !
538            IF( lk_vvl ) THEN                   ! variable volume
539               IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
540            ELSE                                ! constant volume: computes one for all
541               zz0 =        rn_abs   * r1_rau0_rcp
542               zz1 = ( 1. - rn_abs ) * r1_rau0_rcp
543               DO jk = 1, nksr                    !*  solar heat absorbed at T-point computed once for all
544                  DO jj = 1, jpj                              ! top 400 meters
545                     DO ji = 1, jpi
546                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
547                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
548                        etot3(ji,jj,jk) = (  zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1)  ) * tmask(ji,jj,1) 
549                     END DO
550                  END DO
551               END DO
552               etot3(:,:,nksr+1:jpk) = 0.e0                   ! below 400m set to zero
553               !
554            ENDIF
555         ENDIF
556         !                       ! ===================================== !
557      ELSE                       !        No light penetration           !                   
558         !                       ! ===================================== !
559         IF(lwp) THEN
560            WRITE(numout,*)
561            WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration'
562            WRITE(numout,*) '~~~~~~~~~~~~'
563         ENDIF
564      ENDIF
565      !
566      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        ) 
567      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
568      !
569      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr_init')
570      !
571   END SUBROUTINE tra_qsr_init
572
573   !!======================================================================
574END MODULE traqsr
Note: See TracBrowser for help on using the repository browser.