New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zpshde.F90 in branches/2014/dev_r4650_UKMO2_ice_shelves/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2014/dev_r4650_UKMO2_ice_shelves/NEMOGCM/NEMO/OPA_SRC/TRA/zpshde.F90 @ 4724

Last change on this file since 4724 was 4724, checked in by mathiot, 10 years ago

ISF branch: add comments, fix mpp and restar issues, add test to stop if incompatible options and fix mask issue in sbcice and sbcblk.
  • Property svn:keywords set to Id
File size: 23.4 KB
Line 
1MODULE zpshde
2   !!======================================================================
3   !!                       ***  MODULE zpshde   ***
4   !! z-coordinate + partial step : Horizontal Derivative at ocean bottom level
5   !!======================================================================
6   !! History :  OPA  !  2002-04  (A. Bozec)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec E. Durand)  Optimization and Free form
8   !!             -   !  2004-03  (C. Ethe)  adapted for passive tracers
9   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
10   !!======================================================================
11   
12   !!----------------------------------------------------------------------
13   !!   zps_hde      :  Horizontal DErivative of T, S and rd at the last
14   !!                   ocean level (Z-coord. with Partial Steps)
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean: dynamics and tracers variables
17   USE dom_oce         ! domain: ocean variables
18   USE phycst          ! physical constants
19   USE eosbn2          ! ocean equation of state
20   USE in_out_manager  ! I/O manager
21   USE lbclnk          ! lateral boundary conditions (or mpp link)
22   USE lib_mpp         ! MPP library
23   USE wrk_nemo        ! Memory allocation
24   USE timing          ! Timing
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   zps_hde    ! routine called by step.F90
30
31   !! * Substitutions
32#  include "domzgr_substitute.h90"
33#  include "vectopt_loop_substitute.h90"
34   !!----------------------------------------------------------------------
35   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
36   !! $Id$
37   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
38   !!----------------------------------------------------------------------
39CONTAINS
40
41   SUBROUTINE zps_hde( kt, kjpt, pta, pgtu, pgtv,   &
42      &                          prd, pgru, pgrv, pmru, pmrv, pgzu, pgzv, pge3ru, pge3rv,  &
43      &                   sgtu, sgtv, sgru, sgrv, smru, smrv, sgzu, sgzv, sge3ru, sge3rv )
44      !!----------------------------------------------------------------------
45      !!                     ***  ROUTINE zps_hde  ***
46      !!                   
47      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
48      !!      at u- and v-points with a linear interpolation for z-coordinate
49      !!      with partial steps.
50      !!
51      !! ** Method  :   In z-coord with partial steps, scale factors on last
52      !!      levels are different for each grid point, so that T, S and rd
53      !!      points are not at the same depth as in z-coord. To have horizontal
54      !!      gradients again, we interpolate T and S at the good depth :
55      !!      Linear interpolation of T, S   
56      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
57      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
58      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
59      !!         This formulation computes the two cases:
60      !!                 CASE 1                   CASE 2 
61      !!         k-1  ___ ___________   k-1   ___ ___________
62      !!                    Ti  T~                  T~  Ti+1
63      !!                  _____                        _____
64      !!         k        |   |Ti+1     k           Ti |   |
65      !!                  |   |____                ____|   |
66      !!              ___ |   |   |           ___  |   |   |
67      !!                 
68      !!      case 1->   e3w(i+1) >= e3w(i) ( and e3w(j+1) >= e3w(j) ) then
69      !!          t~ = t(i+1,j  ,k) + (e3w(i+1) - e3w(i)) * dk(Ti+1)/e3w(i+1)
70      !!        ( t~ = t(i  ,j+1,k) + (e3w(j+1) - e3w(j)) * dk(Tj+1)/e3w(j+1)  )
71      !!          or
72      !!      case 2->   e3w(i+1) <= e3w(i) ( and e3w(j+1) <= e3w(j) ) then
73      !!          t~ = t(i,j,k) + (e3w(i) - e3w(i+1)) * dk(Ti)/e3w(i )
74      !!        ( t~ = t(i,j,k) + (e3w(j) - e3w(j+1)) * dk(Tj)/e3w(j ) )
75      !!          Idem for di(s) and dj(s)         
76      !!
77      !!      For rho, we call eos_insitu_2d which will compute rd~(t~,s~) at
78      !!      the good depth zh from interpolated T and S for the different
79      !!      formulation of the equation of state (eos).
80      !!      Gradient formulation for rho :
81      !!          di(rho) = rd~ - rd(i,j,k) or rd(i+1,j,k) - rd~
82      !!
83      !! ** Action  : compute for top and bottom interfaces
84      !!              - pgtu, pgtv, sgtu, sgtv: horizontal gradient of tracer at u- & v-points
85      !!              - pgru, pgrv, sgru, sgtv: horizontal gradient of rho (if present) at u- & v-points
86      !!              - pmru, pmrv, smru, smrv: horizontal sum of rho at u- & v- point (used in dynhpg with vvl)
87      !!              - pgzu, pgzv, sgzu, sgzv: horizontal gradient of z at u- and v- point (used in dynhpg with vvl)
88      !!              - pge3ru, pge3rv, sge3ru, sge3rv: horizontal gradient of rho weighted by local e3w at u- & v-points
89      !!----------------------------------------------------------------------
90      !
91      INTEGER                              , INTENT(in   )           ::  kt          ! ocean time-step index
92      INTEGER                              , INTENT(in   )           ::  kjpt        ! number of tracers
93      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   )           ::  pta         ! 4D tracers fields
94      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
95      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  sgtu, sgtv  ! hor. grad. of stra at u- & v-pts (ISF)
96      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ), OPTIONAL ::  prd         ! 3D density anomaly fields
97      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgru, pgrv      ! hor. grad of prd at u- & v-pts (bottom)
98      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pmru, pmrv      ! hor. sum  of prd at u- & v-pts (bottom)
99      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgzu, pgzv      ! hor. grad of z   at u- & v-pts (bottom)
100      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pge3ru, pge3rv  ! hor. grad of prd weighted by local e3w at u- & v-pts (bottom)
101      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  sgru, sgrv      ! hor. grad of prd at u- & v-pts (top)
102      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  smru, smrv      ! hor. sum  of prd at u- & v-pts (top)
103      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  sgzu, sgzv      ! hor. grad of z   at u- & v-pts (top)
104      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  sge3ru, sge3rv  ! hor. grad of prd weighted by local e3w at u- & v-pts (top)
105      !
106      INTEGER  ::   ji, jj, jn      ! Dummy loop indices
107      INTEGER  ::   iku, ikv, ikum1, ikvm1,ikup1, ikvp1   ! partial step level (ocean bottom level) at u- and v-points
108      REAL(wp) ::  ze3wu, ze3wv, zmaxu, zmaxv, zdzwu, zdzwv, zdzwuip1, zdzwvjp1  ! temporary scalars
109      REAL(wp), POINTER, DIMENSION(:,:  ) ::  zri, zrj, zhi, zhj
110      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zti, ztj    ! interpolated value of tracer
111      !!----------------------------------------------------------------------
112      !
113      IF( nn_timing == 1 )  CALL timing_start( 'zps_hde')
114      !
115      CALL wrk_alloc( jpi, jpj,       zri, zrj, zhi, zhj ) 
116      CALL wrk_alloc( jpi, jpj, kjpt, zti, ztj           ) 
117      !
118      pgru(:,:)=0.0_wp ; pgrv(:,:)=0.0_wp ; pgtu(:,:,:)=0.0_wp ; pgtv(:,:,:)=0.0_wp ;
119      !
120      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
121         !
122# if defined key_vectopt_loop
123         jj = 1
124         DO ji = 1, jpij-jpi   ! vector opt. (forced unrolled)
125# else
126         DO jj = 1, jpjm1
127            DO ji = 1, jpim1
128# endif
129               iku = mbku(ji,jj)   ;   ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
130               ikv = mbkv(ji,jj)   ;   ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
131               ! (ISF) case partial step top and bottom in adjacent cell in vertical
132               ze3wu  = (fsdept(ji+1,jj,iku) - fsdepw(ji+1,jj,iku)) - (fsdept(ji,jj,iku) - fsdepw(ji,jj,iku))
133               ze3wv  = (fsdept(ji,jj+1,ikv) - fsdepw(ji,jj+1,ikv)) - (fsdept(ji,jj,ikv) - fsdepw(ji,jj,ikv))
134               !
135               ! i- direction
136               IF (iku .GT. 1) THEN
137               IF( ze3wu >= 0._wp ) THEN      ! case 1
138                  zmaxu =  ze3wu / fse3w(ji+1,jj,iku)
139                  ! interpolated values of tracers
140                  zti(ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
141                  ! gradient of  tracers
142                  pgtu(ji,jj,jn) = umask(ji,jj,iku) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
143                  pgzu(ji,jj)    = (fsde3w(ji+1,jj,iku) - ze3wu) - fsde3w(ji,jj,iku)
144               ELSE                           ! case 2
145                  zmaxu = -ze3wu / fse3w(ji,jj,iku)
146                  ! interpolated values of tracers
147                  zti(ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
148                  ! gradient of tracers
149                  pgtu(ji,jj,jn) = umask(ji,jj,iku) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
150                  pgzu(ji,jj)    = fsde3w(ji+1,jj,iku) - (fsde3w(ji,jj,iku) + ze3wu)
151               ENDIF
152               ENDIF
153               !
154               ! j- direction
155               IF (ikv .GT. 1) THEN
156               IF( ze3wv >= 0._wp ) THEN      ! case 1
157                  zmaxv =  ze3wv / fse3w(ji,jj+1,ikv)
158                  ! interpolated values of tracers
159                  ztj(ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
160                  ! gradient of tracers
161                  pgtv(ji,jj,jn) = vmask(ji,jj,ikv) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
162                  pgzv(ji,jj)    = (fsde3w(ji,jj+1,ikv) - ze3wv) - fsde3w(ji,jj,ikv) 
163               ELSE                           ! case 2
164                  zmaxv =  -ze3wv / fse3w(ji,jj,ikv)
165                  ! interpolated values of tracers
166                  ztj(ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
167                  ! gradient of tracers
168                  pgtv(ji,jj,jn) = vmask(ji,jj,ikv) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
169                  pgzv(ji,jj)    = fsde3w(ji,jj+1,ikv) - (fsde3w(ji,jj,ikv) + ze3wv)
170               ENDIF
171               ENDIF
172# if ! defined key_vectopt_loop
173            END DO
174# endif
175         END DO
176         CALL lbc_lnk( pgtu(:,:,jn), 'U', -1. )   ;   CALL lbc_lnk( pgtv(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
177         !
178      END DO
179
180      ! horizontal derivative of density anomalies (rd)
181      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
182# if defined key_vectopt_loop
183         jj = 1
184         DO ji = 1, jpij-jpi   ! vector opt. (forced unrolled)
185# else
186         DO jj = 1, jpjm1
187            DO ji = 1, jpim1
188# endif
189               iku = mbku(ji,jj)
190               ikv = mbkv(ji,jj)
191               ze3wu  = (fsdept(ji+1,jj,iku) - fsdepw(ji+1,jj,iku)) - (fsdept(ji,jj,iku) - fsdepw(ji,jj,iku))
192               ze3wv  = (fsdept(ji,jj+1,ikv) - fsdepw(ji,jj+1,ikv)) - (fsdept(ji,jj,ikv) - fsdepw(ji,jj,ikv))
193
194               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = fsdept(ji  ,jj,iku)     ! i-direction: case 1
195               ELSE                        ;   zhi(ji,jj) = fsdept(ji+1,jj,iku)     ! -     -      case 2
196               ENDIF
197               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = fsdept(ji,jj  ,ikv)     ! j-direction: case 1
198               ELSE                        ;   zhj(ji,jj) = fsdept(ji,jj+1,ikv)     ! -     -      case 2
199               ENDIF
200# if ! defined key_vectopt_loop
201            END DO
202# endif
203         END DO
204         
205         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
206         ! step and store it in  zri, zrj for each  case
207         CALL eos( zti, zhi, zri ) 
208         CALL eos( ztj, zhj, zrj )
209
210         ! Gradient of density at the last level
211# if defined key_vectopt_loop
212         jj = 1
213         DO ji = 1, jpij-jpi   ! vector opt. (forced unrolled)
214# else
215         DO jj = 1, jpjm1
216            DO ji = 1, jpim1
217# endif
218               iku = mbku(ji,jj) ; ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
219               ikv = mbkv(ji,jj) ; ikvm1 = MAX( ikv - 1 , 1 )    ! last and before last ocean level at u- & v-points
220               ze3wu  = (fsdept(ji+1,jj,iku) - fsdepw(ji+1,jj,iku)) - (fsdept(ji,jj,iku) - fsdepw(ji,jj,iku))
221               ze3wv  = (fsdept(ji,jj+1,ikv) - fsdepw(ji,jj+1,ikv)) - (fsdept(ji,jj,ikv) - fsdepw(ji,jj,ikv))
222               IF( ze3wu >= 0._wp ) THEN
223                  pgru(ji,jj) = umask(ji,jj,iku) * ( zri(ji  ,jj) - prd(ji,jj,iku) )   ! i: 1
224                  pmru(ji,jj) = umask(ji,jj,iku) * ( zri(ji  ,jj) + prd(ji,jj,iku) )   ! i:
225                  pge3ru(ji,jj) = umask(ji,jj,iku)                                                                  &
226                                * ( (fse3w(ji+1,jj,iku) - ze3wu )* ( zri(ji  ,jj    ) + prd(ji+1,jj,ikum1) + 2._wp) &
227                                   - fse3w(ji  ,jj,iku)          * ( prd(ji  ,jj,iku) + prd(ji  ,jj,ikum1) + 2._wp) )  ! j: 2
228               ELSE 
229                  pgru(ji,jj) = umask(ji,jj,iku) * ( prd(ji+1,jj,iku) - zri(ji,jj) )   ! i: 2
230                  pmru(ji,jj) = umask(ji,jj,iku) * ( prd(ji+1,jj,iku) + zri(ji,jj) )   ! i: 2
231                  pge3ru(ji,jj) = umask(ji,jj,iku)                                                                  &
232                                * (  fse3w(ji+1,jj,iku)          * ( prd(ji+1,jj,iku) + prd(ji+1,jj,ikum1) + 2._wp) &
233                                   -(fse3w(ji  ,jj,iku) + ze3wu) * ( zri(ji  ,jj    ) + prd(ji  ,jj,ikum1) + 2._wp) )  ! j: 2
234               ENDIF
235               IF( ze3wv >= 0._wp ) THEN
236                  pgrv(ji,jj) = vmask(ji,jj,ikv) * ( zrj(ji,jj  ) - prd(ji,jj,ikv) )   ! j: 1
237                  pmrv(ji,jj) = vmask(ji,jj,ikv) * ( zrj(ji,jj  ) + prd(ji,jj,ikv) )   ! j: 1
238                  pge3rv(ji,jj) = vmask(ji,jj,ikv)                                                                  &
239                                * ( (fse3w(ji,jj+1,ikv) - ze3wv )* ( zrj(ji,jj      ) + prd(ji,jj+1,ikvm1) + 2._wp) &
240                                   - fse3w(ji,jj  ,ikv)          * ( prd(ji,jj  ,ikv) + prd(ji,jj  ,ikvm1) + 2._wp) )  ! j: 2
241               ELSE
242                  pgrv(ji,jj) = vmask(ji,jj,ikv) * ( prd(ji,jj+1,ikv) - zrj(ji,jj) )   ! j: 2
243                  pmrv(ji,jj) = vmask(ji,jj,ikv) * ( prd(ji,jj+1,ikv) + zrj(ji,jj) )   ! j: 2
244                  pge3rv(ji,jj) = vmask(ji,jj,ikv)                                                                  &
245                                * (  fse3w(ji,jj+1,ikv)          * ( prd(ji,jj+1,ikv) + prd(ji,jj+1,ikvm1) + 2._wp) &
246                                   -(fse3w(ji,jj  ,ikv) + ze3wv) * ( zrj(ji,jj      ) + prd(ji,jj  ,ikvm1) + 2._wp) )  ! j: 2
247               ENDIF
248# if ! defined key_vectopt_loop
249            END DO
250# endif
251         END DO
252         CALL lbc_lnk( pgru   , 'U', -1. )   ;   CALL lbc_lnk( pgrv   , 'V', -1. )   ! Lateral boundary conditions
253         CALL lbc_lnk( pmru   , 'U',  1. )   ;   CALL lbc_lnk( pmrv   , 'V',  1. )   ! Lateral boundary conditions
254         CALL lbc_lnk( pgzu   , 'U', -1. )   ;   CALL lbc_lnk( pgzv   , 'V', -1. )   ! Lateral boundary conditions
255         CALL lbc_lnk( pge3ru , 'U', -1. )   ;   CALL lbc_lnk( pge3rv , 'V', -1. )   ! Lateral boundary conditions
256         !
257      END IF
258         ! (ISH)  compute grui and gruvi
259      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!            !
260# if defined key_vectopt_loop
261         jj = 1
262         DO ji = 1, jpij-jpi   ! vector opt. (forced unrolled)
263# else
264         DO jj = 1, jpjm1
265            DO ji = 1, jpim1
266# endif
267               iku = miku(ji,jj)   ;  ikup1 = miku(ji,jj) + 1
268               ikv = mikv(ji,jj)   ;  ikvp1 = mikv(ji,jj) + 1
269               ze3wu  = fse3w(ji+1,jj  ,iku+1) - fse3w(ji,jj,iku+1)
270               ze3wv  = fse3w(ji  ,jj+1,ikv+1) - fse3w(ji,jj,ikv+1)
271               !
272               ! i- direction
273               IF( ze3wu >= 0._wp ) THEN      ! case 1
274                  zmaxu = ze3wu / fse3w(ji+1,jj,iku+1)
275                  ! interpolated values of tracers
276                  zti(ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,iku+1,jn) - pta(ji+1,jj,iku,jn) )
277                  ! gradient of tracers
278                  sgtu(ji,jj,jn) = umask(ji,jj,iku) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
279                  sgzu(ji,jj)    = (fsde3w(ji+1,jj,iku) + ze3wu) - fsde3w(ji,jj,iku)
280               ELSE                           ! case 2
281                  zmaxu = - ze3wu / fse3w(ji,jj,iku+1)
282                  ! interpolated values of tracers
283                  zti(ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,iku+1,jn) - pta(ji,jj,iku,jn) )
284                  sgtu(ji,jj,jn) = umask(ji,jj,iku) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
285                  ! gradient of  tracers
286                  sgzu(ji,jj)    = fsde3w(ji+1,jj,iku) - (fsde3w(ji,jj,iku) - ze3wu)
287               ENDIF
288               !
289               ! j- direction
290               IF( ze3wv >= 0._wp ) THEN      ! case 1
291                  zmaxv =  ze3wv / fse3w(ji,jj+1,ikv+1)
292                  ! interpolated values of tracers
293                  ztj(ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikv+1,jn) - pta(ji,jj+1,ikv,jn) )
294                  ! gradient of tracers
295                  sgtv(ji,jj,jn) = vmask(ji,jj,ikv) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
296                  sgzv(ji,jj)    = (fsde3w(ji,jj+1,ikv) + ze3wv) - fsde3w(ji,jj,ikv) 
297               ELSE                           ! case 2
298                  zmaxv =  - ze3wv / fse3w(ji,jj,ikv+1)
299                  ! interpolated values of tracers
300                  ztj(ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikv+1,jn) - pta(ji,jj,ikv,jn) )
301                  ! gradient of tracers
302                  sgtv(ji,jj,jn) = vmask(ji,jj,ikv) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
303                  sgzv(ji,jj)    = fsde3w(ji,jj+1,ikv) - (fsde3w(ji,jj,ikv) - ze3wv)
304               ENDIF
305# if ! defined key_vectopt_loop
306            END DO
307# endif
308         END DO!!
309         CALL lbc_lnk( sgtu(:,:,jn), 'U', -1. )   ;   CALL lbc_lnk( sgtv(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
310         !
311      END DO
312
313      ! horizontal derivative of density anomalies (rd)
314      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
315# if defined key_vectopt_loop
316         jj = 1
317         DO ji = 1, jpij-jpi   ! vector opt. (forced unrolled)
318# else
319         DO jj = 1, jpjm1
320            DO ji = 1, jpim1
321# endif
322               iku = miku(ji,jj)
323               ikv = mikv(ji,jj)
324               ze3wu  = fse3w(ji+1,jj  ,iku+1) - fse3w(ji,jj,iku+1)
325               ze3wv  = fse3w(ji  ,jj+1,ikv+1) - fse3w(ji,jj,ikv+1)
326
327               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = fsdept(ji  ,jj,iku)     ! i-direction: case 1
328               ELSE                        ;   zhi(ji,jj) = fsdept(ji+1,jj,iku)     ! -     -      case 2
329               ENDIF
330               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = fsdept(ji,jj  ,ikv)     ! j-direction: case 1
331               ELSE                        ;   zhj(ji,jj) = fsdept(ji,jj+1,ikv)     ! -     -      case 2
332               ENDIF
333# if ! defined key_vectopt_loop
334            END DO
335# endif
336         END DO
337
338         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
339         ! step and store it in  zri, zrj for each  case
340         CALL eos( zti, zhi, zri ) 
341         CALL eos( ztj, zhj, zrj )
342
343         ! Gradient of density at the last level
344# if defined key_vectopt_loop
345         jj = 1
346         DO ji = 1, jpij-jpi   ! vector opt. (forced unrolled)
347# else
348         DO jj = 1, jpjm1
349            DO ji = 1, jpim1
350# endif
351               iku = miku(ji,jj) ; ikup1 = miku(ji,jj) + 1
352               ikv = mikv(ji,jj) ; ikvp1 = mikv(ji,jj) + 1
353               ze3wu  = fse3w(ji+1,jj  ,iku+1) - fse3w(ji,jj,iku+1)
354               ze3wv  = fse3w(ji  ,jj+1,ikv+1) - fse3w(ji,jj,ikv+1)
355               IF( ze3wu >= 0._wp ) THEN
356                 sgru  (ji,jj) = umask(ji,jj,iku)   * ( zri(ji,jj) - prd(ji,jj,iku) )          ! i: 1
357                 smru  (ji,jj) = umask(ji,jj,iku)   * ( zri(ji,jj) + prd(ji,jj,iku) )          ! i: 1
358                 sge3ru(ji,jj) = umask(ji,jj,iku+1)                                                                  &
359                                * ( (fse3w(ji+1,jj,iku+1) - ze3wu) * (zri(ji,jj    ) + prd(ji+1,jj,iku+1) + 2._wp)   &
360                                   - fse3w(ji  ,jj,iku+1)          * (prd(ji,jj,iku) + prd(ji  ,jj,iku+1) + 2._wp)   ) ! i: 1
361               ELSE
362                 sgru  (ji,jj) = umask(ji,jj,iku)   * ( prd(ji+1,jj,iku) - zri(ji,jj) )      ! i: 2
363                 smru  (ji,jj) = umask(ji,jj,iku)   * ( prd(ji+1,jj,iku) + zri(ji,jj) )      ! i: 2
364                 sge3ru(ji,jj) = umask(ji,jj,iku+1)                                                                   &
365                                * (  fse3w(ji+1,jj,iku+1)          * (prd(ji+1,jj,iku) + prd(ji+1,jj,iku+1) + 2._wp)  &
366                                   -(fse3w(ji  ,jj,iku+1) + ze3wu) * (zri(ji,jj      ) + prd(ji  ,jj,iku+1) + 2._wp)  )     ! i: 2
367               ENDIF
368               IF( ze3wv >= 0._wp ) THEN
369                 sgrv  (ji,jj) = vmask(ji,jj,ikv)   * ( zrj(ji,jj  ) - prd(ji,jj,ikv) )        ! j: 1
370                 smrv  (ji,jj) = vmask(ji,jj,ikv)   * ( zrj(ji,jj  ) + prd(ji,jj,ikv) )        ! j: 1
371                 sge3rv(ji,jj) = vmask(ji,jj,ikv+1)                                                                  & 
372                                * ( (fse3w(ji,jj+1,ikv+1) - ze3wv) * ( zrj(ji,jj    ) + prd(ji,jj+1,ikv+1) + 2._wp)  &
373                                   - fse3w(ji,jj  ,ikv+1)          * ( prd(ji,jj,ikv) + prd(ji,jj  ,ikv+1) + 2._wp)  ) ! j: 1
374                                  ! + 2 due to the formulation in density and not in anomalie in hpg sco
375               ELSE
376                 sgrv  (ji,jj) = vmask(ji,jj,ikv)   * ( prd(ji,jj+1,ikv) - zrj(ji,jj) )     ! j: 2
377                 smrv  (ji,jj) = vmask(ji,jj,ikv)   * ( prd(ji,jj+1,ikv) + zrj(ji,jj) )     ! j: 2
378                 sge3rv(ji,jj) = vmask(ji,jj,ikv+1)                                                                   &
379                                * (  fse3w(ji,jj+1,ikv+1)          * ( prd(ji,jj+1,ikv) + prd(ji,jj+1,ikv+1) + 2._wp) &
380                                   -(fse3w(ji,jj  ,ikv+1) + ze3wv) * ( zrj(ji,jj      ) + prd(ji,jj  ,ikv+1) + 2._wp) )  ! j: 2
381               ENDIF
382# if ! defined key_vectopt_loop
383            END DO
384# endif
385         END DO
386         CALL lbc_lnk( sgru   , 'U', -1. )   ;   CALL lbc_lnk( sgrv   , 'V', -1. )   ! Lateral boundary conditions
387         CALL lbc_lnk( smru   , 'U',  1. )   ;   CALL lbc_lnk( smrv   , 'V',  1. )   ! Lateral boundary conditions
388         CALL lbc_lnk( sgzu   , 'U', -1. )   ;   CALL lbc_lnk( sgzv   , 'V', -1. )   ! Lateral boundary conditions
389         CALL lbc_lnk( sge3ru , 'U', -1. )   ;   CALL lbc_lnk( sge3rv , 'V', -1. )   ! Lateral boundary conditions
390         !
391      END IF 
392      !
393      CALL wrk_dealloc( jpi, jpj,       zri, zrj, zhi, zhj) 
394      CALL wrk_dealloc( jpi, jpj, kjpt, zti, ztj           ) 
395      !
396      IF( nn_timing == 1 )  CALL timing_stop( 'zps_hde')
397      !
398   END SUBROUTINE zps_hde
399
400   !!======================================================================
401END MODULE zpshde
Note: See TracBrowser for help on using the repository browser.