source: branches/2014/dev_r4650_UKMO14.12_STAND_ALONE_OBSOPER/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zopt.F90 @ 5600

Last change on this file since 5600 was 5600, checked in by andrewryan, 5 years ago

merged in latest version of trunk alongside changes to SAO_SRC to be compatible with latest OBS

File size: 19.4 KB
Line 
1MODULE p4zopt
2   !!======================================================================
3   !!                         ***  MODULE p4zopt  ***
4   !! TOP - PISCES : Compute the light availability in the water column
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.2  !  2009-04  (C. Ethe, G. Madec)  optimisation
9   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Improve light availability of nano & diat
10   !!----------------------------------------------------------------------
11#if defined  key_pisces
12   !!----------------------------------------------------------------------
13   !!   'key_pisces'                                       PISCES bio-model
14   !!----------------------------------------------------------------------
15   !!   p4z_opt       : light availability in the water column
16   !!----------------------------------------------------------------------
17   USE trc            ! tracer variables
18   USE oce_trc        ! tracer-ocean share variables
19   USE sms_pisces     ! Source Minus Sink of PISCES
20   USE iom            ! I/O manager
21   USE fldread         !  time interpolation
22   USE prtctl_trc      !  print control for debugging
23
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   p4z_opt        ! called in p4zbio.F90 module
29   PUBLIC   p4z_opt_init   ! called in trcsms_pisces.F90 module
30   PUBLIC   p4z_opt_alloc
31
32   !! * Shared module variables
33
34   LOGICAL  :: ln_varpar   !: boolean for variable PAR fraction
35   REAL(wp) :: parlux      !: Fraction of shortwave as PAR
36   REAL(wp) :: xparsw                 !: parlux/3
37   REAL(wp) :: xsi0r                 !:  1. /rn_si0
38
39   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_par      ! structure of input par
40   INTEGER , PARAMETER :: nbtimes = 365  !: maximum number of times record in a file
41   INTEGER  :: ntimes_par                ! number of time steps in a file
42   REAL(wp), ALLOCATABLE, SAVE,   DIMENSION(:,:) :: par_varsw    !: PAR fraction of shortwave
43
44   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: enano, ediat   !: PAR for phyto, nano and diat
45   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: etot_ndcy      !: PAR over 24h in case of diurnal cycle
46   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: emoy           !: averaged PAR in the mixed layer
47   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: ekb, ekg, ekr  !: wavelength (Red-Green-Blue)
48
49   INTEGER  ::   nksrp   ! levels below which the light cannot penetrate ( depth larger than 391 m)
50
51   REAL(wp), DIMENSION(3,61), PUBLIC ::   xkrgb   !: tabulated attenuation coefficients for RGB absorption
52   
53   !!* Substitution
54#  include "top_substitute.h90"
55   !!----------------------------------------------------------------------
56   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
57   !! $Id: p4zopt.F90 3160 2011-11-20 14:27:18Z cetlod $
58   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
59   !!----------------------------------------------------------------------
60CONTAINS
61
62   SUBROUTINE p4z_opt( kt, knt )
63      !!---------------------------------------------------------------------
64      !!                     ***  ROUTINE p4z_opt  ***
65      !!
66      !! ** Purpose :   Compute the light availability in the water column
67      !!              depending on the depth and the chlorophyll concentration
68      !!
69      !! ** Method  : - ???
70      !!---------------------------------------------------------------------
71      !
72      INTEGER, INTENT(in) ::   kt, knt   ! ocean time step
73      !
74      INTEGER  ::   ji, jj, jk
75      INTEGER  ::   irgb
76      REAL(wp) ::   zchl
77      REAL(wp) ::   zc0 , zc1 , zc2, zc3, z1_dep
78      REAL(wp), POINTER, DIMENSION(:,:  ) :: zdepmoy, zetmp1, zetmp2, zetmp3, zetmp4, zqsr100
79      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpar, ze0, ze1, ze2, ze3
80      !!---------------------------------------------------------------------
81      !
82      IF( nn_timing == 1 )  CALL timing_start('p4z_opt')
83      !
84      ! Allocate temporary workspace
85      CALL wrk_alloc( jpi, jpj,      zqsr100, zdepmoy, zetmp1, zetmp2, zetmp3, zetmp4 )
86      CALL wrk_alloc( jpi, jpj, jpk, zpar, ze0, ze1, ze2, ze3 )
87
88      IF( knt == 1 .AND. ln_varpar ) CALL p4z_opt_sbc( kt )
89
90      !     Initialisation of variables used to compute PAR
91      !     -----------------------------------------------
92      ze1(:,:,:) = 0._wp
93      ze2(:,:,:) = 0._wp
94      ze3(:,:,:) = 0._wp
95      !                                        !* attenuation coef. function of Chlorophyll and wavelength (Red-Green-Blue)
96      DO jk = 1, jpkm1                         !  --------------------------------------------------------
97!CDIR NOVERRCHK
98         DO jj = 1, jpj
99!CDIR NOVERRCHK
100            DO ji = 1, jpi
101               zchl = ( trb(ji,jj,jk,jpnch) + trb(ji,jj,jk,jpdch) + rtrn ) * 1.e6
102               zchl = MIN(  10. , MAX( 0.05, zchl )  )
103               irgb = NINT( 41 + 20.* LOG10( zchl ) + rtrn )
104               !                                                         
105               ekb(ji,jj,jk) = xkrgb(1,irgb) * fse3t(ji,jj,jk)
106               ekg(ji,jj,jk) = xkrgb(2,irgb) * fse3t(ji,jj,jk)
107               ekr(ji,jj,jk) = xkrgb(3,irgb) * fse3t(ji,jj,jk)
108            END DO
109         END DO
110      END DO
111      !                                        !* Photosynthetically Available Radiation (PAR)
112      !                                        !  --------------------------------------
113      IF( l_trcdm2dc ) THEN                     !  diurnal cycle
114         ! 1% of qsr to compute euphotic layer
115         zqsr100(:,:) = 0.01 * qsr_mean(:,:)     !  daily mean qsr
116         !
117         CALL p4z_opt_par( kt, qsr_mean, ze1, ze2, ze3 ) 
118         !
119         DO jk = 1, nksrp     
120            etot_ndcy(:,:,jk) =        ze1(:,:,jk) +        ze2(:,:,jk) +       ze3(:,:,jk)
121            enano    (:,:,jk) =  2.1 * ze1(:,:,jk) + 0.42 * ze2(:,:,jk) + 0.4 * ze3(:,:,jk)
122            ediat    (:,:,jk) =  1.6 * ze1(:,:,jk) + 0.69 * ze2(:,:,jk) + 0.7 * ze3(:,:,jk)
123         END DO
124         !
125         CALL p4z_opt_par( kt, qsr, ze1, ze2, ze3 ) 
126         !
127         DO jk = 1, nksrp     
128            etot(:,:,jk) =  ze1(:,:,jk) + ze2(:,:,jk) + ze3(:,:,jk)
129         END DO
130         !
131      ELSE
132         ! 1% of qsr to compute euphotic layer
133         zqsr100(:,:) = 0.01 * qsr(:,:)
134         !
135         CALL p4z_opt_par( kt, qsr, ze1, ze2, ze3 ) 
136         !
137         DO jk = 1, nksrp     
138            etot (:,:,jk) =        ze1(:,:,jk) +        ze2(:,:,jk) +       ze3(:,:,jk)
139            enano(:,:,jk) =  2.1 * ze1(:,:,jk) + 0.42 * ze2(:,:,jk) + 0.4 * ze3(:,:,jk)
140            ediat(:,:,jk) =  1.6 * ze1(:,:,jk) + 0.69 * ze2(:,:,jk) + 0.7 * ze3(:,:,jk)
141         END DO
142         etot_ndcy(:,:,:) =  etot(:,:,:) 
143      ENDIF
144
145
146      IF( ln_qsr_bio ) THEN                    !* heat flux accros w-level (used in the dynamics)
147         !                                     !  ------------------------
148         CALL p4z_opt_par( kt, qsr, ze1, ze2, ze3, pe0=ze0 )
149         !
150         etot3(:,:,1) =  qsr(:,:) * tmask(:,:,1)
151         DO jk = 2, nksrp + 1
152            etot3(:,:,jk) =  ( ze0(:,:,jk) + ze1(:,:,jk) + ze2(:,:,jk) + ze3(:,:,jk) ) * tmask(:,:,jk)
153         END DO
154         !                                     !  ------------------------
155      ENDIF
156      !                                        !* Euphotic depth and level
157      neln(:,:) = 1                            !  ------------------------
158      heup(:,:) = 300.
159
160      DO jk = 2, nksrp
161         DO jj = 1, jpj
162           DO ji = 1, jpi
163              IF( etot_ndcy(ji,jj,jk) * tmask(ji,jj,jk) >= 0.43 * zqsr100(ji,jj) )  THEN
164                 neln(ji,jj) = jk+1                    ! Euphotic level : 1rst T-level strictly below Euphotic layer
165                 !                                     ! nb: ensure the compatibility with nmld_trc definition in trd_mld_trc_zint
166                 heup(ji,jj) = fsdepw(ji,jj,jk+1)      ! Euphotic layer depth
167              ENDIF
168           END DO
169        END DO
170      END DO
171      !
172      heup(:,:) = MIN( 300., heup(:,:) )
173      !                                        !* mean light over the mixed layer
174      zdepmoy(:,:)   = 0.e0                    !  -------------------------------
175      zetmp1 (:,:)   = 0.e0
176      zetmp2 (:,:)   = 0.e0
177      zetmp3 (:,:)   = 0.e0
178      zetmp4 (:,:)   = 0.e0
179
180      DO jk = 1, nksrp
181!CDIR NOVERRCHK
182         DO jj = 1, jpj
183!CDIR NOVERRCHK
184            DO ji = 1, jpi
185               IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
186                  zetmp1 (ji,jj) = zetmp1 (ji,jj) + etot     (ji,jj,jk) * fse3t(ji,jj,jk) ! remineralisation
187                  zetmp2 (ji,jj) = zetmp2 (ji,jj) + etot_ndcy(ji,jj,jk) * fse3t(ji,jj,jk) ! production
188                  zetmp3 (ji,jj) = zetmp3 (ji,jj) + enano    (ji,jj,jk) * fse3t(ji,jj,jk) ! production
189                  zetmp4 (ji,jj) = zetmp4 (ji,jj) + ediat    (ji,jj,jk) * fse3t(ji,jj,jk) ! production
190                  zdepmoy(ji,jj) = zdepmoy(ji,jj) + fse3t(ji,jj,jk)
191               ENDIF
192            END DO
193         END DO
194      END DO
195      !
196      emoy(:,:,:) = etot(:,:,:)       ! remineralisation
197      zpar(:,:,:) = etot_ndcy(:,:,:)  ! diagnostic : PAR with no diurnal cycle
198      !
199      DO jk = 1, nksrp
200!CDIR NOVERRCHK
201         DO jj = 1, jpj
202!CDIR NOVERRCHK
203            DO ji = 1, jpi
204               IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
205                  z1_dep = 1. / ( zdepmoy(ji,jj) + rtrn )
206                  emoy (ji,jj,jk) = zetmp1(ji,jj) * z1_dep
207                  zpar (ji,jj,jk) = zetmp2(ji,jj) * z1_dep
208                  enano(ji,jj,jk) = zetmp3(ji,jj) * z1_dep
209                  ediat(ji,jj,jk) = zetmp4(ji,jj) * z1_dep
210               ENDIF
211            END DO
212         END DO
213      END DO
214      !
215      IF( lk_iomput ) THEN
216        IF( knt == nrdttrc ) THEN
217           IF( iom_use( "Heup"  ) ) CALL iom_put( "Heup" , heup(:,:  ) * tmask(:,:,1) )  ! euphotic layer deptht
218           IF( iom_use( "PARDM" ) ) CALL iom_put( "PARDM", zpar(:,:,:) * tmask(:,:,:) )  ! Photosynthetically Available Radiation
219           IF( iom_use( "PAR"   ) ) CALL iom_put( "PAR"  , emoy(:,:,:) * tmask(:,:,:) )  ! Photosynthetically Available Radiation
220        ENDIF
221      ELSE
222         IF( ln_diatrc ) THEN        ! save output diagnostics
223            trc2d(:,:,  jp_pcs0_2d + 10) = heup(:,:  ) * tmask(:,:,1)
224            trc3d(:,:,:,jp_pcs0_3d + 3)  = etot(:,:,:) * tmask(:,:,:)
225         ENDIF
226      ENDIF
227      !
228      CALL wrk_dealloc( jpi, jpj,      zqsr100, zdepmoy, zetmp1, zetmp2, zetmp3, zetmp4 )
229      CALL wrk_dealloc( jpi, jpj, jpk, zpar,  ze0, ze1, ze2, ze3 )
230      !
231      IF( nn_timing == 1 )  CALL timing_stop('p4z_opt')
232      !
233   END SUBROUTINE p4z_opt
234
235   SUBROUTINE p4z_opt_par( kt, pqsr, pe1, pe2, pe3, pe0 ) 
236      !!----------------------------------------------------------------------
237      !!                  ***  routine p4z_opt_par  ***
238      !!
239      !! ** purpose :   compute PAR of each wavelength (Red-Green-Blue)
240      !!                for a given shortwave radiation
241      !!
242      !!----------------------------------------------------------------------
243      !! * arguments
244      INTEGER, INTENT(in)                                       ::  kt            !   ocean time-step
245      REAL(wp), DIMENSION(jpi,jpj)    , INTENT(in)              ::  pqsr          !   shortwave
246      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout)           ::  pe1 , pe2 , pe3   !  PAR ( R-G-B)
247      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout), OPTIONAL ::  pe0 
248      !! * local variables
249      INTEGER    ::   ji, jj, jk     ! dummy loop indices
250      REAL(wp), DIMENSION(jpi,jpj)     ::  zqsr          !   shortwave
251      !!----------------------------------------------------------------------
252
253      !  Real shortwave
254      IF( ln_varpar ) THEN  ;  zqsr(:,:) = par_varsw(:,:) * pqsr(:,:)
255      ELSE                  ;  zqsr(:,:) = xparsw         * pqsr(:,:)
256      ENDIF
257      !
258      IF( PRESENT( pe0 ) ) THEN     !  W-level
259         !
260         pe0(:,:,1) = pqsr(:,:) - 3. * zqsr(:,:)    !   ( 1 - 3 * alpha ) * q
261         pe1(:,:,1) = zqsr(:,:)         
262         pe2(:,:,1) = zqsr(:,:)
263         pe3(:,:,1) = zqsr(:,:)
264         !
265         DO jk = 2, nksrp + 1
266!CDIR NOVERRCHK
267            DO jj = 1, jpj
268!CDIR NOVERRCHK
269               DO ji = 1, jpi
270                  pe0(ji,jj,jk) = pe0(ji,jj,jk-1) * EXP( -fse3t(ji,jj,jk-1) * xsi0r )
271                  pe1(ji,jj,jk) = pe1(ji,jj,jk-1) * EXP( -ekb(ji,jj,jk-1 ) )
272                  pe2(ji,jj,jk) = pe2(ji,jj,jk-1) * EXP( -ekg(ji,jj,jk-1 ) )
273                  pe3(ji,jj,jk) = pe3(ji,jj,jk-1) * EXP( -ekr(ji,jj,jk-1 ) )
274               END DO
275              !
276            END DO
277            !
278         END DO
279        !
280      ELSE   ! T- level
281        !
282        pe1(:,:,1) = zqsr(:,:) * EXP( -0.5 * ekb(:,:,1) )
283        pe2(:,:,1) = zqsr(:,:) * EXP( -0.5 * ekg(:,:,1) )
284        pe3(:,:,1) = zqsr(:,:) * EXP( -0.5 * ekr(:,:,1) )
285        !
286        DO jk = 2, nksrp     
287!CDIR NOVERRCHK
288           DO jj = 1, jpj
289!CDIR NOVERRCHK
290              DO ji = 1, jpi
291                 pe1(ji,jj,jk) = pe1(ji,jj,jk-1) * EXP( -0.5 * ( ekb(ji,jj,jk-1) + ekb(ji,jj,jk) ) )
292                 pe2(ji,jj,jk) = pe2(ji,jj,jk-1) * EXP( -0.5 * ( ekg(ji,jj,jk-1) + ekg(ji,jj,jk) ) )
293                 pe3(ji,jj,jk) = pe3(ji,jj,jk-1) * EXP( -0.5 * ( ekr(ji,jj,jk-1) + ekr(ji,jj,jk) ) )
294              END DO
295           END DO
296        END DO   
297        !
298      ENDIF
299      !
300   END SUBROUTINE p4z_opt_par
301
302
303   SUBROUTINE p4z_opt_sbc( kt )
304      !!----------------------------------------------------------------------
305      !!                  ***  routine p4z_opt_sbc  ***
306      !!
307      !! ** purpose :   read and interpolate the variable PAR fraction
308      !!                of shortwave radiation
309      !!
310      !! ** method  :   read the files and interpolate the appropriate variables
311      !!
312      !! ** input   :   external netcdf files
313      !!
314      !!----------------------------------------------------------------------
315      !! * arguments
316      INTEGER ,                INTENT(in) ::   kt     ! ocean time step
317
318      !! * local declarations
319      INTEGER  :: ji,jj
320      REAL(wp) :: zcoef
321      !!---------------------------------------------------------------------
322      !
323      IF( nn_timing == 1 )  CALL timing_start('p4z_optsbc')
324      !
325      ! Compute par_varsw at nit000 or only if there is more than 1 time record in par coefficient file
326      IF( ln_varpar ) THEN
327         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_par > 1 ) ) THEN
328            CALL fld_read( kt, 1, sf_par )
329            par_varsw(:,:) = ( sf_par(1)%fnow(:,:,1) ) / 3.0
330         ENDIF
331      ENDIF
332      !
333      IF( nn_timing == 1 )  CALL timing_stop('p4z_optsbc')
334      !
335   END SUBROUTINE p4z_opt_sbc
336
337   SUBROUTINE p4z_opt_init
338      !!----------------------------------------------------------------------
339      !!                  ***  ROUTINE p4z_opt_init  ***
340      !!
341      !! ** Purpose :   Initialization of tabulated attenuation coef
342      !!                and of the percentage of PAR in Shortwave
343      !!
344      !! ** Input   :   external ascii and netcdf files
345      !!----------------------------------------------------------------------
346      !
347      INTEGER :: numpar
348      INTEGER :: ierr
349      INTEGER :: ios                 ! Local integer output status for namelist read
350      REAL(wp), DIMENSION(nbtimes) :: zsteps                 ! times records
351      !
352      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
353      TYPE(FLD_N) ::   sn_par                ! informations about the fields to be read
354      !
355      NAMELIST/nampisopt/cn_dir, sn_par, ln_varpar, parlux
356
357      !!----------------------------------------------------------------------
358
359      IF( nn_timing == 1 )  CALL timing_start('p4z_opt_init')
360
361      REWIND( numnatp_ref )              ! Namelist nampisopt in reference namelist : Pisces attenuation coef. and PAR
362      READ  ( numnatp_ref, nampisopt, IOSTAT = ios, ERR = 901)
363901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisopt in reference namelist', lwp )
364
365      REWIND( numnatp_cfg )              ! Namelist nampisopt in configuration namelist : Pisces attenuation coef. and PAR
366      READ  ( numnatp_cfg, nampisopt, IOSTAT = ios, ERR = 902 )
367902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisopt in configuration namelist', lwp )
368      IF(lwm) WRITE ( numonp, nampisopt )
369
370      IF(lwp) THEN
371         WRITE(numout,*) ' '
372         WRITE(numout,*) ' namelist : nampisopt '
373         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~ '
374         WRITE(numout,*) '    PAR as a variable fraction of SW     ln_varpar      = ', ln_varpar
375         WRITE(numout,*) '    Default value for the PAR fraction   parlux         = ', parlux
376      ENDIF
377      !
378      xparsw = parlux / 3.0
379      xsi0r  = 1.e0 / rn_si0
380      !
381      ! Variable PAR at the surface of the ocean
382      ! ----------------------------------------
383      IF( ln_varpar ) THEN
384         IF(lwp) WRITE(numout,*) '    initialize variable par fraction '
385         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
386         !
387         ALLOCATE( par_varsw(jpi,jpj) )
388         !
389         ALLOCATE( sf_par(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
390         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_opt_init: unable to allocate sf_par structure' )
391         !
392         CALL fld_fill( sf_par, (/ sn_par /), cn_dir, 'p4z_opt_init', 'Variable PAR fraction ', 'nampisopt' )
393                                   ALLOCATE( sf_par(1)%fnow(jpi,jpj,1)   )
394         IF( sn_par%ln_tint )      ALLOCATE( sf_par(1)%fdta(jpi,jpj,1,2) )
395
396         CALL iom_open (  TRIM( sn_par%clname ) , numpar )
397         CALL iom_gettime( numpar, zsteps, kntime=ntimes_par)  ! get number of record in file
398      ENDIF
399      !
400      CALL trc_oce_rgb( xkrgb )                  ! tabulated attenuation coefficients
401      nksrp = trc_oce_ext_lev( r_si2, 0.33e2 )     ! max level of light extinction (Blue Chl=0.01)
402      !
403      IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksrp, ' ref depth = ', gdepw_1d(nksrp+1), ' m'
404      !
405                         ekr      (:,:,:) = 0._wp
406                         ekb      (:,:,:) = 0._wp
407                         ekg      (:,:,:) = 0._wp
408                         etot     (:,:,:) = 0._wp
409                         etot_ndcy(:,:,:) = 0._wp
410                         enano    (:,:,:) = 0._wp
411                         ediat    (:,:,:) = 0._wp
412      IF( ln_qsr_bio )   etot3    (:,:,:) = 0._wp
413      !
414      IF( nn_timing == 1 )  CALL timing_stop('p4z_opt_init')
415      !
416   END SUBROUTINE p4z_opt_init
417
418
419   INTEGER FUNCTION p4z_opt_alloc()
420      !!----------------------------------------------------------------------
421      !!                     ***  ROUTINE p4z_opt_alloc  ***
422      !!----------------------------------------------------------------------
423      ALLOCATE( ekb(jpi,jpj,jpk)      , ekr(jpi,jpj,jpk), ekg(jpi,jpj,jpk),   &
424        &       enano(jpi,jpj,jpk)    , ediat(jpi,jpj,jpk), &
425        &       etot_ndcy(jpi,jpj,jpk), emoy (jpi,jpj,jpk), STAT=p4z_opt_alloc ) 
426         !
427      IF( p4z_opt_alloc /= 0 ) CALL ctl_warn('p4z_opt_alloc : failed to allocate arrays.')
428      !
429   END FUNCTION p4z_opt_alloc
430
431#else
432   !!----------------------------------------------------------------------
433   !!  Dummy module :                                   No PISCES bio-model
434   !!----------------------------------------------------------------------
435CONTAINS
436   SUBROUTINE p4z_opt                   ! Empty routine
437   END SUBROUTINE p4z_opt
438#endif 
439
440   !!======================================================================
441END MODULE  p4zopt
Note: See TracBrowser for help on using the repository browser.