source: branches/2014/dev_r4650_UKMO2_ice_shelves/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 4726

Last change on this file since 4726 was 4726, checked in by mathiot, 6 years ago

ISF branch: change name of 2 variables (icedep ⇒ risfdep and lmask ⇒ ssmask), cosmetic changes and add ldfslp key

  • Property svn:keywords set to Id
File size: 63.2 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!----------------------------------------------------------------------
19
20   !!----------------------------------------------------------------------
21   !!   dyn_hpg      : update the momentum trend with the now horizontal
22   !!                  gradient of the hydrostatic pressure
23   !!   dyn_hpg_init : initialisation and control of options
24   !!       hpg_zco  : z-coordinate scheme
25   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
26   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
27   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
28   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
29   !!----------------------------------------------------------------------
30   USE oce             ! ocean dynamics and tracers
31   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
32   USE dom_oce         ! ocean space and time domain
33   USE phycst          ! physical constants
34   USE trdmod          ! ocean dynamics trends
35   USE trdmod_oce      ! ocean variables trends
36   USE in_out_manager  ! I/O manager
37   USE prtctl          ! Print control
38   USE lbclnk          ! lateral boundary condition
39   USE lib_mpp         ! MPP library
40   USE eosbn2          ! compute density
41   USE wrk_nemo        ! Memory Allocation
42   USE timing          ! Timing
43
44   IMPLICIT NONE
45   PRIVATE
46
47   PUBLIC   dyn_hpg        ! routine called by step module
48   PUBLIC   dyn_hpg_init   ! routine called by opa module
49
50   !                                    !!* Namelist namdyn_hpg : hydrostatic pressure gradient
51   LOGICAL , PUBLIC ::   ln_hpg_zco      !: z-coordinate - full steps
52   LOGICAL , PUBLIC ::   ln_hpg_zps      !: z-coordinate - partial steps (interpolation)
53   LOGICAL , PUBLIC ::   ln_hpg_sco      !: s-coordinate (standard jacobian formulation)
54   LOGICAL , PUBLIC ::   ln_hpg_djc      !: s-coordinate (Density Jacobian with Cubic polynomial)
55   LOGICAL , PUBLIC ::   ln_hpg_prj      !: s-coordinate (Pressure Jacobian scheme)
56   LOGICAL , PUBLIC ::   ln_dynhpg_imp   !: semi-implicite hpg flag
57
58   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
59
60   !! * Substitutions
61#  include "domzgr_substitute.h90"
62#  include "vectopt_loop_substitute.h90"
63   !!----------------------------------------------------------------------
64   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
65   !! $Id$
66   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
67   !!----------------------------------------------------------------------
68CONTAINS
69
70   SUBROUTINE dyn_hpg( kt )
71      !!---------------------------------------------------------------------
72      !!                  ***  ROUTINE dyn_hpg  ***
73      !!
74      !! ** Method  :   Call the hydrostatic pressure gradient routine
75      !!              using the scheme defined in the namelist
76      !!
77      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
78      !!             - Save the trend (l_trddyn=T)
79      !!----------------------------------------------------------------------
80      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
81      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
82      !!----------------------------------------------------------------------
83      !
84      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
85      !
86      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
87         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
88         ztrdu(:,:,:) = ua(:,:,:)
89         ztrdv(:,:,:) = va(:,:,:)
90      ENDIF
91      !
92      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
93      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
94      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
95      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
96      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
97      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
98      END SELECT
99      !
100      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
101         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
102         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
103         CALL trd_mod( ztrdu, ztrdv, jpdyn_trd_hpg, 'DYN', kt )
104         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
105      ENDIF
106      !
107      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
108         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
109      !
110      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
111      !
112   END SUBROUTINE dyn_hpg
113
114
115   SUBROUTINE dyn_hpg_init
116      !!----------------------------------------------------------------------
117      !!                 ***  ROUTINE dyn_hpg_init  ***
118      !!
119      !! ** Purpose :   initializations for the hydrostatic pressure gradient
120      !!              computation and consistency control
121      !!
122      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
123      !!      with the type of vertical coordinate used (zco, zps, sco)
124      !!----------------------------------------------------------------------
125      INTEGER ::   ioptio = 0      ! temporary integer
126      INTEGER ::   ios             ! Local integer output status for namelist read
127      !!
128      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
129         &                 ln_hpg_djc, ln_hpg_prj, ln_dynhpg_imp
130      !!----------------------------------------------------------------------
131      !
132      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
133      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
134901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
135
136      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
137      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
138902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
139      WRITE ( numond, namdyn_hpg )
140      !
141      IF(lwp) THEN                   ! Control print
142         WRITE(numout,*)
143         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
144         WRITE(numout,*) '~~~~~~~~~~~~'
145         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
146         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
147         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
148         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
149         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
150         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
151         WRITE(numout,*) '      time stepping: centered (F) or semi-implicit (T)  ln_dynhpg_imp = ', ln_dynhpg_imp
152      ENDIF
153      !
154      IF( ln_hpg_djc )   &
155         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
156                           & currently disabled (bugs under investigation). Please select &
157                           & either  ln_hpg_sco or  ln_hpg_prj instead')
158      !
159      IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj) )   &
160         &   CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
161                           & the standard jacobian formulation hpg_sco or &
162                           & the pressure jacobian formulation hpg_prj')
163      !
164      !                               ! Set nhpg from ln_hpg_... flags
165      IF( ln_hpg_zco )   nhpg = 0
166      IF( ln_hpg_zps )   nhpg = 1
167      IF( ln_hpg_sco )   nhpg = 2
168      IF( ln_hpg_djc )   nhpg = 3
169      IF( ln_hpg_prj )   nhpg = 4
170      !
171      !                               ! Consistency check
172      ioptio = 0
173      IF( ln_hpg_zco )   ioptio = ioptio + 1
174      IF( ln_hpg_zps )   ioptio = ioptio + 1
175      IF( ln_hpg_sco )   ioptio = ioptio + 1
176      IF( ln_hpg_djc )   ioptio = ioptio + 1
177      IF( ln_hpg_prj )   ioptio = ioptio + 1
178      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
179      IF( (ln_hpg_zco .OR. ln_hpg_zps .OR. ln_hpg_djc .OR. ln_hpg_prj ) .AND. nn_isf .NE. 0 )   CALL ctl_stop( 'Only hpg_sco has been corrected to work with ice shelf cavity. Comparison in a GYRE simulation with bump in the middle show similar result than hpg_zps' )
180      !
181   END SUBROUTINE dyn_hpg_init
182
183
184   SUBROUTINE hpg_zco( kt )
185      !!---------------------------------------------------------------------
186      !!                  ***  ROUTINE hpg_zco  ***
187      !!
188      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
189      !!      The now hydrostatic pressure gradient at a given level, jk,
190      !!      is computed by taking the vertical integral of the in-situ
191      !!      density gradient along the model level from the suface to that
192      !!      level:    zhpi = grav .....
193      !!                zhpj = grav .....
194      !!      add it to the general momentum trend (ua,va).
195      !!            ua = ua - 1/e1u * zhpi
196      !!            va = va - 1/e2v * zhpj
197      !!
198      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
199      !!----------------------------------------------------------------------
200      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
201      !!
202      INTEGER  ::   ji, jj, jk       ! dummy loop indices
203      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
204      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
205      !!----------------------------------------------------------------------
206      !
207      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
208      !
209      IF( kt == nit000 ) THEN
210         IF(lwp) WRITE(numout,*)
211         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
212         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
213      ENDIF
214
215      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
216
217      ! Surface value
218      DO jj = 2, jpjm1
219         DO ji = fs_2, fs_jpim1   ! vector opt.
220            zcoef1 = zcoef0 * fse3w(ji,jj,1)
221            ! hydrostatic pressure gradient
222            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
223            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
224            ! add to the general momentum trend
225            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
226            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
227         END DO
228      END DO
229
230      !
231      ! interior value (2=<jk=<jpkm1)
232      DO jk = 2, jpkm1
233         DO jj = 2, jpjm1
234            DO ji = fs_2, fs_jpim1   ! vector opt.
235               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
236               ! hydrostatic pressure gradient
237               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
238                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
239                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
240
241               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
242                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
243                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
244               ! add to the general momentum trend
245               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
246               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
247            END DO
248         END DO
249      END DO
250      !
251      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
252      !
253   END SUBROUTINE hpg_zco
254
255
256   SUBROUTINE hpg_zps( kt )
257      !!---------------------------------------------------------------------
258      !!                 ***  ROUTINE hpg_zps  ***
259      !!
260      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
261      !!
262      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
263      !!----------------------------------------------------------------------
264      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
265      !!
266      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
267      INTEGER  ::   iku, ikv                         ! temporary integers
268      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
269      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
270      !!----------------------------------------------------------------------
271      !
272      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
273      !
274      IF( kt == nit000 ) THEN
275         IF(lwp) WRITE(numout,*)
276         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
277         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
278      ENDIF
279
280
281      ! Local constant initialization
282      zcoef0 = - grav * 0.5_wp
283
284      !  Surface value (also valid in partial step case)
285      DO jj = 2, jpjm1
286         DO ji = fs_2, fs_jpim1   ! vector opt.
287            zcoef1 = zcoef0 * fse3w(ji,jj,1)
288            ! hydrostatic pressure gradient
289            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
290            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
291            ! add to the general momentum trend
292            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
293            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
294         END DO
295      END DO
296
297
298      ! interior value (2=<jk=<jpkm1)
299      DO jk = 2, jpkm1
300         DO jj = 2, jpjm1
301            DO ji = fs_2, fs_jpim1   ! vector opt.
302               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
303               ! hydrostatic pressure gradient
304               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
305                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
306                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
307
308               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
309                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
310                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
311               ! add to the general momentum trend
312               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
313               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
314            END DO
315         END DO
316      END DO
317
318
319      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
320# if defined key_vectopt_loop
321         jj = 1
322         DO ji = jpi+2, jpij-jpi-1   ! vector opt. (forced unrolling)
323# else
324      DO jj = 2, jpjm1
325         DO ji = 2, jpim1
326# endif
327            iku = mbku(ji,jj)
328            ikv = mbkv(ji,jj)
329            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
330            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
331            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
332               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
333               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
334                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
335               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
336            ENDIF
337            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
338               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
339               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
340                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
341               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
342            ENDIF
343# if ! defined key_vectopt_loop
344         END DO
345# endif
346      END DO
347      !
348      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
349      !
350   END SUBROUTINE hpg_zps
351
352
353   SUBROUTINE hpg_sco( kt )
354      !!---------------------------------------------------------------------
355      !!                  ***  ROUTINE hpg_sco  ***
356      !!
357      !! ** Method  :   s-coordinate case. Jacobian scheme.
358      !!      The now hydrostatic pressure gradient at a given level, jk,
359      !!      is computed by taking the vertical integral of the in-situ
360      !!      density gradient along the model level from the suface to that
361      !!      level. s-coordinates (ln_sco): a corrective term is added
362      !!      to the horizontal pressure gradient :
363      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
364      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
365      !!      add it to the general momentum trend (ua,va).
366      !!         ua = ua - 1/e1u * zhpi
367      !!         va = va - 1/e2v * zhpj
368      !!
369      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
370      !!----------------------------------------------------------------------
371      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
372      !!
373      INTEGER  ::   ji, jj, jk, iku, ikv, ikt, iktp1i, iktp1j                 ! dummy loop indices
374      REAL(wp) ::   zcoef0, zuap, zvap, znad, ze3wu, ze3wv, zuapint, zvapint, zhpjint, zhpiint, zdzwt, zdzwtjp1, zdzwtip1             ! temporary scalars
375      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  zhpi, zhpj, zrhd
376      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop
377      REAL(wp), POINTER, DIMENSION(:,:)     ::  ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj
378      !!----------------------------------------------------------------------
379      !
380      CALL wrk_alloc( jpi,jpj, 2, ztstop) 
381      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
382      CALL wrk_alloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj) 
383      !
384     IF( kt == nit000 ) THEN
385         IF(lwp) WRITE(numout,*)
386         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
387         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
388      ENDIF
389
390      ! Local constant initialization
391      zcoef0 = - grav * 0.5_wp
392      ! To use density and not density anomaly
393!      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
394!      ELSE                 ;     znad = 0._wp         ! Fixed volume
395!      ENDIF
396      znad=1._wp
397      ! iniitialised to 0. zhpi zhpi
398      zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
399     
400      ! assume density of water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
401      ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
402      zrhd = rhd ! save rhd
403      DO jk = 1, jpk
404           zdept(:,:)=gdept_1d(jk)
405           CALL eos(ztstop(:,:,:),zdept(:,:),rhd(:,:,jk))
406      END DO
407      WHERE ( tmask(:,:,:) == 1._wp)
408        rhd(:,:,:) = zrhd(:,:,:) ! replace wet cell by the saved rhd
409      END WHERE
410     
411      ! compute rhd at the ice/oce interface (ice shelf side)
412      CALL eos(ztstop,risfdep,zrhdtop_isf)
413
414      ! compute rhd at the ice/oce interface (ocean side)
415      DO ji=1,jpi
416        DO jj=1,jpj
417          ikt=mikt(ji,jj)
418          ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
419          ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
420        END DO
421      END DO
422      CALL eos(ztstop,risfdep,zrhdtop_oce)
423      !
424      ! Surface value + ice shelf gradient
425      ! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
426      ziceload = 0._wp
427      DO jj = 1, jpj
428         DO ji = 1, jpi   ! vector opt.
429            ikt=mikt(ji,jj)
430            ziceload(ji,jj) = ziceload(ji,jj) + (znad + rhd(ji,jj,1) ) * fse3w(ji,jj,1) * (1._wp - tmask(ji,jj,1))
431            DO jk=2,ikt-1
432               ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + rhd(ji,jj,jk-1) + rhd(ji,jj,jk)) * fse3w(ji,jj,jk) &
433                  &                              * (1._wp - tmask(ji,jj,jk))
434            END DO
435            IF (ikt .GE. 2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + rhd(ji,jj,ikt-1)) &
436                               &                              * ( fsdepw(ji,jj,ikt) - gdept_1d(ikt-1) )
437         END DO
438      END DO
439      riceload(:,:) = 0.0_wp ; riceload(:,:)=ziceload(:,:)  ! need to be saved for diaar5
440      ! compute zp from z=0 to first T wet point (correction due to zps not yet applied)
441      DO jj = 2, jpjm1
442         DO ji = fs_2, fs_jpim1   ! vector opt.
443            ikt=mikt(ji,jj) ; iktp1i=mikt(ji+1,jj); iktp1j=mikt(ji,jj+1)
444            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
445            ! we assume ISF is in isostatic equilibrium
446            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * fse3w(ji+1,jj  ,iktp1i)                                    &
447               &                                  * ( 2._wp * znad + rhd(ji+1,jj  ,iktp1i) + zrhdtop_oce(ji+1,jj  ) )   &
448               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    &
449               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
450               &                                  + ( ziceload(ji+1,jj) - ziceload(ji,jj))                              ) 
451            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * fse3w(ji  ,jj+1,iktp1j)                                    &
452               &                                  * ( 2._wp * znad + rhd(ji  ,jj+1,iktp1j) + zrhdtop_oce(ji  ,jj+1) )   &
453               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    & 
454               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
455               &                                  + ( ziceload(ji,jj+1) - ziceload(ji,jj) )                             ) 
456            ! s-coordinate pressure gradient correction (=0 if z coordinate)
457            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
458               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
459            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
460               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
461            ! add to the general momentum trend
462            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
463            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
464         END DO
465      END DO
466      !
467      DO jj = 2, jpjm1
468         DO ji = fs_2, fs_jpim1   ! vector opt.
469            iku = miku(ji,jj) ; 
470            zpshpi(ji,jj)=0.0_wp ; zpshpj(ji,jj)=0.0_wp
471            ze3wu  = fse3w(ji+1,jj,iku+1)-fse3w(ji,jj,iku+1) 
472            ! u direction
473            IF ( iku .GT. 1 ) THEN
474               ! case iku
475               zhpi(ji,jj,iku)   =  zcoef0 / e1u(ji,jj) * ze3wu                                            &
476                      &                                 * ( rhd    (ji+1,jj,iku) + rhd   (ji,jj,iku)       &
477                      &                                   + SIGN(1._wp,ze3wu) * grui(ji,jj) + 2._wp * znad )
478               ! corrective term ( = 0 if z coordinate )
479               zuap              = -zcoef0 * ( arui(ji,jj) + 2._wp * znad ) * gzui(ji,jj) / e1u(ji,jj)
480               ! zhpi will be added in interior loop and zuapint will be removed in the interior loop
481               ua(ji,jj,iku)     = ua(ji,jj,iku) + zuap
482               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
483               IF (mbku(ji,jj) == iku + 1) zpshpi(ji,jj)  = zhpi(ji,jj,iku)
484
485               ! zhpi will be added in interior loop and zuapint will be removed in the interior loop
486               ! case iku + 1 (remove the zphi term added in the interior loop)
487               zhpiint        =  zcoef0 / e1u(ji,jj)                                                             &   
488                  &           * (  fse3w(ji+1,jj  ,iku+1) * ( (rhd(ji+1,jj,iku+1) + znad)                          &
489                  &                                         + (rhd(ji+1,jj,iku  ) + znad) ) * tmask(ji+1,jj,iku)   &
490                  &              - fse3w(ji  ,jj  ,iku+1) * ( (rhd(ji  ,jj,iku+1) + znad)                          &
491                  &                                         + (rhd(ji  ,jj,iku  ) + znad) ) * tmask(ji  ,jj,iku)   )
492               zhpi(ji,jj,iku+1) =  zcoef0 / e1u(ji,jj) * ge3rui(ji,jj) - zhpiint 
493            END IF
494            ! v direction
495            ikv = mikv(ji,jj)
496            ze3wv  = fse3w(ji,jj+1,ikv+1)-fse3w(ji,jj,ikv+1) 
497            IF ( ikv .GT. 1 ) THEN
498               ! case ikv
499               zhpj(ji,jj,ikv)   =  zcoef0 / e2v(ji,jj) * ze3wv                                            &
500                     &                                  * ( rhd(ji,jj+1,ikv) + rhd   (ji,jj,ikv)           &
501                     &                                    + SIGN(1._wp,ze3wv) * grvi(ji,jj) + 2._wp * znad )
502               ! corrective term ( = 0 if z coordinate )
503               zvap              = -zcoef0 * ( arvi(ji,jj) + 2._wp * znad ) * gzvi(ji,jj) / e2v(ji,jj)
504               ! zhpi will be added in interior loop and zvapint will be removed in the interior loop
505               va(ji,jj,ikv)      = va(ji,jj,ikv) + zvap
506               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
507               IF (mbkv(ji,jj) == ikv + 1)  zpshpj(ji,jj)  =  zhpj(ji,jj,ikv) 
508               ! zhpi will be added in interior loop and zvapint will be removed in the interior loop
509               ! case ikv + 1 (remove the zphj term added in the interior loop)
510               zhpjint        =  zcoef0 / e2v(ji,jj)                                                            &
511                  &           * (  fse3w(ji  ,jj+1,ikv+1) * ( (rhd(ji,jj+1,ikv+1) + znad)                         &
512                  &                                       + (rhd(ji,jj+1,ikv  ) + znad) ) * tmask(ji,jj+1,ikv)  &
513                  &              - fse3w(ji  ,jj  ,ikv+1) * ( (rhd(ji,jj  ,ikv+1) + znad)                         &
514                  &                                       + (rhd(ji,jj  ,ikv  ) + znad) ) * tmask(ji,jj  ,ikv)  )
515               zhpj(ji,jj,ikv+1) =  zcoef0 / e2v(ji,jj) * ge3rvi(ji,jj) - zhpjint
516            END IF
517         END DO
518      END DO
519
520      ! interior value (2=<jk=<jpkm1)
521      DO jj = 2, jpjm1
522         DO ji = fs_2, fs_jpim1   ! vector opt.
523            iku=miku(ji,jj); ikv=mikv(ji,jj)
524            DO jk = 2, jpkm1
525               ! hydrostatic pressure gradient along s-surfaces
526               ! s-coordinate pressure gradient correction
527               zhpi(ji,jj,jk) = zhpi(ji,jj,jk) + zhpi(ji,jj,jk-1)                                                              &
528                  &                            + zcoef0 / e1u(ji,jj)                                                           &
529                  &                                     * ( fse3w(ji+1,jj  ,jk) * ( (rhd(ji+1,jj,jk  ) + znad)                 &
530                  &                                                     + (rhd(ji+1,jj,jk-1) + znad) ) * tmask(ji+1,jj,jk-1)   &
531                  &                                       - fse3w(ji  ,jj  ,jk) * ( (rhd(ji  ,jj,jk  ) + znad)                 &
532                  &                                                     + (rhd(ji  ,jj,jk-1) + znad) ) * tmask(ji  ,jj,jk-1)   ) 
533             !corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
534               zuap = - zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
535                  &            * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj) * umask(ji,jj,jk-1)
536               ua(ji,jj,jk) = ua(ji,jj,jk) + ( zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
537
538               zhpj(ji,jj,jk) = zhpj(ji,jj,jk) + zhpj(ji,jj,jk-1)                                                              &
539                  &                            + zcoef0 / e2v(ji,jj)                                                           &
540                  &                                     * ( fse3w(ji  ,jj+1,jk) * ( (rhd(ji,jj+1,jk  ) + znad)                 &
541                  &                                                     + (rhd(ji,jj+1,jk-1) + znad) ) * tmask(ji,jj+1,jk-1)   &
542                  &                                       - fse3w(ji  ,jj  ,jk) * ( (rhd(ji,jj  ,jk  ) + znad)                 &
543                  &                                                     + (rhd(ji,jj  ,jk-1) + znad) ) * tmask(ji,jj  ,jk-1)   )
544             !corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
545               zvap = - zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
546                  &            * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj) * vmask(ji,jj,jk-1)
547               ! add to the general momentum trend
548               va(ji,jj,jk) = va(ji,jj,jk) + ( zhpj(ji,jj,jk) + zvap ) * vmask(ji,jj,jk)
549            END DO
550         END DO
551      END DO
552     
553      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
554# if defined key_vectopt_loop
555         jj = 1
556         DO ji = jpi+2, jpij-jpi-1   ! vector opt. (forced unrolling)
557# else
558      DO jj = 2, jpjm1
559         DO ji = 2, jpim1
560# endif
561            iku = mbku(ji,jj)
562            ikv = mbkv(ji,jj)
563
564            IF (iku .GT. 1) THEN
565               ! remove old value (interior case)
566               zuap            = -zcoef0 * ( rhd   (ji+1,jj  ,iku) + rhd   (ji,jj,iku) + 2._wp * znad )   &
567                     &                   * ( fsde3w(ji+1,jj  ,iku) - fsde3w(ji,jj,iku) ) / e1u(ji,jj)
568               ua(ji,jj,iku)   = ua(ji,jj,iku) - zhpi(ji,jj,iku) - zuap
569               ! put new value
570               ! -zpshpi to avoid double contribution of the partial step in the top layer
571               zuap            = -zcoef0 * ( aru(ji,jj) + 2._wp * znad ) * gzu(ji,jj)  / e1u(ji,jj)
572               zhpi(ji,jj,iku) =  zhpi(ji,jj,iku-1) + zcoef0 / e1u(ji,jj) * ge3ru(ji,jj) - zpshpi(ji,jj) 
573               ua(ji,jj,iku)   =  ua(ji,jj,iku) + zhpi(ji,jj,iku) + zuap
574            END IF
575            ! v direction
576            IF (ikv .GT. 1) THEN
577               ! remove old value (interior case)
578               zvap            = -zcoef0 * ( rhd   (ji  ,jj+1,ikv) + rhd   (ji,jj,ikv) + 2._wp * znad )   &
579                     &                   * ( fsde3w(ji  ,jj+1,ikv) - fsde3w(ji,jj,ikv) )   / e2v(ji,jj)
580               va(ji,jj,ikv)   = va(ji,jj,ikv) - zhpj(ji,jj,ikv) - zvap
581               ! put new value
582               ! -zpshpj to avoid double contribution of the partial step in the top layer
583               zvap            = -zcoef0 * ( arv(ji,jj) + 2._wp * znad ) * gzv(ji,jj)     / e2v(ji,jj)
584               zhpj(ji,jj,ikv) =  zhpj(ji,jj,ikv-1) + zcoef0 / e2v(ji,jj) * ge3rv(ji,jj) - zpshpj(ji,jj)   
585               va(ji,jj,ikv)   =  va(ji,jj,ikv) + zhpj(ji,jj,ikv) + zvap
586            END IF
587# if ! defined key_vectopt_loop
588         END DO
589# endif
590      END DO
591
592
593      rhd = zrhd
594      !
595      CALL wrk_dealloc( jpi,jpj,2, ztstop)
596      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
597      CALL wrk_dealloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
598      !
599   END SUBROUTINE hpg_sco
600
601   SUBROUTINE hpg_djc( kt )
602      !!---------------------------------------------------------------------
603      !!                  ***  ROUTINE hpg_djc  ***
604      !!
605      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
606      !!
607      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
608      !!----------------------------------------------------------------------
609      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
610      !!
611      INTEGER  ::   ji, jj, jk          ! dummy loop indices
612      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
613      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
614      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
615      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
616      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
617      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
618      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
619      !!----------------------------------------------------------------------
620      !
621      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
622      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
623      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
624      !
625
626      IF( kt == nit000 ) THEN
627         IF(lwp) WRITE(numout,*)
628         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
629         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
630      ENDIF
631
632      ! Local constant initialization
633      zcoef0 = - grav * 0.5_wp
634      z1_10  = 1._wp / 10._wp
635      z1_12  = 1._wp / 12._wp
636
637      !----------------------------------------------------------------------------------------
638      !  compute and store in provisional arrays elementary vertical and horizontal differences
639      !----------------------------------------------------------------------------------------
640
641!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
642
643      DO jk = 2, jpkm1
644         DO jj = 2, jpjm1
645            DO ji = fs_2, fs_jpim1   ! vector opt.
646               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
647               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
648               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
649               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
650               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
651               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
652            END DO
653         END DO
654      END DO
655
656      !-------------------------------------------------------------------------
657      ! compute harmonic averages using eq. 5.18
658      !-------------------------------------------------------------------------
659      zep = 1.e-15
660
661!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
662!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
663
664      DO jk = 2, jpkm1
665         DO jj = 2, jpjm1
666            DO ji = fs_2, fs_jpim1   ! vector opt.
667               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
668
669               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
670               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
671
672               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
673               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
674
675               IF( cffw > zep) THEN
676                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
677                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
678               ELSE
679                  drhow(ji,jj,jk) = 0._wp
680               ENDIF
681
682               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
683                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
684
685               IF( cffu > zep ) THEN
686                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
687                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
688               ELSE
689                  drhou(ji,jj,jk ) = 0._wp
690               ENDIF
691
692               IF( cffx > zep ) THEN
693                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
694                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
695               ELSE
696                  dzu(ji,jj,jk) = 0._wp
697               ENDIF
698
699               IF( cffv > zep ) THEN
700                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
701                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
702               ELSE
703                  drhov(ji,jj,jk) = 0._wp
704               ENDIF
705
706               IF( cffy > zep ) THEN
707                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
708                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
709               ELSE
710                  dzv(ji,jj,jk) = 0._wp
711               ENDIF
712
713            END DO
714         END DO
715      END DO
716
717      !----------------------------------------------------------------------------------
718      ! apply boundary conditions at top and bottom using 5.36-5.37
719      !----------------------------------------------------------------------------------
720      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
721      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
722      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
723
724      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
725      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
726      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
727
728
729      !--------------------------------------------------------------
730      ! Upper half of top-most grid box, compute and store
731      !-------------------------------------------------------------
732
733!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
734!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
735
736      DO jj = 2, jpjm1
737         DO ji = fs_2, fs_jpim1   ! vector opt.
738            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )               &
739               &                   * (  rhd(ji,jj,1)                                    &
740               &                     + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
741               &                              * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
742               &                              / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  )
743         END DO
744      END DO
745
746!!bug gm    : here also, simplification is possible
747!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
748
749      DO jk = 2, jpkm1
750         DO jj = 2, jpjm1
751            DO ji = fs_2, fs_jpim1   ! vector opt.
752
753               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
754                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
755                  &            - grav * z1_10 * (                                                                     &
756                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
757                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
758                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
759                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
760                  &                             )
761
762               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
763                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
764                  &            - grav* z1_10 * (                                                                      &
765                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
766                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
767                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
768                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
769                  &                            )
770
771               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
772                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
773                  &            - grav* z1_10 * (                                                                      &
774                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
775                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
776                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
777                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
778                  &                            )
779
780            END DO
781         END DO
782      END DO
783      CALL lbc_lnk(rho_k,'W',1.)
784      CALL lbc_lnk(rho_i,'U',1.)
785      CALL lbc_lnk(rho_j,'V',1.)
786
787
788      ! ---------------
789      !  Surface value
790      ! ---------------
791      DO jj = 2, jpjm1
792         DO ji = fs_2, fs_jpim1   ! vector opt.
793            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
794            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
795            ! add to the general momentum trend
796            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
797            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
798         END DO
799      END DO
800
801      ! ----------------
802      !  interior value   (2=<jk=<jpkm1)
803      ! ----------------
804      DO jk = 2, jpkm1
805         DO jj = 2, jpjm1
806            DO ji = fs_2, fs_jpim1   ! vector opt.
807               ! hydrostatic pressure gradient along s-surfaces
808               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
809                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
810                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
811               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
812                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
813                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
814               ! add to the general momentum trend
815               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
816               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
817            END DO
818         END DO
819      END DO
820      !
821      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
822      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
823      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
824      !
825   END SUBROUTINE hpg_djc
826
827
828   SUBROUTINE hpg_prj( kt )
829      !!---------------------------------------------------------------------
830      !!                  ***  ROUTINE hpg_prj  ***
831      !!
832      !! ** Method  :   s-coordinate case.
833      !!      A Pressure-Jacobian horizontal pressure gradient method
834      !!      based on the constrained cubic-spline interpolation for
835      !!      all vertical coordinate systems
836      !!
837      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
838      !!             - Save the trend (l_trddyn=T)
839      !!
840      !!----------------------------------------------------------------------
841      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
842      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
843      !!
844      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
845      REAL(wp) ::   zcoef0, znad                    ! temporary scalars
846      !!
847      !! The local variables for the correction term
848      INTEGER  :: jk1, jis, jid, jjs, jjd
849      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
850      REAL(wp) :: zrhdt1
851      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
852      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh
853      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
854      !!----------------------------------------------------------------------
855      !
856      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
857      CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
858      !
859      IF( kt == nit000 ) THEN
860         IF(lwp) WRITE(numout,*)
861         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
862         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
863      ENDIF
864
865      !!----------------------------------------------------------------------
866      ! Local constant initialization
867      zcoef0 = - grav
868      znad = 0.0_wp
869      IF( lk_vvl ) znad = 1._wp
870
871      ! Clean 3-D work arrays
872      zhpi(:,:,:) = 0._wp
873      zrhh(:,:,:) = rhd(:,:,:)
874
875      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
876      DO jj = 1, jpj
877        DO ji = 1, jpi
878          jk = mbathy(ji,jj)
879          IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
880          ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
881          ELSE IF(jk < jpkm1) THEN
882             DO jkk = jk+1, jpk
883                zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk),   fsde3w(ji,jj,jkk-1), &
884                                         fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
885             END DO
886          ENDIF
887        END DO
888      END DO
889
890      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
891      DO jj = 1, jpj;   DO ji = 1, jpi
892          zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
893      END DO        ;   END DO
894
895      DO jk = 2, jpk;   DO jj = 1, jpj;   DO ji = 1, jpi
896          zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
897      END DO        ;   END DO        ;   END DO
898
899      fsp(:,:,:) = zrhh(:,:,:)
900      xsp(:,:,:) = zdept(:,:,:)
901
902      ! Construct the vertical density profile with the
903      ! constrained cubic spline interpolation
904      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
905      CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
906
907      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
908      DO jj = 2, jpj
909        DO ji = 2, jpi
910          zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
911                                         bsp(ji,jj,1),   csp(ji,jj,1), &
912                                         dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
913
914          ! assuming linear profile across the top half surface layer
915          zhpi(ji,jj,1) =  0.5_wp * fse3w(ji,jj,1) * zrhdt1
916        END DO
917      END DO
918
919      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
920      DO jk = 2, jpkm1
921        DO jj = 2, jpj
922          DO ji = 2, jpi
923            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                          &
924                             integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
925                                    asp(ji,jj,jk-1),    bsp(ji,jj,jk-1), &
926                                    csp(ji,jj,jk-1),    dsp(ji,jj,jk-1))
927          END DO
928        END DO
929      END DO
930
931      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
932      DO jj = 2, jpjm1
933        DO ji = 2, jpim1
934          zu(ji,jj,1) = - ( fse3u(ji,jj,1) - sshn(ji,jj) * znad)    ! probable bug: changed from sshu_n for ztilde compilation
935          zv(ji,jj,1) = - ( fse3v(ji,jj,1) - sshn(ji,jj) * znad)    ! probable bug: changed from sshv_n for ztilde compilation
936        END DO
937      END DO
938
939      DO jk = 2, jpkm1
940        DO jj = 2, jpjm1
941          DO ji = 2, jpim1
942            zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
943            zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
944          END DO
945        END DO
946      END DO
947
948      DO jk = 1, jpkm1
949        DO jj = 2, jpjm1
950          DO ji = 2, jpim1
951            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
952            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
953          END DO
954        END DO
955      END DO
956
957      DO jk = 1, jpkm1
958        DO jj = 2, jpjm1
959          DO ji = 2, jpim1
960            zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
961            zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
962            zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
963            zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
964          END DO
965        END DO
966      END DO
967
968
969      DO jk = 1, jpkm1
970        DO jj = 2, jpjm1
971          DO ji = 2, jpim1
972            zpwes = 0._wp; zpwed = 0._wp
973            zpnss = 0._wp; zpnsd = 0._wp
974            zuijk = zu(ji,jj,jk)
975            zvijk = zv(ji,jj,jk)
976
977            !!!!!     for u equation
978            IF( jk <= mbku(ji,jj) ) THEN
979               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
980                 jis = ji + 1; jid = ji
981               ELSE
982                 jis = ji;     jid = ji +1
983               ENDIF
984
985               ! integrate the pressure on the shallow side
986               jk1 = jk
987               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
988                 IF( jk1 == mbku(ji,jj) ) THEN
989                   zuijk = -zdept(jis,jj,jk1)
990                   EXIT
991                 ENDIF
992                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
993                 zpwes = zpwes +                                    &
994                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
995                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
996                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
997                 jk1 = jk1 + 1
998               END DO
999
1000               ! integrate the pressure on the deep side
1001               jk1 = jk
1002               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1003                 IF( jk1 == 1 ) THEN
1004                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1005                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1006                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1007                                                     dsp(jid,jj,1)) * zdeps
1008                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1009                   EXIT
1010                 ENDIF
1011                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1012                 zpwed = zpwed +                                        &
1013                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1014                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1015                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1016                 jk1 = jk1 - 1
1017               END DO
1018
1019               ! update the momentum trends in u direction
1020
1021               zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
1022               IF( lk_vvl ) THEN
1023                 zdpdx2 = zcoef0 / e1u(ji,jj) * &
1024                         ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1025                ELSE
1026                 zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1027               ENDIF
1028
1029               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
1030               &           umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
1031            ENDIF
1032
1033            !!!!!     for v equation
1034            IF( jk <= mbkv(ji,jj) ) THEN
1035               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1036                 jjs = jj + 1; jjd = jj
1037               ELSE
1038                 jjs = jj    ; jjd = jj + 1
1039               ENDIF
1040
1041               ! integrate the pressure on the shallow side
1042               jk1 = jk
1043               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1044                 IF( jk1 == mbkv(ji,jj) ) THEN
1045                   zvijk = -zdept(ji,jjs,jk1)
1046                   EXIT
1047                 ENDIF
1048                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1049                 zpnss = zpnss +                                      &
1050                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1051                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1052                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1053                 jk1 = jk1 + 1
1054               END DO
1055
1056               ! integrate the pressure on the deep side
1057               jk1 = jk
1058               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1059                 IF( jk1 == 1 ) THEN
1060                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1061                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1062                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1063                                                     dsp(ji,jjd,1) ) * zdeps
1064                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1065                   EXIT
1066                 ENDIF
1067                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1068                 zpnsd = zpnsd +                                        &
1069                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1070                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1071                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1072                 jk1 = jk1 - 1
1073               END DO
1074
1075
1076               ! update the momentum trends in v direction
1077
1078               zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
1079               IF( lk_vvl ) THEN
1080                   zdpdy2 = zcoef0 / e2v(ji,jj) * &
1081                           ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1082               ELSE
1083                   zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1084               ENDIF
1085
1086               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
1087               &              vmask(ji,jj,jk)*tmask(ji,jj,jk)*tmask(ji,jj+1,jk)
1088            ENDIF
1089
1090
1091           END DO
1092        END DO
1093      END DO
1094      !
1095      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1096      CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
1097      !
1098   END SUBROUTINE hpg_prj
1099
1100   SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
1101      !!----------------------------------------------------------------------
1102      !!                 ***  ROUTINE cspline  ***
1103      !!
1104      !! ** Purpose :   constrained cubic spline interpolation
1105      !!
1106      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1107      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1108      !!
1109      !!----------------------------------------------------------------------
1110      IMPLICIT NONE
1111      REAL(wp), DIMENSION(:,:,:), INTENT(in)  :: fsp, xsp           ! value and coordinate
1112      REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
1113                                                                    ! the interpoated function
1114      INTEGER, INTENT(in) :: polynomial_type                        ! 1: cubic spline
1115                                                                    ! 2: Linear
1116
1117      ! Local Variables
1118      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1119      INTEGER  ::   jpi, jpj, jpkm1
1120      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1121      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1122      REAL(wp) ::   zdf(size(fsp,3))
1123      !!----------------------------------------------------------------------
1124
1125      jpi   = size(fsp,1)
1126      jpj   = size(fsp,2)
1127      jpkm1 = size(fsp,3) - 1
1128
1129
1130      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1131         DO ji = 1, jpi
1132            DO jj = 1, jpj
1133           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1134           !    DO jk = 2, jpkm1-1
1135           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1136           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1137           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1138           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1139           !
1140           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1141           !
1142           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1143           !           zdf(jk) = 0._wp
1144           !       ELSE
1145           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1146           !       ENDIF
1147           !    END DO
1148
1149           !!Simply geometric average
1150               DO jk = 2, jpkm1-1
1151                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1152                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1153
1154                  IF(zdf1 * zdf2 <= 0._wp) THEN
1155                     zdf(jk) = 0._wp
1156                  ELSE
1157                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1158                  ENDIF
1159               END DO
1160
1161               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1162                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) ) -  0.5_wp * zdf(2)
1163               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1164                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1165                          & 0.5_wp * zdf(jpkm1 - 1)
1166
1167               DO jk = 1, jpkm1 - 1
1168                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1169                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1170                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1171                 zddf1  = -2._wp * ztmp1 + ztmp2
1172                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1173                 zddf2  =  2._wp * ztmp1 - ztmp2
1174
1175                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1176                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1177                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1178                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1179                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1180                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1181                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1182                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1183                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1184               END DO
1185            END DO
1186         END DO
1187
1188      ELSE IF (polynomial_type == 2) THEN     ! Linear
1189         DO ji = 1, jpi
1190            DO jj = 1, jpj
1191               DO jk = 1, jpkm1-1
1192                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1193                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1194
1195                  dsp(ji,jj,jk) = 0._wp
1196                  csp(ji,jj,jk) = 0._wp
1197                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1198                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1199               END DO
1200            END DO
1201         END DO
1202
1203      ELSE
1204           CALL ctl_stop( 'invalid polynomial type in cspline' )
1205      ENDIF
1206
1207
1208   END SUBROUTINE cspline
1209
1210
1211   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1212      !!----------------------------------------------------------------------
1213      !!                 ***  ROUTINE interp1  ***
1214      !!
1215      !! ** Purpose :   1-d linear interpolation
1216      !!
1217      !! ** Method  :
1218      !!                interpolation is straight forward
1219      !!                extrapolation is also permitted (no value limit)
1220      !!
1221      !!----------------------------------------------------------------------
1222      IMPLICIT NONE
1223      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1224      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1225      REAL(wp)             ::  zdeltx
1226      !!----------------------------------------------------------------------
1227
1228      zdeltx = xr - xl
1229      IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1230        f = 0.5_wp * (fl + fr)
1231      ELSE
1232        f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1233      ENDIF
1234
1235   END FUNCTION interp1
1236
1237   FUNCTION interp2(x, a, b, c, d)  RESULT(f)
1238      !!----------------------------------------------------------------------
1239      !!                 ***  ROUTINE interp1  ***
1240      !!
1241      !! ** Purpose :   1-d constrained cubic spline interpolation
1242      !!
1243      !! ** Method  :  cubic spline interpolation
1244      !!
1245      !!----------------------------------------------------------------------
1246      IMPLICIT NONE
1247      REAL(wp), INTENT(in) ::  x, a, b, c, d
1248      REAL(wp)             ::  f ! value from the interpolation
1249      !!----------------------------------------------------------------------
1250
1251      f = a + x* ( b + x * ( c + d * x ) )
1252
1253   END FUNCTION interp2
1254
1255
1256   FUNCTION interp3(x, a, b, c, d)  RESULT(f)
1257      !!----------------------------------------------------------------------
1258      !!                 ***  ROUTINE interp1  ***
1259      !!
1260      !! ** Purpose :   Calculate the first order of deriavtive of
1261      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1262      !!
1263      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1264      !!
1265      !!----------------------------------------------------------------------
1266      IMPLICIT NONE
1267      REAL(wp), INTENT(in) ::  x, a, b, c, d
1268      REAL(wp)             ::  f ! value from the interpolation
1269      !!----------------------------------------------------------------------
1270
1271      f = b + x * ( 2._wp * c + 3._wp * d * x)
1272
1273   END FUNCTION interp3
1274
1275
1276   FUNCTION integ_spline(xl, xr, a, b, c, d)  RESULT(f)
1277      !!----------------------------------------------------------------------
1278      !!                 ***  ROUTINE interp1  ***
1279      !!
1280      !! ** Purpose :   1-d constrained cubic spline integration
1281      !!
1282      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1283      !!
1284      !!----------------------------------------------------------------------
1285      IMPLICIT NONE
1286      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1287      REAL(wp)             ::  za1, za2, za3
1288      REAL(wp)             ::  f                   ! integration result
1289      !!----------------------------------------------------------------------
1290
1291      za1 = 0.5_wp * b
1292      za2 = c / 3.0_wp
1293      za3 = 0.25_wp * d
1294
1295      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1296         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1297
1298   END FUNCTION integ_spline
1299
1300
1301   !!======================================================================
1302END MODULE dynhpg
1303
Note: See TracBrowser for help on using the repository browser.