source: branches/2014/dev_r4650_UKMO14.12_STAND_ALONE_OBSOPER/NEMOGCM/NEMO/TOP_SRC/PISCES/P2Z/p2zexp.F90 @ 5600

Last change on this file since 5600 was 5600, checked in by andrewryan, 5 years ago

merged in latest version of trunk alongside changes to SAO_SRC to be compatible with latest OBS

  • Property svn:keywords set to Id
File size: 11.8 KB
Line 
1MODULE p2zexp
2   !!======================================================================
3   !!                         ***  MODULE p2zsed  ***
4   !! TOP :   LOBSTER Compute loss of organic matter in the sediments
5   !!======================================================================
6   !! History :    -   !  1999    (O. Aumont, C. Le Quere)  original code
7   !!              -   !  2001-05 (O. Aumont, E. Kestenare) add sediment computations
8   !!             1.0  !  2005-06 (A.-S. Kremeur) new temporal integration for sedpoc
9   !!             2.0  !  2007-12  (C. Deltel, G. Madec)  F90
10   !!             3.5  !  2012-03  (C. Ethe)  Merge PISCES-LOBSTER
11   !!----------------------------------------------------------------------
12#if defined key_pisces_reduced
13   !!----------------------------------------------------------------------
14   !!   'key_pisces_reduced'                                     LOBSTER bio-model
15   !!----------------------------------------------------------------------
16   !!   p2z_exp        :  Compute loss of organic matter in the sediments
17   !!----------------------------------------------------------------------
18   USE oce_trc         !
19   USE trc
20   USE sms_pisces
21   USE p2zsed
22   USE lbclnk
23   USE prtctl_trc      ! Print control for debbuging
24   USE trd_oce
25   USE trdtrc
26   USE iom
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   p2z_exp   
32   PUBLIC   p2z_exp_init 
33   PUBLIC   p2z_exp_alloc
34
35   !
36   REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   dminl     !: fraction of sinking POC released in sediments
37   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   dmin3     !: fraction of sinking POC released at each level
38   REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   sedpocb   !: mass of POC in sediments
39   REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   sedpocn   !: mass of POC in sediments
40   REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   cmask     !: Coastal mask area
41   REAL(wp)                                ::   areacot   !: surface coastal area
42
43   !!* Substitution
44#  include "top_substitute.h90"
45   !!----------------------------------------------------------------------
46   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
47   !! $Id$
48   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50
51CONTAINS
52
53   SUBROUTINE p2z_exp( kt )
54      !!---------------------------------------------------------------------
55      !!                     ***  ROUTINE p2z_exp  ***
56      !!
57      !! ** Purpose :   MODELS EXPORT OF BIOGENIC MATTER (POC ''SOFT
58      !!              TISSUE'') AND ITS DISTRIBUTION IN WATER COLUMN
59      !!
60      !! ** Method  : - IN THE SURFACE LAYER POC IS PRODUCED ACCORDING TO
61      !!              NURTRIENTS AVAILABLE AND GROWTH CONDITIONS. NUTRIENT UPTAKE
62      !!              KINETICS FOLLOW MICHAELIS-MENTON FORMULATION.
63      !!              THE TOTAL PARTICLE AMOUNT PRODUCED, IS DISTRIBUTED IN THE WATER
64      !!              COLUMN BELOW THE SURFACE LAYER.
65      !!---------------------------------------------------------------------
66      !!
67      INTEGER, INTENT( in ) ::   kt      ! ocean time-step index     
68      !!
69      INTEGER  ::   ji, jj, jk, jl, ikt
70      REAL(wp) ::   zgeolpoc, zfact, zwork, ze3t, zsedpocd, zmaskt
71      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrbio
72      REAL(wp), POINTER, DIMENSION(:,:)   ::  zsedpoca
73      CHARACTER (len=25) :: charout
74      !!---------------------------------------------------------------------
75      !
76      IF( nn_timing == 1 )  CALL timing_start('p2z_exp')
77      !
78      IF( kt == nittrc000 )   CALL p2z_exp_init
79
80      CALL wrk_alloc( jpi, jpj, zsedpoca ) 
81      zsedpoca(:,:) = 0.
82
83      IF( l_trdtrc )  THEN
84         CALL wrk_alloc( jpi, jpj, jpk, ztrbio )   ! temporary save of trends
85         ztrbio(:,:,:) = tra(:,:,:,jpno3)
86      ENDIF
87
88      ! VERTICAL DISTRIBUTION OF NEWLY PRODUCED BIOGENIC
89      ! POC IN THE WATER COLUMN
90      ! (PARTS OF NEWLY FORMED MATTER REMAINING IN THE DIFFERENT
91      ! LAYERS IS DETERMINED BY DMIN3 DEFINED IN sms_p2z.F90
92      ! ----------------------------------------------------------------------
93      DO jk = 1, jpkm1
94         DO jj = 2, jpjm1
95            DO ji = fs_2, fs_jpim1
96               ze3t = 1. / fse3t(ji,jj,jk)
97               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) + ze3t * dmin3(ji,jj,jk) * xksi(ji,jj)
98            END DO
99         END DO
100      END DO
101
102      ! Find the last level of the water column
103      ! Compute fluxes due to sinking particles (slow)
104   
105
106      zgeolpoc = 0.e0         !     Initialization
107      ! Release of nutrients from the "simple" sediment
108      DO jj = 2, jpjm1
109         DO ji = fs_2, fs_jpim1
110            ikt = mbkt(ji,jj) 
111            tra(ji,jj,ikt,jpno3) = tra(ji,jj,ikt,jpno3) + sedlam * sedpocn(ji,jj) / fse3t(ji,jj,ikt) 
112            ! Deposition of organic matter in the sediment
113            zwork = vsed * trn(ji,jj,ikt,jpdet)
114            zsedpoca(ji,jj) = ( zwork + dminl(ji,jj) * xksi(ji,jj)   &
115               &           - sedlam * sedpocn(ji,jj) - sedlostpoc * sedpocn(ji,jj) ) * rdt
116            zgeolpoc = zgeolpoc + sedlostpoc * sedpocn(ji,jj) * e1e2t(ji,jj)
117         END DO
118      END DO
119
120      DO jj = 2, jpjm1
121         DO ji = fs_2, fs_jpim1
122            tra(ji,jj,1,jpno3) = tra(ji,jj,1,jpno3) + zgeolpoc * cmask(ji,jj) / areacot / fse3t(ji,jj,1)
123         END DO
124      END DO
125
126      CALL lbc_lnk( sedpocn, 'T', 1. )
127 
128      ! Oa & Ek: diagnostics depending on jpdia2d !          left as example
129      IF( lk_iomput ) THEN 
130         CALL iom_put( "SEDPOC" , sedpocn )
131      ELSE
132         IF( ln_diatrc )           trc2d(:,:,jp_pcs0_2d + 18) = sedpocn(:,:)
133      ENDIF
134
135     
136      ! Time filter and swap of arrays
137      ! ------------------------------
138      IF( neuler == 0 .AND. kt == nittrc000 ) THEN        ! Euler time-stepping at first time-step
139        !                                             ! (only swap)
140        sedpocn(:,:) = zsedpoca(:,:)
141        !                                             
142      ELSE
143        !
144        DO jj = 1, jpj
145           DO ji = 1, jpi
146              zsedpocd = zsedpoca(ji,jj) - 2. * sedpocn(ji,jj) + sedpocb(ji,jj)      ! time laplacian on tracers
147              sedpocb(ji,jj) = sedpocn(ji,jj) + atfp * zsedpocd                     ! sedpocb <-- filtered sedpocn
148              sedpocn(ji,jj) = zsedpoca(ji,jj)                                       ! sedpocn <-- sedpoca
149           END DO
150        END DO
151        !
152      ENDIF
153      !
154      IF( lrst_trc ) THEN
155         IF(lwp) WRITE(numout,*)
156         IF(lwp) WRITE(numout,*) 'p2z_exp : POC in sediment fields written in ocean restart file ',   &
157            &                    'at it= ', kt,' date= ', ndastp
158         IF(lwp) WRITE(numout,*) '~~~~'
159         CALL iom_rstput( kt, nitrst, numrtw, 'SEDB'//ctrcnm(jpdet), sedpocb(:,:) )
160         CALL iom_rstput( kt, nitrst, numrtw, 'SEDN'//ctrcnm(jpdet), sedpocn(:,:) )
161      ENDIF
162      !
163      IF( l_trdtrc ) THEN
164         ztrbio(:,:,:) = tra(:,:,:,jpno3) - ztrbio(:,:,:)
165         jl = jp_pcs0_trd + 16
166         CALL trd_trc( ztrbio, jl, kt )   ! handle the trend
167         CALL wrk_dealloc( jpi, jpj, jpk, ztrbio )   ! temporary save of trends
168      ENDIF
169      !
170      CALL wrk_dealloc( jpi, jpj, zsedpoca)   ! temporary save of trends
171
172      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
173         WRITE(charout, FMT="('exp')")
174         CALL prt_ctl_trc_info(charout)
175         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
176      ENDIF
177      !
178      IF( nn_timing == 1 )  CALL timing_stop('p2z_exp')
179      !
180   END SUBROUTINE p2z_exp
181
182   SUBROUTINE p2z_exp_init
183      !!----------------------------------------------------------------------
184      !!                    ***  ROUTINE p4z_exp_init  ***
185      !! ** purpose :   specific initialisation for export
186      !!----------------------------------------------------------------------
187      INTEGER  ::   ji, jj, jk
188      REAL(wp) ::   zmaskt, zfluo, zfluu
189      REAL(wp), POINTER, DIMENSION(:,:  ) :: zrro
190      REAL(wp), POINTER, DIMENSION(:,:,:) :: zdm0
191      !!---------------------------------------------------------------------
192
193      IF(lwp) THEN
194         WRITE(numout,*)
195         WRITE(numout,*) ' p2z_exp: LOBSTER export'
196         WRITE(numout,*) ' ~~~~~~~'
197         WRITE(numout,*) '  compute remineralisation-damping arrays for tracers'
198      ENDIF
199      !
200      ! Allocate temporary workspace
201      CALL wrk_alloc( jpi, jpj,      zrro )
202      CALL wrk_alloc( jpi, jpj, jpk, zdm0 )
203
204
205      ! Calculate vertical distribution of newly formed biogenic poc
206      ! in the water column in the case of max. possible bottom depth
207      ! ------------------------------------------------------------
208      zdm0 = 0._wp
209      zrro = 1._wp
210      DO jk = jpkb, jpkm1
211         DO jj = 1, jpj
212            DO ji = 1, jpi
213               zfluo = ( fsdepw(ji,jj,jk  ) / fsdepw(ji,jj,jpkb) )**xhr
214               zfluu = ( fsdepw(ji,jj,jk+1) / fsdepw(ji,jj,jpkb) )**xhr
215               IF( zfluo.GT.1. )   zfluo = 1._wp
216               zdm0(ji,jj,jk) = zfluo - zfluu
217               IF( jk <= jpkb-1 )   zdm0(ji,jj,jk) = 0._wp
218               zrro(ji,jj) = zrro(ji,jj) - zdm0(ji,jj,jk)
219            END DO
220         END DO
221      END DO
222      !
223      zdm0(:,:,jpk) = zrro(:,:)
224
225      ! Calculate vertical distribution of newly formed biogenic poc
226      ! in the water column with realistic topography (first "dry" layer
227      ! contains total fraction, which has passed to the upper layers)
228      ! ----------------------------------------------------------------------
229      dminl(:,:)   = 0._wp
230      dmin3(:,:,:) = zdm0
231      DO jk = 1, jpk
232         DO jj = 1, jpj
233            DO ji = 1, jpi
234               IF( tmask(ji,jj,jk) == 0._wp ) THEN
235                  dminl(ji,jj) = dminl(ji,jj) + dmin3(ji,jj,jk)
236                  dmin3(ji,jj,jk) = 0._wp
237               ENDIF
238            END DO
239         END DO
240      END DO
241
242      DO jj = 1, jpj
243         DO ji = 1, jpi
244            IF( tmask(ji,jj,1) == 0 )   dmin3(ji,jj,1) = 0._wp
245         END DO
246      END DO
247
248      ! Coastal mask
249      cmask(:,:) = 0._wp
250      DO jj = 2, jpjm1
251         DO ji = fs_2, fs_jpim1
252            IF( tmask(ji,jj,1) /= 0. ) THEN
253               zmaskt = tmask(ji+1,jj,1) * tmask(ji-1,jj,1) * tmask(ji,jj+1,1) * tmask(ji,jj-1,1) 
254               IF( zmaskt == 0. )   cmask(ji,jj) = 1._wp
255            END IF
256         END DO
257      END DO
258      CALL lbc_lnk( cmask , 'T', 1. )      ! lateral boundary conditions on cmask   (sign unchanged)
259      areacot = glob_sum( e1e2t(:,:) * cmask(:,:) )
260      !
261      IF( ln_rsttr ) THEN
262         CALL iom_get( numrtr, jpdom_autoglo, 'SEDB'//ctrcnm(jpdet), sedpocb(:,:) )
263         CALL iom_get( numrtr, jpdom_autoglo, 'SEDN'//ctrcnm(jpdet), sedpocn(:,:) )
264      ELSE
265         sedpocb(:,:) = 0._wp
266         sedpocn(:,:) = 0._wp
267      ENDIF
268      !
269      CALL wrk_dealloc( jpi, jpj,      zrro )
270      CALL wrk_dealloc( jpi, jpj, jpk, zdm0 )
271      !
272   END SUBROUTINE p2z_exp_init
273
274   INTEGER FUNCTION p2z_exp_alloc()
275      !!----------------------------------------------------------------------
276      !!                     ***  ROUTINE p2z_exp_alloc  ***
277      !!----------------------------------------------------------------------
278      ALLOCATE( cmask(jpi,jpj) , dminl(jpi,jpj) , dmin3(jpi,jpj,jpk), &
279         &      sedpocb(jpi,jpj) , sedpocn(jpi,jpj),   STAT=p2z_exp_alloc )
280      IF( p2z_exp_alloc /= 0 ) CALL ctl_warn('p2z_exp_alloc : failed to allocate arrays.')
281      !
282   END FUNCTION p2z_exp_alloc
283
284#else
285   !!======================================================================
286   !!  Dummy module :                                   No PISCES bio-model
287   !!======================================================================
288CONTAINS
289   SUBROUTINE p2z_exp( kt )                   ! Empty routine
290      INTEGER, INTENT( in ) ::   kt
291      WRITE(*,*) 'p2z_exp: You should not have seen this print! error?', kt
292   END SUBROUTINE p2z_exp
293#endif 
294
295   !!======================================================================
296END MODULE  p2zexp
Note: See TracBrowser for help on using the repository browser.