source: branches/2014/dev_r4650_UKMO2_ice_shelves/NEMOGCM/NEMO/OPA_SRC/LDF/ldfeiv.F90 @ 4726

Last change on this file since 4726 was 4726, checked in by mathiot, 6 years ago

ISF branch: change name of 2 variables (icedep ⇒ risfdep and lmask ⇒ ssmask), cosmetic changes and add ldfslp key

  • Property svn:keywords set to Id
File size: 11.3 KB
Line 
1MODULE ldfeiv
2   !!======================================================================
3   !!                     ***  MODULE  ldfeiv  ***
4   !! Ocean physics:  variable eddy induced velocity coefficients
5   !!======================================================================
6   !! History :  OPA  ! 1999-03  (G. Madec, A. Jouzeau)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  Free form, F90
8   !!----------------------------------------------------------------------
9#if   defined key_traldf_eiv   &&   defined key_traldf_c2d
10   !!----------------------------------------------------------------------
11   !!   'key_traldf_eiv'      and                     eddy induced velocity
12   !!   'key_traldf_c2d'                    2D tracer lateral  mixing coef.
13   !!----------------------------------------------------------------------
14   !!   ldf_eiv      : compute the eddy induced velocity coefficients
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and tracers
17   USE dom_oce         ! ocean space and time domain
18   USE sbc_oce         ! surface boundary condition: ocean
19   USE sbcrnf          ! river runoffs
20   USE ldftra_oce      ! ocean tracer   lateral physics
21   USE phycst          ! physical constants
22   USE ldfslp          ! iso-neutral slopes
23   USE in_out_manager  ! I/O manager
24   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
25   USE prtctl          ! Print control
26   USE iom             ! I/O library
27   USE wrk_nemo        ! work arrays
28   USE timing          ! Timing
29
30   IMPLICIT NONE
31   PRIVATE
32   
33   PUBLIC   ldf_eiv    ! routine called by step.F90
34   
35   !! * Substitutions
36#  include "domzgr_substitute.h90"
37#  include "vectopt_loop_substitute.h90"
38   !!----------------------------------------------------------------------
39   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
40   !! $Id$
41   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
42   !!----------------------------------------------------------------------
43CONTAINS
44
45   SUBROUTINE ldf_eiv( kt )
46      !!----------------------------------------------------------------------
47      !!                  ***  ROUTINE ldf_eiv  ***
48      !!
49      !! ** Purpose :   Compute the eddy induced velocity coefficient from the
50      !!              growth rate of baroclinic instability.
51      !!
52      !! ** Method :
53      !!
54      !! ** Action : - uslp , vslp  : i- and j-slopes of neutral surfaces at u- & v-points
55      !!             - wslpi, wslpj : i- and j-slopes of neutral surfaces at w-points.
56      !!----------------------------------------------------------------------
57      INTEGER, INTENT(in) ::   kt   ! ocean time-step inedx
58      !
59      INTEGER  ::   ji, jj, jk   ! dummy loop indices
60      REAL(wp) ::   zfw, ze3w, zn2, zf20, zaht, zaht_min      ! temporary scalars
61      REAL(wp), DIMENSION(:,:), POINTER ::   zn, zah, zhw, zross   ! 2D workspace
62      !!----------------------------------------------------------------------
63      !
64      IF( nn_timing == 1 )  CALL timing_start('ldf_eiv')
65      !
66      CALL wrk_alloc( jpi,jpj, zn, zah, zhw, zross )
67
68      IF( kt == nit000 ) THEN
69         IF(lwp) WRITE(numout,*)
70         IF(lwp) WRITE(numout,*) 'ldf_eiv : eddy induced velocity coefficients'
71         IF(lwp) WRITE(numout,*) '~~~~~~~'
72      ENDIF
73     
74      ! 0. Local initialization
75      ! -----------------------
76      zn   (:,:) = 0._wp
77      zhw  (:,:) = 5._wp
78      zah  (:,:) = 0._wp
79      zross(:,:) = 0._wp
80
81
82      ! 1. Compute lateral diffusive coefficient
83      ! ----------------------------------------
84      IF( ln_traldf_grif ) THEN
85         DO jk = 1, jpk
86#  if defined key_vectopt_loop 
87!CDIR NOVERRCHK
88            DO ji = 1, jpij   ! vector opt.
89               ! Take the max of N^2 and zero then take the vertical sum
90               ! of the square root of the resulting N^2 ( required to compute
91               ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
92               zn2 = MAX( rn2b(ji,1,jk), 0._wp )
93               zn(ji,1) = zn(ji,1) + SQRT( zn2 ) * fse3w(ji,1,jk)
94               ! Compute elements required for the inverse time scale of baroclinic
95               ! eddies using the isopycnal slopes calculated in ldfslp.F :
96               ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
97               ze3w = fse3w(ji,1,jk) * tmask(ji,1,jk)
98               zah(ji,1) = zah(ji,1) + zn2 * wslp2(ji,1,jk) * ze3w
99               zhw(ji,1) = zhw(ji,1) + ze3w
100            END DO
101#  else
102            DO jj = 2, jpjm1
103!CDIR NOVERRCHK
104               DO ji = 2, jpim1
105                  ! Take the max of N^2 and zero then take the vertical sum
106                  ! of the square root of the resulting N^2 ( required to compute
107                  ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
108                  zn2 = MAX( rn2b(ji,jj,jk), 0._wp )
109                  zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * fse3w(ji,jj,jk)
110                  ! Compute elements required for the inverse time scale of baroclinic
111                  ! eddies using the isopycnal slopes calculated in ldfslp.F :
112                  ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
113                  ze3w = fse3w(ji,jj,jk) * tmask(ji,jj,jk)
114                  zah(ji,jj) = zah(ji,jj) + zn2 * wslp2(ji,jj,jk) * ze3w
115                  zhw(ji,jj) = zhw(ji,jj) + ze3w
116               END DO
117            END DO
118#  endif
119         END DO
120      ELSE
121         DO jk = 1, jpk
122#  if defined key_vectopt_loop 
123!CDIR NOVERRCHK
124            DO ji = 1, jpij   ! vector opt.
125               ! Take the max of N^2 and zero then take the vertical sum
126               ! of the square root of the resulting N^2 ( required to compute
127               ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
128               zn2 = MAX( rn2b(ji,1,jk), 0._wp )
129               zn(ji,1) = zn(ji,1) + SQRT( zn2 ) * fse3w(ji,1,jk)
130               ! Compute elements required for the inverse time scale of baroclinic
131               ! eddies using the isopycnal slopes calculated in ldfslp.F :
132               ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
133               ze3w = fse3w(ji,1,jk) * tmask(ji,1,jk)
134               zah(ji,1) = zah(ji,1) + zn2 * ( wslpi(ji,1,jk) * wslpi(ji,1,jk)   &
135                  &                          + wslpj(ji,1,jk) * wslpj(ji,1,jk) ) * ze3w
136               zhw(ji,1) = zhw(ji,1) + ze3w
137            END DO
138#  else
139            DO jj = 2, jpjm1
140!CDIR NOVERRCHK
141               DO ji = 2, jpim1
142                  ! Take the max of N^2 and zero then take the vertical sum
143                  ! of the square root of the resulting N^2 ( required to compute
144                  ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
145                  zn2 = MAX( rn2b(ji,jj,jk), 0._wp )
146                  zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * fse3w(ji,jj,jk)
147                  ! Compute elements required for the inverse time scale of baroclinic
148                  ! eddies using the isopycnal slopes calculated in ldfslp.F :
149                  ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
150                  ze3w = fse3w(ji,jj,jk) * tmask(ji,jj,jk)
151                  zah(ji,jj) = zah(ji,jj) + zn2 * ( wslpi(ji,jj,jk) * wslpi(ji,jj,jk)   &
152                     &                            + wslpj(ji,jj,jk) * wslpj(ji,jj,jk) ) * ze3w
153                  zhw(ji,jj) = zhw(ji,jj) + ze3w
154               END DO
155            END DO
156#  endif
157         END DO
158      END IF
159
160      DO jj = 2, jpjm1
161!CDIR NOVERRCHK
162         DO ji = fs_2, fs_jpim1   ! vector opt.
163            zfw = MAX( ABS( 2. * omega * SIN( rad * gphit(ji,jj) ) ) , 1.e-10 )
164            ! Rossby radius at w-point taken < 40km and  > 2km
165            zross(ji,jj) = MAX( MIN( .4 * zn(ji,jj) / zfw, 40.e3 ), 2.e3 )
166            ! Compute aeiw by multiplying Ro^2 and T^-1
167            aeiw(ji,jj) = zross(ji,jj) * zross(ji,jj) * SQRT( zah(ji,jj) / zhw(ji,jj) ) * ssmask(ji,jj)
168         END DO
169      END DO
170
171      IF( cp_cfg == "orca" .AND. jp_cfg == 2 ) THEN   ! ORCA R2
172         DO jj = 2, jpjm1
173!CDIR NOVERRCHK
174            DO ji = fs_2, fs_jpim1   ! vector opt.
175               ! Take the minimum between aeiw and 1000 m2/s over shelves (depth shallower than 650 m)
176               IF( mbkt(ji,jj) <= 20 )   aeiw(ji,jj) = MIN( aeiw(ji,jj), 1000. )
177            END DO
178         END DO
179      ENDIF
180
181      ! Decrease the coefficient in the tropics (20N-20S)
182      zf20 = 2._wp * omega * sin( rad * 20._wp )
183      DO jj = 2, jpjm1
184         DO ji = fs_2, fs_jpim1   ! vector opt.
185            aeiw(ji,jj) = MIN( 1., ABS( ff(ji,jj) / zf20 ) ) * aeiw(ji,jj)
186         END DO
187      END DO
188
189      ! ORCA R05: Take the minimum between aeiw  and aeiv0
190      IF( cp_cfg == "orca" .AND. jp_cfg == 05 ) THEN
191         DO jj = 2, jpjm1
192            DO ji = fs_2, fs_jpim1   ! vector opt.
193               aeiw(ji,jj) = MIN( aeiw(ji,jj), aeiv0 )
194            END DO
195         END DO
196      ENDIF
197      CALL lbc_lnk( aeiw, 'W', 1. )      ! lateral boundary condition on aeiw
198
199
200      ! Average the diffusive coefficient at u- v- points
201      DO jj = 2, jpjm1
202         DO ji = fs_2, fs_jpim1   ! vector opt.
203            aeiu(ji,jj) = 0.5_wp * ( aeiw(ji,jj) + aeiw(ji+1,jj  ) )
204            aeiv(ji,jj) = 0.5_wp * ( aeiw(ji,jj) + aeiw(ji  ,jj+1) )
205         END DO
206      END DO
207      CALL lbc_lnk( aeiu, 'U', 1. )   ;   CALL lbc_lnk( aeiv, 'V', 1. )      ! lateral boundary condition
208
209
210      IF(ln_ctl) THEN
211         CALL prt_ctl(tab2d_1=aeiu, clinfo1=' eiv  - u: ', ovlap=1)
212         CALL prt_ctl(tab2d_1=aeiv, clinfo1=' eiv  - v: ', ovlap=1)
213      ENDIF
214
215      ! ORCA R05: add a space variation on aht (=aeiv except at the equator and river mouth)
216      IF( cp_cfg == "orca" .AND. jp_cfg == 05 ) THEN
217         zf20     = 2._wp * omega * SIN( rad * 20._wp )
218         zaht_min = 100._wp                           ! minimum value for aht
219         DO jj = 1, jpj
220            DO ji = 1, jpi
221               zaht      = ( 1._wp -  MIN( 1._wp , ABS( ff(ji,jj) / zf20 ) ) ) * ( aht0 - zaht_min )  &
222                  &      + aht0 * rnfmsk(ji,jj)                          ! enhanced near river mouths
223               ahtu(ji,jj) = MAX( MAX( zaht_min, aeiu(ji,jj) ) + zaht, aht0 )
224               ahtv(ji,jj) = MAX( MAX( zaht_min, aeiv(ji,jj) ) + zaht, aht0 )
225               ahtw(ji,jj) = MAX( MAX( zaht_min, aeiw(ji,jj) ) + zaht, aht0 )
226            END DO
227         END DO
228         IF(ln_ctl) THEN
229            CALL prt_ctl(tab2d_1=ahtu, clinfo1=' aht  - u: ', ovlap=1)
230            CALL prt_ctl(tab2d_1=ahtv, clinfo1=' aht  - v: ', ovlap=1)
231            CALL prt_ctl(tab2d_1=ahtw, clinfo1=' aht  - w: ', ovlap=1)
232         ENDIF
233      ENDIF
234
235      IF( aeiv0 == 0._wp ) THEN
236         aeiu(:,:) = 0._wp
237         aeiv(:,:) = 0._wp
238         aeiw(:,:) = 0._wp
239      ENDIF
240
241      CALL iom_put( "aht2d"    , ahtw )   ! lateral eddy diffusivity
242      CALL iom_put( "aht2d_eiv", aeiw )   ! EIV lateral eddy diffusivity
243     
244      CALL wrk_dealloc( jpi,jpj, zn, zah, zhw, zross )
245      !
246      IF( nn_timing == 1 )  CALL timing_stop('ldf_eiv')
247      !
248   END SUBROUTINE ldf_eiv
249
250#else
251   !!----------------------------------------------------------------------
252   !!   Default option                                         Dummy module
253   !!----------------------------------------------------------------------
254CONTAINS
255   SUBROUTINE ldf_eiv( kt )       ! Empty routine
256      INTEGER :: kt
257      WRITE(*,*) 'ldf_eiv: You should not have seen this print! error?', kt
258   END SUBROUTINE ldf_eiv
259#endif
260
261   !!======================================================================
262END MODULE ldfeiv
Note: See TracBrowser for help on using the repository browser.